विषयसूची
यह ट्यूटोरियल बताता है कि एक्सेल में MATCH फ़ंक्शन का उपयोग फॉर्मूला उदाहरणों के साथ कैसे करें। यह यह भी दिखाता है कि VLOOKUP और MATCH के साथ एक गतिशील सूत्र बनाकर अपने लुकअप फ़ार्मुलों को कैसे बेहतर बनाया जाए।
Microsoft Excel में, कई अलग-अलग लुकअप/संदर्भ फ़ंक्शंस हैं जो आपको एक निश्चित मूल्य खोजने में मदद कर सकते हैं कोशिकाओं की श्रेणी, और MATCH उनमें से एक है। मूल रूप से, यह कोशिकाओं की श्रेणी में किसी आइटम की सापेक्ष स्थिति की पहचान करता है। हालाँकि, MATCH फ़ंक्शन अपने शुद्ध सार से बहुत अधिक कर सकता है।
Excel MATCH फ़ंक्शन - सिंटैक्स और उपयोग करता है
Excel में MATCH फ़ंक्शन निर्दिष्ट मान की खोज करता है कोशिकाओं की एक श्रेणी, और उस मान की सापेक्ष स्थिति लौटाता है। (आवश्यक) - वह मान जिसे आप खोजना चाहते हैं। यह एक संख्यात्मक, पाठ या तार्किक मान के साथ-साथ एक सेल संदर्भ भी हो सकता है।
Lookup_array (आवश्यक) - खोज करने के लिए कोशिकाओं की श्रेणी।
Match_type (वैकल्पिक) - मिलान प्रकार को परिभाषित करता है। यह इन मानों में से एक हो सकता है: 1, 0, -1। match_type तर्क 0 पर सेट केवल सटीक मिलान देता है, जबकि अन्य दो प्रकार अनुमानित मिलान की अनुमति देते हैं।
- 1 या छोड़ा गया (डिफ़ॉल्ट) - सबसे बड़ा मान खोजें लुकअप सरणी जो लुकअप मान से कम या उसके बराबर है। लुकअप सरणी को आरोही क्रम में सॉर्ट करने की आवश्यकता है,डाउनलोड के लिए कार्यपुस्तिका
Excel MATCH सूत्र उदाहरण (.xlsx फ़ाइल)
सबसे छोटे से सबसे बड़े या A से Z तक। - 0 - सरणी में पहला मान खोजें जो लुकअप मान के बिल्कुल बराबर है। किसी क्रमांकन की आवश्यकता नहीं है।
- -1 - सरणी में सबसे छोटा मान खोजें जो लुकअप मान से अधिक या उसके बराबर हो। लुकअप सरणी को अवरोही क्रम में, सबसे बड़े से सबसे छोटे या Z से A तक क्रमबद्ध किया जाना चाहिए।
मैच फ़ंक्शन को बेहतर ढंग से समझने के लिए, आइए इस डेटा के आधार पर एक सरल सूत्र बनाते हैं: कॉलम में छात्रों के नाम ए और उनके परीक्षा अंक कॉलम बी में, सबसे बड़े से सबसे छोटे के क्रम में। यह पता लगाने के लिए कि एक विशिष्ट छात्र (जैसे, लौरा ) दूसरों के बीच में कहाँ खड़ा है, इस सरल सूत्र का उपयोग करें:
=MATCH("Laura", A2:A8, 0)
वैकल्पिक रूप से, आप कुछ में लुकअप मान डाल सकते हैं सेल (इस उदाहरण में E1) और अपने एक्सेल मिलान सूत्र में उस सेल का संदर्भ लें:
=MATCH(E1, A2:A8, 0)
जैसा कि आप ऊपर स्क्रीनशॉट में देखते हैं, छात्र के नाम एक मनमाना क्रम में दर्ज किया जाता है, और इसलिए हम match_type तर्क को 0 (सटीक मिलान) पर सेट करते हैं, क्योंकि केवल इस मिलान प्रकार को लुकअप सरणी में सॉर्टिंग मानों की आवश्यकता नहीं होती है। तकनीकी रूप से, मिलान सूत्र सीमा में लौरा की सापेक्ष स्थिति लौटाता है। लेकिन चूंकि अंकों को सबसे बड़े से छोटे क्रम में क्रमबद्ध किया जाता है, इसलिए यह हमें यह भी बताता है कि लौरा का सभी छात्रों के बीच 5वां सर्वश्रेष्ठ स्कोर है।
युक्ति। Excel 365 और Excel 2021 में, आप XMATCH फ़ंक्शन का उपयोग कर सकते हैं, जो एक आधुनिक और अधिक शक्तिशाली उत्तराधिकारी हैMATCH का।
4 चीजें जो आपको MATCH फ़ंक्शन के बारे में जाननी चाहिए
जैसा कि आपने अभी देखा, Excel में MATCH का उपयोग करना आसान है। हालाँकि, जैसा कि लगभग किसी भी अन्य फ़ंक्शन के मामले में होता है, कुछ विशिष्टताएँ हैं जिनके बारे में आपको अवगत होना चाहिए:
- MATCH फ़ंक्शन लुकअप मान की सापेक्ष स्थिति लौटाता है सरणी में, स्वयं मान नहीं।
- MATCH केस-असंवेदी है, जिसका अर्थ है कि पाठ मानों के साथ व्यवहार करते समय यह लोअरकेस और अपरकेस वर्णों के बीच अंतर नहीं करता है।
- यदि लुकअप सरणी में लुकअप मान की कई आवृत्तियाँ होती हैं, पहले मान की स्थिति वापस आ जाती है।
- यदि लुकअप सरणी में लुकअप मान नहीं मिलता है, तो #N/A त्रुटि वापस आ जाती है।
Excel में MATCH का उपयोग कैसे करें - सूत्र उदाहरण
अब जब आप Excel MATCH फ़ंक्शन के मूलभूत उपयोगों को जानते हैं, तो आइए कुछ और सूत्र उदाहरणों पर चर्चा करें जो मूल बातों से परे हैं।
वाइल्डकार्ड के साथ आंशिक मिलान
कई अन्य कार्यों की तरह, MATCH निम्नलिखित वाइल्डकार्ड वर्णों को समझता है:
- प्रश्न चिह्न (?) - किसी एक वर्ण को प्रतिस्थापित करता है
- तारांकन चिह्न (*) - किसी भी s को प्रतिस्थापित करता है वर्णों की समानता
ध्यान दें। वाइल्डकार्ड का उपयोग केवल मिलान सूत्रों में किया जा सकता है, जिसमें match_type को 0 पर सेट किया गया है।
वाइल्डकार्ड के साथ एक मिलान सूत्र उन स्थितियों में उपयोगी होता है, जब आप संपूर्ण पाठ स्ट्रिंग का मिलान नहीं करना चाहते, बल्कि केवल कुछ वर्णों या कुछ भाग का मिलान करना चाहते हैं स्ट्रिंग का।इस बिंदु को स्पष्ट करने के लिए, निम्नलिखित उदाहरण पर विचार करें।
मान लें कि आपके पास पिछले महीने के लिए क्षेत्रीय पुनर्विक्रेताओं और उनकी बिक्री के आंकड़ों की एक सूची है। आप सूची में एक निश्चित पुनर्विक्रेता की सापेक्ष स्थिति खोजना चाहते हैं (बिक्री राशियों द्वारा अवरोही क्रम में क्रमबद्ध) लेकिन आपको उसका नाम ठीक से याद नहीं है, हालांकि आपको कुछ पहले अक्षर याद हैं।
यह मानते हुए कि पुनर्विक्रेता नाम A2:A11 श्रेणी में हैं, और आप उस नाम की खोज कर रहे हैं जो "कार" से शुरू होता है, सूत्र इस प्रकार है:
=MATCH("car*", A2:A11,0)
हमारे मिलान सूत्र को अधिक बहुमुखी बनाने के लिए, आप कुछ सेल में लुकअप मान टाइप कर सकते हैं (इस उदाहरण में E1), और उस सेल को वाइल्डकार्ड कैरेक्टर से जोड़ सकते हैं, जैसे:
=MATCH(E1&"*", A2:A11,0)
जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, सूत्र रिटर्न 2, जो "कार्टर" की स्थिति है:
लुकअप वैल्यू में केवल एक वर्ण को बदलने के लिए, "?" का उपयोग करें। वाइल्डकार्ड ऑपरेटर, इस तरह:
=MATCH("ba?er", A2:A11,0)
उपरोक्त सूत्र " बेकर " नाम से मेल खाएगा और इसकी सापेक्ष स्थिति फिर से चलाएगा, जो 5 है।
केस-संवेदी MATCH सूत्र
जैसा कि इस ट्यूटोरियल की शुरुआत में उल्लेख किया गया है, MATCH फ़ंक्शन अपरकेस और लोअरकेस वर्णों में अंतर नहीं करता है। केस-संवेदी मिलान फ़ॉर्मूला बनाने के लिए, MATCH का उपयोग EXACT फ़ंक्शन के संयोजन में करें, जो वर्ण केस सहित सेल की सटीक रूप से तुलना करता है।
मिलान करने के लिए सामान्य केस-संवेदी फ़ॉर्मूला यहां दिया गया हैडेटा:
MATCH(TRUE, EXACT( लुकअप ऐरे , लुकअप वैल्यू ), 0)फॉर्मूला निम्नलिखित लॉजिक के साथ काम करता है:
- EXACT फ़ंक्शन लुकअप सरणी के प्रत्येक तत्व के साथ लुकअप मान की तुलना करता है। यदि तुलना किए गए सेल बिलकुल बराबर हैं, तो फ़ंक्शन TRUE देता है, अन्यथा FALSE देता है। सटीक, और पहले मिलान की स्थिति लौटाता है।
कृपया ध्यान रखें कि यह एक सरणी सूत्र है जिसे सही ढंग से पूरा करने के लिए Ctrl + Shift + Enter दबाने की आवश्यकता होती है।
मान लें कि आपका लुकअप मान कक्ष E1 में है और लुकअप सरणी A2:A9 है, सूत्र इस प्रकार है:
=MATCH(TRUE, EXACT(A2:A9,E1),0)
निम्नलिखित स्क्रीनशॉट Excel में केस-संवेदी मिलान सूत्र दिखाता है:
मैच और अंतर के लिए 2 कॉलम की तुलना करें (ISNA MATCH)
मिलान और अंतर के लिए दो सूचियों की जांच करना एक्सेल में सबसे आम कार्यों में से एक है, और यह हो सकता है विभिन्न प्रकार से किया। एक ISNA/MATCH सूत्र उनमें से एक है:
IF(ISNA(MATCH( 1st value in List1 , List2 , 0)), "Not in List 1", " ")सूची 2 के किसी भी मान के लिए जो सूची 1 में मौजूद नहीं है, सूत्र " सूची 1 में नहीं " लौटाता है। और यहां बताया गया है कि कैसे:
- मैच फ़ंक्शन सूची 2 में सूची 1 से मान की खोज करता है। यदि कोई मान मिलता है, तो यह अपनी सापेक्ष स्थिति लौटाता है, #N/A त्रुटिअन्यथा।
- एक्सेल में आईएसएनए फ़ंक्शन केवल एक काम करता है - #एन/ए त्रुटियों की जांच करता है (जिसका अर्थ है "उपलब्ध नहीं")। यदि दिया गया मान एक #N/A त्रुटि है, तो फ़ंक्शन TRUE देता है, अन्यथा FALSE देता है। हमारे मामले में, TRUE का अर्थ है कि सूची 1 का मान सूची 2 में नहीं मिला है (अर्थात MATCH द्वारा एक #N/A त्रुटि लौटा दी गई है)।
- क्योंकि TRUE को देखना आपके उपयोगकर्ताओं के लिए बहुत भ्रमित करने वाला हो सकता है उन मानों के लिए जो सूची 1 में प्रकट नहीं होते हैं, आप इसके बजाय " सूची 1 में नहीं ", या जो भी पाठ आप चाहते हैं उसे प्रदर्शित करने के लिए ISNA के चारों ओर IF फ़ंक्शन लपेटते हैं।
उदाहरण के लिए , कॉलम A में मानों के विरुद्ध कॉलम B में मानों की तुलना करने के लिए, सूत्र निम्न आकार लेता है (जहाँ B2 सबसे ऊपरी सेल है):
=IF(ISNA(MATCH(B2,A:A,0)), "Not in List 1", "")
जैसा कि आपको याद है, एक्सेल में MATCH फ़ंक्शन अपने आप में केस-असंवेदनशील है। कैरेक्टर केस को अलग करने के लिए, EXACT फ़ंक्शन को lookup_array तर्क में एम्बेड करें, और इस सरणी सूत्र :
<0 को पूरा करने के लिए Ctrl + Shift + Enter दबाना याद रखें> =IF(ISNA(MATCH(TRUE, EXACT(A:A, B2),0)), "Not in List 1", "") निम्नलिखित स्क्रीनशॉट क्रियाशील दोनों सूत्रों को दिखाता है:
एक्सेल में दो सूचियों की तुलना करने के अन्य तरीके सीखने के लिए, कृपया निम्नलिखित ट्यूटोरियल देखें: कैसे एक्सेल में दो कॉलम की तुलना करने के लिए। और यदि आप करते हैं, तो संभावना है कि आप इसकी कई सीमाओं में आ गए हैं (जिसका विस्तृत अवलोकन हो सकता हैएक्सेल वीलुकअप क्यों काम नहीं कर रहा है में पाया जाता है) और एक अधिक मजबूत विकल्प की तलाश कर रहे हैं। ऐसा इसलिए होता है क्योंकि VLOOKUP आपके द्वारा निर्दिष्ट रिटर्न कॉलम की संख्या (इंडेक्स नंबर) के आधार पर एक मिलान मूल्य को खींचता है। चूंकि सूत्र में अनुक्रमणिका संख्या "हार्ड-कोडेड" है, तालिका में कोई नया स्तंभ जोड़े जाने या उससे हटाए जाने पर एक्सेल इसे समायोजित करने में असमर्थ है।
एक्सेल MATCH फ़ंक्शन लुकअप मान की सापेक्ष स्थिति से संबंधित है, जो इसे VLOOKUP के col_index_num तर्क के लिए एकदम उपयुक्त बनाता है. दूसरे शब्दों में, रिटर्न कॉलम को एक स्थिर संख्या के रूप में निर्दिष्ट करने के बजाय, आप उस कॉलम की वर्तमान स्थिति प्राप्त करने के लिए MATCH का उपयोग करते हैं।
चीजों को समझने में आसान बनाने के लिए, आइए फिर से छात्रों के परीक्षा स्कोर वाली तालिका का उपयोग करें (जैसा कि हमने इस ट्यूटोरियल की शुरुआत में उपयोग किया था), लेकिन इस बार हम वास्तविक स्कोर प्राप्त करेंगे न कि इसकी सापेक्ष स्थिति।
यह मानते हुए कि लुकअप मान सेल F1 में है, तालिका सरणी है $A$1:$C$2 (यदि आप सूत्र को अन्य कक्षों में कॉपी करने की योजना बनाते हैं तो पूर्ण सेल संदर्भों का उपयोग करके इसे लॉक करना एक अच्छा अभ्यास है), सूत्र इस प्रकार है:
=VLOOKUP(F1, $A$1:$C$8, 3, FALSE)
तीसरा तर्क ( col_index_num ) 3 पर सेट है क्योंकि गणित स्कोर जिसे हम निकालना चाहते हैं, वह तीसरा स्तंभ हैमेज़। जैसा कि आप नीचे दिए गए स्क्रीनशॉट में देख सकते हैं, यह नियमित वीलुकअप फॉर्मूला अच्छी तरह से काम करता है:
लेकिन केवल तब तक जब तक आप कोई कॉलम डालें या हटाएं:
तो, #REF क्यों! गलती? क्योंकि col_index_num 3 पर सेट एक्सेल को तीसरे कॉलम से मान प्राप्त करने के लिए कहता है, जबकि अब तालिका सरणी में केवल 2 कॉलम हैं।
ऐसी चीजों को होने से रोकने के लिए, आप कर सकते हैं निम्नलिखित मिलान फ़ंक्शन को शामिल करके आपका Vlookup सूत्र अधिक गतिशील है:
MATCH(E2,A1:C1,0)
कहाँ:
- E2 लुकअप मान है, जो बिल्कुल बराबर है रिटर्न कॉलम के नाम पर, यानी वह कॉलम जिससे आप एक मान निकालना चाहते हैं ( गणित स्कोर इस उदाहरण में)।
- A1:C1 लुकअप सरणी है जिसमें टेबल हेडर।
और अब, इस मिलान फ़ंक्शन को अपने Vlookup सूत्र के col_index_num तर्क में इस तरह शामिल करें:
=VLOOKUP(F1,$A$1:$C$8, MATCH(E2,$A$1:$C$1, 0), FALSE)
और सुनिश्चित करें कि यह त्रुटिहीन रूप से काम करता है चाहे आप कितने भी कॉलम जोड़ें या हटाएं:
उपरोक्त स्क्रीनशॉट में, मैंने फॉर्मूला के सही ढंग से काम करने के लिए सभी सेल संदर्भों को लॉक कर दिया है, भले ही मेरी उपयोगकर्ता इसे वर्कशीट में दूसरी जगह ले जाते हैं। A आप नीचे स्क्रीनशॉट में देख सकते हैं, सूत्र किसी कॉलम को हटाने के बाद ठीक काम करता है; इसके अलावा एक्सेल इस मामले में पूर्ण संदर्भों को ठीक से समायोजित करने के लिए काफी स्मार्ट है:
एक्सेल लुकअप और मैच
इसी तरह से, आप एक्सेल मैच का उपयोग कर सकते हैं कार्य करने के लिएअपने HLOOKUP फ़ार्मुलों में सुधार करें। सामान्य सिद्धांत अनिवार्य रूप से Vlookup के मामले में समान है: आप मिलान फ़ंक्शन का उपयोग रिटर्न कॉलम की सापेक्ष स्थिति प्राप्त करने के लिए करते हैं, और उस संख्या को अपने Hlookup सूत्र के row_index_num तर्क में आपूर्ति करते हैं।
मान लें कि लुकअप मान सेल B5 में है, तालिका सरणी B1:H3 है, वापसी पंक्ति का नाम (MATCH के लिए लुकअप मान) सेल A6 में है और पंक्ति शीर्ष लेख A1:A3 हैं, पूरा सूत्र इस प्रकार है:
=HLOOKUP(B5, B1:H3, MATCH(A6, A1:A3, 0), FALSE)
जैसा कि आपने अभी देखा, Hlookup/Vlookup & मैच निश्चित रूप से नियमित हलुकअप और वीलुकअप सूत्रों पर एक सुधार है। हालाँकि, MATCH फ़ंक्शन उनकी सभी सीमाओं को समाप्त नहीं करता है। विशेष रूप से, Vlookup मिलान सूत्र अभी भी अपनी बाईं ओर नहीं देख सकता है, और Hlookup मिलान शीर्ष पंक्ति के अलावा किसी भी पंक्ति में खोज करने में विफल रहता है।
उपरोक्त (और कुछ अन्य) सीमाओं को पार करने के लिए, एक का उपयोग करने पर विचार करें INDEX MATCH का संयोजन, जो एक्सेल में लुकअप करने का वास्तव में शक्तिशाली और बहुमुखी तरीका प्रदान करता है, कई मामलों में Vlookup और Hlookup से बेहतर है। विस्तृत मार्गदर्शन और सूत्र के उदाहरण INDEX & एक्सेल में मैच - वीलुकअप का एक बेहतर विकल्प।
इस तरह आप एक्सेल में मैच फॉर्मूले का उपयोग करते हैं। उम्मीद है, इस ट्यूटोरियल में चर्चा किए गए उदाहरण आपके काम में मददगार साबित होंगे। पढ़ने के लिए मैं आपको धन्यवाद देता हूं और आशा करता हूं कि अगले सप्ताह आप हमारे ब्लॉग पर मिलेंगे!
अभ्यास करें
