Bagaimana cara menghitung sel dengan teks di Excel? Ada beberapa rumus berbeda untuk menghitung sel yang berisi teks apa pun, karakter tertentu, atau hanya sel yang difilter. Semua rumus bekerja di Excel 365, 2021, 2019, 2016, 2013, dan 2010.

Awalnya, spreadsheet Excel didesain untuk bekerja dengan angka. Tapi sekarang ini kita sering menggunakannya untuk menyimpan dan memanipulasi teks juga. Ingin tahu berapa banyak sel dengan teks yang ada di lembar kerja Anda? Microsoft Excel memiliki beberapa fungsi untuk ini. Yang mana yang harus Anda gunakan? Tergantung situasinya. Dalam tutorial ini, Anda akan menemukan berbagai rumus dan kapan setiap rumus paling baik untuk digunakan.digunakan.

Cara menghitung jumlah sel dengan teks di Excel

Ada dua rumus dasar untuk menemukan berapa banyak sel dalam rentang tertentu yang berisi string teks atau karakter apa pun.

Rumus COUNTIF untuk menghitung semua sel dengan teks

Saat Anda ingin menemukan jumlah sel dengan teks di Excel, fungsi COUNTIF dengan tanda bintang di kriteria argumen adalah solusi terbaik dan termudah:

Karena tanda bintang (*) adalah wildcard yang cocok dengan urutan karakter apa pun, rumus menghitung semua sel yang berisi teks apa pun.

Rumus SUMPRODUCT untuk menghitung sel dengan teks apa pun

Cara lain untuk mendapatkan jumlah sel yang berisi teks adalah dengan menggabungkan fungsi SUMPRODUCT dan ISTEXT:

Atau

Fungsi ISTEXT memeriksa apakah setiap sel dalam rentang yang ditentukan berisi karakter teks apa pun dan mengembalikan larik nilai TRUE (sel dengan teks) dan FALSE (sel lain). Unary ganda (--) atau operasi perkalian memaksa TRUE dan FALSE menjadi 1 dan 0, masing-masing, menghasilkan larik satu dan nol. Fungsi SUMPRODUCT menjumlahkan semua elemen larik dan mengembalikan jumlah1, yang merupakan jumlah sel yang berisi teks.

Untuk mendapatkan pemahaman lebih lanjut mengenai cara kerja rumus-rumus ini, silakan lihat nilai mana yang dihitung dan mana yang tidak:

Misalnya, untuk menghitung sel dengan teks dalam rentang A2: A10, tidak termasuk angka, tanggal, nilai logika, kesalahan, dan sel kosong, gunakan salah satu rumus ini:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--ISTEXT(A2:A10))

=SUMPRODUCT(ISTEXT(A2:A10)*1)

Tangkapan layar di bawah ini menunjukkan hasilnya:

Hitung sel dengan teks tidak termasuk spasi dan string kosong

Rumus yang dibahas di atas menghitung semua sel yang memiliki karakter teks di dalamnya. Namun, dalam beberapa situasi, hal itu mungkin membingungkan karena sel tertentu mungkin hanya terlihat kosong tetapi, pada kenyataannya, berisi karakter yang tidak terlihat oleh mata manusia seperti string kosong, tanda apostrof, spasi, jeda baris, dll. Akibatnya, sel yang kosong secara visual dihitung oleh rumus yang menyebabkan pengguna menarik keluar sel mereka.rambut mencoba mencari tahu mengapa :)

Untuk mengecualikan sel kosong "positif palsu" dari hitungan, gunakan fungsi COUNTIFS dengan karakter "dikecualikan" di kriteria kedua.

Misalnya, untuk menghitung sel dengan teks dalam rentang A2:A7 dengan mengabaikan sel yang berisi karakter ruang , gunakan rumus ini:

=COUNTIFS(A2:A7, "*", A2:A7, " ")

Jika kisaran target Anda berisi data berbasis formula apa pun, sebagian formula dapat menghasilkan string kosong (""). Untuk mengabaikan sel dengan string kosong juga, ganti "*" dengan "*?*" di dalam kriteria1 argumen:

=COUNTIFS(A2:A9, "*?*", A2:A9, " ")

Tanda tanya yang dikelilingi tanda bintang mengindikasikan bahwa setidaknya harus ada satu karakter teks di dalam sel. Karena string kosong tidak memiliki karakter di dalamnya, maka string tersebut tidak memenuhi kriteria dan tidak dihitung. Sel kosong yang diawali dengan apostrof (') juga tidak dihitung.

Pada gambar di bawah ini, ada spasi di A7, apostrof di A8, dan string kosong (= "") di A9. Rumus kami mengabaikan semua sel tersebut dan mengembalikan jumlah sel teks 3:

Cara menghitung sel dengan teks tertentu di Excel

Untuk mendapatkan jumlah sel yang berisi teks atau karakter tertentu, Anda cukup menyediakan teks itu di kriteria argumen dari fungsi COUNTIF. Contoh di bawah ini menjelaskan nuansanya.

Untuk mencocokkan teks contoh persis , masukkan teks lengkap yang diapit oleh tanda kutip:

Untuk menghitung sel dengan sebagian cocok , tempatkan teks di antara dua tanda bintang, yang mewakili sejumlah karakter sebelum dan sesudah teks:

Misalnya, untuk menemukan berapa banyak sel dalam rentang A2: A7 yang berisi persis kata "pisang", gunakan rumus ini:

=COUNTIF(A2:A7, "pisang")

Untuk menghitung semua sel yang berisi "pisang" sebagai bagian dari isinya di posisi mana pun, gunakan yang ini:

=COUNTIF(A2:A7, "*pisang*")

Untuk membuat rumus lebih ramah pengguna, Anda dapat menempatkan kriteria dalam sel yang telah ditentukan sebelumnya, katakanlah D2, dan meletakkan referensi sel di argumen kedua:

=COUNTIF(A2:A7, D2)

Tergantung pada input di D2, rumusnya bisa cocok dengan teks sampel sepenuhnya atau sebagian:

• Untuk pencocokan penuh, ketik seluruh kata atau frasa seperti yang muncul dalam tabel sumber, misalnya Pisang .
• Untuk pencocokan parsial, ketik teks sampel yang dikelilingi oleh karakter wildcard, seperti * Pisang* .

Karena rumusnya adalah tidak peka huruf besar-kecil , Anda mungkin tidak peduli tentang kasus huruf, yang berarti bahwa * pisang* akan melakukannya juga.

Atau, untuk menghitung sel dengan kecocokan parsial , gabungkan referensi sel dan karakter wildcard seperti:

=COUNTIF(A2:A7, "*"&D2&"*")

Untuk informasi lebih lanjut, silakan lihat Cara menghitung sel dengan teks tertentu di Excel.

Cara menghitung sel yang difilter dengan teks di Excel

Ketika menggunakan filter Excel untuk menampilkan hanya data yang relevan pada saat tertentu, terkadang Anda mungkin perlu menghitung sel yang terlihat dengan teks Sayangnya, tidak ada solusi satu-klik untuk tugas ini, tetapi contoh di bawah ini akan memandu Anda dengan nyaman melalui langkah-langkahnya.

Misalkan, Anda memiliki tabel seperti yang ditunjukkan pada gambar di bawah ini. Beberapa entri ditarik dari database yang lebih besar menggunakan rumus, dan berbagai kesalahan terjadi di sepanjang jalan. Anda ingin menemukan jumlah total item di kolom A. Dengan semua baris terlihat, rumus COUNTIF yang telah kita gunakan untuk menghitung sel dengan teks berfungsi dengan baik:

=COUNTIF(A2:A10, "*")

Dan sekarang, Anda mempersempit daftar dengan beberapa kriteria, katakanlah menyaring item dengan kuantitas lebih besar dari 10. Pertanyaannya adalah - berapa banyak item yang tersisa?

Untuk menghitung sel yang disaring dengan teks , inilah yang perlu Anda lakukan:

1. Dalam tabel sumber Anda, buat semua baris terlihat. Untuk ini, hapus semua filter dan tampilkan baris tersembunyi.
2. Tambahkan kolom pembantu dengan rumus SUBTOTAL yang menunjukkan apakah suatu baris difilter atau tidak.

   Untuk menangani sel yang disaring , gunakan 3 untuk function_num argumen:

   =SUBTOTAL(3, A2)

   Untuk mengidentifikasi semua sel tersembunyi , disaring dan disembunyikan secara manual, masukkan 103 ke dalam function_num :

   =SUBTOTAL(103, A2)

   Dalam contoh ini, kita hanya ingin menghitung sel yang terlihat dengan teks terlepas dari bagaimana sel lain disembunyikan, jadi kami memasukkan rumus kedua di A2 dan menyalinnya ke A10.

   Untuk sel yang terlihat, rumusnya mengembalikan 1. Segera setelah Anda memfilter atau menyembunyikan beberapa baris secara manual, rumus akan mengembalikan 0 untuk baris tersebut. (Anda tidak akan melihat angka nol tersebut karena dikembalikan untuk baris tersembunyi. Untuk memastikannya berfungsi dengan cara ini, cukup salin konten sel tersembunyi dengan rumus Subtotal ke sel mana pun yang terlihat, katakanlah =D2, dengan asumsi baris 2 tersembunyi).

   

3. Gunakan fungsi COUNTIFS dengan dua fungsi yang berbeda criteria_range / kriteria untuk menghitung sel yang terlihat dengan teks:
   • Kriteria1 - mencari sel dengan teks apa pun ("*") dalam rentang A2: A10.
   • Criteria2 - mencari 1 dalam rentang D2:D10 untuk mendeteksi sel yang terlihat.

   =COUNTIFS(A2:A10, "*", D2:D10, 1)

Sekarang, Anda dapat memfilter data seperti yang Anda inginkan, dan rumus akan memberi tahu Anda berapa banyak sel yang difilter di kolom A berisi teks (3 dalam kasus kami):

Jika kamu lebih suka tidak menyisipkan kolom tambahan dalam lembar kerjamu, maka kamu akan membutuhkan rumus yang lebih panjang untuk menyelesaikan tugas tersebut. Pilih saja yang lebih kamu sukai:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), -- (ISTEXT(A2:A10)))

Operator perkalian juga akan bekerja:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))) * (ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10)-MIN(ROW(A2:A10)),,1)) * (ISTEXT(A2:A10)))

Formula mana yang digunakan adalah masalah preferensi pribadi Anda - hasilnya akan sama dalam hal apa pun:

Bagaimana rumus-rumus ini bekerja

Rumus pertama menggunakan fungsi INDIRECT untuk "memberi makan" referensi individu dari semua sel dalam rentang yang ditentukan ke SUBTOTAL. Rumus kedua menggunakan kombinasi fungsi OFFSET, ROW dan MIN untuk tujuan yang sama.

Fungsi SUBTOTAL mengembalikan larik 1 dan 0 di mana satu mewakili sel yang terlihat dan nol cocok dengan sel tersembunyi (seperti kolom pembantu di atas).

Fungsi ISTEXT memeriksa setiap sel di A2: A10 dan mengembalikan TRUE jika sel berisi teks, jika tidak, FALSE. Operator unary ganda (--) memaksa nilai TRUE dan FALSE menjadi 1 dan 0. Pada titik ini, rumusnya terlihat sebagai berikut:

=SUMPRODUCT({0;1;1;1;0;1;1;0;0}, {1;1;1;0;1;1;0;1;1})

Fungsi SUMPRODUCT pertama-tama mengalikan elemen dari kedua larik di posisi yang sama dan kemudian menjumlahkan larik yang dihasilkan.

Karena perkalian dengan nol menghasilkan nol, hanya sel yang diwakili oleh 1 dalam kedua larik yang memiliki 1 dalam larik akhir.

=SUMPRODUCT({0;1;1;0;0;1;0;0;0})

Dan jumlah 1 dalam larik di atas adalah jumlah sel yang terlihat berisi teks.

Itulah cara menghitung sel dengan teks di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

Rumus Excel untuk menghitung sel dengan teks