Si mund të numëroj qelizat me tekst në Excel? Ka disa formula të ndryshme për të numëruar qelizat që përmbajnë çdo tekst, karaktere specifike ose vetëm qeliza të filtruara. Të gjitha formulat funksionojnë në Excel 365, 2021, 2019, 2016, 2013 dhe 2010.

Fillimisht, tabelat e Excel u krijuan për të punuar me numra. Por këto ditë ne shpesh i përdorim ato për të ruajtur dhe manipuluar gjithashtu tekstin. Dëshironi të dini sa qeliza me tekst ka në fletën tuaj të punës? Microsoft Excel ka disa funksione për këtë. Cilin duhet të përdorni? Epo, varet nga situata. Në këtë tutorial, do të gjeni një shumëllojshmëri formulash dhe kur secila formulë është më e mira për t'u përdorur.

Si të numëroni numrin e qelizave me tekst në Excel

Atje janë dy formula bazë për të gjetur se sa qeliza në një varg të caktuar përmbajnë ndonjë varg teksti ose karakter.

Formula COUNTIF për të numëruar të gjitha qelizat me tekst

Kur dëshironi të gjeni numrin e qelizave me teksti në Excel, funksioni COUNTIF me një yll në argumentin kriteret është zgjidhja më e mirë dhe më e lehtë:

Sepse ylli (*) është një karakteristikë që përputhet me çdo sekuencë karakteresh, formula numëron të gjitha qelizat që përmbajnë çdo tekst.

Formula SUMPRODUCT për të numëruar qelizat me çdo tekst

Një mënyrë tjetër për të marrë numrin e qelizat që përmbajnë tekst duhet të kombinojnë funksionet SUMPRODUCT dhe ISTEXT:

Ose

Funksioni ISTEXT kontrollon nëse çdo qelizë në specifikimin vargu përmban çdo karakter teksti dhe kthen një grup vlerash TRUE (qeliza me tekst) dhe FALSE (qeliza të tjera). Unari i dyfishtë (--) ose operacioni i shumëzimit detyron TRUE dhe FALSE në 1 dhe 0, përkatësisht, duke prodhuar një grup njësh dhe zero. Funksioni SUMPRODUCT mbledh të gjithë elementët e grupit dhe kthen numrin e 1-ve, që është numri i qelizave që përmbajnë tekst.

Për të kuptuar më shumë se si funksionojnë këto formula, ju lutemi shikoni se cilat vlera janë numëruar dhe të cilat nuk janë:

Për shembull, për të numëruar qelizat me tekst në intervalin A2:A10, duke përjashtuar numrat, datat, vlerat logjike, gabimet dhe qelizat e zbrazëta, përdorni një nga këto formula:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--ISTEXT(A2:A10))

=SUMPRODUCT(ISTEXT(A2:A10)*1)

Pamja e ekranit më poshtë tregon rezultatin:

Numëroni qelizat me tekst duke përjashtuar hapësirat dhe vargjet boshe

Formulat e diskutuara më sipër numërojtë gjitha qelizat që kanë ndonjë karakter teksti në to. Megjithatë, në disa situata, kjo mund të jetë konfuze, sepse disa qeliza mund të duken vetëm boshe, por në fakt, përmbajnë karaktere të padukshme për syrin e njeriut si vargje boshe, apostrofa, hapësira, ndërprerje rreshtash, etj. Si rezultat, një boshllëk vizualisht qeliza numërohet nga formula që bën që një përdorues të shkulë flokët duke u përpjekur të kuptojë pse :)

Për të përjashtuar qelizat bosh "false pozitive" nga numërimi, përdorni funksionin COUNTIFS me karakterin "të përjashtuar" në kriteri i dytë.

Për shembull, për të numëruar qelizat me tekst në rangun A2:A7 duke injoruar ato që përmbajnë një karakter hapësirë , përdorni këtë formulë:

=COUNTIFS(A2:A7,"*", A2:A7, " ")

Nëse diapazoni juaj i synuar përmban ndonjë të dhënë të drejtuar nga formula, disa nga formulat mund të rezultojnë në një varg bosh (""). Për të injoruar qelizat me vargje boshe gjithashtu, zëvendësoni "*" me "*?*" në argumentin criteria1 :

=COUNTIFS(A2:A9,"*?*", A2:A9, " ")

Një pyetje Shenja e rrethuar me yje tregon se duhet të ketë të paktën një karakter teksti në qelizë. Meqenëse një varg bosh nuk ka karaktere në të, ai nuk i plotëson kriteret dhe nuk llogaritet. Qelizat boshe që fillojnë me një apostrof (') nuk numërohen as.

Në pamjen e ekranit më poshtë, ka një hapësirë ​​në A7, një apostrof në A8 dhe një varg bosh (="") në A9. Formula jonë i lë jashtë të gjitha ato qeliza dhe kthen një numër të qelizave tekstuale prej3:

Si të numëroni qelizat me tekst të caktuar në Excel

Për të marrë numrin e qelizave që përmbajnë tekst ose karakter të caktuar, thjesht jepni atë tekst në argumentin kriteret të funksionit COUNTIF. Shembujt e mëposhtëm shpjegojnë nuancat.

Për t'u përshtatur me tekstin e mostrës saktësisht , shkruani tekstin e plotë të mbyllur në thonjëza:

Për të numëruar qelizat me pjesshme përputhje , vendoseni tekstin midis dy yjeve, të cilët përfaqësojnë çdo numër karakteresh para dhe pas tekstit:

Për shembull, për të gjetur se sa qeliza në diapazonin A2:A7 përmbajnë saktësisht fjalën "banane", përdorni këtë formulë:

=COUNTIF(A2:A7, "bananas")

Për të numëruar të gjitha qelizat që përmbajnë "banane" si pjesë e përmbajtjes së tyre në çdo pozicion, përdorni këtë:

=COUNTIF(A2:A7, "*bananas*")

Për ta bërë formulën më miqësore për përdoruesit, mund t'i vendosni kriteret në një qelizë të paracaktuar, le të themi D2, dhe të vendosni referencën e qelizës në argumentin e dytë:

=COUNTIF(A2:A7, D2)

Në varësi të hyrjes në D2, formula mund të përputhet plotësisht ose pjesërisht me tekstin e mostrës:

• Për përputhje të plotë, shkruani të gjithë fjalën ose frazën siç shfaqet në tabelën burimore, p.sh. Bananet .
• Për përputhje të pjesshme, shkruani tekstin e mostrës të rrethuar me karaktere të gërmadha, si *Bananet* .

Si formula është të pandjeshme ndaj shkronjave , mund të mos shqetësoheni për shkronjat e mëdha,që do të thotë se *bananet* do të veprojnë gjithashtu.

Përndryshe, për të numëruar qelizat me përputhje të pjesshme , lidhni referencën e qelizës dhe shkronjat e karakterit të egër si:

=COUNTIF(A2:A7, "*"&D2&"*")

Për më shumë informacion, ju lutemi shihni Si të numëroni qelizat me tekst specifik në Excel.

Si për të numëruar qelizat e filtruara me tekst në Excel

Kur përdorni filtrin Excel për të shfaqur vetëm të dhënat përkatëse në një moment të caktuar, ndonjëherë mund t'ju duhet të numëroni qelizat e dukshme me tekst . Fatkeqësisht, nuk ka zgjidhje me një klikim për këtë detyrë, por shembulli i mëposhtëm do t'ju përcjellë lehtësisht nëpër hapat.

Si të supozojmë se keni një tabelë siç tregohet në imazhin më poshtë. Disa hyrje u nxorrën nga një bazë të dhënash më e madhe duke përdorur formula dhe gabime të ndryshme ndodhën gjatë rrugës. Ju po kërkoni të gjeni numrin total të artikujve në kolonën A. Me të gjitha rreshtat të dukshëm, formula COUNTIF që kemi përdorur për numërimin e qelizave me tekst funksionon mirë:

=COUNTIF(A2:A10, "*")

Dhe tani, ju e ngushtoni listën me disa kritere, të themi filtrojini artikujt me sasi më të madhe se 10. Pyetja është - sa artikuj kanë mbetur?

Për të numëruar qelizat e filtruara me tekst , kjo është ajo që duhet të bëni:

1. Në tabelën tuaj burimore, bëjini të dukshme të gjitha rreshtat. Për këtë, pastroni të gjithë filtrat dhe fshihni rreshtat e fshehur.
2. Shtoni një kolonë ndihmëse me formulën SUBTOTAL që tregon nëse një rresht ështëfiltruar apo jo.

   Për të trajtuar qelizat e filtruara , përdorni 3 për argumentin function_num :

   =SUBTOTAL(3, A2)

   Për të identifikuar të gjitha qelizat e fshehura , të filtruara dhe të fshehura me dorë, vendosni 103 në funksion_num :

   =SUBTOTAL(103, A2)

   Në këtë shembull, duam të numërojmë vetëm qelizat e dukshme me tekst pavarësisht se si ishin fshehur qelizat e tjera, kështu që ne futim formulën e dytë në A2 dhe e kopjojmë atë në A10.

   Për qelizat e dukshme, formula kthen 1. Sapo të filtrosh ose fshehni manualisht disa rreshta, formula do të kthejë 0 për to. (Nuk do t'i shihni ato zero sepse ato janë kthyer për rreshta të fshehur. Për t'u siguruar që funksionon në këtë mënyrë, thjesht kopjoni përmbajtjen e një qelize të fshehur me formulën Subtotal në çdo të dukshme, të themi =D2, duke supozuar se rreshti 2 është i fshehur .)

   

3. Përdor funksionin COUNTIFS me dy çifte të ndryshme varg_kriteresh / kritere për të numëruar qelizat e dukshme me tekst:
   • Kriteri 1 - kërkon qeliza me çdo tekst ("*") në intervalin A2:A10.
   • Kriteri 2 - kërkon 1 në diapazonin D2:D10 për të zbuluar qelizat e dukshme.

   =COUNTIFS(A2:A10, "*", D2:D10, 1)

Tani, ju mund t'i filtroni të dhënat ashtu siç dëshironi dhe formula do t'ju tregojë se sa qeliza të filtruara në kolonën A përmbajnë tekst (3 in rasti ynë):

Nëse nuk dëshironi të futni një kolonë shtesë në fletën tuaj të punës, atëherë do t'ju duhet një formulë më e gjatë për të përmbushur detyrën. Thjesht zgjidhni atë që jusi më mirë:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), -- (ISTEXT(A2:A10)))

Operatori i shumëzimit do të funksionojë gjithashtu:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))) * (ISTEXT(A2:A10)))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10)-MIN(ROW(A2:A10)),,1)) * (ISTEXT(A2:A10)))

Cilën formulë të përdorni është çështje e preferencës suaj personale - rezultati do të jetë i njëjtë në çdo rast:

Si funksionojnë këto formula

E para formula përdor funksionin INDIRECT për të "ushqyer" referencat individuale të të gjitha qelizave në diapazonin e specifikuar në SUBTOTAL. Formula e dytë përdor një kombinim të funksioneve OFFSET, ROW dhe MIN për të njëjtin qëllim.

Funksioni SUBTOTAL kthen një grup me 1 dhe 0 ku njëra përfaqëson qelizat e dukshme dhe zerat përputhen me qelizat e fshehura (si kolona ndihmëse më sipër).

Funksioni ISTEXT kontrollon çdo qelizë në A2:A10 dhe kthen TRUE nëse një qelizë përmban tekst, përndryshe FALSE. Operatori i dyfishtë unar (--) detyron vlerat TRUE dhe FALSE në 1 dhe 0. Në këtë pikë, formula duket si më poshtë:

=SUMPRODUCT({0;1;1;1;0;1;1;0;0}, {1;1;1;0;1;1;0;1;1})

Funksioni SUMPRODUCT fillimisht shumëzon elementet e të dy vargjeve në të njëjtat pozicione dhe më pas përmbledh grupin që rezulton.

Ndërsa shumëzimi me zero jep zero, vetëm qelizat e përfaqësuara nga 1 në të dy vargjet kanë 1 në grupin përfundimtar.

=SUMPRODUCT({0;1;1;0;0;1;0;0;0})

Dhe numri i 1-ve në grupin e mësipërm është numri i të dukshmeve qelizat që përmbajnë tekst.

Kjo është se si të numërohen qelizat me tekst në Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme!

E disponueshmeshkarkime

Formulat e Excel për të numëruar qelizat me tekst