Ini adalah bagian terakhir dari seri Nilai Unik Excel yang menunjukkan cara mendapatkan daftar nilai yang berbeda / unik dalam kolom menggunakan rumus, dan cara mengubah rumus tersebut untuk kumpulan data yang berbeda. Anda juga akan belajar cara cepat mendapatkan daftar berbeda menggunakan Filter Lanjutan Excel, dan cara mengekstrak baris unik dengan Duplicate Remover.

Dalam beberapa artikel baru-baru ini, kami membahas berbagai metode untuk menghitung dan menemukan nilai unik di Excel. Jika Anda berkesempatan membaca tutorial tersebut, Anda sudah tahu cara mendapatkan daftar unik atau berbeda dengan mengidentifikasi, memfilter, dan menyalin. Tapi itu agak lama, dan sejauh ini bukan satu-satunya, cara untuk mengekstrak nilai unik di Excel. Anda dapat melakukannya lebih cepat dengan menggunakan rumus khusus, dan sebentar lagiSaya akan menunjukkan ini dan beberapa teknik lainnya.

Tip. Untuk mendapatkan nilai unik dengan cepat di versi terbaru Excel 365 yang mendukung array dinamis, gunakan fungsi UNIQUE seperti yang dijelaskan dalam tutorial terkait di atas.

Cara mendapatkan nilai unik di Excel

Untuk menghindari kebingungan, pertama-tama, mari kita sepakati apa yang kita sebut nilai unik di Excel. Nilai-nilai unik adalah nilai yang hanya ada dalam daftar sekali saja. Sebagai contoh:

Untuk mengekstrak daftar nilai unik di Excel, gunakan salah satu rumus berikut.

Larik rumus nilai unik (diselesaikan dengan menekan Ctrl + Shift + Enter ):

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1,$A$2:$A$10) + (COUNTIF($A$2:$A$10, $A$2:$A$10)1), 0)), "")

Reguler rumus nilai unik (diselesaikan dengan menekan Enter):

=IFERROR(INDEX($A$2:$A$10, MATCH(0,INDEX(COUNTIF($B$1:B1, $A$2:$A$10)+(COUNTIF($A$2:$A$10, $A$2:$A$10)1),0,0), 0), 0)), "")

Dalam rumus di atas, referensi berikut digunakan:

• A2:A10 - daftar sumber.
• B1 - sel teratas dari daftar unik dikurangi 1. Dalam contoh ini, kita memulai daftar unik di B2, dan oleh karena itu kita menyediakan B1 ke rumus (B2-1 = B1). Jika daftar unik Anda dimulai, katakanlah, di sel C3, maka ubah $ B $ 1: B1 menjadi $ C $ 2: C2.

Catatan. Karena rumusnya mereferensikan sel di atas sel pertama dari daftar unik, yang biasanya merupakan header kolom (B1 dalam contoh ini), pastikan header Anda memiliki nama unik yang tidak muncul di tempat lain dalam kolom.

Dalam contoh ini, kami mengekstrak nama unik dari kolom A (lebih tepatnya dari rentang A2: A20), dan tangkapan layar berikut menunjukkan rumus array dalam tindakan:

Penjelasan mendetail tentang logika rumus disediakan di bagian terpisah, dan berikut cara menggunakan rumus untuk mengekstrak nilai unik di lembar kerja Excel Anda:

• Ubah salah satu rumus sesuai dengan kumpulan data Anda.
• Masukkan rumus di sel pertama dari daftar unik (B2 dalam contoh ini).
• Jika Anda menggunakan rumus array, tekan Ctrl + Shift + Enter . Jika Anda memilih rumus biasa, tekan tombol Enter seperti biasa.
• Salin rumus ke bawah sejauh yang diperlukan dengan menyeret gagang isiannya. Karena kedua rumus nilai uniknya kami bungkus dalam fungsi IFERROR, kamu bisa menyalin rumusnya hingga akhir tabelmu, dan rumus ini tidak akan mengacaukan datamu dengan error apapun, tidak peduli seberapa sedikit nilai unik yang telah diekstrak.

Cara mendapatkan nilai berbeda di Excel (unik + kejadian duplikat pertama)

Seperti yang mungkin sudah Anda duga dari judul bagian ini, nilai yang berbeda di Excel adalah semua nilai yang berbeda dalam daftar, yaitu nilai unik dan contoh pertama dari nilai duplikat. Misalnya:

Untuk mendapatkan daftar berbeda di Excel, gunakan rumus berikut.

Larik rumus yang berbeda (membutuhkan penekanan Ctrl + Shift + Enter ):

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10), 0)), "")

Reguler rumus yang berbeda:

=IFERROR(INDEX($A$2:$A$10, MATCH(0, INDEX(COUNTIF($B$1:B1, $A$2:$A$10), 0, 0), 0), 0)), "")

Di mana:

• A2:A10 adalah daftar sumber.
• B1 adalah sel di atas sel pertama dari daftar yang berbeda. Dalam contoh ini, daftar yang berbeda dimulai di sel B2 (ini adalah sel pertama tempat Anda memasukkan rumus), jadi Anda mereferensikan B1.

Mengekstrak nilai yang berbeda dalam kolom dengan mengabaikan sel kosong

Jika daftar sumber Anda berisi sel kosong, rumus berbeda yang baru saja kita bahas akan mengembalikan nol untuk setiap baris kosong, yang mungkin menjadi masalah. Untuk memperbaikinya, tingkatkan rumusnya sedikit lebih jauh:

Rumus array untuk mengekstrak nilai yang berbeda tidak termasuk kosong :

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10&"") + IF($A$2:$A$10="",1,0), 0)), 0), "")

Dapatkan daftar nilai teks yang berbeda dengan mengabaikan angka dan kosong

Dengan cara yang sama, Anda bisa mendapatkan daftar nilai yang berbeda tidak termasuk sel kosong dan sel dengan angka :

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10&"") + IF(ISTEXT($A$2:$A$10)=FALSE,1,0), 0), 0)), "")

Sebagai pengingat cepat, dalam rumus di atas, A2: A10 adalah daftar sumber, dan B1 adalah sel tepat di atas sel pertama dari daftar yang berbeda.

Tangkapan layar berikut ini menunjukkan hasil dari kedua rumus tersebut:

Cara mengekstrak nilai berbeda yang peka huruf besar-kecil di Excel

Saat bekerja dengan data yang peka huruf besar-kecil seperti kata sandi, nama pengguna, atau nama file, Anda mungkin perlu mendapatkan daftar nilai berbeda yang peka huruf besar-kecil. Untuk ini, gunakan rumus larik berikut, di mana A2: A10 adalah daftar sumber, dan B1 adalah sel di atas sel pertama dari daftar berbeda:

Rumus array untuk mendapatkan nilai berbeda yang peka huruf besar-kecil (memerlukan penekanan Ctrl + Shift + Enter)

=IFERROR(INDEX($A$2:$A$10, MATCH(0, FREQUENCY(IF(EXACT($A$2:$A$10,TRANSPOSE($B$1:B1)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)))), 0)), "")

Cara kerja rumus unik / berbeda

Bagian ini ditulis khusus untuk para pengguna Excel yang penasaran dan bijaksana yang tidak hanya ingin mengetahui rumusnya, tetapi juga memahami sepenuhnya mur dan bautnya.

Tak perlu dikatakan bahwa rumus untuk mengekstrak nilai unik dan berbeda di Excel bukanlah hal yang sepele atau langsung. Tetapi setelah melihat lebih dekat, Anda mungkin memperhatikan bahwa semua rumus didasarkan pada pendekatan yang sama - menggunakan INDEX / MATCH yang dikombinasikan dengan fungsi COUNTIF, atau COUNTIF + IF.

Untuk analisis mendalam kita, mari kita gunakan rumus array yang mengekstrak daftar nilai yang berbeda karena semua rumus lain yang dibahas dalam tutorial ini adalah perbaikan atau variasi dari rumus dasar ini:

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10), 0)), "")

Sebagai permulaan, mari kita buang fungsi IFERROR yang jelas, yang digunakan dengan satu tujuan untuk menghilangkan kesalahan # N / A ketika jumlah sel tempat Anda menyalin rumus melebihi jumlah nilai berbeda dalam daftar sumber.

Dan sekarang, mari kita uraikan bagian inti dari formula kita yang berbeda:

1. COUNTIF(rentang, kriteria) mengembalikan jumlah sel dalam rentang yang memenuhi kondisi tertentu.

   Dalam contoh ini, COUNTIF($B$1:B1, $A$2:$A$10) mengembalikan larik 1 dan 0 berdasarkan apakah salah satu nilai daftar sumber ($A$2:$A$10) muncul di suatu tempat dalam daftar yang berbeda ($B$1:B1). Jika nilainya ditemukan, rumus mengembalikan 1, jika tidak - 0.

   Khususnya, di sel B2, COUNTIF($B$1:B1, $A$2:$A$10) menjadi:

   COUNTIF("Distinct", {"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"})

   dan kembali:

   {0;0;0;0;0;0;0;0;0}

   karena tidak ada item dari daftar sumber ( kriteria ) muncul dalam rentang di mana fungsi mencari kecocokan. Dalam kasus ini, rentang ($B$1:B1) terdiri dari satu item - "Distinct".

2. MATCH(lookup_value, lookup_array, [match_type]) mengembalikan posisi relatif dari nilai pencarian dalam larik.

Dalam contoh ini, lookup_value adalah 0, dan akibatnya:

MATCH(0,COUNTIF($B$1:B1, $A$2:$A$10), 0)

berubah menjadi:

MATCH(0, { 0 ;0;0;0;0;0;0;0;0},0)

dan kembali

karena fungsi MATCH kita mendapatkan nilai pertama yang persis sama dengan nilai pencarian (seperti yang Anda ingat, nilai pencarian adalah 0).

Dalam contoh ini, INDEX($A$2:$A$10, 1)

menjadi:

INDEX({"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"}, 1)

dan mengembalikan "Ronnie".

Saat rumus disalin ke bawah kolom, daftar yang berbeda ($ B $ 1: B1) mengembang karena referensi sel kedua (B1) adalah referensi relatif yang berubah sesuai dengan posisi relatif sel tempat rumus bergerak.

Jadi, ketika disalin ke sel B3, COUNTIF($B$1: B1 , $A$2:$A$10) berubah menjadi COUNTIF($B$1: B2 , $A$2:$A$10), dan menjadi:

COUNTIF({"Distinct"; "Ronnie"}, {"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"}), 0)), "")

dan kembali:

{1;0;0;0;0;0;0;0;0}

karena satu "Ronnie" ditemukan dalam rentang $ B $ 1: B2.

Dan kemudian, MATCH(0,{1; 0 ;0;0;0;0;0;0;0;0},0) mengembalikan 2, karena 2 adalah posisi relatif dari 0 pertama dalam larik.

Dan akhirnya, INDEKS($A$2:$A$10, 2) mengembalikan nilai dari baris ke-2, yaitu "David".

Tip. Untuk pemahaman yang lebih baik tentang logika rumus, Anda dapat memilih bagian rumus yang berbeda di bilah rumus dan tekan F9 untuk melihat apa yang dievaluasi oleh bagian yang dipilih:

Jika kamu masih mengalami kesulitan dalam mencari tahu rumusnya, kamu bisa melihat tutorial berikut untuk penjelasan detail mengenai bagaimana cara kerja penghubung INDEX/MATCH: INDEX & MATCH sebagai alternatif yang lebih baik dari VLOOKUP Excel.

Seperti yang sudah disebutkan, rumus-rumus lain yang dibahas dalam tutorial ini didasarkan pada logika yang sama, hanya dengan beberapa modifikasi:

Rumus nilai unik - berisi satu lagi fungsi COUNTIF yang mengecualikan dari daftar unik semua item yang muncul dalam daftar sumber lebih dari sekali: COUNTIF($A$2:$A$10, $A$2:$A$10)1 .

Rumus nilai berbeda mengabaikan kosong - di sini Anda menambahkan fungsi IF yang mencegah sel kosong ditambahkan ke daftar berbeda: IF($A$2:$A$13="",1,0) .

Formula nilai teks yang berbeda mengabaikan angka - Anda menggunakan fungsi ISTEXT untuk memeriksa apakah suatu nilai adalah teks, dan fungsi IF untuk mengabaikan semua jenis nilai lainnya, termasuk sel kosong: IF(ISTEXT($A$2:$A$13)=FALSE,1,0) .

Ekstrak nilai berbeda dari kolom dengan Filter Lanjutan Excel

Jika Anda tidak ingin membuang waktu untuk mencari tahu liku-liku misterius dari rumus nilai yang berbeda, Anda dapat dengan cepat mendapatkan daftar nilai yang berbeda dengan menggunakan Filter Lanjutan. Langkah-langkah rinci mengikuti di bawah ini.

1. Pilih kolom data dari mana Anda ingin mengekstrak nilai yang berbeda.
2. Beralih ke Data tab> Urutkan &; Saring kelompok, dan klik tombol Lanjutan tombol:

• Periksa Salin ke lokasi lain tombol radio.
• Dalam Rentang daftar kotak, verifikasi bahwa kisaran sumber ditampilkan dengan benar.
• Dalam Salin ke kotak masukkan sel paling atas dari rentang tujuan. Harap diingat bahwa Anda dapat menyalin data yang difilter hanya ke sel lembar aktif .
• Pilih Hanya catatan unik

Harap perhatikan bahwa meskipun opsi Advanced Filter dinamai " Hanya catatan unik ", itu mengekstrak nilai yang berbeda yaitu nilai unik dan kemunculan pertama dari nilai duplikat.

Ekstrak baris unik dan berbeda dengan Duplicate Remover

Di bagian akhir tutorial ini, izinkan saya menunjukkan solusi kami sendiri untuk menemukan dan mengekstrak nilai yang berbeda dan unik di lembar Excel. Solusi ini menggabungkan keserbagunaan rumus Excel dan kesederhanaan filter lanjutan. Selain itu, ia menyediakan beberapa fitur unik seperti:

• Temukan dan ekstrak baris yang unik / berbeda berdasarkan nilai dalam satu kolom atau lebih.
• Temukan , sorot dan salinan nilai unik ke lokasi lain, di buku kerja yang sama atau berbeda.

Dan sekarang, mari kita lihat alat Duplicate Remover beraksi.

Misalkan Anda memiliki tabel ringkasan yang dibuat dengan menggabungkan data dari beberapa tabel lain. Jelas, tabel ringkasan itu berisi banyak baris duplikat dan tugas Anda adalah mengekstrak baris unik yang muncul di tabel hanya sekali, atau baris berbeda termasuk kejadian duplikat unik dan 1. Apa pun itu, dengan add-in Penghilang Duplikat, pekerjaan selesai dalam 5 langkah cepat.

1. Pilih sel mana pun dalam tabel sumber Anda dan klik tombol Penghapus Duplikat tombol pada Data Ablebits tab, di tab Dedupe kelompok.

Wizard Duplicate Remover akan berjalan dan memilih seluruh tabel. Jadi, klik saja Berikutnya untuk melanjutkan ke langkah berikutnya.

• Unik
• Kejadian unik ke-1 (berbeda)

Dalam contoh ini, kita bertujuan untuk mengekstrak baris unik yang muncul dalam tabel sumber hanya sekali, jadi kita memilih Unik pilihan:

Tip. Seperti yang bisa Anda lihat pada tangkapan layar di atas, ada juga 2 opsi untuk nilai duplikat , ingatlah itu jika Anda perlu menyimpulkan beberapa lembar kerja lainnya.

Menyukai cara cepat dan sederhana ini untuk mendapatkan daftar nilai atau baris unik di Excel? Jika demikian, saya mendorong Anda untuk mengunduh versi evaluasi di bawah ini dan mencobanya. Duplicate Remover serta semua alat penghemat waktu lainnya yang kami miliki disertakan dengan Ultimate Suite untuk Excel.

Unduhan yang tersedia

Temukan Nilai Unik di Excel - contoh buku kerja (file .xlsx)

Ultimate Suite - versi evaluasi (file .exe)