Porovnávanie stĺpcov v programe Excel je niečo, čo raz za čas robíme všetci. Microsoft Excel ponúka niekoľko možností na porovnávanie a porovnávanie údajov, ale väčšina z nich sa zameriava na vyhľadávanie v jednom stĺpci. V tomto návode preskúmame niekoľko techník na porovnať dva stĺpce v programe Excel a nájsť medzi nimi zhody a rozdiely.

Ako porovnať 2 stĺpce v programe Excel riadok po riadku

Pri analýze údajov v programe Excel je jednou z najčastejších úloh porovnávanie údajov v jednotlivých riadkoch. Túto úlohu možno vykonať pomocou funkcie IF, ako je uvedené v nasledujúcich príkladoch.

Príklad 1. Porovnanie dvoch stĺpcov na zhodu alebo rozdiel v tom istom riadku

Ak chcete porovnať dva stĺpce v programe Excel riadok po riadku, napíšte bežný vzorec IF, ktorý porovnáva prvé dve bunky. Zadajte vzorec do iného stĺpca v tom istom riadku a potom ho skopírujte do ďalších buniek potiahnutím úchytu výplne (malý štvorček v pravom dolnom rohu vybranej bunky). Kurzor sa pri tom zmení na znamienko plus:

Vzorec pre zápasy

Ak chcete nájsť bunky v rámci toho istého riadku s rovnakým obsahom, v tomto príklade A2 a B2, vzorec je nasledujúci:

=IF(A2=B2,"Match","")

Vzorec pre rozdiely

Ak chcete nájsť bunky v tom istom riadku s rôznymi hodnotami, jednoducho nahraďte znak rovnosti znakom nerovnosti ():

=IF(A2B2, "Žiadna zhoda","")

Zhody a rozdiely

A samozrejme, nič vám nebráni nájsť zhodu aj rozdiely pomocou jediného vzorca:

=IF(A2=B2, "Zhoda", "Žiadna zhoda")

Alebo

=IF(A2B2, "Žiadna zhoda", "Zhoda")

Výsledok môže vyzerať podobne:

Ako vidíte, vzorec rieši čísla , dátumy , krát a textové reťazce rovnako dobre.

Tip. Pomocou pokročilého filtra programu Excel môžete tiež porovnávať dva stĺpce po riadkoch. Tu je príklad, ktorý ukazuje, ako filtrovať zhody a rozdiely medzi 2 stĺpcami.

Príklad 2. Porovnanie dvoch zoznamov pre zhody rozlišujúce veľké a malé písmená v tom istom riadku

Ako ste si pravdepodobne všimli, vzorce z predchádzajúceho príkladu pri porovnávaní textových hodnôt ignorujú veľkosť písmen, ako je to v riadku 10 na vyššie uvedenej snímke. zhody rozlišujúce malé a veľké písmená medzi 2 stĺpcami v každom riadku, potom použite funkciu EXACT:

=IF(EXACT(A2, B2), "Match", "")

Nájsť rozdiely citlivé na veľkosť písmen v tom istom riadku zadajte príslušný text ("Unique" v tomto príklade) do 3. argumentu funkcie IF, napr:

=IF(EXACT(A2, B2), "Match", "Unique")

Porovnanie viacerých stĺpcov na zhody v tom istom riadku

V hárkoch programu Excel môžete porovnávať viacero stĺpcov na základe nasledujúcich kritérií:

• Nájdite riadky s rovnakými hodnotami v všetky stĺpce (Príklad 1)
• Nájdite riadky s rovnakými hodnotami v ľubovoľné 2 stĺpce (Príklad 2)

Príklad 1. Nájdite zhody vo všetkých bunkách v rámci toho istého riadku

Ak má vaša tabuľka tri alebo viac stĺpcov a chcete nájsť riadky, ktoré majú rovnaké hodnoty vo všetkých bunkách, vzorec IF s príkazom AND bude fungovať veľmi dobre:

=IF(AND(A2=B2, A2=C2), "Úplná zhoda", "")

Ak má vaša tabuľka veľa stĺpcov, elegantnejším riešením by bolo použitie funkcie COUNTIF:

=IF(COUNTIF($A2:$E2, $A2)=5, "Úplná zhoda", "")

Kde 5 je počet porovnávaných stĺpcov.

Príklad 2. Nájdite zhodu v ľubovoľných dvoch bunkách v tom istom riadku

Ak hľadáte spôsob, ako porovnať stĺpce pre akékoľvek dve alebo viac buniek s rovnakými hodnotami v rámci jedného riadku, použite vzorec IF s príkazom OR:

=IF(OR(A2=B2, B2=C2, A2=C2), "Zhoda", "")

V prípade, že je stĺpcov na porovnanie veľa, môže váš príkaz OR narásť do príliš veľkej veľkosti. V tomto prípade by bolo lepším riešením sčítanie niekoľkých funkcií COUNTIF. Prvá COUNTIF spočíta, koľko stĺpcov má rovnakú hodnotu ako v 1. stĺpci, druhá COUNTIF spočíta, koľko zo zvyšných stĺpcov sa rovná 2. stĺpcu atď. Ak je počet 0, vzorec vráti "Unique","Match" inak. Napríklad:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Unique", "Match")

Ako porovnať dva stĺpce v programe Excel na zhody a rozdiely

Predpokladajme, že máte v programe Excel 2 zoznamy údajov a chcete nájsť všetky hodnoty (čísla, dátumy alebo textové reťazce), ktoré sa nachádzajú v stĺpci A, ale nie v stĺpci B.

Na tento účel môžete do logického testu IF vložiť funkciu COUNTIF($B:$B, $A2)=0 a skontrolovať, či vráti nulu (nebola nájdená žiadna zhoda) alebo akékoľvek iné číslo (bola nájdená aspoň 1 zhoda).

Napríklad nasledujúci vzorec IF/COUNTIF hľadá v celom stĺpci B hodnotu v bunke A2. Ak sa nenájde žiadna zhoda, vzorec vráti "Žiadna zhoda v B", inak prázdny reťazec:

=IF(COUNTIF($B:$B, $A2)=0, "Žiadna zhoda v B", "")

Tip. Ak má vaša tabuľka pevný počet riadkov, môžete zadať určitý rozsah (napr. $B2:$B10) namiesto celého stĺpca ($B:$B), aby vzorec pracoval rýchlejšie pri veľkých súboroch údajov.

Rovnaký výsledok možno dosiahnuť použitím vzorca IF s vloženými funkciami ISERROR a MATCH:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Žiadna zhoda v B","")

Alebo pomocou nasledujúceho vzorca (nezabudnite stlačiť klávesovú skratku Ctrl + Shift + Enter, aby ste ho zadali správne):

=IF(SUM(--($B$2:$B$10=$A2))=0, " Žiadna zhoda v B", "")

Ak chcete, aby jeden vzorec identifikoval zhody (duplikáty) aj rozdiely (jedinečné hodnoty), vložte text pre zhody do prázdnych dvojitých úvodzoviek ("") v ktoromkoľvek z uvedených vzorcov:

=IF(COUNTIF($B:$B, $A2)=0, "Žiadna zhoda v B", "Zhoda v B")

Ako porovnať dva zoznamy v programe Excel a vytiahnuť zhody

Niekedy môžete potrebovať nielen porovnať dva stĺpce v dvoch rôznych tabuľkách, ale aj vytiahnuť zodpovedajúce záznamy z vyhľadávacej tabuľky. Microsoft Excel na to poskytuje špeciálnu funkciu - funkciu VLOOKUP. Ako alternatívu môžete použiť výkonnejší a univerzálnejší vzorec INDEX MATCH. Používatelia aplikácií Excel 2021 a Excel 365, môžu túto úlohu vykonať pomocou funkcie XLOOKUP.

Napríklad nasledujúce vzorce porovnávajú názvy výrobkov v stĺpcoch D s názvami v stĺpci A a v prípade zistenia zhody vytiahnu zo stĺpca B zodpovedajúci údaj o predaji, inak sa vráti chyba #N/A.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

Viac informácií nájdete v časti Ako porovnať dva stĺpce pomocou VLOOKUP.

Ak sa so vzorcami necítite príliš pohodlne, môžete prácu vykonať pomocou rýchleho a intuitívneho riešenia - Sprievodcu zlúčením tabuliek.

Porovnanie dvoch zoznamov a zvýraznenie zhody a rozdielov

Pri porovnávaní stĺpcov v programe Excel môžete chcieť "vizualizovať" položky, ktoré sú prítomné v jednom stĺpci, ale chýbajú v druhom. Takéto bunky môžete pomocou funkcie podmieneného formátovania programu Excel odtieniť ľubovoľnou farbou podľa vlastného výberu a nasledujúce príklady ukazujú podrobný postup.

Príklad 1. Zvýraznite zhody a rozdiely v každom riadku

Porovnanie dvoch stĺpcov a programu Excel a zvýraznenie buniek v stĺpci A, ktoré majú identické záznamy v stĺpci B v tom istom riadku vykonajte nasledujúce kroky:

• Vyberte bunky, ktoré chcete zvýrazniť (môžete vybrať bunky v rámci jedného stĺpca alebo v niekoľkých stĺpcoch, ak chcete vyfarbiť celé riadky).
• Kliknite na . Podmienené formátovanie> Nové pravidlo.> Pomocou vzorca určíte, ktoré bunky sa majú formátovať .
• Vytvorte pravidlo s jednoduchým vzorcom, ako napríklad =$B2=$A2 (za predpokladu, že riadok 2 je prvý riadok s údajmi, bez záhlavia stĺpca). Dvakrát skontrolujte, či používate relatívny odkaz na riadok (bez znaku $), ako je to vo vzorci vyššie.

Zvýraznenie rozdiely medzi stĺpcami A a B vytvorte pravidlo s týmto vzorcom:

=$B2$A2

Ak s podmieneným formátovaním Excelu začínate, pozrite si časť Ako vytvoriť pravidlo podmieneného formátovania založené na vzorci, kde nájdete pokyny krok za krokom.

Príklad 2. Zvýraznite jedinečné položky v každom zozname

Vždy, keď v programe Excel porovnávate dva zoznamy, môžete zvýrazniť 3 typy položiek:

• Položky, ktoré sú len v 1. zozname (jedinečné)
• Položky, ktoré sú len v 2. zozname (jedinečné)
• Položky, ktoré sú v oboch zoznamoch (duplikáty) - demonštrované v ďalšom príklade.

Tento príklad ukazuje, ako vyfarbiť položky, ktoré sú len v jednom zozname.

Predpokladajme, že váš Zoznam 1 je v stĺpci A (A2:A6) a Zoznam 2 v stĺpci C (C2:C5). Vytvoríte pravidlá podmieneného formátovania pomocou nasledujúcich vzorcov:

Zvýraznite jedinečné hodnoty v zozname 1 (stĺpec A):

=COUNTIF($C$2:$C$5, $A2)=0

Zvýraznite jedinečné hodnoty v zozname 2 (stĺpec C):

=COUNTIF($A$2:$A$6, $C2)=0

A dostanete nasledujúci výsledok:

Príklad 3. Zvýraznenie zhody (duplikátov) medzi 2 stĺpcami

Ak ste pozorne sledovali predchádzajúci príklad, nebudete mať problém upraviť vzorce COUNTIF tak, aby našli zhody a nie rozdiely. Stačí, ak nastavíte počet väčší ako nula:

Zvýraznite zhody v zozname 1 (stĺpec A):

=COUNTIF($C$2:$C$5, $A2)>0

Zvýraznite zhody v zozname 2 (stĺpec C):

=COUNTIF($A$2:$A$6, $C2)>0

Zvýraznenie rozdielov riadkov a zhody vo viacerých stĺpcoch

Pri porovnávaní hodnôt v niekoľkých stĺpcoch po riadkoch je najrýchlejším spôsobom, ako zvýrazniť zhody, vytvorenie pravidla podmieneného formátovania a najrýchlejším spôsobom, ako odtieniť rozdiely, je použitie Prejsť na špeciálny ako je uvedené v nasledujúcich príkladoch.

Príklad 1. Porovnanie viacerých stĺpcov a zvýraznenie zhody riadkov

Zvýraznenie riadkov, ktoré majú rovnaké hodnoty vo všetkých stĺpcoch , vytvorte pravidlo podmieneného formátovania na základe jedného z nasledujúcich vzorcov:

=AND($A2=$B2, $A2=$C2)

alebo

=COUNTIF($A2:$C2, $A2)=3

Kde A2, B2 a C2 sú najvyššie položené bunky a 3 je počet stĺpcov na porovnanie.

Vzorec AND ani COUNTIF samozrejme nie je obmedzený na porovnávanie iba 3 stĺpcov, podobné vzorce môžete použiť na zvýraznenie riadkov s rovnakými hodnotami v 4, 5, 6 alebo viacerých stĺpcoch.

Príklad 2. Porovnanie viacerých stĺpcov a zvýraznenie rozdielov v riadkoch

Ak chcete rýchlo zvýrazniť bunky s rôznymi hodnotami v jednotlivých riadkoch, môžete použiť funkciu aplikácie Excel Prejsť na špeciálny funkcia.

1. Vyberte rozsah buniek, ktoré chcete porovnať. V tomto príklade som vybral bunky A2 až C8.

   V predvolenom nastavení je najvyššia bunka vybraného rozsahu aktívna bunka a bunky z ostatných vybraných stĺpcov v tom istom riadku sa porovnajú s touto bunkou. Ako vidíte na obrázku vyššie, aktívna bunka je biela, zatiaľ čo všetky ostatné bunky vybraného rozsahu sú zvýraznené. V tomto príklade je aktívna bunka A2, takže porovnávací stĺpec je stĺpec A.

   Na zmeniť porovnávací stĺpec , použite buď kláves Tab na pohyb po vybraných bunkách zľava doprava, alebo kláves Enter na pohyb zhora nadol.

   Tip. Ak chcete vybrať nesusediace stĺpce , vyberte prvý stĺpec, stlačte a podržte kláves Ctrl a potom vyberte ostatné stĺpce. Aktívna bunka bude v poslednom stĺpci (alebo v poslednom bloku susedných stĺpcov). Ak chcete zmeniť porovnávací stĺpec, použite kláves Tab alebo Enter, ako je opísané vyššie.

2. Na Domov karta, prejdite na Úprava stránky a kliknite na tlačidlo Nájsť & Vybrať > Prejsť na špeciálnu... Potom vyberte Rozdiely v riadkoch a kliknite na OK tlačidlo.
3. Bunky, ktorých hodnoty sa líšia od porovnávacej bunky v každom riadku, sú podfarbené. Ak chcete zvýraznené bunky odtieniť nejakou farbou, jednoducho kliknite na tlačidlo Farba výplne na páse a vyberte požadovanú farbu.

Ako porovnať dve bunky v programe Excel

Porovnávanie 2 buniek je vlastne špecifickým prípadom porovnávania dvoch stĺpcov v programe Excel po riadkoch s tým rozdielom, že nemusíte kopírovať vzorce do ďalších buniek v stĺpci.

Na porovnanie buniek A1 a C1 môžete napríklad použiť nasledujúce vzorce.

Pre zápasy:

=IF(A1=C1, "Zhoda", "")

Pre rozdiely:

=IF(A1C1, "Rozdiel", "")

Ak sa chcete dozvedieť niekoľko ďalších spôsobov porovnávania buniek v programe Excel, pozrite si:

• Ako porovnať dva reťazce v programe Excel
• Skontrolovať, či sa dve bunky zhodujú alebo či sa viacero buniek rovná

Spôsob porovnávania dvoch stĺpcov / zoznamov v programe Excel bez použitia vzorcov

Teraz, keď už poznáte ponuku programu Excel na porovnávanie a párovanie stĺpcov, vám ukážem naše vlastné riešenie tejto úlohy. Tento nástroj sa nazýva Porovnať dve tabuľky a je súčasťou nášho balíka Ultimate Suite.

Doplnok dokáže porovnať dve tabuľky alebo zoznamy podľa ľubovoľného počtu stĺpcov a identifikovať zhody/rozdiely (ako sme to urobili so vzorcami) a zvýrazniť ich (ako sme to urobili s podmieneným formátovaním).

Na účely tohto článku budeme porovnávať nasledujúce 2 zoznamy a hľadať spoločné hodnoty, ktoré sa vyskytujú v oboch.

Ak chcete porovnať dva zoznamy, postupujte podľa nasledujúcich krokov:

1. Začnite kliknutím na Porovnanie tabuliek tlačidlo na Údaje Ablebits tab.
2. Vyberte prvý stĺpec/ zoznam a kliknite na Ďalšie Z hľadiska doplnku je to vaša tabuľka 1.
3. Vyberte druhý stĺpec/zoznam a kliknite na Ďalšie . Pokiaľ ide o doplnok, je to vaša tabuľka 2 a môže sa nachádzať v tom istom alebo inom hárku alebo dokonca v inom zošite.
4. Vyberte si, aký druh údajov chcete hľadať:
   • Duplikát hodnoty (zhody) - položky, ktoré existujú v oboch zoznamoch.
   • Jedinečné hodnoty (rozdiely) - položky, ktoré sa nachádzajú v zozname 1, ale nie v zozname 2.

   Keďže naším cieľom je nájsť zhody, vyberieme prvú možnosť a klikneme na Ďalšie .

5. Toto je kľúčový krok, v ktorom vyberiete stĺpce na porovnanie V našom prípade je voľba zrejmá, pretože porovnávame len 2 stĺpce: Víťazi za rok 2000 proti Víťazi v roku 2021 Vo väčších tabuľkách môžete vybrať niekoľko dvojíc stĺpcov, ktoré chcete porovnať.
6. V poslednom kroku vyberiete, ako naložiť s nájdenými položkami, a kliknete na tlačidlo Dokončenie .

   K dispozícii je niekoľko rôznych možností. Pre naše účely sú najužitočnejšie tieto dve:

   • Zvýraznenie farbou - odtiene sa zhodujú alebo líšia vo vybranej farbe (podobne ako podmienené formátovanie Excelu).
   • Identifikujte v stĺpci Stav - vloží Stav stĺpec s označením "Duplicitný" alebo "Jedinečný" (ako vzorce IF).

V tomto príklade som sa rozhodol zvýrazniť duplikáty nasledujúcou farbou:

A za chvíľu som dostal nasledujúci výsledok:

S Stav Výsledok by vyzeral takto:

Tip. Ak sú porovnávané zoznamy v rôznych hárkoch alebo zošitoch, môže byť užitočné zobraziť hárky programu Excel vedľa seba.

Takto môžete porovnávať stĺpce v programe Excel na zhodu (duplicity) a rozdiely (jedinečné hodnoty). Ak máte záujem vyskúšať tento nástroj, môžete si stiahnuť skúšobnú verziu pomocou nižšie uvedeného odkazu.

Ďakujem vám za prečítanie a odporúčam vám pozrieť si ďalšie užitočné návody, ktoré máme :)

Dostupné súbory na stiahnutie

Porovnanie zoznamov Excel - príklady (.xlsx súbor)

Ultimate Suite - skúšobná verzia (.exe súbor)