Како да бројим ћелије са текстом у Екцел-у? Постоји неколико различитих формула за бројање ћелија које садрже било који текст, специфичне знакове или само филтриране ћелије. Све формуле функционишу у Екцел-у 365, 2021, 2019, 2016, 2013 и 2010.

У почетку су Екцел табеле биле дизајниране да раде са бројевима. Али ових дана их често користимо и за складиштење и манипулацију текстом. Желите да знате колико ћелија са текстом има на вашем радном листу? Мицрософт Екцел има неколико функција за ово. Који треба да користите? Па, зависи од ситуације. У овом водичу ћете пронаћи различите формуле и када је сваку формулу најбоље користити.

Како пребројати број ћелија са текстом у Екцел-у

Тамо су две основне формуле за проналажење колико ћелија у датом опсегу садржи било који текстуални низ или знак.

Формула ЦОУНТИФ за бројање свих ћелија са текстом

Када желите да пронађете број ћелија са текста у Екцел-у, функција ЦОУНТИФ са звездицом у аргументу критеријум је најбоље и најлакше решење:

Зато што је звездица (*) је џокер знак који одговара било ком низу знакова, формула броји све ћелије које садрже било који текст.

Формула ЗБИРНИ ПРОИЗВОД за бројање ћелија са било којим текстом

Још један начин да добијете број ћелије које садрже текст треба да комбинују функције СУМПРОДУЦТ и ИСТЕКСТ:

Или

Функција ИСТЕКСТ проверава да ли свака ћелија у наведеној опсег садржи све текстуалне знакове и враћа низ вредности ТРУЕ (ћелије са текстом) и ФАЛСЕ (остале ћелије). Двострука унарна (--) или операција множења доводи до ТРУЕ и ФАЛСЕ на 1 и 0, респективно, производећи низ јединица и нула. Функција СУМПРОДУЦТ сабира све елементе низа и враћа број 1, што је број ћелија које садрже текст.

Да бисте боље разумели како ове формуле функционишу, погледајте које вредности се броје и који нису:

На пример, за бројање ћелија са текстом у опсегу А2:А10, искључујући бројеве, датуме, логичке вредности, грешке и празне ћелије, користите једну од ових формула:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--ISTEXT(A2:A10))

=SUMPRODUCT(ISTEXT(A2:A10)*1)

Снимак екрана испод показује резултат:

Број ћелија са текстом искључујући размаке и празне стрингове

Формуле о којима смо расправљали изнад цоунтсве ћелије које имају било које текстуалне знакове у себи. У неким ситуацијама, међутим, то може бити збуњујуће јер одређене ћелије могу изгледати само празне, али заправо садрже знакове невидљиве људском оку, као што су празни низови, апострофи, размаци, преломи редова, итд. Као резултат тога, визуелно празан ћелија се броји по формули која узрокује да корисник чупа косу покушавајући да схвати зашто :)

Да бисте искључили „лажно позитивне“ празне ћелије из бројања, користите функцију ЦОУНТИФС са знаком „искључено“ у други критеријум.

На пример, да бисте пребројали ћелије са текстом у опсегу А2:А7 игноришући оне које садрже размак , користите ову формулу:

=COUNTIFS(A2:A7,"*", A2:A7, " ")

Ако ваш циљни опсег садржи податке засноване на формули, неке од формула могу довести до празног стринга (""). Да бисте игнорисали ћелије са празним стринговима , замените "*" са "*?*" у аргументу критеријум1 :

=COUNTIFS(A2:A9,"*?*", A2:A9, " ")

Питање ознака окружена звездицама означава да у ћелији треба да постоји најмање један текстуални карактер. Пошто празан низ нема знакова у себи, не испуњава критеријуме и не рачуна се. Не рачунају се ни празне ћелије које почињу апострофом (').

На снимку екрана испод, постоји размак у А7, апостроф у А8 и празан низ (="") у А9. Наша формула изоставља све те ћелије и враћа број текстуалних ћелија3:

Како пребројати ћелије са одређеним текстом у Екцел-у

Да бисте добили број ћелија које садрже одређени текст или карактер, једноставно унесите тај текст у аргументу критеријум функције ЦОУНТИФ. Примери у наставку објашњавају нијансе.

Да би се текст примера тачно подударао, унесите цео текст стављен под наводнике:

Да бисте пребројали ћелије са делимично подударање , поставите текст између две звездице, које представљају било који број знакова пре и после текста:

На пример, да бисте пронашли колико ћелија у опсегу А2:А7 садржи тачно реч "банане", користите ову формулу:

=COUNTIF(A2:A7, "bananas")

Да бисте пребројали све ћелије које садрже "банане" као део свог садржаја на било којој позицији, користите ову:

=COUNTIF(A2:A7, "*bananas*")

Да бисте формулу учинили једноставнијом за корисника, можете поставити критеријуме у унапред дефинисану ћелију, рецимо Д2, и ставити референцу ћелије у други аргумент:

=COUNTIF(A2:A7, D2)

У зависности од уноса у Д2, формула може у потпуности или делимично да се подудара са примером текста:

• За потпуно подударање, откуцајте целу реч или фразу како се појављује у изворној табели, нпр. Банане .
• За делимично подударање, откуцајте пример текста окружен џокер знаковима, на пример *Банане* .

Као формула је неосетљива на велика и мала слова , можда се не трудите око великих слова,што значи да ће *банане* исто тако радити.

Алтернативно, да бисте пребројали ћелије са делимичним подударањем , спојите референцу ћелије и џокер знакови као што су:

=COUNTIF(A2:A7, "*"&D2&"*")

За више информација погледајте Како пребројати ћелије са одређеним текстом у Екцел-у.

Како за бројање филтрираних ћелија са текстом у Екцел-у

Када користите Екцел филтер за приказ само података релевантних у датом тренутку, можда ћете понекад морати да пребројите видљиве ћелије са текстом . Нажалост, не постоји решење једним кликом за овај задатак, али пример у наставку ће вас удобно провести кроз кораке.

Претпоставимо да имате табелу као што је приказано на слици испод. Неки уноси су извучени из веће базе података помоћу формула, а успут су се дешавале разне грешке. Тражите да пронађете укупан број ставки у колони А. Пошто су сви редови видљиви, формула ЦОУНТИФ коју смо користили за бројање ћелија са текстом ради као посластица:

=COUNTIF(A2:A10, "*")

И сад, сузите листу по неким критеријумима, рецимо филтрирајте ставке са количином већом од 10. Питање је – колико је ставки остало?

Да се ​​преброје филтриране ћелије са текстом , ово је оно што треба да урадите:

1. У вашој изворној табели, учините све редове видљивим. За ово, обришите све филтере и покажите скривене редове.
2. Додајте помоћну колону са формулом СУБТОТАЛ која показује да ли је редфилтрирано или не.

   Да бисте руковали филтрираним ћелијама , користите 3 за аргумент фунцтион_нум :

   =SUBTOTAL(3, A2)

   Да бисте идентификовали све скривене ћелије , филтриране и скривене ручно, ставите 103 у фунцтион_нум :

   =SUBTOTAL(103, A2)

   У овом примеру желимо да бројимо само видљиве ћелије са текстом без обзира на то како су друге ћелије сакривене, тако да уносимо другу формулу у А2 и копирамо је на А10.

   За видљиве ћелије, формула враћа 1. Чим филтрирате или ручно сакрити неке редове, формула ће за њих вратити 0. (Нећете видети те нуле јер се враћају за скривене редове. Да бисте били сигурни да функционише на овај начин, само копирајте садржај скривене ћелије са формулом међузбир у било коју видљиву, рецимо, =Д2, под претпоставком да је ред 2 сакривен .)

   

3. Користите функцију ЦОУНТИФС са два различита пара опсег_критеријума / критеријум да бисте пребројали видљиве ћелије са текстом:
   • Критеријуми1 – тражи ћелије са било којим текстом („*“) у опсегу А2:А10.
   • Критеријуми2 – тражи 1 у опсегу Д2:Д10 да би открио видљиве ћелије.

   =COUNTIFS(A2:A10, "*", D2:D10, 1)

Сада, можете филтрирати податке на начин на који желите, а формула ће вам рећи колико филтрираних ћелија у колони А садржи текст (3 ин наш случај):

Ако не желите да уметнете додатну колону у радни лист, биће вам потребна дужа формула да бисте извршили задатак. Само изаберите ону коју викао боље:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), -- (ISTEXT(A2:A10)))

Оператор множења ће такође радити:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))) * (ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10)-MIN(ROW(A2:A10)),,1)) * (ISTEXT(A2:A10)))

Коју формулу ћете користити је ствар ваших личних преференција - резултат ће у сваком случају бити исти:

Како ове формуле раде

Прва формула користи ИНДИРЕЦТ функцију да "нахрани" појединачне референце свих ћелија у наведеном опсегу до СУБТОТАЛ. Друга формула користи комбинацију функција ОФФСЕТ, РОВ и МИН за исту сврху.

Функција СУБТОТАЛ враћа низ 1 и 0 где јединице представљају видљиве ћелије, а нуле одговарају скривеним ћелијама (као помоћна колона изнад).

Функција ИСТЕКСТ проверава сваку ћелију у А2:А10 и враћа ТРУЕ ако ћелија садржи текст, ФАЛСЕ у супротном. Двоструки унарни оператор (--) приморава вредности ТРУЕ и ФАЛСЕ у 1 и 0. У овом тренутку формула изгледа овако:

=SUMPRODUCT({0;1;1;1;0;1;1;0;0}, {1;1;1;0;1;1;0;1;1})

Функција СУМПРОДУЦТ прво множи елементе оба низа на истим позицијама, а затим сабира резултујући низ.

Пошто множење са нулом даје нулу, само ћелије представљене са 1 у оба низа имају 1 у коначном низу.

=SUMPRODUCT({0;1;1;0;0;1;0;0;0})

А број 1 у горњем низу је број видљивих ћелије које садрже текст.

Тако се пребројавају ћелије са текстом у Екцел-у. Захваљујем вам на читању и надам се да се видимо на нашем блогу следеће недеље!

Доступнопреузимања

Екцел формуле за бројање ћелија са текстом