Tutorial ini menunjukkan cara menggunakan fungsi TEXTSPLIT baru untuk memisahkan string di Excel 365 dengan pembatas apa pun yang Anda tentukan.

Mungkin ada berbagai situasi ketika Anda perlu membagi sel di Excel. Di versi sebelumnya, kami sudah dilengkapi dengan sejumlah instrumen untuk menyelesaikan tugas seperti Teks ke Kolom dan Isi Flash. Sekarang, kami juga memiliki fungsi khusus untuk ini, TEXTSPLIT, yang dapat memisahkan string menjadi beberapa sel di seluruh kolom atau / dan baris berdasarkan parameter yang Anda tentukan.

Fungsi TEXTSPLIT Excel

Fungsi TEXTSPLIT di Excel membagi string teks dengan pembatas yang diberikan di seluruh kolom atau / dan baris. Hasilnya adalah larik dinamis yang tumpah ke beberapa sel secara otomatis.

Fungsi ini mengambil sebanyak 6 argumen, hanya dua yang pertama yang diperlukan.

teks (wajib) - teks yang akan dipisahkan. Dapat diberikan sebagai string atau referensi sel.

col_delimiter (wajib) - karakter yang mengindikasikan tempat untuk membagi teks di seluruh kolom. Jika dihilangkan, row_delimiter harus didefinisikan.

row_delimiter (opsional) - karakter yang mengindikasikan tempat untuk membagi teks di seluruh baris.

ignore_empty (opsional) - menentukan apakah akan mengabaikan nilai kosong atau tidak:

• FALSE (default) - membuat sel kosong untuk pembatas berurutan tanpa nilai di antaranya.
• TRUE - abaikan nilai kosong, yaitu tidak membuat sel kosong untuk dua atau lebih pembatas yang berurutan.

match_mode (opsional) - menentukan sensitivitas huruf besar-kecil untuk pembatas. Diaktifkan secara default.

• 0 (default) - peka huruf besar-kecil
• 1 - tidak peka huruf besar-kecil

pad_with (opsional) - nilai untuk digunakan sebagai pengganti nilai yang hilang dalam array dua dimensi. Defaultnya adalah kesalahan #N/A.

Misalnya, untuk membagi string teks di A2 menjadi beberapa sel menggunakan koma dan spasi sebagai pemisah, rumusnya adalah:

=TEXTSPLIT(A2, ", ")

Ketersediaan TEXTSPLIT

Fungsi TEXTSPLIT hanya tersedia di Excel untuk Microsoft 365 (Windows dan Mac) dan Excel untuk web.

Tips:

• Di versi Excel di mana fungsi TEXTSPLIT tidak tersedia (selain Excel 365), Anda dapat menggunakan wizard Teks ke Kolom untuk membagi sel.
• Untuk melakukan tugas sebaliknya, yaitu untuk menggabungkan konten beberapa sel menjadi satu menggunakan pembatas tertentu, TEXTJOIN adalah fungsi yang digunakan.

Rumus TEXTSPLIT dasar untuk membagi sel di Excel

Sebagai permulaan, mari kita lihat cara menggunakan rumus TEXTSPLIT dalam bentuk paling sederhana untuk membagi string teks dengan pembatas tertentu.

Membagi sel secara horizontal di seluruh kolom

Untuk membagi konten sel tertentu ke dalam beberapa kolom, berikan referensi ke sel yang berisi string asli untuk yang pertama ( teks ) argumen dan pembatas yang menandai titik di mana pemisahan harus terjadi untuk argumen kedua ( col_delimiter ) argumen.

Misalnya, untuk memisahkan string di A2 secara horizontal dengan koma, rumusnya adalah:

=TEXTSPLIT(A2, ",")

Untuk pembatas, kita menggunakan koma yang diapit oleh tanda kutip ganda (",").

Hasilnya, setiap item yang dipisahkan oleh koma masuk ke dalam kolom tersendiri:

Membagi sel secara vertikal melintasi baris

Untuk membagi teks di beberapa baris, argumen ketiga ( row_delimiter ) adalah tempat Anda menempatkan pembatas. Argumen kedua ( col_delimiter ) dihilangkan dalam kasus ini.

Contohnya, untuk memisahkan nilai dalam A2 ke dalam baris yang berbeda, rumusnya adalah:

=TEXTSPLIT(A2, ,",")

Harap dicatat bahwa, dalam kedua kasus tersebut, rumus hanya dimasukkan dalam satu sel (C2). Di sel tetangga, nilai yang dikembalikan tumpah secara otomatis. Larik yang dihasilkan (yang disebut rentang tumpahan) disorot dengan batas biru yang menunjukkan bahwa semua yang ada di dalamnya dihitung oleh rumus di sel kiri atas.

Pisahkan teks dengan substring

Dalam banyak kasus, nilai dalam string sumber dipisahkan oleh urutan karakter, koma dan spasi menjadi contoh tipikal. Untuk menangani skenario ini, gunakan substring untuk pembatas.

Contohnya, untuk memisahkan teks dalam A2 ke dalam beberapa kolom dengan koma dan spasi, gunakan string ", " untuk col_delimiter .

=TEXTSPLIT(A2, ", ")

Rumus ini masuk ke B2, lalu Anda menyalinnya ke bawah melalui sel sebanyak yang diperlukan.

Pisahkan string menjadi kolom dan baris sekaligus

Untuk membagi string teks menjadi baris dan kolom sekaligus, tentukan kedua pembatas dalam rumus TEXTSPLIT Anda.

Misalnya, untuk membagi string teks di A2 di seluruh kolom dan baris, kita menyediakan:

• Tanda sama dengan ("=") untuk col_delimiter
• Koma dan spasi (", ") untuk row_delimiter

Rumus lengkapnya mengambil bentuk ini:

=TEXTSPLIT(A2, "=", ", ")

Hasilnya adalah larik 2-D yang terdiri dari 2 kolom dan 3 baris:

Pisahkan sel dengan beberapa pembatas

Untuk menangani beberapa atau pembatas yang tidak konsisten dalam string sumber, gunakan konstanta array seperti {"x", "y", "z"} untuk argumen pembatas.

Pada tangkapan layar di bawah ini, teks di A2 dibatasi oleh koma (",") dan titik koma (";") dengan dan tanpa spasi. Untuk membagi string secara vertikal menjadi beberapa baris dengan semua 4 variasi pembatas, rumusnya adalah:

=TEXTSPLIT(A2, , {",",", ",";",",";"})

Atau, Anda bisa menyertakan hanya koma (",") dan titik koma (";") dalam larik, dan kemudian menghapus spasi ekstra dengan bantuan fungsi TRIM:

=TRIM(TEXTSPLIT(A2, , {",",";"}))

Memisahkan teks dengan mengabaikan nilai kosong

Jika string berisi dua atau lebih pembatas yang berurutan tanpa nilai di antara keduanya, Anda dapat memilih apakah akan mengabaikan nilai kosong tersebut atau tidak. Perilaku ini dikendalikan oleh ignore_empty parameter, yang secara default adalah FALSE.

Secara default, fungsi TEXTSPLIT tidak mengabaikan nilai kosong. Perilaku default berfungsi dengan baik untuk data terstruktur seperti pada contoh di bawah ini.

Dalam tabel contoh ini, skor tidak ada dalam beberapa string. Rumus TEXTSTSPLIT dengan ignore_empty argumen yang dihilangkan atau disetel ke FALSE menangani kasus ini dengan sempurna, membuat sel kosong untuk setiap nilai kosong.

=TEXTSPLIT(A2, ", ")

Atau

=TEXTSPLIT(A2, ", ", FALSE)

Hasilnya, semua nilai muncul dalam kolom yang sesuai.

Jika string Anda berisi data yang homogen, mungkin masuk akal untuk mengabaikan nilai kosong. Untuk ini, aturlah ignore_empty argumen ke TRUE atau 1.

Misalnya, untuk membagi t string di bawah ini menempatkan setiap keterampilan dalam sel terpisah tanpa celah, rumusnya adalah:

=TEXTSPLIT(A2, ", ", ,TRUE)

Dalam hal ini, nilai yang hilang di antara pembatas yang berurutan diabaikan sepenuhnya:

Pemisahan sel peka huruf besar-kecil atau peka huruf besar-kecil

Untuk mengontrol sensitivitas huruf besar-kecil dari pembatas, gunakan argumen kelima, match_mode .

Secara default, match_mode diatur ke 0, membuat TEXTSPLIT peka huruf besar-kecil .

Dalam contoh ini, angka-angka dipisahkan oleh huruf kecil "x" dan huruf besar "X".

Rumus dengan sensitivitas huruf besar-kecil default hanya menerima huruf kecil "x" sebagai pembatas:

=TEXTSPLIT(A2, " x ")

Harap perhatikan bahwa pembatas memiliki spasi di kedua sisi huruf " x " untuk mencegah spasi di depan dan di belakang dalam hasil.

Untuk mematikan sensitivitas huruf besar, Anda menyediakan 1 untuk match_mode untuk memaksa formula TEXTSPLIT mengabaikan huruf besar:

=TEXTSPLIT(A2, " x ", , ,1)

Sekarang, semua string dipisah dengan benar oleh salah satu pembatas:

Pad nilai yang hilang dalam larik 2D

Argumen terakhir dari fungsi TEXTSPLIT, pad_with Ketika string seperti itu dibagi menjadi kolom dan baris, secara default, Excel mengembalikan kesalahan # N / A alih-alih nilai yang hilang agar tidak mengacaukan struktur array dua dimensi.

Dalam string di bawah ini, tidak ada "=" ( col_delimiter Untuk menjaga integritas larik yang dihasilkan, TEXTSPLIT mengeluarkan #N/A di samping "Score".

Untuk membuat hasilnya lebih mudah digunakan, Anda bisa mengganti error #N/A dengan nilai apa pun yang Anda inginkan. Cukup, ketik nilai yang diinginkan dalam kolom pad_with argumen.

Dalam kasus kita, itu bisa berupa tanda hubung ("-"):

=TEXTSPLIT(A2, "=", ", ", , ,"-")

Atau string kosong (""):

=TEXTSPLIT(A2, "=", ", ", , ,"")

Sekarang setelah Anda mempelajari penggunaan praktis dari setiap argumen fungsi TEXTSPLIT, mari kita bahas beberapa contoh lanjutan yang dapat membantu Anda mengatasi tantangan non-sepele di spreadsheet Excel Anda.

Pisahkan tanggal menjadi hari, bulan dan tahun

Untuk membagi tanggal menjadi unit individu, pertama-tama Anda perlu mengonversi tanggal menjadi teks karena fungsi TEXTSPLIT berurusan dengan string teks sedangkan tanggal Excel adalah angka.

Cara termudah untuk mengonversi nilai numerik ke teks adalah dengan menggunakan fungsi TEXT. Pastikan untuk memberikan kode format yang sesuai untuk tanggal Anda.

Dalam kasus kami, rumusnya adalah:

=TEXT(A2, "m/d/yyyy")

Langkah berikutnya adalah menyarangkan fungsi di atas dalam argumen pertama TEXTSPLIT dan memasukkan pembatas yang sesuai untuk argumen ke-2 atau ke-3, tergantung pada apakah Anda memisahkan seluruh kolom atau baris. Dalam contoh ini, unit tanggal dibatasi dengan garis miring, jadi kami menggunakan "/" untuk col_delimiter argumen:

=TEXTSPLIT(TEXT(A2, "m/d/yyyy"), "/")

Pisahkan sel dan hapus karakter tertentu

Bayangkan ini: Anda telah membagi string panjang menjadi beberapa bagian, tetapi larik yang dihasilkan masih mengandung beberapa karakter yang tidak diinginkan, seperti tanda kurung pada gambar di bawah:

=TEXTSPLIT(A2, " ", "; ")

Untuk menanggalkan tanda kurung pembuka dan penutup pada satu waktu, sarangkan dua fungsi SUBSTITUTE satu ke yang lain (masing-masing mengganti satu tanda kurung dengan string kosong) dan gunakan rumus TEXTSPLIT untuk teks argumen dari SUBSTITUTE bagian dalam:

=SUBSTITUTE(SUBSTITUTE(TEXTSPLIT(A2, " ", "; "), "(", ""), ")", "")

Tip. Jika larik terakhir berisi terlalu banyak karakter tambahan, Anda dapat membersihkannya menggunakan salah satu metode yang dijelaskan dalam artikel ini: Cara menghapus karakter yang tidak diinginkan di Excel.

Memisahkan string yang melewatkan nilai tertentu

Misalkan Anda ingin memisahkan string di bawah ini menjadi 4 kolom: Nama depan , Nama belakang , Skor dan Hasil Masalahnya adalah bahwa beberapa string mengandung judul "Mr." atau "Ms.", karena itu hasilnya semua salah:

Solusinya tidak jelas tetapi cukup sederhana :)

Selain pembatas yang sudah ada, yaitu spasi (" ") dan koma dan spasi (", "), Anda menyertakan string "Mr." dan "Ms." dalam col_delimiter sehingga fungsi ini menggunakan judul-judul itu sendiri untuk memisahkan teks. Untuk mengabaikan nilai kosong, Anda mengatur ignore_empty argumen ke TRUE.

=TEXTSPLIT(A2, {" ",", ", "Mr.", "Ms."}, ,TRUE)

Sekarang, hasilnya benar-benar sempurna!

Alternatif TEXTSPLIT

Dalam versi Excel di mana fungsi TEXTSPLIT tidak didukung, Anda dapat membagi string dengan menggunakan kombinasi yang berbeda dari fungsi SEARCH / FIND dengan LEFT, RIGHT dan MID:

• Case-insensitive SEARCH atau case-sensitive FIND menentukan posisi pembatas dalam string, dan
• Fungsi LEFT, RIGHT, dan MID mengekstrak substring sebelum, setelah atau di antara dua contoh pembatas.

Dalam kasus kita, untuk membagi nilai yang dipisahkan oleh koma dan spasi , rumusnya adalah sebagai berikut.

Untuk mengekstrak nama:

=KIRI(A2, CARI(",", A2, 1) -1)

Untuk menarik skor:

=MID(A2, SEARCH(",",", A2) + 2, SEARCH(",", A2, SEARCH(",",A2)+1) - SEARCH(",", A2) - 2)

Untuk mendapatkan hasilnya:

=RIGHT(A2, LEN(A2) - SEARCH(",", A2, SEARCH(",", A2) + 1)-1)

Untuk penjelasan rinci tentang logika rumus, lihat Cara membagi string berdasarkan karakter atau mask.

Harap diingat bahwa tidak seperti fungsi TEXTSPLIT larik dinamis, rumus ini mengikuti pendekatan satu rumus-satu sel tradisional. Anda memasukkan rumus di sel pertama, lalu menyeretnya ke bawah kolom untuk menyalin ke sel di bawahnya.

Tangkapan layar di bawah ini menunjukkan hasilnya:

Itulah cara membagi sel di Excel 365 dengan menggunakan TEXTSPLIT atau solusi alternatif di versi sebelumnya. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Buku kerja latihan untuk diunduh

TEXTSPLIT berfungsi untuk membagi string - contoh rumus (file .xlsx)