Jest to ostatnia część serii Excel Unikalne wartości, która pokazuje, jak uzyskać listę odrębnych / unikalnych wartości w kolumnie za pomocą formuły i jak dostosować tę formułę do różnych zbiorów danych. Dowiesz się również, jak szybko uzyskać odrębną listę za pomocą zaawansowanego filtra programu Excel i jak wyodrębnić unikalne wiersze za pomocą Duplicate Remover.

W kilku ostatnich artykułach omawialiśmy różne metody liczenia i znajdowania unikalnych wartości w Excelu. Jeśli miałeś okazję przeczytać te tutoriale, to wiesz już, jak uzyskać unikalną lub wyróżniającą się listę poprzez identyfikację, filtrowanie i kopiowanie. Ale to trochę długi i zdecydowanie nie jedyny, sposób na wydobycie unikalnych wartości w Excelu. Możesz to zrobić znacznie szybciej, używając specjalnej formuły, a za chwilęPokażę wam tę i kilka innych technik.

Wskazówka. Aby szybko uzyskać unikalne wartości w najnowszej wersji programu Excel 365, która obsługuje dynamiczne tablice, użyj funkcji UNIQUE, jak wyjaśniono w wyżej podlinkowanym samouczku.

Jak uzyskać unikalne wartości w programie Excel

Aby uniknąć zamieszania, najpierw uzgodnijmy, co nazywamy unikalnymi wartościami w Excelu. Wartości unikalne to wartości, które występują na liście tylko raz. na przykład:

Aby wyodrębnić listę unikalnych wartości w programie Excel, należy użyć jednej z poniższych formuł.

Array formuła unikalnych wartości (uzupełniana przez naciśnięcie klawiszy Ctrl + Shift + Enter ):

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1,$A$2:$A$10) + (COUNTIF($A$2:$A$10, $A$2:$A$10)1), 0)), "")

Regularnie formuła wartości unikalnych (zakończona naciśnięciem klawisza Enter):

=IFERROR(INDEX($A$2:$A$10, MATCH(0,INDEX(COUNTIF($B$1:B1, $A$2:$A$10)+(COUNTIF($A$2:$A$10, $A$2:$A$10)1),0,0)), "")

W powyższych wzorach stosuje się następujące odniesienia:

• A2:A10 - lista źródeł.
• B1 - górna komórka listy unikalnej minus 1. W tym przykładzie zaczynamy listę unikalną w B2, a zatem do formuły podajemy B1 (B2-1=B1). Jeśli Twoja lista unikalna zaczyna się, powiedzmy, w komórce C3, to zmień $B$1:B1 na $C$2:C2.

Uwaga. Ponieważ formuła odwołuje się do komórki znajdującej się nad pierwszą komórką unikalnej listy, która zwykle jest nagłówkiem kolumny (B1 w tym przykładzie), upewnij się, że twój nagłówek ma unikalną nazwę, która nie pojawia się nigdzie indziej w kolumnie.

W tym przykładzie wyciągamy unikalne nazwy z kolumny A (dokładniej z zakresu A2:A20), a poniższy zrzut ekranu demonstruje formułę tablicową w akcji:

Szczegółowe wyjaśnienie logiki formuły znajduje się w osobnej sekcji, a oto jak wykorzystać formułę do wyodrębnienia unikalnych wartości w twoich arkuszach Excela:

• Dostosuj jedną z formuł do swojego zestawu danych.
• Wprowadź formułę w pierwszej komórce listy unikatów (B2 w tym przykładzie).
• Jeśli używasz formuły tablicowej, naciśnij Ctrl + Shift + Enter . Jeśli wybrałeś zwykłą formułę, naciśnij klawisz Enter jak zwykle.
• Kopiuj formułę w dół tak daleko, jak to konieczne, przeciągając uchwyt wypełnienia. Ponieważ obie formuły unikalnych wartości są zamknięte w funkcji IFERROR, możesz skopiować formułę do końca tabeli, a nie będzie ona zagracać danych żadnymi błędami, niezależnie od tego, jak mało unikalnych wartości zostało wyodrębnionych.

Jak uzyskać odrębne wartości w programie Excel (unikalne + 1. wystąpienie duplikatów)

Jak już pewnie domyślacie się z nagłówka tego działu, odrębne wartości w Excelu to wszystkie różne wartości na liście, czyli wartości unikalne i pierwsze instancje wartości zduplikowanych. Na przykład:

Aby uzyskać wyraźną listę w programie Excel, użyj następujących formuł.

Array wyraźna formuła (wymaga naciśnięcia klawiszy Ctrl + Shift + Enter ):

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10), 0)), "")

Regularnie odrębna formuła:

=IFERROR(INDEX($A$2:$A$10, MATCH(0, INDEX(COUNTIF($B$1:B1, $A$2:$A$10), 0, 0)), "")

Gdzie:

• A2:A10 to lista źródeł.
• B1 jest komórką powyżej pierwszej komórki listy wyróżnionej. W tym przykładzie lista wyróżniona zaczyna się w komórce B2 (jest to pierwsza komórka, w której wpisujemy formułę), więc odwołujemy się do B1.

Wyodrębnij różne wartości w kolumnie, ignorując puste komórki

Jeśli twoja lista źródłowa zawiera jakiekolwiek puste komórki, formuła distinct, którą właśnie omówiliśmy, zwróciłaby zero dla każdego pustego wiersza, co może stanowić problem. Aby to naprawić, popraw formułę nieco dalej:

Formuła tablicowa do wyodrębnienia odrębne wartości z wyłączeniem pustych miejsc :

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10&"") + IF($A$2:$A$10="",1,0), 0)), "")

Uzyskaj listę różnych wartości tekstowych, ignorując liczby i spacje

W podobny sposób można uzyskać listę odrębnych wartości z wyłączeniem pustych komórek i komórek z numerami :

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$10&"") + IF(ISTEXT($A$2:$A$10)=FALSE,1,0), 0)), "")

Dla szybkiego przypomnienia, w powyższych formułach, A2:A10 to lista źródłowa, a B1 to komórka tuż nad pierwszą komórką listy odrębnej.

Poniższy zrzut ekranu przedstawia wynik działania obu formuł:

Jak wyodrębnić wartości odrębne z uwzględnieniem wielkości liter w programie Excel

Podczas pracy z danymi wrażliwymi na wielkość liter, takimi jak hasła, nazwy użytkowników lub nazwy plików, może być konieczne uzyskanie listy wartości rozróżniających wielkość liter. W tym celu należy użyć następującej formuły tablicowej, gdzie A2:A10 to lista źródłowa, a B1 to komórka nad pierwszą komórką listy rozróżniającej:

Formuła tablicowa do uzyskania rozróżniania wielkości liter w różnych wartościach (wymaga naciśnięcia Ctrl + Shift + Enter )

=IFERROR(INDEX($A$2:$A$10, MATCH(0, FREQUENCY(IF(EXACT($A$2:$A$10,TRANSPOSE($B$1:B1)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0)), "")

Jak działa formuła unique / distinct

Ten rozdział jest napisany specjalnie dla tych ciekawskich i myślących użytkowników Excela, którzy nie tylko chcą poznać formułę, ale w pełni zrozumieć jej bakcyle.

Nie ulega wątpliwości, że formuły służące do wyodrębniania unikalnych i różnych wartości w Excelu nie są ani trywialne, ani proste. Jednak po bliższym przyjrzeniu się, można zauważyć, że wszystkie formuły opierają się na tym samym podejściu - użyciu INDEX/MATCH w połączeniu z funkcjami COUNTIF, lub COUNTIF + IF.

Do naszej dogłębnej analizy użyjmy formuły tablicowej, która wydobywa listę odrębnych wartości, ponieważ wszystkie inne formuły omawiane w tym samouczku są ulepszeniami lub odmianami tej podstawowej:

=IFERROR(INDEX($A$2:$A$10, MATCH(0, COUNTIF($B$1:B1, $A$2:$A$10), 0)), "")

Na początek odrzućmy oczywistą funkcję IFERROR, która służy w jednym celu - do eliminacji błędów #N/A, gdy liczba komórek, do których skopiowałeś formułę, przekracza liczbę odrębnych wartości na liście źródłowej.

A teraz rozbijmy zasadniczą część naszej wyrazistej formuły:

1. COUNTIF(zakres, kryteria) zwraca liczbę komórek w zakresie, które spełniają określony warunek.

   W tym przykładzie, COUNTIF($B$1:B1, $A$2:$A$10) zwraca tablicę 1 i 0 na podstawie tego, czy któraś z wartości z listy źródłowej ($A$2:$A$10) pojawia się gdzieś w liście odrębnej ($B$1:B1). Jeśli wartość zostanie znaleziona, formuła zwraca 1, w przeciwnym razie - 0.

   W szczególności w komórce B2, COUNTIF($B$1:B1, $A$2:$A$10) staje się:

   COUNTIF("Distinct", {"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"})

   i wraca:

   {0;0;0;0;0;0;0;0;0}

   ponieważ żaden z elementów listy źródłowej ( kryteria ) pojawia się w zakres gdzie funkcja szuka dopasowania. W tym przypadku, zakres ($B$1:B1) składa się z jednego elementu - "Distinct".

2. MATCH(lookup_value, lookup_array, [match_type]) zwraca względną pozycję wartości lookup w tablicy.

W tym przykładzie lookup_value wynosi 0, a w konsekwencji:

MATCH(0,COUNTIF($B$1:B1, $A$2:$A$10), 0)

zamienia się w:

MATCH(0, { 0 ;0;0;0;0;0;0;0;0},0)

i zwraca

ponieważ nasza funkcja MATCH pobiera pierwszą wartość, która jest dokładnie równa wartości lookup (jak pamiętasz, wartość lookup to 0).

W tym przykładzie INDEX($A$2:$A$10, 1)

staje się:

INDEX({"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"}, 1)

i zwraca "Ronnie".

Gdy formuła jest kopiowana w dół kolumny, lista wyróżniona ($B$1:B1) rozszerza się, ponieważ drugie odwołanie do komórki (B1) jest odwołaniem względnym, które zmienia się zgodnie ze względną pozycją komórki, do której przesuwa się formuła.

Zatem po skopiowaniu do komórki B3, COUNTIF($B$1: B1 , $A$2:$A$10) zmienia się na COUNTIF($B$1: B2 , $A$2:$A$10), i staje się:

COUNTIF({"Distinct"; "Ronnie"}, {"Ronnie"; "David"; "Sally"; "Jeremy"; "Robert"; "David"; "Robert"; "Tom"; "Sally"}), 0)), "")

i wraca:

{1;0;0;0;0;0;0;0;0}

ponieważ w zakresie $B$1:B2 znaleziono jednego "Ronnie".

A następnie, MATCH(0,{1; 0 ;0;0;0;0;0},0) zwraca 2, ponieważ 2 jest względną pozycją pierwszego 0 w tablicy.

I wreszcie, INDEX($A$2:$A$10, 2) zwraca wartość z 2. rzędu, którą jest "Dawid".

Wskazówka. Aby lepiej zrozumieć logikę formuły, można zaznaczyć różne części formuły na pasku formuły i nacisnąć klawisz F9, aby zobaczyć, na co ocenia się wybraną część:

Jeśli nadal masz trudności z rozgryzieniem formuły, możesz sprawdzić następujący samouczek dla szczegółowego wyjaśnienia, jak działa łącznik INDEX/MATCH: INDEX & MATCH jako lepsza alternatywa dla Excel VLOOKUP.

Jak już wspomniano, pozostałe formuły omawiane w tym tutorialu opierają się na tej samej logice, z kilkoma tylko modyfikacjami:

Formuła wartości unikalnych - zawiera jeszcze jedną funkcję COUNTIF, która wyklucza z listy unikalnej wszystkie pozycje, które pojawiają się na liście źródłowej więcej niż raz: COUNTIF($A$2:$A$10, $A$2:$A$10)1 .

Formuła wartości wyróżnionych ignorująca puste miejsca - tutaj dodajemy funkcję JEŻELI, która zapobiega dodawaniu pustych komórek do listy wyróżnionych: IF($A$2:$A$13="",1,0) .

Wyróżnianie wartości tekstowych formuła ignorująca liczby - używasz funkcji ISTEXT do sprawdzania, czy wartość jest tekstem, oraz funkcji JEŻELI do odrzucania wszystkich innych typów wartości, w tym pustych komórek: IF(ISTEXT($A$2:$A$13)=FALSE,1,0) .

Wyodrębnij różne wartości z kolumny za pomocą zaawansowanego filtra Excela

Jeśli nie chcesz tracić czasu na rozgryzanie zawiłości formuł wartości różnej, możesz szybko uzyskać listę wartości różnej za pomocą filtra zaawansowanego. Szczegółowe kroki znajdziesz poniżej.

1. Wybierz kolumnę danych, z której chcesz wyodrębnić odrębne wartości.
2. Przełącz się na Dane tab> Sortowanie & Filtr grupę, a następnie kliknij przycisk Zaawansowane przycisk:

• Sprawdź Kopiuj do innej lokalizacji przycisk radiowy.
• W Zakres listy sprawdź, czy zakres źródeł jest wyświetlany prawidłowo.
• W Kopiuj do skrzynki Należy pamiętać, że przefiltrowane dane można skopiować tylko do komórki aktywny arkusz .
• Wybierz Tylko unikalne rekordy

Proszę zwrócić uwagę, że choć opcja filtra zaawansowanego nosi nazwę " Tylko unikalne rekordy ", wyciąga. odrębne wartości , czyli wartości unikalne i 1. wystąpienie wartości zduplikowanych.

Wyodrębnij unikalne i różne wiersze za pomocą Duplicate Remover

W ostatniej części tego tutorialu pozwolę sobie pokazać własne rozwiązanie do wyszukiwania i wydobywania odrębnych i unikalnych wartości w arkuszach Excela. Rozwiązanie to łączy w sobie wszechstronność formuł Excela i prostotę zaawansowanego filtra. Dodatkowo zapewnia kilka unikalnych funkcji takich jak:

• Znajdź i wyodrębnij unikalne / odrębne wiersze na podstawie wartości w jednej lub kilku kolumnach.
• Znajdź , podkreślenie oraz kopia unikalnych wartości do dowolnej innej lokalizacji, w tym samym lub innym skoroszycie.

A teraz zobaczmy narzędzie Duplicate Remover w akcji.

Załóżmy, że masz tabelę podsumowującą utworzoną przez konsolidację danych z kilku innych tabel. Oczywiście tabela podsumowująca zawiera wiele zduplikowanych wierszy i twoim zadaniem jest wyodrębnienie unikalnych wierszy, które pojawiają się w tabeli tylko raz, lub odrębnych wierszy zawierających unikalne i pierwsze zduplikowane wystąpienia. Tak czy inaczej, dzięki dodatkowi Duplicate Remover zadanie zostanie wykonane w 5 szybkich krokach.

1. Wybierz dowolną komórkę w tabeli źródłowej i kliknij przycisk Usuwacz duplikatów przycisk na Dane Ablebits zakładka, w Dedupe grupa.

Kreator usuwania duplikatów uruchomi się i wybierze całą tabelę. Wystarczy więc kliknąć Następny aby przejść do następnego kroku.

• Wyjątkowa
• Unikalne +1 wystąpienie (distinct)

W tym przykładzie chcemy wyodrębnić unikalne rzędy które pojawiają się w tabeli źródłowej tylko raz, więc wybieramy Wyjątkowa opcja:

Wskazówka. Jak widać na powyższym zrzucie ekranu, istnieją również 2 opcje dla zduplikowane wartości , po prostu pamiętaj o tym, jeśli musisz dedupować jakiś inny arkusz.

Czy podoba ci się ten szybki i prosty sposób na uzyskanie listy unikalnych wartości lub wierszy w Excelu? Jeśli tak, to zachęcam cię do pobrania wersji ewaluacyjnej poniżej i wypróbowania jej. Duplicate Remover, jak również wszystkie inne narzędzia oszczędzające czas, które mamy, są zawarte w Ultimate Suite for Excel.

Dostępne pliki do pobrania

Znajdź unikalne wartości w Excelu - przykładowy skoroszyt (plik .xlsx)

Ultimate Suite - wersja ewaluacyjna (plik .exe)