Esta es la parte final de la serie Excel Valores Únicos que muestra cómo obtener una lista de valores distintos / únicos en una columna utilizando una fórmula, y cómo ajustar esa fórmula para diferentes conjuntos de datos. También aprenderá cómo obtener rápidamente una lista distinta utilizando el Filtro Avanzado de Excel, y cómo extraer filas únicas con Eliminador de Duplicados.

En un par de artículos recientes, discutimos diferentes métodos para contar y encontrar valores únicos en Excel. Si tuviste la oportunidad de leer esos tutoriales, ya sabes cómo obtener una lista única o distinta identificando, filtrando y copiando. Pero eso es un poco largo, y por mucho no es la única forma de extraer valores únicos en Excel. Puedes hacerlo mucho más rápido usando una fórmula especial, y en un momentoTe mostraré ésta y un par de técnicas más.

Consejo: Para obtener rápidamente valores únicos en la última versión de Excel 365 que admite matrices dinámicas, utilice la función UNIQUE tal y como se explica en el tutorial enlazado anteriormente.

Cómo obtener valores únicos en Excel

Para evitar cualquier confusión, en primer lugar, vamos a ponernos de acuerdo sobre lo que llamamos valores únicos en Excel. Valores únicos son los valores que existen en una lista sólo una vez. Por ejemplo:

Para extraer una lista de valores únicos en Excel, utilice una de las siguientes fórmulas.

Matriz fórmula de valores únicos (se completa pulsando Ctrl + Mayús + Intro ):

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1,$A$2:$A$10) + (COUNTIF($A$2:$A$10, $A$2:$A$10)1), 0)), "")

Regular fórmula de valores únicos (se completa pulsando Intro):

=IFERROR(INDEX($A$2:$A$10, MATCH(0,INDEX(COUNTIF($B$1:B1, $A$2:$A$10)+(COUNTIF($A$2:$A$10, $A$2:$A$10)1),0,0), 0)), "")

En las fórmulas anteriores, se utilizan las siguientes referencias:

• A2:A10 - el libro de pedidos.
• B1 - la celda superior de la lista única menos 1. En este ejemplo, comenzamos la lista única en B2, y por lo tanto suministramos B1 a la fórmula (B2-1=B1). Si su lista única comienza, digamos, en la celda C3, entonces cambie $B$1:B1 por $C$2:C2.

Nota: Dado que la fórmula hace referencia a la celda situada encima de la primera celda de la lista única, que suele ser la cabecera de la columna (B1 en este ejemplo), asegúrese de que su cabecera tiene un nombre único que no aparece en ninguna otra parte de la columna.

En este ejemplo, estamos extrayendo nombres únicos de la columna A (más concretamente del rango A2:A20), y la siguiente captura de pantalla muestra la fórmula de array en acción:

La explicación detallada de la lógica de la fórmula se proporciona en una sección aparte, y a continuación se explica cómo utilizar la fórmula para extraer valores únicos en sus hojas de cálculo de Excel:

• Ajusta una de las fórmulas en función de tu conjunto de datos.
• Introduzca la fórmula en la primera celda de la lista única (B2 en este ejemplo).
• Si utiliza la fórmula de matriz, pulse Ctrl + Mayús + Intro. Si ha optado por la fórmula normal, pulse la tecla Intro como de costumbre.
• Como ambas fórmulas de valores únicos están encapsuladas en la función IFERROR, puede copiar la fórmula hasta el final de la tabla y no se producirán errores en los datos, independientemente del número de valores únicos que se hayan extraído.

Cómo obtener valores distintos en Excel (único + 1er duplicado)

Como ya habrá adivinado por el título de esta sección, valores distintos en Excel son todos los valores diferentes de una lista, es decir, valores únicos y primeras instancias de valores duplicados. Por ejemplo:

Para obtener una lista diferenciada en Excel, utilice las siguientes fórmulas.

Matriz fórmula distinta (requiere pulsar Ctrl + Mayús + Intro ):

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10), 0)), "")

Regular fórmula distinta:

=IFERROR(INDEX($A$2:$A$10, MATCH(0, INDEX(COUNTIF($B$1:B1, $A$2:$A$10), 0, 0), 0)), "")

Dónde:

• A2:A10 es el libro de pedidos.
• B1 es la celda situada encima de la primera celda de la lista diferenciada. En este ejemplo, la lista diferenciada comienza en la celda B2 (es la primera celda en la que introduces la fórmula), por lo que haces referencia a B1.

Extraer valores distintos en una columna ignorando las celdas en blanco

Si tu lista fuente contiene alguna celda en blanco, la fórmula distinta que acabamos de comentar devolvería un cero por cada fila vacía, lo que podría suponer un problema. Para solucionarlo, mejora un poco más la fórmula:

Fórmula de matriz para extraer valores distintos sin espacios en blanco :

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10&"") + IF($A$2:$A$10="",1,0), 0)), "")

Obtener una lista de valores de texto distintos ignorando números y espacios en blanco

De forma similar, puede obtener una lista de valores distintos excluyendo las celdas vacías y las celdas con números :

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10&"") + IF(ISTEXT($A$2:$A$10)=FALSE,1,0), 0)), "")

Como recordatorio rápido, en las fórmulas anteriores, A2:A10 es la lista de origen, y B1 es la celda justo encima de la primera celda de la lista distinta.

La siguiente captura de pantalla muestra el resultado de ambas fórmulas:

Cómo extraer valores distintos que distinguen mayúsculas de minúsculas en Excel

Al trabajar con datos que distinguen mayúsculas y minúsculas, como contraseñas, nombres de usuario o nombres de archivo, puede que necesites obtener una lista de valores distintos que distinguen mayúsculas y minúsculas. Para ello, utiliza la siguiente fórmula de matriz, donde A2:A10 es la lista de origen, y B1 es la celda situada encima de la primera celda de la lista de valores distintos:

Fórmula de matriz para obtener valores distintos con distinción entre mayúsculas y minúsculas (requiere pulsar Ctrl + Mayús + Intro )

=IFERROR(INDEX($A$2:$A$10, MATCH(0, FREQUENCY(IF(EXACT($A$2:$A$10,TRANSPOSE($B$1:B1))), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0)), "")

Cómo funciona la fórmula único/distinto

Esta sección está escrita especialmente para aquellos usuarios de Excel curiosos y reflexivos que no sólo quieren conocer la fórmula, sino comprender plenamente sus entresijos.

Ni que decir tiene que las fórmulas para extraer valores únicos y distintos en Excel no son ni triviales ni sencillas. Pero si las examina más de cerca, se dará cuenta de que todas las fórmulas se basan en el mismo enfoque: utilizar INDEX/MATCH en combinación con COUNTIF, o COUNTIF + funciones IF.

Para nuestro análisis en profundidad, vamos a utilizar la fórmula de matriz que extrae una lista de valores distintos, ya que todas las demás fórmulas tratadas en este tutorial son mejoras o variaciones de esta fórmula básica:

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10), 0)), "")

Para empezar, desechemos la obvia función IFERROR, que se utiliza con el único propósito de eliminar los errores #N/A cuando el número de celdas en las que has copiado la fórmula supera el número de valores distintos de la lista de origen.

Y ahora, vamos a desglosar la parte central de nuestra fórmula distintiva:

1. COUNTIF(intervalo, criterios) devuelve el número de celdas de un rango que cumplen una condición especificada.

   En este ejemplo, COUNTIF($B$1:B1, $A$2:$A$10) devuelve una matriz de 1's y 0's en función de si alguno de los valores de la lista origen ($A$2:$A$10) aparece en algún lugar de la lista distinta ($B$1:B1). Si se encuentra el valor, la fórmula devuelve 1, en caso contrario - 0.

   En particular, en la celda B2, COUNTIF($B$1:B1, $A$2:$A$10) se convierte en:

   COUNTIF("Distinto", {"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"})

   y vuelve:

   {0;0;0;0;0;0;0;0;0}

   porque ninguno de los elementos de la lista de origen ( criterios ) aparece en el gama donde la función busca una coincidencia. En este caso, gama ($B$1:B1) consta de un único elemento: "Distinto".

2. MATCH(valor_consulta, matriz_consulta, [tipo_coincidencia]) devuelve la posición relativa del valor de búsqueda en la matriz.

En este ejemplo, el lookup_value es 0, y en consecuencia:

MATCH(0,COUNTIF($B$1:B1, $A$2:$A$10), 0)

se convierte en:

MATCH(0, { 0 ;0;0;0;0;0;0;0;0},0)

y devuelve

porque nuestra función MATCH obtiene el primer valor que es exactamente igual al valor de búsqueda (como recordará, el valor de búsqueda es 0).

En este ejemplo, INDEX($A$2:$A$10, 1)

se convierte:

INDEX({"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"}, 1)

y devuelve "Ronnie".

Cuando la fórmula se copia hacia abajo en la columna, la lista distinta ($B$1:B1) se expande porque la segunda referencia de celda (B1) es una referencia relativa que cambia según la posición relativa de la celda donde se mueve la fórmula.

Así, cuando se copia en la celda B3, COUNTIF($B$1: B1 , $A$2:$A$10) cambia a COUNTIF($B$1: B2 , $A$2:$A$10), y se convierte en:

COUNTIF({"Distinto"; "Ronnie"}, {"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"}), 0)), "")

y vuelve:

{1;0;0;0;0;0;0;0;0}

porque se encuentra un "Ronnie" en el rango $B$1:B2.

Y luego, MATCH(0,{1; 0 ;0;0;0;0;0;0},0) devuelve 2, porque 2 es la posición relativa del primer 0 de la matriz.

Y por último, INDEX($A$2:$A$10, 2) devuelve el valor de la 2ª fila, que es "David".

Sugerencia: para comprender mejor la lógica de la fórmula, puede seleccionar diferentes partes de la fórmula en la barra de fórmulas y pulsar F9 para ver qué evalúa una parte seleccionada:

Si todavía tiene dificultades para descifrar la fórmula, puede consultar el siguiente tutorial para obtener una explicación detallada de cómo funciona el enlace INDEX/MATCH: INDEX & MATCH as a better alternative to Excel VLOOKUP.

Como ya se ha mencionado, las demás fórmulas que se tratan en este tutorial se basan en la misma lógica, con sólo algunas modificaciones:

Fórmula de valores únicos - contiene una función COUNTIF más que excluye de la lista única todos los elementos que aparecen en la lista de origen más de una vez: COUNTIF($A$2:$A$10, $A$2:$A$10)1 .

Fórmula de valores distintos ignorando los espacios en blanco - aquí se añade una función SI que impide que las celdas en blanco se añadan a la lista de valores distintos: IF($A$2:$A$13="",1,0) .

Fórmula para distinguir valores de texto ignorando los números - se utiliza la función ISTEXT para comprobar si un valor es texto, y la función IF para descartar todos los demás tipos de valores, incluidas las celdas en blanco: IF(ISTEXT($A$2:$A$13)=FALSE,1,0) .

Extraer valores distintos de una columna con el filtro avanzado de Excel

Si no quiere perder el tiempo descifrando los arcanos vericuetos de las fórmulas de valores distintos, puede obtener rápidamente una lista de valores distintos utilizando el Filtro avanzado. A continuación se detallan los pasos a seguir.

1. Seleccione la columna de datos de la que desea extraer valores distintos.
2. Cambiar a la Datos tab> Ordenar y filtrar y haga clic en el botón Avanzado botón:

• Consulte Copiar a otra ubicación botón de radio.
• En el Rango de la lista compruebe que la gama de fuentes se muestra correctamente.
• En el Copiar al buzón introduzca la celda superior del rango de destino. Tenga en cuenta que sólo puede copiar los datos filtrados en la celda hoja activa .
• Seleccione Sólo registros únicos

Tenga en cuenta que, aunque la opción del filtro avanzado se llama " Sólo registros únicos ", extrae valores distintos es decir, valores únicos y 1ª aparición de valores duplicados.

Extraiga filas únicas y distintas con Duplicate Remover

En la parte final de este tutorial, permítanme mostrarles nuestra propia solución para encontrar y extraer valores distintos y únicos en hojas de Excel. Esta solución combina la versatilidad de las fórmulas de Excel y la simplicidad del filtro avanzado. Además, proporciona un par de características únicas como:

• Buscar y extraer filas únicas / distintas en función de los valores de una o varias columnas.
• Encuentre , destacar y copia valores únicos a cualquier otra ubicación, en el mismo o diferente libro de trabajo.

Y ahora, veamos la herramienta Duplicate Remover en acción.

Supongamos que tiene una tabla resumen creada consolidando datos de otras tablas. Obviamente, esa tabla resumen contiene muchas filas duplicadas y su tarea consiste en extraer filas únicas que aparecen en la tabla sólo una vez, o filas distintas que incluyen ocurrencias únicas y 1er duplicado. De cualquier forma, con el complemento Duplicate Remover el trabajo se hace en 5 rápidos pasos.

1. Seleccione cualquier celda de la tabla de origen y haga clic en el botón Eliminador de duplicados en el botón Datos de Ablebits en la pestaña Deduplicación grupo.

El asistente de eliminación de duplicados se ejecutará y seleccionará toda la tabla. Entonces, basta con hacer clic en Siguiente para pasar al siguiente paso.

• Único
• Único +1ª vez (distinto)

En este ejemplo, pretendemos extraer filas únicas que aparecen en la tabla de origen sólo una vez, por lo que seleccionamos el Único opción:

Como puede ver en la captura de pantalla anterior, también hay 2 opciones para valores duplicados Téngalo en cuenta si necesita desduplicar alguna otra hoja de cálculo.

¿Le ha gustado esta forma rápida y sencilla de obtener una lista de valores únicos o filas en Excel? Si es así, le animo a que descargue una versión de evaluación a continuación y la pruebe. Duplicate Remover, así como todas las demás herramientas de ahorro de tiempo que tenemos, están incluidas en Ultimate Suite for Excel.

Descargas disponibles

Buscar valores únicos en Excel - libro de ejemplo (archivo .xlsx)

Ultimate Suite - versión de evaluación (archivo .exe)