Az oszlopok összehasonlítása az Excelben olyan dolog, amit mindannyian csinálunk egyszer-egyszer. A Microsoft Excel számos lehetőséget kínál az adatok összehasonlítására és egybevetésére, de a legtöbbjük egy oszlopban való keresésre összpontosít. Ebben a bemutatóban számos technikát fogunk megvizsgálni, hogy két oszlop összehasonlítása Excelben, és találja meg az egyezéseket és a különbségeket közöttük.

Hogyan hasonlítsunk össze 2 oszlopot az Excelben soronként soronként

Az Excelben végzett adatelemzés során az egyik leggyakoribb feladat az egyes sorok adatainak összehasonlítása. Ezt a feladatot az IF függvény segítségével végezheti el, amint azt a következő példák is mutatják.

Példa 1. Két oszlop összehasonlítása egyezések vagy különbségek keresésére ugyanabban a sorban

Két oszlop soronkénti összehasonlításához az Excelben írjon egy szokásos IF-képletet, amely összehasonlítja az alábbi értékeket az első két cellát. Írja be a képletet ugyanannak a sornak egy másik oszlopába, majd másolja le más cellákba a kitöltési fogantyú (egy kis négyzet a kijelölt cella jobb alsó sarkában) húzásával. Ennek során a kurzor plusz jelre változik:

A mérkőzések képlete

Az azonos soron belüli, azonos tartalmú cellák - ebben a példában A2 és B2 - kereséséhez a képlet a következő:

=IF(A2=B2,"Match","")

A különbségek képlete

Ha ugyanabban a sorban különböző értékű cellákat szeretne találni, egyszerűen cserélje ki az egyenlőségjelet a nem egyenlőségjelre ():

=IF(A2B2, "Nincs egyezés","")

Egyezések és különbségek

És természetesen semmi sem akadályozza meg, hogy egyetlen képlettel találjon egyezéseket és különbségeket is:

=IF(A2=B2, "Egyezés", "Nincs egyezés")

Vagy

=IF(A2B2, "Nincs egyezés", "Egyezés")

Az eredmény ehhez hasonlóan nézhet ki:

Amint látja, a képlet kezeli számok , dátumok , times és szöveges karakterláncok ugyanolyan jól.

Tipp. Két oszlopot soronként is összehasonlíthat az Excel Speciális szűrőjével. Íme egy példa, amely bemutatja, hogyan lehet 2 oszlop közötti egyezéseket és különbségeket szűrni.

Példa 2. Két lista összehasonlítása az azonos sorban lévő nagy- és kisbetűs egyezésekhez

Amint valószínűleg észrevetted, az előző példában szereplő képletek figyelmen kívül hagyják az eseteket a szöveges értékek összehasonlításakor, mint a fenti képernyőkép 10. sorában. Ha meg akarod találni az alábbiakat nagy- és kisbetű-érzékeny egyezések 2 oszlop között minden sorban, majd használja az EXACT függvényt:

=IF(EXACT(A2, B2), "Match", "")

Megtalálni nagy- és kisbetűs különbségek ugyanabban a sorban az IF függvény 3. argumentumába írja be a megfelelő szöveget ("Unique" ebben a példában), pl.:

=IF(EXACT(A2, B2), "Match", "Unique")

Több oszlop összehasonlítása egy sorban lévő egyezésekhez

Az Excel munkalapokon több oszlopot lehet összehasonlítani a következő kritériumok alapján:

• Keresse meg az azonos értékű sorokat a minden oszlop (1. példa)
• Keresse meg az azonos értékű sorokat a 2 tetszőleges oszlop (2. példa)

Példa 1. Találjon találatokat az azonos soron belüli összes cellában

Ha a táblázatnak három vagy több oszlopa van, és olyan sorokat szeretne találni, amelyek minden cellájában ugyanazok az értékek vannak, akkor az ÉS utasítással ellátott IF-képlet remekül fog működni:

=IF(AND(A2=B2, A2=C2), "Teljes egyezés", "")

Ha a táblázatodnak sok oszlopa van, elegánsabb megoldás a COUNTIF függvény használata:

=IF(COUNTIF($A2:$E2, $A2)=5, "Teljes egyezés", "")

Ahol 5 az összehasonlítandó oszlopok száma.

Példa 2. Találjon találatokat ugyanazon sor két cellájában

Ha az oszlopok összehasonlításának módját keresi a bármely két vagy több sejt azonos soron belüli azonos értékekkel, használjon IF képletet OR utasítással:

=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")

Abban az esetben, ha sok oszlopot kell összehasonlítani, a VAGY utasítás túl nagyra nőhet. Ebben az esetben jobb megoldás lenne több COUNTIF függvény összeadása. Az első COUNTIF megszámolja, hogy hány oszlopban van az 1. oszlop értékével megegyező érték, a második COUNTIF megszámolja, hogy a többi oszlop közül hány egyenlő a 2. oszloppal, és így tovább. Ha a számolás 0, a formula "Unique" értéket ad vissza,"Match" egyébként. Például:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Unique", "Match")

Két oszlop összehasonlítása az Excelben az egyezések és különbségek tekintetében

Tegyük fel, hogy az Excelben 2 adatlistával rendelkezik, és szeretné megtalálni az összes olyan értéket (számokat, dátumokat vagy szöveges karakterláncokat), amelyek az A oszlopban szerepelnek, de a B oszlopban nem.

Ehhez a COUNTIF($B:$B, $A2)=0 függvényt beágyazhatjuk az IF logikai tesztjébe, és ellenőrizhetjük, hogy nullát (nem találtunk egyezést) vagy bármilyen más számot (legalább 1 egyezést találtunk) ad-e vissza.

Például a következő IF/COUNTIF képlet az egész B oszlopban keresi az A2 cellában lévő értéket. Ha nem talál egyezést, a képlet a "Nincs egyezés B-ben", egyébként pedig egy üres karakterláncot ad vissza:

=IF(COUNTIF($B:$B, $A2)=0, "Nincs egyezés B-ben", "")

Tipp: Ha a táblázata rögzített számú sorból áll, akkor a teljes oszlop ($B:$B) helyett megadhat egy bizonyos tartományt (pl. $B2:$B10), hogy a képlet gyorsabban működjön nagy adathalmazok esetén.

Ugyanez az eredmény érhető el egy IF formula használatával, a beágyazott ISERROR és MATCH függvényekkel:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Nincs egyezés B-ben","")

Vagy a következő tömbképlet használatával (ne feledje, hogy a Ctrl + Shift + Enter billentyűkombinációt kell lenyomnia a helyes bevitelhez):

=IF(SUM(--($B$2:$B$10=$A2))=0, " Nincs egyezés B-ben", "")

Ha azt szeretné, hogy egyetlen képlet azonosítsa mind az egyezéseket (duplikátumokat), mind a különbségeket (egyedi értékeket), akkor a fenti képletek bármelyikében az üres idézőjelek ("") közé írjon be valamilyen szöveget az egyezésekhez. Például:

=IF(COUNTIF($B:$B, $A2)=0, "Nincs egyezés B-ben", "Egyezés B-ben")

Hogyan hasonlítsunk össze két listát Excelben és húzzuk ki a mérkőzéseket?

Néha előfordulhat, hogy nem csak két különböző táblázat két oszlopának összevetésére van szükség, hanem a keresőtáblából is ki kell húzni az egyező bejegyzéseket. A Microsoft Excel erre egy speciális funkciót biztosít - a VLOOKUP funkciót. Alternatívaként használhatja az erősebb és sokoldalúbb INDEX MATCH képletet. Az Excel 2021 és az Excel 365 felhasználói az XLOOKUP funkcióval oldhatják meg a feladatot.

A következő képletek például összehasonlítják a D oszlopokban szereplő termékneveket az A oszlopban szereplő nevekkel, és ha találnak egyezést, akkor a B oszlopból kihúzzák a megfelelő értékesítési számadatot, ellenkező esetben a #N/A hiba kerül visszaküldésre.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

További információért lásd: Hogyan hasonlítsunk össze két oszlopot a VLOOKUP segítségével.

Ha nem érzi magát túl otthonosan a képletekkel, akkor egy gyors és intuitív megoldás - a Merge Tables Wizard - segítségével is elvégezheti a feladatot.

Két lista összehasonlítása és az egyezések és különbségek kiemelése

Amikor oszlopokat hasonlít össze az Excelben, előfordulhat, hogy "láthatóvá szeretné tenni" azokat az elemeket, amelyek az egyik oszlopban jelen vannak, de a másikból hiányoznak. Az ilyen cellákat tetszőleges színnel árnyalhatja az Excel Feltételes formázás funkciójának használatával, és az alábbi példák bemutatják a részletes lépéseket.

Példa 1. Egyezések és különbségek kiemelése minden sorban

Két oszlop és az Excel összehasonlítása, valamint az A oszlop azon celláinak kiemelése, amelyeknek azonos bejegyzések a B oszlopban ugyanabban a sorban, tegye a következőket:

• Jelölje ki a kiemelni kívánt cellákat (kijelölheti a cellákat egy oszlopon belül vagy több oszlopban, ha egész sorokat szeretne színezni).
• Kattintson a címre. Feltételes formázás> Új szabály.> Egy képlet segítségével határozza meg, hogy mely cellákat kell formázni. .
• Hozzon létre egy szabályt egy egyszerű képlettel, például =$B2=$A2 (feltételezve, hogy a 2. sor az első sor az adatokkal, az oszlopfejlécet nem számítva). Kérjük, ellenőrizze, hogy a fenti képlethez hasonlóan relatív sorhivatkozást használ ($ jel nélkül).

Kiemelni különbségek az A és B oszlop között, hozzon létre egy szabályt ezzel a képlettel:

=$B2$A2

Ha még nem ismeri az Excel feltételes formázását, a lépésről lépésre történő útmutatásért tekintse meg a Hogyan hozzunk létre képletalapú feltételes formázási szabályt?

Példa 2. Egyedi bejegyzések kiemelése minden listában

Amikor két listát hasonlít össze az Excelben, 3 elemtípus van, amelyet kiemelhet:

• Csak az 1. listában szereplő elemek (egyedi)
• Csak a 2. listában szereplő tételek (egyedi)
• Mindkét listában szereplő elemek (duplikátumok) - a következő példa mutatja be.

Ez a példa azt mutatja be, hogyan lehet kiszínezni azokat az elemeket, amelyek csak egy listában szerepelnek.

Tegyük fel, hogy az 1. lista az A oszlopban (A2:A6), a 2. lista pedig a C oszlopban (C2:C5) található. A feltételes formázási szabályokat a következő képletekkel hozza létre:

Jelölje ki az egyedi értékeket az 1. listában (A oszlop):

=COUNTIF($C$2:$C$5, $A2)=0

Jelölje ki az egyedi értékeket a 2. listában (C oszlop):

=COUNTIF($A$2:$A$6, $C2)=0

És a következő eredményt kapjuk:

Példa 3. 2 oszlop közötti egyezések (duplikátumok) kiemelése

Ha szorosan követte az előző példát, akkor nem lesz nehézsége a COUNTIF képleteket úgy beállítani, hogy azok inkább az egyezéseket, mint a különbségeket találják meg. Mindössze annyit kell tennie, hogy a számlálót nullánál nagyobbra állítja:

Jelölje ki az 1. listában (A oszlop) szereplő találatokat:

=COUNTIF($C$2:$C$5, $A2)>0

Jelölje ki a 2. listában (C oszlop) szereplő találatokat:

=COUNTIF($A$2:$A$6, $C2)>0

Sorok közötti különbségek és egyezések kiemelése több oszlopban

Ha több oszlopban soronként hasonlítjuk össze az értékeket, az egyezések kiemelésének leggyorsabb módja egy feltételes formázási szabály létrehozása, a különbségek árnyékolásának leggyorsabb módja pedig a Go To Special funkciót, amint azt a következő példák is mutatják.

Példa 1. Több oszlop összehasonlítása és a sorok egyezéseinek kiemelése

Az olyan sorok kiemelése, amelyek azonos értékek minden oszlopban , hozzon létre egy feltételes formázási szabályt az alábbi képletek egyikén alapuló feltételes formázási szabályt:

=AND($A2=$B2, $A2=$C2)

vagy

=COUNTIF($A2:$C2, $A2)=3

Ahol A2, B2 és C2 a legfelső cellák, és 3 az összehasonlítandó oszlopok száma.

Természetesen sem az AND, sem a COUNTIF formula nem korlátozódik csak 3 oszlop összehasonlítására, hasonló képleteket használhat a 4, 5, 6 vagy több oszlopban azonos értékkel rendelkező sorok kiemelésére.

Példa 2. Több oszlop összehasonlítása és a sorok közötti különbségek kiemelése

Az egyes sorokban különböző értékeket tartalmazó cellák gyors kiemeléséhez használhatja az Excel Go To Special funkció.

1. Válassza ki az összehasonlítani kívánt cellatartományt. Ebben a példában az A2 és C8 közötti cellákat választottam ki.

   Alapértelmezés szerint a kiválasztott tartomány legfelső cellája az aktív cella, és az ugyanabban a sorban lévő többi kiválasztott oszlop celláit ehhez a cellához hasonlítja. Amint a fenti képernyőképen látható, az aktív cella fehér színű, míg a kiválasztott tartomány összes többi cellája kiemelt. Ebben a példában az aktív cella az A2, így a összehasonlító oszlop az A oszlop.

   A címre. az összehasonlító oszlop megváltoztatása , a Tab billentyűvel balról jobbra navigálhat a kijelölt cellák között, vagy az Enter billentyűvel léphet fentről lefelé.

   Tipp. nem szomszédos oszlopok , jelölje ki az első oszlopot, tartsa lenyomva a Ctrl billentyűt, majd jelölje ki a többi oszlopot. Az aktív cella az utolsó oszlopban (vagy a szomszédos oszlopok utolsó blokkjában) lesz. Az összehasonlító oszlop megváltoztatásához használja a Tab vagy Enter billentyűt a fent leírtak szerint.

2. A Home fülre, menjen a Szerkesztés csoport, és kattintson a Keresés & kiválasztás > Tovább a Special... Ezután válassza ki Sorok közötti különbségek és kattintson a OK gomb.
3. Azokat a cellákat, amelyek értéke eltér az összehasonlító cellától, minden sorban színezi. Ha a kiemelt cellákat valamilyen színnel szeretné árnyalni, egyszerűen kattintson a Kitöltés színe ikonra a szalagon, és válassza ki a kívánt színt.

Hogyan hasonlítsunk össze két cellát az Excelben

Valójában 2 cella összehasonlítása az Excelben két oszlop soronkénti összehasonlításának sajátos esete, kivéve, hogy nem kell a képleteket az oszlop más celláiba másolni.

Az A1 és C1 cellák összehasonlításához például a következő képleteket használhatja.

A mérkőzésekhez:

=IF(A1=C1, "Match", "")

A különbségekért:

=IF(A1C1, "Különbség", "")

A cellák Excelben történő összehasonlításának néhány más módját lásd:

• Hogyan hasonlítsunk össze két karakterláncot az Excelben
• Ellenőrizze, hogy két cella egyezik-e vagy több cella egyenlő-e

Képletmentes mód két oszlop / lista összehasonlítására az Excelben

Most, hogy már ismeri az Excel kínálatát az oszlopok összehasonlítására és megfeleltetésére, hadd mutassam meg a saját megoldásunkat erre a feladatra. Ez az eszköz a Két táblázat összehasonlítása nevet viseli, és az Ultimate Suite csomagunkban szerepel.

A bővítmény képes két táblázat vagy lista összehasonlítására tetszőleges számú oszlop alapján, és mind az egyezések/különbségek azonosítására (ahogyan azt a képletekkel tettük), mind pedig azok kiemelésére (ahogyan azt a feltételes formázással tettük).

E cikk céljaira a következő két listát hasonlítjuk össze, hogy megtaláljuk azokat a közös értékeket, amelyek mindkettőben jelen vannak.

Két lista összehasonlításához az alábbi lépéseket kell követnie:

1. Kezdje a Táblázatok összehasonlítása gombot a Ablebits adatok tab.
2. Válassza ki a első oszlop/lista és kattintson Következő Az add-in szempontjából ez az Ön 1. táblázata.
3. Válassza ki a második oszlop/lista és kattintson Következő A bővítmény szempontjából ez a 2. táblázat, és lehet ugyanabban vagy egy másik munkalapban, vagy akár egy másik munkafüzetben is.
4. Válassza ki, hogy milyen adatokat keres:
   • Duplikátum értékek (egyezik) - a két listában szereplő elemek.
   • Egyedi értékek (különbségek) - azok a tételek, amelyek az 1. listán szerepelnek, de a 2. listán nem.

   Mivel a célunk az, hogy találjunk egyezéseket, válasszuk az első lehetőséget, és kattintsunk a Következő .

5. Ez az a kulcsfontosságú lépés, amikor kiválasztja a oszlopok az összehasonlításhoz A mi esetünkben a választás nyilvánvaló, mivel csak 2 oszlopot hasonlítunk össze: 2000 győztesek a ellen. 2021 győztesek Nagyobb táblázatokban több oszloppárt is kiválaszthat az összehasonlításhoz.
6. Az utolsó lépésben kiválasztja, hogyan kezelje a talált elemeket, majd kattintson a Befejezés .

   Itt néhány különböző lehetőség áll rendelkezésre, de a mi céljainkra ez a kettő a leghasznosabb:

   • Kiemelés színnel - a kiválasztott szín árnyalatai megegyeznek vagy eltérnek (mint az Excel feltételes formázás).
   • Azonosítsa a státusz oszlopban - beilleszti a Állapot oszlopot a "Duplicate" vagy "Unique" címkékkel (mint az IF képletek).

Ehhez a példához úgy döntöttem, hogy a duplikációkat a következő színnel jelölöm ki:

És egy pillanat alatt a következő eredményt kaptam:

A Állapot oszlopban az eredmény a következőképpen nézne ki:

Tipp: Ha az összehasonlítandó listák különböző munkalapokon vagy munkafüzetekben vannak, hasznos lehet, ha egymás mellett nézi meg az Excel-lapokat.

Így lehet összehasonlítani az Excel oszlopokat az egyezések (duplikátumok) és a különbségek (egyedi értékek) szempontjából. Ha szeretné kipróbálni ezt az eszközt, akkor az alábbi linken letölthet egy tesztverziót.

Köszönöm, hogy elolvastad, és arra bátorítalak, hogy nézd meg a többi hasznos oktatóanyagot, ami van :)

Elérhető letöltések

Excel listák összehasonlítása - példák (.xlsx fájl)

Ultimate Suite - próbaverzió (.exe fájl)