Kako da brojim ćelije s tekstom u Excelu? Postoji nekoliko različitih formula za brojanje ćelija koje sadrže bilo koji tekst, specifične znakove ili samo filtrirane ćelije. Sve formule rade u Excelu 365, 2021, 2019, 2016, 2013 i 2010.

U početku su Excel tabele bile dizajnirane za rad s brojevima. Ali ovih dana ih često koristimo i za skladištenje i manipulaciju tekstom. Želite znati koliko ćelija sa tekstom ima na vašem radnom listu? Microsoft Excel ima nekoliko funkcija za to. Koji biste trebali koristiti? Pa, zavisi od situacije. U ovom vodiču ćete pronaći razne formule i kada je svaku formulu najbolje koristiti.

Kako prebrojati broj ćelija s tekstom u Excelu

Tamo su dvije osnovne formule za pronalaženje koliko ćelija u datom rasponu sadrži bilo koji tekstualni niz ili znak.

Formula COUNTIF za brojanje svih ćelija s tekstom

Kada želite pronaći broj ćelija sa teksta u Excelu, funkcija COUNTIF sa zvjezdicom u argumentu kriterijum je najbolje i najlakše rješenje:

Zato što je zvjezdica (*) je zamjenski znak koji odgovara bilo kojem nizu znakova, formula broji sve ćelije koje sadrže bilo koji tekst.

SUMPRODUCT formula za brojanje ćelija s bilo kojim tekstom

Još jedan način da dobijete broj ćelije koje sadrže tekst treba da kombinuju funkcije SUMPRODUCT i ISTEXT:

Ili

Funkcija ISTEXT provjerava da li svaka ćelija u navedenoj raspon sadrži sve tekstualne znakove i vraća niz vrijednosti TRUE (ćelije s tekstom) i FALSE (ostale ćelije). Dvostruka unarna (--) ili operacija množenja dovodi do TRUE i FALSE na 1 i 0, respektivno, proizvodeći niz jedinica i nula. Funkcija SUMPRODUCT zbraja sve elemente niza i vraća broj 1, što je broj ćelija koje sadrže tekst.

Da biste bolje razumjeli kako ove formule rade, pogledajte koje se vrijednosti broje i koji nisu:

Na primjer, za brojanje ćelija s tekstom u rasponu A2:A10, isključujući brojeve, datume, logičke vrijednosti, greške i prazne ćelije, koristite jednu od ovih formula:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--ISTEXT(A2:A10))

=SUMPRODUCT(ISTEXT(A2:A10)*1)

Snimak ekrana ispod prikazuje rezultat:

Broj ćelija s tekstom isključujući razmake i prazne nizove

Formule o kojima smo raspravljali gore countsve ćelije koje imaju bilo koje tekstualne znakove u sebi. Međutim, u nekim situacijama to može biti zbunjujuće jer određene ćelije mogu izgledati samo prazne, ali zapravo sadrže znakove nevidljive ljudskom oku, kao što su prazni nizovi, apostrofi, razmaci, prijelomi reda, itd. Kao rezultat toga, vizualno prazan ćelija se broji po formuli koja uzrokuje da korisnik čupa kosu pokušavajući shvatiti zašto :)

Da biste isključili "lažno pozitivne" prazne ćelije iz brojanja, koristite funkciju COUNTIFS sa "isključenim" znakom u drugi kriterij.

Na primjer, da prebrojite ćelije s tekstom u rasponu A2:A7 zanemarujući one koje sadrže razmak , koristite ovu formulu:

=COUNTIFS(A2:A7,"*", A2:A7, " ")

Ako vaš ciljni raspon sadrži podatke vođene formulom, neke od formula mogu rezultirati praznim nizom (""). Da biste zanemarili i ćelije s praznim nizovima , zamijenite "*" sa "*?*" u argumentu kriterijum1 :

=COUNTIFS(A2:A9,"*?*", A2:A9, " ")

Pitanje oznaka okružena zvjezdicama označava da u ćeliji treba biti barem jedan karakter teksta. Pošto prazan niz nema znakova u sebi, ne ispunjava kriterijume i ne računa se. Ne računaju se ni prazne ćelije koje počinju apostrofom (').

Na snimku ekrana ispod, postoji razmak u A7, apostrof u A8 i prazan niz (="") u A9. Naša formula izostavlja sve te ćelije i vraća broj tekstualnih ćelija3:

Kako prebrojati ćelije s određenim tekstom u Excelu

Da biste dobili broj ćelija koje sadrže određeni tekst ili znak, jednostavno unesite taj tekst u argumentu kriterijum funkcije COUNTIF. Primjeri u nastavku objašnjavaju nijanse.

Da biste odgovarali uzorku teksta tačno , unesite cijeli tekst u navodnicima:

Da prebrojite ćelije sa djelimično podudaranje , postavite tekst između dvije zvjezdice, koje predstavljaju bilo koji broj znakova prije i poslije teksta:

Na primjer, da biste pronašli koliko ćelija u rasponu A2:A7 sadrži točno riječ "banane", koristite ovu formulu:

=COUNTIF(A2:A7, "bananas")

Da prebrojite sve ćelije koje sadrže "banane" kao dio svog sadržaja na bilo kojoj poziciji, koristite ovu:

=COUNTIF(A2:A7, "*bananas*")

Da biste formulu učinili jednostavnijom za korisnika, možete postaviti kriterije u unaprijed definiranu ćeliju, recimo D2, i staviti referencu ćelije u drugi argument:

=COUNTIF(A2:A7, D2)

U zavisnosti od unosa u D2, formula može u potpunosti ili djelomično odgovarati uzorku teksta:

• Za potpuno podudaranje, otkucajte cijelu riječ ili frazu kako se pojavljuje u izvornoj tabeli, npr. Banane .
• Za djelomično podudaranje, unesite uzorak teksta okružen zamjenskim znakovima, kao što je *Bananas* .

Kao formula je neosjetljiva na velika i mala slova , ne morate se truditi oko velikih i malih slova,što znači da će i *banane* poslužiti.

Alternativno, da prebrojite ćelije sa djelimično podudaranjem , spojite referencu ćelije i zamjenski znakovi kao što su:

=COUNTIF(A2:A7, "*"&D2&"*")

Za više informacija pogledajte Kako prebrojati ćelije sa određenim tekstom u Excelu.

Kako za brojanje filtriranih ćelija s tekstom u Excelu

Kada koristite Excel filter za prikaz samo podataka relevantnih u datom trenutku, ponekad ćete možda morati brojati vidljive ćelije s tekstom . Nažalost, ne postoji rješenje jednim klikom za ovaj zadatak, ali primjer ispod će vas udobno provesti kroz korake.

Pretpostavimo da imate tabelu kao što je prikazano na slici ispod. Neki unosi su izvučeni iz veće baze podataka pomoću formula, a usput su se javljale razne greške. Tražite da pronađete ukupan broj stavki u koloni A. Sa svim vidljivim redovima, formula COUNTIF koju smo koristili za brojanje ćelija sa tekstom radi kao poslastica:

=COUNTIF(A2:A10, "*")

A sada, suzite listu po nekim kriterijima, recimo filtrirajte stavke s količinom većom od 10. Pitanje je – koliko je stavki ostalo?

Da prebrojim filtrirane ćelije s tekstom , ovo je ono što trebate učiniti:

1. U vašoj izvornoj tabeli, učinite sve redove vidljivima. Za ovo, obrišite sve filtere i pokažite skrivene redove.
2. Dodajte pomoćnu kolonu sa formulom SUBTOTAL koja pokazuje da li je redfiltrirano ili ne.

   Za rukovanje filtriranim ćelijama , koristite 3 za argument function_num :

   =SUBTOTAL(3, A2)

   Da biste identificirali sve skrivene ćelije , filtrirane i skrivene ručno, stavite 103 u function_num :

   =SUBTOTAL(103, A2)

   U ovom primjeru želimo brojati samo vidljive ćelije sa tekstom bez obzira na to kako su ostale ćelije skrivene, tako da upisujemo drugu formulu u A2 i kopiramo je na A10.

   Za vidljive ćelije, formula vraća 1. Čim filtrirate ili ručno sakriti neke redove, formula će za njih vratiti 0. (Nećete vidjeti te nule jer su vraćene za skrivene redove. Da biste bili sigurni da funkcionira na ovaj način, samo kopirajte sadržaj skrivene ćelije sa formulom Subtotal na bilo koju vidljivu, recimo =D2, pod pretpostavkom da je red 2 skriven .)

   

3. Koristite funkciju COUNTIFS s dva različita para criteria_range / criteria za brojanje vidljivih ćelija s tekstom:
   • Kriterijumi1 - traži ćelije s bilo kojim tekstom ("*") u rasponu A2:A10.
   • Kriterijumi2 - traži 1 u rasponu D2:D10 za otkrivanje vidljivih ćelija.

   =COUNTIFS(A2:A10, "*", D2:D10, 1)

Sada, možete filtrirati podatke na način na koji želite, a formula će vam reći koliko filtriranih ćelija u koloni A sadrži tekst (3 in naš slučaj):

Ako radije ne umetnete dodatni stupac u radni list, tada će vam trebati duža formula da biste izvršili zadatak. Samo izaberite onu koju vikao bolje:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), -- (ISTEXT(A2:A10)))

Operator množenja će također raditi:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))) * (ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10)-MIN(ROW(A2:A10)),,1)) * (ISTEXT(A2:A10)))

Koju formulu koristiti je stvar vaših ličnih preferencija - rezultat će u svakom slučaju biti isti:

Kako ove formule funkcioniraju

Prva formula koristi INDIRECT funkciju da "nahrani" pojedinačne reference svih ćelija u navedenom rasponu do SUBTOTAL. Druga formula koristi kombinaciju funkcija OFFSET, ROW i MIN za istu svrhu.

Funkcija SUBTOTAL vraća niz 1 i 0 gdje jedinice predstavljaju vidljive ćelije, a nule odgovaraju skrivenim ćelijama (kao pomoćni stupac gore).

Funkcija ISTEXT provjerava svaku ćeliju u A2:A10 i vraća TRUE ako ćelija sadrži tekst, FALSE u suprotnom. Dvostruki unarni operator (--) prisiljava vrijednosti TRUE i FALSE u 1 i 0. U ovom trenutku formula izgleda ovako:

=SUMPRODUCT({0;1;1;1;0;1;1;0;0}, {1;1;1;0;1;1;0;1;1})

Funkcija SUMPRODUCT prvo množi elemente oba niza na istim pozicijama, a zatim zbraja rezultirajući niz.

Pošto množenje sa nulom daje nulu, samo ćelije predstavljene sa 1 u oba niza imaju 1 u konačnom nizu.

=SUMPRODUCT({0;1;1;0;0;1;0;0;0})

A broj 1 u gornjem nizu je broj vidljivih ćelije koje sadrže tekst.

Tako se prebrojavaju ćelije sa tekstom u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeće sedmice!

Dostupnopreuzimanja

Excel formule za brojanje ćelija s tekstom