Hướng dẫn cho biết cách sử dụng hàm VLOOKUP để sao chép dữ liệu từ một trang tính hoặc sổ làm việc khác, Vlookup trong nhiều trang tính và tra cứu động để trả về các giá trị từ các trang tính khác nhau vào các ô khác nhau.

Khi tra cứu một số thông tin trong Excel, rất hiếm trường hợp tất cả dữ liệu nằm trên cùng một trang tính. Thường xuyên hơn, bạn sẽ phải tìm kiếm trên nhiều trang tính hoặc thậm chí nhiều sổ làm việc khác nhau. Tin vui là Microsoft Excel cung cấp nhiều hơn một cách để thực hiện việc này và tin xấu là tất cả các cách đều phức tạp hơn một chút so với công thức VLOOKUP tiêu chuẩn. Nhưng chỉ cần một chút kiên nhẫn, chúng ta sẽ tìm ra chúng :)

Cách VLOOKUP giữa hai trang tính

Để bắt đầu, hãy tìm hiểu một trường hợp đơn giản nhất - sử dụng VLOOKUP để sao chép dữ liệu từ một trang tính khác. Nó rất giống với công thức VLOOKUP thông thường tìm kiếm trên cùng một trang tính. Sự khác biệt là bạn bao gồm tên trang tính trong đối số table_array để cho công thức của bạn biết phạm vi tra cứu nằm trong trang tính nào.

Công thức chung để VLOOKUP từ một trang tính khác như sau:

VLOOKUP(lookup_value, Sheet!range, col_index_num, [range_lookup])

Ví dụ: hãy kéo số liệu bán hàng từ báo cáo Jan sang Summary tấm. Đối với điều này, chúng tôi xác định các đối số sau:

• Giá_trị_tìm_kiếm nằm trong cột A trên trang tính Tóm tắt và chúng tôiVLOOKUP:

  VLOOKUP($A2, 'West'!$A$2:$C$6 , 2, FALSE)

  Cuối cùng, công thức VLOOKUP rất chuẩn này tìm kiếm giá trị A2 trong cột đầu tiên của dải ô A2:C6 trên trang tính Tây và trả về một phù hợp từ cột thứ 2. Vậy là xong!

  VLOOKUP động để trả về dữ liệu từ nhiều trang tính vào các ô khác nhau

  Trước hết, hãy xác định chính xác từ "động" nghĩa là gì trong ngữ cảnh này và công thức này sẽ diễn ra như thế nào khác với những cái trước đó.

  Trong trường hợp bạn có khối dữ liệu lớn ở cùng định dạng được chia thành nhiều bảng tính, bạn có thể muốn trích xuất thông tin từ các trang tính khác nhau vào các ô khác nhau. Hình ảnh bên dưới minh họa khái niệm:

  

  Xem thêm: Cách tạo biểu đồ đường trong Excel

  Không giống như các công thức trước đây lấy giá trị từ một trang tính cụ thể dựa trên một mã định danh duy nhất, lần này chúng tôi đang tìm cách trích xuất các giá trị từ một số trang tính cùng một lúc thời gian.

  Có hai giải pháp khác nhau cho nhiệm vụ này. Trong cả hai trường hợp, bạn cần thực hiện một số công việc chuẩn bị nhỏ và tạo các phạm vi được đặt tên cho các ô dữ liệu trong mỗi bảng tra cứu. Đối với ví dụ này, chúng tôi đã xác định các phạm vi sau:

  • East_Sales - A2:B6 trên trang tính East
  • North_Sales - A2: B6 trên tờ North
  • South_Sales - A2:B6 trên tờ South
  • West_Sales - A2:B6 trên tờ West

  Vlookup và hàm IF lồng nhau

  Nếu bạn có số lượng trang tính hợp lý cần tra cứu, bạn có thể sử dụng hàm IF lồng nhauđể chọn trang tính dựa trên các từ khóa trong các ô được xác định trước (trong trường hợp của chúng tôi là các ô từ B1 đến D1).

  Với giá trị tra cứu trong ô A2, công thức như sau:

  =VLOOKUP($A2, IF(B$1="east", East_Sales, IF(B$1="north", North_Sales, IF(B$1="south", South_Sales, IF(B$1="west", West_Sales)))), 2, FALSE)

  Được dịch sang tiếng Anh, phần IF có nội dung:

  Nếu B1 là East , hãy tìm trong phạm vi có tên East_Sales ; nếu B1 là North , hãy tìm trong phạm vi có tên North_Sales ; nếu B1 là Nam , hãy tìm trong phạm vi có tên Nam_Sales ; và nếu B1 là West , hãy tìm trong phạm vi có tên West_Sales .

  Phạm vi được trả về bởi IF chuyển đến table_array của VLOOKUP, kéo một giá trị phù hợp từ cột thứ 2 trên trang tính tương ứng.

  Việc sử dụng thông minh các tham chiếu hỗn hợp cho giá trị tra cứu ($A2 - cột tuyệt đối và hàng tương đối) và kiểm tra logic của IF (B$1 - cột tương đối và hàng tuyệt đối) cho phép sao chép công thức sang các ô khác mà không có bất kỳ thay đổi nào - Excel sẽ tự động điều chỉnh tham chiếu dựa trên vị trí tương đối của hàng và cột.

  Vì vậy, chúng ta nhập công thức vào ô B2, sao chép sang phải và xuống bao nhiêu cột và hàng nếu cần và nhận được kết quả sau:

  

  VLOOKUP GIÁN TIẾP

  Khi làm việc với nhiều trang tính, nhiều mức lồng nhau cũng có thể tạo ra công thức dài và khó đọc. Một cách tốt hơn nhiều là tạo một phạm vi vlookup động với sự trợ giúp của INDIRECT:

  =VLOOKUP($A2, INDIRECT(B$1&"_Sales"), 2, FALSE)

  Ở đây, chúng ta nối tham chiếu đến ô chứa mộtphần duy nhất của phạm vi được đặt tên (B1) và phần chung (_Sales). Điều này tạo ra một chuỗi văn bản như "East_Sales", chuỗi này INDIRECT chuyển đổi thành tên dải ô mà Excel có thể hiểu được.

  Kết quả là bạn có được một công thức nhỏ gọn hoạt động đẹp mắt trên bất kỳ số lượng trang tính nào:

  

  Đó là cách Vlookup giữa sheet và file trong Excel. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!

  Sách bài tập thực hành để tải xuống

  Vlookup nhiều trang tính ví dụ (tệp .xlsx)

  tham chiếu đến ô dữ liệu đầu tiên, là A2.
• Table_array là phạm vi A2:B6 trên trang tính tháng 1. Để tham chiếu đến nó, hãy đặt trước tham chiếu dải ô bằng tên trang tính theo sau dấu chấm than: Jan!$A$2:$B$6.

  Xin lưu ý rằng chúng tôi khóa phạm vi với các tham chiếu ô tuyệt đối để ngăn không cho phạm vi đó thay đổi khi sao chép công thức sang các ô khác.

  Col_index_num là 2 vì chúng tôi muốn sao chép một giá trị từ cột B, là cột thứ 2 trong mảng bảng.

• Range_lookup được đặt thành FALSE để tra cứu kết quả khớp chính xác.

Đặt các đối số lại với nhau, chúng ta có công thức sau:

=VLOOKUP(A2, Jan!$A$2:$B$6, 2, FALSE)

Kéo công thức xuống dưới cột và bạn sẽ nhận được kết quả sau:

Trong một theo cách tương tự, bạn có thể Vlookup dữ liệu từ trang tính Feb và Mar :

=VLOOKUP(A2, Feb!$A$2:$B$6, 2, FALSE)

=VLOOKUP(A2, Mar!$A$2:$B$6, 2, FALSE)

Mẹo và lưu ý:

• Nếu tên trang tính chứa dấu cách hoặc ký tự không phải bảng chữ cái , thì tên đó phải được đặt trong dấu ngoặc kép, chẳng hạn như 'Giảm giá tháng 1'!$A$2:$B$6 . Để biết thêm thông tin, vui lòng xem Cách tham chiếu trang tính khác trong Excel.
• Thay vì nhập tên trang tính trực tiếp vào công thức, bạn có thể chuyển sang trang tính tra cứu và chọn phạm vi ở đó. Excel sẽ tự động chèn một tham chiếu với cú pháp chính xác, giúp bạn không phải kiểm tra tên và khắc phục sự cố.

Vlookup từ một sổ làm việc khác

Tới VLOOKUP giữa haisổ làm việc, bao gồm tên tệp trong dấu ngoặc vuông, theo sau là tên trang tính và dấu chấm than.

Ví dụ: để tìm kiếm giá trị A2 trong phạm vi A2:B6 trên trang tính Jan trong sổ làm việc Sales_reports.xlsx , hãy sử dụng công thức sau:

=VLOOKUP(A2, [Sales_reports.xlsx]Jan!$A$2:$B$6, 2, FALSE)

Để biết chi tiết đầy đủ, vui lòng xem VLOOKUP từ một sổ làm việc khác trong Excel.

Vlookup trên toàn bộ nhiều trang tính với IFERROR

Khi bạn cần tra cứu giữa nhiều hơn hai trang tính, giải pháp đơn giản nhất là sử dụng VLOOKUP kết hợp với IFERROR. Ý tưởng là lồng nhiều hàm IFERROR để kiểm tra từng trang tính một: nếu hàm VLOOKUP đầu tiên không tìm thấy kết quả khớp trên trang tính đầu tiên, hãy tìm kiếm trong trang tính tiếp theo, v.v.

IFERROR(VLOOKUP(…), IFERROR(VLOOKUP(…), …, " Không tìm thấy "))

Để xem phương pháp này hoạt động như thế nào trên dữ liệu thực tế, hãy xem xét ví dụ sau. Dưới đây là bảng Tóm tắt mà chúng tôi muốn điền tên và số lượng mặt hàng bằng cách tra cứu số thứ tự trong trang tính Tây và Đông :

Đầu tiên, chúng ta sẽ kéo các vật phẩm. Đối với điều này, chúng tôi hướng dẫn công thức VLOOKUP tìm kiếm số thứ tự trong A2 trên trang tính East và trả về giá trị từ cột B (cột thứ 2 trong table_array A2:C6). Nếu không tìm thấy kết quả khớp chính xác, hãy tìm kiếm trong trang tính Tây . Nếu cả hai Vlookup không thành công, hãy trả về "Không tìm thấy".

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 2, FALSE), "Not found"))

Để trả lại số tiền,chỉ cần thay đổi số chỉ mục cột thành 3:

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 3, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 3, FALSE), "Not found"))

Mẹo. Nếu cần, bạn có thể chỉ định các mảng bảng khác nhau cho các hàm VLOOKUP khác nhau. Trong ví dụ này, cả hai trang tính tra cứu đều có cùng số hàng (A2:C6), nhưng các trang tính của bạn có thể khác nhau về kích cỡ.

Vlookup trong nhiều sổ làm việc

Để Vlookup giữa hai hoặc nhiều sổ làm việc, hãy đặt tên sổ làm việc trong dấu ngoặc vuông và đặt trước tên trang tính. Ví dụ: đây là cách bạn có thể Vlookup trong hai tệp khác nhau ( Book1 và Book2 ) bằng một công thức duy nhất:

=IFERROR(VLOOKUP(A2, [Book1.xlsx]East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, [Book2.xlsx]West!$A$2:$C$6, 2, FALSE),"Not found"))

Làm cho số chỉ mục cột động thành nhiều cột của Vlookup

Trong trường hợp bạn cần trả về dữ liệu từ nhiều cột, làm cho col_index_num động có thể giúp bạn tiết kiệm thời gian. Có một số điều chỉnh cần thực hiện:

• Đối với đối số col_index_num , hãy sử dụng hàm COLUMNS trả về số lượng cột trong một mảng đã chỉ định: COLUMNS($A$1 :B$1). (Tọa độ hàng không thực sự quan trọng, nó có thể là bất kỳ hàng nào.)
• Trong đối số lookup_value , hãy khóa tham chiếu cột bằng ký hiệu $ ($A2), để nó giữ nguyên đã sửa lỗi khi sao chép công thức sang các cột khác.

Kết quả là bạn nhận được một loại công thức động trích xuất các giá trị phù hợp từ các cột khác nhau, tùy thuộc vào cột mà công thức được sao chép tới:

=IFERROR(VLOOKUP($A2, East!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), IFERROR(VLOOKUP($A2, West!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), "Not found"))

Khi được nhập vào cột B, COLUMNS($A$1:B$1)ước tính thành 2 yêu cầu VLOOKUP trả về giá trị từ cột thứ 2 trong mảng bảng.

Khi được sao chép sang cột C (tức là bạn đã kéo công thức từ B2 sang C2), B$1 thay đổi thành C$1 vì tham chiếu cột là tương đối. Do đó, COLUMNS($A$1:C$1) ước tính thành 3 buộc VLOOKUP trả về giá trị từ cột thứ 3.

Công thức này phù hợp với 2 - 3 trang tính tra cứu. Nếu bạn có nhiều hơn, các IFERROR lặp đi lặp lại sẽ trở nên quá cồng kềnh. Ví dụ tiếp theo minh họa cách tiếp cận phức tạp hơn một chút nhưng tinh tế hơn rất nhiều.

Vlookup nhiều trang tính với INDIRECT

Một cách nữa để Vlookup giữa nhiều trang tính trong Excel là sử dụng kết hợp VLOOKUP và Các hàm GIÁN TIẾP. Phương pháp này yêu cầu một chút chuẩn bị, nhưng cuối cùng, bạn sẽ có một công thức nhỏ gọn hơn cho Vlookup trong bất kỳ số lượng bảng tính nào.

Một công thức chung cho Vlookup trên các trang tính như sau:

VLOOKUP( lookup_value , INDIRECT("'"&INDEX( Lookup_sheet , MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheet & " '! lookup_range "), lookup_value )>0), 0)) & "'! table_array "), col_index_num , FALSE)

Ở đâu:

• Lookup_sheets - một phạm vi được đặt tên bao gồm các tên trang tính tra cứu.
• Lookup_value - giá trị tra cứu giá trị cần tìm kiếm.
• Dải_tìm_kiếm - phạm vi cột trong trang tính tra cứu nơi tìm kiếm tra cứugiá trị.
• Table_array - phạm vi dữ liệu trong bảng tra cứu.
• Col_index_num - số cột trong mảng bảng mà từ đó trả về một giá trị.

Để công thức hoạt động chính xác, hãy ghi nhớ những lưu ý sau:

• Đây là công thức mảng, phải được hoàn thành bằng cách nhấn Ctrl + Tổ hợp phím Shift + Enter.
• Tất cả các trang tính phải có thứ tự các cột như nhau .
• Khi chúng tôi sử dụng một mảng bảng cho tất cả các trang tính tra cứu, hãy chỉ định phạm vi lớn nhất nếu trang tính của bạn có số lượng hàng khác nhau.

Cách sử dụng công thức để Vlookup trên nhiều trang tính

Để Vlookup nhiều trang tính cùng một lúc, hãy thực hiện các bước sau các bước:

1. Viết tất cả tên trang tính tra cứu vào đâu đó trong sổ làm việc của bạn và đặt tên cho dải ô đó ( Lookup_sheets trong trường hợp của chúng tôi).

Điều chỉnh công thức chung cho dữ liệu của bạn. Trong ví dụ này, chúng tôi sẽ:

• tìm kiếm giá trị A2 ( lookup_value )
• trong phạm vi A2:A6 ( lookup_range ) trong bốn trang tính ( Đông , Bắc , Nam và Tây ) và
• lấy các giá trị phù hợp từ cột B, đó là cột 2 ( col_index_num ) trong phạm vi dữ liệu A2:C6 ( table_array ).

Với các đối số trên, công thức sẽ có dạng như sau:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

Xin lưu ý rằng chúng tôi khóa cả hai phạm vi ($A$2:$A$6 và $A$2:$C$6) bằng tham chiếu ô tuyệt đối.

Nhập công thứctrong ô trên cùng (B2 trong ví dụ này) và nhấn Ctrl + Shift + Enter để hoàn thành.

Nhấp đúp hoặc kéo núm điều khiển điền để sao chép công thức xuống cột.

Như Kết quả ta có công thức tra mã số đơn hàng trong 4 sheet và lấy mặt hàng tương ứng. Nếu không tìm thấy số đơn đặt hàng cụ thể, lỗi #N/A sẽ hiển thị như trong hàng 14:

Để trả lại số tiền, chỉ cần thay 2 bằng 3 trong col_index_num đối số dưới dạng số tiền nằm trong cột thứ 3 của mảng bảng:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE)

Nếu bạn muốn thay thế ký hiệu lỗi #N/A tiêu chuẩn bằng văn bản của riêng bạn, hãy ngắt dòng công thức vào hàm IFNA:

=IFNA(VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE), "Not found")

Vlookup nhiều trang tính giữa các sổ làm việc

Công thức chung này (hoặc bất kỳ biến thể nào của nó) cũng có thể được sử dụng đến Vlookup nhiều trang tính trong sổ làm việc khác nhau . Đối với điều này, hãy nối tên sổ làm việc bên trong INDIRECT như được hiển thị trong công thức bên dưới:

=IFNA(VLOOKUP($A2, INDIRECT("'[Book1.xlsx]" & INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'[Book1.xlsx]" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 2, FALSE), "Not found")

Vlookup giữa các trang tính và trả về nhiều cột

Nếu bạn muốn lấy dữ liệu từ nhiều trang tính cột, công thức mảng nhiều ô có thể thực hiện điều đó trong một lần. Để tạo một công thức như vậy, hãy cung cấp một hằng số mảng cho đối số col_index_num .

Trong ví dụ này, chúng tôi muốn trả về tên mục (cột B) và số tiền (cột C), mà lần lượt là các cột thứ 2 và thứ 3 trong mảng bảng. Vì vậy, mảng yêu cầu là{2,3}.

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets &"'!$A$2:$C$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), {2,3}, FALSE)

Để nhập chính xác công thức vào nhiều ô, bạn cần làm như sau:

• Ở hàng đầu tiên, chọn tất cả các ô sẽ được điền (trong ví dụ của chúng tôi là B2:C2).
• Nhập công thức và nhấn Ctrl + Shift + Enter . Thao tác này sẽ nhập cùng một công thức vào các ô đã chọn. Công thức này sẽ trả về một giá trị khác trong mỗi cột.
• Kéo công thức xuống các hàng còn lại.

Cách thức hoạt động của công thức này

Để hiểu rõ hơn về logic, hãy chia nhỏ công thức cơ bản này thành các hàm riêng lẻ:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

Làm việc từ trong ra ngoài, đây là chức năng của công thức:

COUNTIF và INDIRECT

Tóm lại, INDIRECT tạo tham chiếu cho tất cả các trang tra cứu và COUNTIF đếm số lần tra cứu giá trị (A2) trong mỗi trang tính:

--(COUNTIF( INDIRECT("'"&Lookup_sheets&"'!$A$2:$A$6"), $A2)>0)

Chi tiết hơn:

Trước tiên, bạn nối tên dải ô (Lookup_sheets) và tham chiếu dải ô ($A$2: $A$6), thêm dấu nháy đơn và dấu chấm than vào đúng vị trí để tạo tham chiếu bên ngoài và cung cấp chuỗi văn bản kết quả cho hàm INDIRECT để tự động tham chiếu đến trang tính tra cứu:

INDIRECT({"'East'!$A$2:$A$6"; "'South'!$A$2:$A$6"; "'North'!$A$2:$A$6"; "'West'!$A$2:$A$6"})

COUNTIF kiểm tra từng ô trong phạm vi A2:A6 trên mỗi bảng tra cứu so với giá trị trong A2 trên trang chính sheet và trả về số lượng khớp cho mỗi sheet. Trong tập dữ liệu của chúng tôi, số thứ tự trong A2 (101) được tìm thấy trong trang tính Tây , thứ 4 trong trang tínhphạm vi đã đặt tên, vì vậy COUNTIF trả về mảng này:

{0;0;0;1}

Tiếp theo, bạn so sánh từng phần tử của mảng trên với 0:

--({0; 0; 0; 1}>0)

Kết quả này một mảng các giá trị TRUE (lớn hơn 0) và FALSE (bằng 0), mà bạn ép buộc các giá trị 1 và 0 bằng cách sử dụng một đơn nguyên kép (--) và nhận được kết quả là mảng sau:

{0; 0; 0; 1}

Thao tác này là một biện pháp phòng ngừa bổ sung để xử lý tình huống khi một bảng tra cứu chứa một số lần xuất hiện của giá trị tra cứu, trong trường hợp đó, COUNTIF sẽ trả về số lượng lớn hơn 1, trong khi chúng tôi chỉ muốn các số 1 và 0 trong bảng mảng cuối cùng (trong giây lát, bạn sẽ hiểu tại sao).

Sau tất cả các phép biến đổi này, công thức của chúng ta sẽ như sau:

VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, {0;0;0;1} , 0)) &"'!$A$2:$C$6"), 2, FALSE)

INDEX và MATCH

Tại thời điểm này, một tổ hợp INDEX MATCH cổ điển sẽ bước vào:

INDEX(Lookup_sheets, MATCH(1, {0;0;0;1}, 0))

Hàm MATCH được định cấu hình để khớp chính xác (0 trong đối số cuối cùng) tìm kiếm giá trị 1 trong mảng { 0;0;0;1} và trả về vị trí của nó, đó là 4:

INDEX(Lookup_sheets, 4)

Hàm INDEX sử dụng số được trả về bằng MATCH làm đối số số hàng (row_num) và trả về giá trị thứ 4 trong dải ô đã đặt tên Lookup_sheets , là Tây .

Vì vậy, công thức tiếp tục rút gọn thành:

VLOOKUP($A2, INDIRECT("'"&" West "&"'!$A$2:$C$6"), 2, FALSE)

Vlookup và INDIRECT

Hàm INDIRECT xử lý chuỗi văn bản bên trong nó:

INDIRECT("'"&"West"&"'!$A$2:$C$6")

Và chuyển đổi nó thành một tham chiếu đến đối số table_array của