Šioje pamokoje rodoma, kaip naudoti VLOOKUP funkciją duomenims kopijuoti iš kito darbalapio ar sąsiuvinio, Vlookup keliuose lapuose ir dinamiškai ieškoti, kad būtų galima grąžinti reikšmes iš skirtingų lapų į skirtingus langelius.

Ieškant tam tikros informacijos "Excel" programoje, retai kada visi duomenys yra tame pačiame lape. Dažniau teks ieškoti keliuose lapuose ar net skirtinguose sąsiuviniuose. Gera žinia ta, kad "Microsoft Excel" pateikia daugiau nei vieną būdą, kaip tai padaryti, o bloga žinia ta, kad visi būdai yra šiek tiek sudėtingesni nei standartinė VLOOKUP formulė. Tačiau, pasitelkę šiek tiek kantrybės, galimejuos išsiaiškinsime :)

Kaip atlikti VLOOKUP tarp dviejų lapų

Pirmiausia panagrinėkime paprasčiausią atvejį - VLOOKUP naudojimą duomenims kopijuoti iš kito darbalapio. Tai labai panašu į įprastą VLOOKUP formulę, kuri ieško tame pačiame darbalapyje. Skirtumas tas, kad į formulę įtraukiamas lapo pavadinimas. table_array argumentas, kuriuo formulėje nurodoma, kuriame darbalapyje yra paieškos sritis.

Bendroji VLOOKUP formulė iš kito lapo yra tokia:

Pavyzdžiui, paimkime pardavimų duomenis iš Jan ataskaitą Santrauka lapą. Tam apibrėžiame šiuos argumentus:

• Lookup_values yra A stulpelyje Santrauka lape ir nurodome pirmąjį duomenų langelį, kuris yra A2.
• Table_array tai Jan lapo A2:B6 intervalas. Norėdami į jį nurodyti, prieš nuorodą į intervalą įrašykite lapo pavadinimą ir šauktuką: Jan!$A$2:$B$6.

  Atkreipkite dėmesį, kad diapazoną užrakiname absoliučiomis ląstelių nuorodomis, kad jis nepasikeistų kopijuojant formulę į kitas ląsteles.

  Col_index_num yra 2, nes norime nukopijuoti reikšmę iš stulpelio B, kuris yra antrasis lentelės masyvo stulpelis.

• Range_lookup nustatoma į FALSE, kad būtų ieškoma tikslaus atitikmens.

Sudėję argumentus, gausime šią formulę:

=VLOOKUP(A2, Jan!$A$2:$B$6, 2, FALSE)

Vilkite formulę žemyn stulpeliu ir gausite šį rezultatą:

Panašiai galite Vlookup duomenis iš Vasaris ir Mar lapai:

=VLOOKUP(A2, Feb!$A$2:$B$6, 2, FALSE)

=VLOOKUP(A2, Mar!$A$2:$B$6, 2, FALSE)

Patarimai ir pastabos:

• Jei lapo pavadinime yra erdvės arba ne abėcėlės ženklai , ji turi būti pateikiama viengubomis kabutėmis, pvz. 'Jan Sales'!$A$2:$B$6 . Daugiau informacijos rasite skyriuje Kaip pateikti nuorodą į kitą "Excel" lapą.
• Užuot formulėje tiesiogiai įvedę lapo pavadinimą, galite pereiti į paieškos darbalapį ir jame pasirinkti diapazoną. "Excel" automatiškai įterps nuorodą su teisinga sintakse, todėl jums nereikės tikrinti pavadinimo ir spręsti problemų.

Vlookup iš kito sąsiuvinio

Norėdami atlikti VLOOKUP tarp dviejų sąsiuvinių, laužtiniuose skliaustuose įrašykite failo pavadinimą, po to lapo pavadinimą ir šauktuką.

Pavyzdžiui, jei norite ieškoti A2 reikšmės diapazone A2:B6 Jan lape, esančiame Sales_reports.xlsx darbaknygėje naudokite šią formulę:

=VLOOKUP(A2, [Sales_reports.xlsx]Jan!$A$2:$B$6, 2, FALSE)

Išsamios informacijos rasite skyriuje VLOOKUP iš kito "Excel" sąsiuvinio.

Vlookup per kelis lapus su IFERROR

Kai reikia atlikti paiešką tarp daugiau nei dviejų lapų, paprasčiausias sprendimas yra naudoti VLOOKUP kartu su IFERROR. Idėja yra įterpti kelias IFERROR funkcijas, kad būtų galima patikrinti kelis darbo lapus vieną po kito: jei pirmasis VLOOKUP neranda atitikmens pirmame lape, ieškoma kitame lape ir t. t.

Norėdami pamatyti, kaip šis metodas veikia realių duomenų atveju, panagrinėkime toliau pateiktą pavyzdį. Toliau pateikiamas Santrauka lentelę, kurią norime užpildyti elementų pavadinimais ir sumomis, ieškodami užsakymo numerio Vakarų ir Rytų lapai:

Pirmiausia ištrauksime prekes. Šiuo tikslu VLOOKUP formulei nurodysime ieškoti užsakymo numerio A2 eilutėje Rytų lape ir grąžinkite B stulpelio (2-asis stulpelis table_array A2:C6). Jei tikslaus atitikmens nerandama, tada ieškokite Vakarų lapą. Jei abu Vlookups nepavyksta, grąžinama "Nerastas".

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 2, FALSE), "Not found"))

Norėdami grąžinti sumą, tiesiog pakeiskite stulpelio indekso numerį į 3:

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 3, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 3, FALSE), "Not found"))

Patarimas. Jei reikia, skirtingoms VLOOKUP funkcijoms galite nurodyti skirtingus lentelių masyvus. Šiame pavyzdyje abiejuose paieškos lapuose yra tas pats eilučių skaičius (A2:C6), tačiau jūsų darbalapiai gali būti skirtingo dydžio.

Vlookup keliuose sąsiuviniuose

Jei norite atlikti Vlookup tarp dviejų ar daugiau darbaknygių, darbaknygės pavadinimą įrašykite laužtiniuose skliaustuose ir prieš lapo pavadinimą. du skirtingi failai ( 1 knyga ir 2 knyga ) su viena formule:

=IFERROR(VLOOKUP(A2, [Book1.xlsx]East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, [Book2.xlsx]West!$A$2:$C$6, 2, FALSE), "Nerastas"))

Padaryti stulpelio indekso numerį dinamišką, kad būtų galima atlikti "Vlookup" paiešką keliuose stulpeliuose

Kai reikia grąžinti kelių stulpelių duomenis, reikia col_index_num dinamika gali sutaupyti šiek tiek laiko. Reikia atlikti keletą pakeitimų:

• Dėl col_index_num argumentą, naudokite funkciją COLUMNS, kuri grąžina stulpelių skaičių nurodytame masyve: COLUMNS($A$1:B$1). (Eilutės koordinatė nėra svarbi, tai gali būti bet kuri eilutė.)
• Į lookup_value argumentą, užfiksuokite stulpelio nuorodą su ženklu $ ($A2), kad kopijuojant formulę į kitus stulpelius ji išliktų fiksuota.

Taip gaunama tam tikra dinaminė formulė, kuri iš skirtingų stulpelių ištraukia atitinkamas reikšmes, priklausomai nuo to, į kurį stulpelį kopijuojama formulė:

=IFERROR(VLOOKUP($A2, East!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), IFERROR(VLOOKUP($A2, West!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), "Not found"))

Įrašius į B stulpelį, COLUMNS($A$1:B$1) įvertinama kaip 2, todėl VLOOKUP grąžina vertę iš 2-ojo lentelės masyvo stulpelio.

Nukopijavus į C stulpelį (t. y. perkėlus formulę iš B2 į C2), B$1 pasikeičia į C$1, nes stulpelio nuoroda yra santykinė. Todėl COLUMNS($A$1:C$1) įvertinama kaip 3 ir priverčia VLOOKUP grąžinti 3 stulpelio reikšmę.

Ši formulė puikiai tinka 2-3 paieškos lapams. Jei jų yra daugiau, pasikartojančios IFERROR tampa pernelyg nepatogios. Kitame pavyzdyje parodytas šiek tiek sudėtingesnis, bet daug elegantiškesnis metodas.

Vlookup kelių lapų su INDIRECT

Dar vienas būdas "Excel" programoje atlikti "Vlookup" tarp kelių lapų - naudoti VLOOKUP ir INDIRECT funkcijų derinį. Šiam metodui reikia šiek tiek pasiruošti, tačiau galiausiai turėsite kompaktiškesnę formulę, skirtą "Vlookup" bet kokiame skaičiuje skaičiuoklių.

Bendroji formulė Vlookup per lapus yra tokia:

Kur:

• Paieškos lapai - įvardytas intervalas, sudarytas iš paieškos lapo pavadinimų.
• Lookup_value - ieškomą reikšmę.
• Lookup_range - stulpelių intervalas paieškos lapuose, kuriame reikia ieškoti paieškos vertės.
• Table_array - duomenų diapazoną paieškos lapuose.
• Col_index_num - lentelės masyvo stulpelio, iš kurio reikia grąžinti reikšmę, numeris.

Kad formulė veiktų teisingai, turėkite omenyje šias pastabas:

• Tai masyvo formulė, kurią reikia užbaigti kartu spaudžiant klavišus Ctrl + Shift + Enter.
• Visuose lapuose turi būti ta pati stulpelių tvarka .
• Kadangi naudojame vieną lentelės masyvą visiems paieškos lapams, nurodykite didžiausias diapazonas jei jūsų lapuose yra skirtingas eilučių skaičius.

Kaip naudoti formulę Vlookup per lapus

Jei norite vienu metu peržiūrėti kelis lapus, atlikite šiuos veiksmus:

1. Užsirašykite visų paieškos lapų pavadinimus kur nors savo darbaknygėje ir pavadinkite tą diapazoną ( Paieškos lapai mūsų atveju).

• ieškodami A2 reikšmės ( lookup_value )
• A2:A6 diapazone ( lookup_range ) keturiuose darbalapiuose ( Rytų , Šiaurės , Pietų ir Vakarų ) ir
• iš B stulpelio, t. y. 2 stulpelio ( col_index_num ) duomenų intervale A2:C6 ( table_array ).

Naudojant minėtus argumentus, formulė įgauna tokią formą:

=VLOOKUP($A2, INDIRECT("""&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("""& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

Atkreipkite dėmesį, kad abu intervalus ($A$2:$A$6 ir $A$2:$C$6) užrakiname absoliučiomis ląstelių nuorodomis.

Kaip rezultatą gavome formulę, pagal kurią užsakymo numerio reikia ieškoti 4 lapuose ir gauti atitinkamą elementą. Jei konkretaus užsakymo numerio nerandama, rodoma klaida #N/A, kaip 14 eilutėje:

Norėdami grąžinti sumą, tiesiog pakeiskite 2 į 3 col_index_num argumentas, nes sumos yra lentelės masyvo 3 stulpelyje:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE)

Jei norite standartinį #N/A klaidų užrašą pakeisti savo tekstu, formulę įrašykite į funkciją IFNA:

=IFNA(VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE), "Nerastas")

Kelių lapų paieška tarp sąsiuvinių

Šią bendrąją formulę (arba bet kokį jos variantą) taip pat galima naudoti kelių lapų skirtingas sąsiuvinis . Šiuo tikslu darbo knygos pavadinimą įrašykite INDIRECT viduje, kaip parodyta toliau pateiktoje formulėje:

=IFNA(VLOOKUP($A2, INDIRECT("''[Book1.xlsx]" & INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("''[Book1.xlsx]" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 2, FALSE), "Nerastas")

Vlookup tarp lapų ir grąžinti kelis stulpelius

Jei norite ištraukti duomenis iš kelių stulpelių, naudokite kelių ląstelių masyvo formulė gali tai padaryti vienu veiksmu. Norėdami sukurti tokią formulę, pateikite masyvo konstantą col_index_num argumentas.

Šiame pavyzdyje norime grąžinti elementų pavadinimus (B stulpelis) ir sumas (C stulpelis), kurie yra atitinkamai 2 ir 3 lentelės masyvo stulpeliai. Taigi reikiamas masyvas yra {2,3}.

=VLOOKUP($A2, INDIRECT("""&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("""& Lookup_sheets &"'!$A$2:$C$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), {2,3}, FALSE)

Norėdami teisingai įvesti formulę keliose ląstelėse, turite padaryti štai ką:

• Pirmoje eilutėje pažymėkite visus langelius, kuriuos reikia užpildyti (mūsų pavyzdyje - B2:C2).
• Įveskite formulę ir paspauskite Ctrl + Shift + Enter . Taip į pasirinktus langelius įvesite tą pačią formulę, kuri kiekviename stulpelyje grąžins skirtingą reikšmę.
• Vilkite žemyn formulę į likusias eilutes.

Kaip veikia ši formulė

Kad geriau suprastume logiką, išskaidykime šią pagrindinę formulę į atskiras funkcijas:

=VLOOKUP($A2, INDIRECT("""&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("""& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

Ši formulė veikia iš vidaus į išorę:

COUNTIF ir INDIRECT

Trumpai tariant, INDIRECT sukuria nuorodas į visus paieškos lapus, o COUNTIF skaičiuoja paieškos vertės (A2) pasikartojimus kiekviename lape:

--(COUNTIF( INDIRECT("'"&Lookup_sheets&"'!$A$2:$A$6"), $A2)>0)

Išsamiau:

Pirmiausia sujungiate diapazono pavadinimą ("Lookup_sheets") ir diapazono nuorodą ($A$2:$A$6), pridėdami apostrofus ir šauktuką reikiamose vietose, kad sukurtumėte išorinę nuorodą, ir gautą teksto eilutę perduodate funkcijai INDIRECT, kad būtų galima dinamiškai daryti nuorodas į paieškos lapus:

INDIRECT({"'East'!$A$2:$A$6"; "'South'!$A$2:$A$6"; "'North'!$A$2:$A$6"; "'West'!$A$2:$A$6"})

COUNTIF patikrina kiekvieno paieškos lapo A2:A6 intervalo ląstelę su pagrindinio lapo A2 verte ir grąžina kiekvieno lapo atitikčių skaičių. Mūsų duomenų rinkinyje A2 eilės numeris (101) randamas lape Vakarų lapas, kuris yra 4-as įvardytame intervale, todėl COUNTIF grąžina šį masyvą:

{0;0;0;1}

Tada kiekvieną pirmiau pateikto masyvo elementą palyginkite su 0:

--({0; 0; 0; 0; 1}>0)

Taip gaunamas TRUE (didesnis už 0) ir FALSE (lygus 0) reikšmių masyvas, kurį, naudodami dvigubą vienaženklį jungtuką (--), paverčiate 1 ir 0 reikšmėmis ir gaunate tokį masyvą:

{0; 0; 0; 1}

Ši operacija - tai papildoma atsargumo priemonė, skirta situacijai, kai paieškos lape yra keli paieškos reikšmės pasikartojimai - tokiu atveju COUNTIF grąžintų skaičių, didesnį nei 1, o mes norime, kad galutiniame masyve būtų tik 1 ir 0 (po akimirkos suprasite, kodėl).

Po visų šių transformacijų mūsų formulė atrodo taip:

VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, {0;0;0;0;1} , 0)) &"'!$A$2:$C$6"), 2, FALSE)

INDEX ir MATCH

Šiuo metu naudojamas klasikinis INDEX MATCH derinys:

INDEX(Lookup_sheets, MATCH(1, {0;0;0;0;1}, 0))

Funkcija MATCH, sukonfigūruota tiksliam atitikimui (0 paskutiniame argumente), ieško reikšmės 1 masyve {0;0;0;0;1} ir grąžina jos poziciją, kuri yra 4:

INDEX(Lookup_sheets, 4)

Funkcija INDEX naudoja skaičių, gautą MATCH, kaip eilutės numerio argumentą (eilutės_numeris) ir grąžina 4-ąją reikšmę įvardytame intervale. Paieškos lapai , kuris yra Vakarų .

Taigi formulė dar labiau redukuojama į:

VLOOKUP($A2, INDIRECT("'"&" West "&"'!$A$2:$C$6"), 2, FALSE)

VLOOKUP ir INDIRECT

Funkcija INDIRECT apdoroja joje esančią teksto eilutę:

INDIRECT("'"& "West"&"'!$A$2:$C$6")

ir paverčia jį nuoroda, kuri patenka į table_array VLOOKUP argumentas:

VLOOKUP($A2, 'West'!$A$2:$C$6 , 2, FALSE)

Galiausiai ši labai standartinė VLOOKUP formulė ieško A2 reikšmės pirmajame A2:C6 intervalo stulpelyje. Vakarų ir grąžina atitikmenį iš 2-ojo stulpelio. Štai ir viskas!

Dinaminis VLOOKUP, kad grąžintumėte duomenis iš kelių lapų į skirtingas ląsteles

Pirmiausia apibrėžkime, ką šiame kontekste reiškia žodis "dinamiškas" ir kuo ši formulė skirsis nuo ankstesnių.

Jei turite didelius to paties formato duomenų gabalus, kurie padalyti į kelias skaičiuokles, galite norėti informaciją iš skirtingų lapų išskirti į skirtingas ląsteles. Toliau pateiktas paveikslėlis iliustruoja šią koncepciją:

Kitaip nei ankstesnėse formulėse, kuriose vertė buvo gaunama iš konkretaus lapo pagal unikalų identifikatorių, šį kartą norime išgauti vertes iš kelių lapų vienu metu.

Yra du skirtingi šios užduoties sprendimo būdai. Abiem atvejais reikia atlikti nedidelį parengiamąjį darbą ir kiekviename paieškos lape duomenų ląstelėms sukurti pavadintus intervalus. Šiame pavyzdyje apibrėžėme šiuos intervalus:

• East_Sales - A2:B6 rytiniame lape
• North_Sales - A2:B6 šiauriniame lape
• South_Sales - A2:B6 pietiniame lape
• West_Sales - A2:B6 vakariniame lape

VLOOKUP ir įterptiniai IF

Jei turite pakankamai daug lapų, kuriuos reikia peržiūrėti, galite naudoti įterptines IF funkcijas, kad pasirinktumėte lapą pagal raktinius žodžius iš anksto nustatytose ląstelėse (mūsų atveju - ląstelėse nuo B1 iki D1).

Naudojant A2 paieškos vertę, formulė yra tokia:

=VLOOKUP($A2, IF(B$1="east", East_Sales, IF(B$1="north", North_Sales, IF(B$1="south", South_Sales, IF(B$1="west", West_Sales)))), 2, FALSE)

Išvertus į anglų kalbą, IF dalis skamba taip:

Jei B1 yra Rytų , ieškokite diapazone, pavadintame East_Sales ; jei B1 yra Šiaurės , ieškokite diapazone, pavadintame North_Sales ; jei B1 yra Pietų , ieškokite diapazone, pavadintame South_Sales ; ir jei B1 yra Vakarų , ieškokite diapazone, pavadintame West_Sales .

IF grąžinamas diapazonas siekia table_array VLOOKUP, kuris iš atitinkamo lapo 2-ojo stulpelio ištraukia atitinkamą vertę.

Sumaniai naudojant mišrias nuorodas paieškos vertei ($A2 - absoliutus stulpelis ir santykinė eilutė) ir loginį IF testą (B$1 - santykinis stulpelis ir absoliuti eilutė), formulę galima kopijuoti į kitas ląsteles be jokių pakeitimų - "Excel" automatiškai pritaiko nuorodas pagal santykinę eilutės ir stulpelio padėtį.

Taigi, į B2 įrašome formulę, nukopijuojame ją į dešinę ir į apačią tiek stulpelių ir eilučių, kiek reikia, ir gauname tokį rezultatą:

NETIESIOGINĖ PAIEŠKA

Dirbant su daugeliu lapų, dėl kelių įterptų lygių formulė gali tapti per ilga ir sunkiai įskaitoma. Kur kas geresnis būdas yra sukurti dinaminis "vlookup" diapazonas su INDIRECT pagalba:

=VLOOKUP($A2, INDIRECT(B$1&"_Sales"), 2, FALSE)

Čia sujungiame nuorodą į ląstelę, kurioje yra unikali pavadinto diapazono dalis (B1), ir bendrąją dalį (_Sales). Taip gaunama tokia teksto eilutė kaip "East_Sales", kurią INDIRECT konvertuoja į "Excel" suprantamą diapazono pavadinimą.

Todėl gaunate kompaktišką formulę, kuri puikiai tinka bet kokiam lapų skaičiui:

Štai kaip "Excel" programoje atlikti "Vlookup" tarp lapų ir failų. Dėkoju, kad perskaitėte, ir tikiuosi, kad kitą savaitę susitiksime mūsų tinklaraštyje!

Atsisiųsti praktikos sąsiuvinį

"Vlookup" kelių lapų pavyzdžiai (.xlsx failas)