Ինչպե՞ս հաշվել տեքստով բջիջները Excel-ում: Բջիջները հաշվելու մի քանի տարբեր բանաձևեր կան, որոնք պարունակում են ցանկացած տեքստ, հատուկ նիշ կամ միայն զտված բջիջներ: Բոլոր բանաձևերն աշխատում են Excel 365, 2021, 2019, 2016, 2013 և 2010 թվականներին:

Սկզբում Excel աղյուսակները նախատեսված էին թվերի հետ աշխատելու համար: Բայց այս օրերին մենք հաճախ դրանք օգտագործում ենք նաև տեքստը պահելու և շահարկելու համար: Ցանկանու՞մ եք իմանալ, թե տեքստով քանի բջիջ կա ձեր աշխատաթերթում: Microsoft Excel-ը դրա համար ունի մի քանի գործառույթ: Ո՞ր մեկը պետք է օգտագործեք: Դե, դա կախված է իրավիճակից: Այս ձեռնարկում դուք կգտնեք մի շարք բանաձևեր, և երբ յուրաքանչյուր բանաձև ավելի լավ է օգտագործել:

Ինչպես հաշվել տեքստով բջիջների քանակը Excel-ում

Այնտեղ երկու հիմնական բանաձև է՝ պարզելու, թե տվյալ տիրույթում քանի բջիջ է պարունակում որևէ տեքստային տող կամ նիշ:

COUNTIF բանաձև՝ տեքստով բոլոր բջիջները հաշվելու համար

Երբ ցանկանում եք գտնել բջիջների քանակը Excel-ում տեքստը, չափանիշ արգումենտում աստղանիշով COUNTIF ֆունկցիան լավագույն և ամենահեշտ լուծումն է.

Որովհետև աստղանիշը (*) նիշերի ցանկացած հաջորդականությանը համապատասխանող նշան է, բանաձևը հաշվում է բոլոր բջիջները, որոնք պարունակում են ցանկացած տեքստ:

SUMPRODUCT բանաձև՝ ցանկացած տեքստով բջիջները հաշվելու համար

Մեկ այլ եղանակ՝ թվերը ստանալու համար: Տեքստ պարունակող բջիջները պետք է համատեղեն SUMPRODUCT և ISTEXT ֆունկցիաները՝

Կամ

ISTEXT ֆունկցիան ստուգում է, արդյոք յուրաքանչյուր բջիջ նշվածում միջակայքը պարունակում է ցանկացած տեքստային նիշ և վերադարձնում է TRUE (տեքստով բջիջներ) և FALSE (այլ բջիջներ) արժեքների զանգված: Կրկնակի միանին (--) կամ բազմապատկման գործողությունը ստիպում է TRUE-ը և FALSE-ը համապատասխանաբար 1-ի և 0-ի վերածել՝ արտադրելով միավորների և զրոների զանգված: SUMPRODUCT ֆունկցիան գումարում է զանգվածի բոլոր տարրերը և վերադարձնում է 1-ների թիվը, որը տեքստ պարունակող բջիջների թիվն է:

Այս բանաձևերի աշխատանքի վերաբերյալ ավելի շատ պատկերացում կազմելու համար տեսեք, թե որ արժեքներն են հաշվվում և որոնք չեն՝

Օրինակ՝ A2:A10 միջակայքի տեքստով բջիջները հաշվելու համար՝ բացառելով թվերը, ամսաթվերը, տրամաբանական արժեքները, սխալները։ և դատարկ բջիջներ, օգտագործեք հետևյալ բանաձևերից մեկը.

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--ISTEXT(A2:A10))

=SUMPRODUCT(ISTEXT(A2:A10)*1)

Սքրինշոթը ցույց է տալիս արդյունքը.

Հաշվե՛ք տեքստով բջիջները՝ բացառությամբ բացատների և դատարկ տողերի

Վերևում քննարկված բանաձևերը հաշվելբոլոր բջիջները, որոնք ունեն ցանկացած տեքստային նիշ: Այնուամենայնիվ, որոշ իրավիճակներում դա կարող է շփոթեցնող լինել, քանի որ որոշ բջիջներ կարող են միայն դատարկ թվալ, բայց իրականում պարունակում են մարդու աչքի համար անտեսանելի նիշեր, ինչպիսիք են դատարկ տողերը, ապոստրոֆները, բացատները, տողերի ընդմիջումները և այլն: Արդյունքում՝ տեսողականորեն դատարկ բջիջը հաշվվում է բանաձևով, որը ստիպում է օգտվողին քաշել մազերը՝ փորձելով պարզել, թե ինչու :)

«Կեղծ դրական» դատարկ բջիջները հաշվից բացառելու համար օգտագործեք COUNTIFS ֆունկցիան՝ «բացառված» նիշով: երկրորդ չափանիշը:

Օրինակ, A2:A7 տիրույթում տեքստով բջիջները հաշվելու համար՝ անտեսելով բացատ նիշ պարունակող բջիջները, օգտագործեք այս բանաձևը.

=COUNTIFS(A2:A7,"*", A2:A7, " ")

Եթե ձեր թիրախային տիրույթը պարունակում է որևէ բանաձևով հիմնված տվյալ, որոշ բանաձևեր կարող են հանգեցնել դատարկ տողի (""): դատարկ տողերով բջիջները նույնպես անտեսելու համար criteria1 արգումենտում փոխարինեք «*»-ը «*?*»-ով.

=COUNTIFS(A2:A9,"*?*", A2:A9, " ")

Հարց: Աստղանիշներով շրջապատված նշանը ցույց է տալիս, որ վանդակում պետք է լինի առնվազն մեկ տեքստային նիշ: Քանի որ դատարկ տողը իր մեջ նիշ չունի, այն չի համապատասխանում չափանիշներին և չի հաշվվում: Դատարկ բջիջները, որոնք սկսվում են ապոստրոֆով (') նույնպես չեն հաշվվում:

Սքրինշոթում ներքևում կա բացատ A7-ում, ապաստրոֆ` A8-ում և դատարկ տող (="") A9-ում: Մեր բանաձևը դուրս է թողնում բոլոր այդ բջիջները և վերադարձնում է տեքստային բջիջների քանակը3:

Ինչպես հաշվել բջիջները որոշակի տեքստով Excel-ում

Որպեսզի ստանաք որոշակի տեքստ կամ նիշ պարունակող բջիջների քանակը, դուք պարզապես տրամադրում եք այդ տեքստը: COUNTIF ֆունկցիայի չափանիշ արգումենտում: Ստորև բերված օրինակները բացատրում են նրբերանգները:

Նմուշի տեքստին ճիշտ համապատասխանելու համար մուտքագրեք ամբողջական տեքստը չակերտների մեջ.

մասնակի համընկնող բջիջները հաշվելու համար տեքստը տեղադրեք երկու աստղանիշների միջև, որոնք ներկայացնում են ցանկացած թվով նիշ տեքստից առաջ և հետո:

Օրինակ, գտնելու համար, թե A2:A7 տիրույթում քանի բջիջ է պարունակում հենց "bananas" բառը, օգտագործեք այս բանաձևը.

=COUNTIF(A2:A7, "bananas")

Բոլոր բջիջները, որոնք պարունակում են «բանաններ» որպես իրենց բովանդակության մաս, ցանկացած դիրքում հաշվելու համար օգտագործեք սա՝

=COUNTIF(A2:A7, "*bananas*")

Բանաձևն ավելի հարմարավետ դարձնելու համար կարող եք չափորոշիչները տեղադրել նախապես սահմանված բջիջում, ասենք D2, և բջջային հղումը դնել երկրորդ արգումենտում.

=COUNTIF(A2:A7, D2)

Կախված մուտքագրումից: D2-ում բանաձևը կարող է ամբողջությամբ կամ մասնակիորեն համընկնել նմուշի տեքստին.

• Լրիվ համընկնման համար մուտքագրեք ամբողջ բառը կամ արտահայտությունը, ինչպես երևում է սկզբնաղբյուր աղյուսակում, օրինակ. Բանան ։
• Մասնակի համընկնման համար մուտքագրեք տեքստի նմուշը, որը շրջապատված է նիշերով, օրինակ՝ *Bananas* ։

Որպես բանաձևը առանց մեծատառերի , դուք կարող եք չանհանգստանալ տառերի մեծատառերի համար,նշանակում է, որ *բանանները* նույնպես կանեն:

Այլընտրանքով, մասնակի համընկնումով բջիջները հաշվելու համար , միացրեք բջիջի հղումը և նիշերը, ինչպիսիք են՝

=COUNTIF(A2:A7, "*"&D2&"*")

Լրացուցիչ տեղեկությունների համար տե՛ս Ինչպես հաշվել բջիջները հատուկ տեքստով Excel-ում:

Ինչպես Excel-ում զտված բջիջները տեքստով հաշվելու համար

Երբ Excel-ի զտիչն օգտագործում եք տվյալ պահին միայն համապատասխան տվյալները ցուցադրելու համար, երբեմն կարող է անհրաժեշտ լինել հաշվել տեսանելի բջիջները տեքստով : Ցավոք, այս առաջադրանքի համար մեկ սեղմումով լուծում չկա, բայց ստորև բերված օրինակը ձեզ հեշտությամբ կուղեկցի քայլերի միջով:

Ենթադրենք, դուք ունեք աղյուսակ, ինչպիսին ցույց է տրված ստորև նկարում: Որոշ գրառումներ հանվել են ավելի մեծ տվյալների բազայից՝ օգտագործելով բանաձևեր, և ճանապարհին տեղի են ունեցել տարբեր սխալներ: Դուք փնտրում եք A սյունակի տարրերի ընդհանուր թիվը: Բոլոր տողերով տեսանելի լինելով, COUNTIF բանաձևը, որը մենք օգտագործել ենք տեքստով բջիջները հաշվելու համար, գործում է.

=COUNTIF(A2:A10, "*")

Եվ հիմա, դուք նեղացնում եք ցուցակը որոշ չափորոշիչներով, ասենք, զտեք 10-ից մեծ քանակով իրերը: Հարցն այն է, թե քանի՞ ապրանք է մնացել:

Հաշվելու համար տեքստով զտված բջիջներ , սա այն է, ինչ դուք պետք է անեք.

1. Ձեր սկզբնաղբյուր աղյուսակում տեսանելի դարձրեք բոլոր տողերը: Դրա համար մաքրեք բոլոր զտիչները և ցուցադրեք թաքնված տողերը:
2. Ավելացրեք օգնական սյունակ SUBTOTAL բանաձևով, որը ցույց է տալիս, թե արդյոք տողը կազտված է, թե ոչ:

   զտված բջիջները մշակելու համար օգտագործեք 3 function_num արգումենտի համար.

   =SUBTOTAL(3, A2)

   բոլորը նույնականացնելու համար թաքնված բջիջներ , զտված և ձեռքով թաքցված, դրեք 103 function_num :

   =SUBTOTAL(103, A2)

   Այս օրինակում մենք ուզում ենք հաշվել միայն տեսանելի բջիջները տեքստով անկախ նրանից, թե ինչպես են թաքնված այլ բջիջները, ուստի մենք մուտքագրում ենք երկրորդ բանաձևը A2-ում և պատճենում այն ​​A10-ում:

   Տեսանելի բջիջների համար բանաձևը վերադարձնում է 1: Հենց որ դուք զտեք կամ ձեռքով թաքցրեք որոշ տողեր, բանաձևը նրանց համար կվերադարձնի 0: (Դուք չեք տեսնի այդ զրոները, քանի որ դրանք վերադարձվում են թաքնված տողերի համար: Որպեսզի համոզվեք, որ այն աշխատում է այսպես, պարզապես պատճենեք թաքնված բջիջի բովանդակությունը Subtotal բանաձևով ցանկացած տեսանելի ասենք, ասենք =D2, ենթադրելով, որ 2-րդ տողը թաքնված է: .)

   

3. Օգտագործեք COUNTIFS ֆունկցիան երկու տարբեր չափանիշ_միջակայք / չափանիշ զույգերով` տեսանելի բջիջները տեքստով հաշվելու համար.
   • Չափանիշ 1 - որոնում է ցանկացած տեքստով բջիջներ ("*") A2:A10 միջակայքում:
   • Չափանիշ 2 - որոնում է 1-ը D2:D10 միջակայքում տեսանելի բջիջները հայտնաբերելու համար:

   =COUNTIFS(A2:A10, "*", D2:D10, 1)

Այժմ դուք կարող եք զտել տվյալները այնպես, ինչպես ցանկանում եք, և բանաձևը ձեզ կասի, թե Ա սյունակի քանի զտված բջիջներ են պարունակում տեքստ (3 դյույմ մեր դեպքը):

Եթե նախընտրում եք լրացուցիչ սյունակ չմտցնել ձեր աշխատաթերթում, ապա ձեզ ավելի երկար բանաձև կպահանջվի առաջադրանքն իրականացնելու համար: Պարզապես ընտրեք այն մեկը, որը դուք եքավելի լավ հավանել՝

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), -- (ISTEXT(A2:A10)))

Բազմապատկման օպերատորը նույնպես կաշխատի՝

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))) * (ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10)-MIN(ROW(A2:A10)),,1)) * (ISTEXT(A2:A10)))

Որ բանաձևն օգտագործելը ձեր անձնական նախասիրության հարցն է. արդյունքը ամեն դեպքում նույնը կլինի.

Ինչպես են աշխատում այս բանաձևերը

Առաջինը Բանաձևն օգտագործում է INDIRECT ֆունկցիան՝ նշված տիրույթի բոլոր բջիջների առանձին հղումները «սնուցելու» SUBTOTAL: Երկրորդ բանաձևը օգտագործում է OFFSET, ROW և MIN ֆունկցիաների համակցությունը նույն նպատակով:

SUBTOTAL ֆունկցիան վերադարձնում է 1-ի և 0-ի զանգված, որտեղ մեկը ներկայացնում է տեսանելի բջիջները, իսկ զրոները համընկնում են թաքնված բջիջների հետ (ինչպես օժանդակ սյունակը: վերևում):

ISTEXT ֆունկցիան ստուգում է A2:A10-ի յուրաքանչյուր բջիջ և վերադարձնում է TRUE, եթե բջիջը պարունակում է տեքստ, հակառակ դեպքում՝ FALSE: Կրկնակի միանման օպերատորը (--) ստիպում է TRUE և FALSE արժեքները վերածել 1-ի և 0-ի: Այս պահին բանաձևն ունի հետևյալ տեսքը.

=SUMPRODUCT({0;1;1;1;0;1;1;0;0}, {1;1;1;0;1;1;0;1;1})

SUMPRODUCT ֆունկցիան սկզբում բազմապատկում է երկու զանգվածների էլեմենտները նույն դիրքերում, այնուհետև գումարում է ստացված զանգվածը:

Քանի որ զրոյով բազմապատկելուց ստացվում է զրո, երկու զանգվածներում միայն 1-ով ներկայացված բջիջներն ունեն 1 վերջնական զանգվածում:

=SUMPRODUCT({0;1;1;0;0;1;0;0;0})

Իսկ վերը նշված զանգվածում 1-երի թիվը տեսանելիների թիվն է: բջիջներ, որոնք պարունակում են տեքստ:

Ահա թե ինչպես կարելի է հաշվել բջիջները տեքստով Excel-ում: Շնորհակալ եմ կարդալու համար և հուսով եմ, որ հաջորդ շաբաթ կտեսնենք ձեզ մեր բլոգում:

Հասանելի էներբեռնումներ

Excel-ի բանաձևեր՝ տեքստով բջիջները հաշվելու համար