টিউটোরিয়ালটি দেখায় কিভাবে অন্য ওয়ার্কশীট বা ওয়ার্কবুক থেকে ডেটা অনুলিপি করতে VLOOKUP ফাংশন ব্যবহার করতে হয়, একাধিক শীটে Vlookup এবং বিভিন্ন শীট থেকে বিভিন্ন কক্ষে মান ফেরাতে গতিশীলভাবে সন্ধান করতে হয়৷

Excel-এ কিছু তথ্য খোঁজার সময়, সমস্ত ডেটা একই শীটে থাকা একটি বিরল ঘটনা। প্রায়শই, আপনাকে একাধিক শীট বা এমনকি বিভিন্ন ওয়ার্কবুক জুড়ে অনুসন্ধান করতে হবে। ভাল খবর হল যে মাইক্রোসফ্ট এক্সেল এটি করার জন্য একাধিক উপায় সরবরাহ করে এবং খারাপ খবর হল যে সমস্ত উপায় একটি স্ট্যান্ডার্ড VLOOKUP সূত্রের চেয়ে একটু বেশি জটিল। কিন্তু একটু ধৈর্যের সাথে, আমরা সেগুলি বের করব :)

দুটি পত্রকের মধ্যে কীভাবে VLOOKUP করবেন

শুরু করার জন্য, আসুন একটি সহজ ঘটনা তদন্ত করি - VLOOKUP ব্যবহার করে অন্য ওয়ার্কশীট থেকে ডেটা অনুলিপি করুন। এটি একটি নিয়মিত VLOOKUP সূত্রের মতো যা একই ওয়ার্কশীটে অনুসন্ধান করে৷ পার্থক্য হল যে আপনি টেবিল_অ্যারে আর্গুমেন্টে শীটের নাম অন্তর্ভুক্ত করেন আপনার সূত্রটি জানাতে যে ওয়ার্কশীটে লুকআপ পরিসরটি অবস্থিত।

অন্য শীট থেকে VLOOKUP করার জেনেরিক সূত্রটি নিম্নরূপ:

VLOOKUP(lookup_value, Sheet!range, col_index_num, [range_lookup])

উদাহরণস্বরূপ, আসুন জানুয়ারি রিপোর্ট থেকে সারাংশ<তে বিক্রয় পরিসংখ্যান টানুন। 2> শীট। এর জন্য, আমরা নিম্নলিখিত আর্গুমেন্টগুলিকে সংজ্ঞায়িত করি:

• Lookup_values সারাংশ পত্রকের কলাম A-তে রয়েছে এবং আমরাVLOOKUP:

  VLOOKUP($A2, 'West'!$A$2:$C$6 , 2, FALSE)

  অবশেষে, এই খুব সাধারণ VLOOKUP সূত্রটি ওয়েস্ট শীটে A2:C6 রেঞ্জের প্রথম কলামে A2 মান অনুসন্ধান করে এবং একটি রিটার্ন করে ২য় কলাম থেকে মিল। এটাই!

  ডাইনামিক VLOOKUP একাধিক শীট থেকে বিভিন্ন কক্ষে ডেটা ফেরত দিতে

  প্রথমে, এই প্রসঙ্গে "ডাইনামিক" শব্দের অর্থ কী এবং এই সূত্রটি কীভাবে হবে তা সংজ্ঞায়িত করা যাক আগেরগুলির থেকে আলাদা৷

  যদি আপনার কাছে একই ফর্ম্যাটে প্রচুর পরিমাণে ডেটা থাকে যা একাধিক স্প্রেডশীটে বিভক্ত হয়, আপনি বিভিন্ন শীট থেকে বিভিন্ন কক্ষে তথ্য বের করতে চাইতে পারেন৷ নীচের চিত্রটি ধারণাটি তুলে ধরে:

  

  আগের সূত্রগুলির বিপরীতে যা একটি অনন্য শনাক্তকারীর উপর ভিত্তি করে একটি নির্দিষ্ট শীট থেকে একটি মান পুনরুদ্ধার করেছিল, এবার আমরা একটিতে বেশ কয়েকটি শীট থেকে মান বের করতে চাইছি সময়।

  এই কাজের জন্য দুটি ভিন্ন সমাধান আছে। উভয় ক্ষেত্রেই, আপনাকে একটু প্রস্তুতিমূলক কাজ করতে হবে এবং প্রতিটি লুকআপ শীটে ডেটা সেলের জন্য নামকৃত রেঞ্জ তৈরি করতে হবে। এই উদাহরণের জন্য, আমরা নিম্নলিখিত ব্যাপ্তিগুলিকে সংজ্ঞায়িত করেছি:

  • East_Sales - A2:B6 ইস্ট শীটে
  • North_Sales - A2: উত্তর শীটে B6
  • South_Sales - A2:B6 দক্ষিণ শীটে
  • West_Sales - A2:B6 পশ্চিম শীটে

  VLOOKUP এবং নেস্টেড IFs

  যদি আপনার কাছে উপযুক্ত সংখ্যক শীট থাকে, আপনি নেস্টেড IF ফাংশন ব্যবহার করতে পারেনপূর্বনির্ধারিত কক্ষে (আমাদের ক্ষেত্রে B1 থেকে D1 কোষ) কীওয়ার্ডের উপর ভিত্তি করে শীট নির্বাচন করতে।

  A2-তে লুকআপ মানের সাথে, সূত্রটি নিম্নরূপ:

  =VLOOKUP($A2, IF(B$1="east", East_Sales, IF(B$1="north", North_Sales, IF(B$1="south", South_Sales, IF(B$1="west", West_Sales)))), 2, FALSE)

  ইংরেজিতে অনুবাদ করা হলে, IF অংশটি পড়ে:

  যদি B1 হয় East , তাহলে East_Sales নামের পরিসরে দেখুন; যদি B1 হয় উত্তর , তাহলে North_Sales নামের রেঞ্জে দেখুন; যদি B1 দক্ষিণ হয়, তাহলে দক্ষিণ_বিক্রয় নামের পরিসরে দেখুন; এবং যদি B1 পশ্চিম হয়, ওয়েস্ট_সেলস নামের রেঞ্জটি দেখুন।

  IF দ্বারা প্রত্যাবর্তিত পরিসরটি VLOOKUP এর টেবিল_অ্যারে এ যায়, যা টানে সংশ্লিষ্ট শীটে ২য় কলাম থেকে একটি মিলে যাওয়া মান।

  আরো দেখুন: এক্সেলের প্রতিটি মুদ্রিত পৃষ্ঠায় একটি হেডার সারি (কলাম হেডার) পুনরাবৃত্তি করুন

  লুকআপ মানের জন্য মিশ্র রেফারেন্সের চতুর ব্যবহার ($A2 - পরম কলাম এবং আপেক্ষিক সারি) এবং IF (B$1 - আপেক্ষিক কলাম) এর যৌক্তিক পরীক্ষা এবং পরম সারি) কোনো পরিবর্তন ছাড়াই অন্য কক্ষে সূত্র অনুলিপি করার অনুমতি দেয় - এক্সেল একটি সারি এবং কলামের আপেক্ষিক অবস্থানের উপর ভিত্তি করে স্বয়ংক্রিয়ভাবে রেফারেন্সগুলিকে সামঞ্জস্য করে। যতগুলি প্রয়োজন ততগুলি কলাম এবং সারিতে নিচে যান এবং নিম্নলিখিত ফলাফল পান:

  

  ইডাইরেক্ট VLOOKUP

  অনেক শীটের সাথে কাজ করার সময়, একাধিক নেস্টেড স্তরগুলিও সূত্র তৈরি করতে পারে দীর্ঘ এবং পড়া কঠিন। আরও ভাল উপায় হল ইনডাইরেক্টের সাহায্যে একটি ডাইনামিক ভলুকআপ রেঞ্জ তৈরি করা:

  =VLOOKUP($A2, INDIRECT(B$1&"_Sales"), 2, FALSE)

  এখানে, আমরা একটি কক্ষের রেফারেন্সকে সংযুক্ত করিনামকৃত পরিসরের অনন্য অংশ (B1) এবং সাধারণ অংশ (_বিক্রয়)। এটি "East_Sales" এর মত একটি টেক্সট স্ট্রিং তৈরি করে, যা INDIRECT এক্সেল দ্বারা বোধগম্য পরিসরের নামে রূপান্তরিত করে৷

  ফলে, আপনি একটি কমপ্যাক্ট ফর্মুলা পাবেন যা যেকোনো সংখ্যক শীটে সুন্দরভাবে কাজ করে:

  <0

  এভাবে Excel এ শীট এবং ফাইলের মধ্যে Vlookup করতে হয়। পড়ার জন্য আমি আপনাকে ধন্যবাদ জানাই এবং আশা করছি আগামী সপ্তাহে আমাদের ব্লগে আপনাকে দেখতে পাব!

  ডাউনলোডের জন্য ওয়ার্কবুক অনুশীলন করুন

  ভিলুকআপ একাধিক শীট উদাহরণ (.xlsx ফাইল)

  ৷প্রথম ডেটা সেল দেখুন, যা A2।
• টেবিল_অ্যারে হল জান শীটে A2:B6 পরিসর। এটি উল্লেখ করার জন্য, বিস্ময়বোধক বিন্দু অনুসরণ করে শীট নামের সাথে পরিসরের রেফারেন্স উপসর্গ করুন: Jan!$A$2:$B$6।

  অনুগ্রহ করে মনোযোগ দিন যে আমরা অন্য কক্ষে সূত্রটি অনুলিপি করার সময় পরিবর্তিত হওয়া থেকে বিরত রাখতে পরম সেল রেফারেন্স সহ পরিসরটি লক করি৷

  Col_index_num হল 2 কারণ আমরা একটি মান অনুলিপি করতে চাই কলাম B থেকে, যা টেবিল অ্যারের ২য় কলাম।

• রেঞ্জ_লুকআপ একটি সঠিক মিল দেখতে মিথ্যাতে সেট করা হয়েছে।

আর্গুমেন্ট একসাথে রেখে, আমরা এই সূত্রটি পাই:

=VLOOKUP(A2, Jan!$A$2:$B$6, 2, FALSE)

সূত্রটিকে কলামের নিচে টেনে আনুন এবং আপনি এই ফলাফলটি পাবেন:

এতে একইভাবে, আপনি ফেব্রুয়ারি এবং মার্চ শীটগুলি থেকে ডেটা ভিলুকআপ করতে পারেন:

=VLOOKUP(A2, Feb!$A$2:$B$6, 2, FALSE)

=VLOOKUP(A2, Mar!$A$2:$B$6, 2, FALSE)

টিপস এবং নোট:

• যদি শীটের নামে স্পেস বা অ-বর্ণানুক্রমিক অক্ষর থাকে, তবে এটি অবশ্যই একক উদ্ধৃতি চিহ্নগুলিতে আবদ্ধ থাকতে হবে, যেমন 'জান সেলস'!$A$2:$B$6 । আরও তথ্যের জন্য, অনুগ্রহ করে দেখুন কিভাবে Excel এ অন্য একটি শীট রেফারেন্স করবেন।
• একটি সূত্রে সরাসরি একটি শীটের নাম টাইপ করার পরিবর্তে, আপনি লুকআপ ওয়ার্কশীটে স্যুইচ করতে পারেন এবং সেখানে পরিসরটি নির্বাচন করতে পারেন। এক্সেল স্বয়ংক্রিয়ভাবে সঠিক সিনট্যাক্স সহ একটি রেফারেন্স সন্নিবেশ করাবে, আপনাকে নাম পরীক্ষা করতে এবং সমস্যা সমাধানের ঝামেলা বাঁচিয়ে রাখবে।

একটি ভিন্ন ওয়ার্কবুক থেকে দেখুন

দুইটির মধ্যে VLOOKUP করতেওয়ার্কবুক, বর্গাকার বন্ধনীতে ফাইলের নাম অন্তর্ভুক্ত করুন, তারপরে শীটের নাম এবং বিস্ময়বোধক বিন্দু।

উদাহরণস্বরূপ, জানুয়ারি শীটে A2:B6 পরিসরে A2 মান অনুসন্ধান করতে Sales_reports.xlsx ওয়ার্কবুক, এই সূত্রটি ব্যবহার করুন:

=VLOOKUP(A2, [Sales_reports.xlsx]Jan!$A$2:$B$6, 2, FALSE)

সম্পূর্ণ বিবরণের জন্য, অনুগ্রহ করে এক্সেলের অন্য ওয়ার্কবুক থেকে VLOOKUP দেখুন।

জুড়ে দেখুন। IFERROR সহ একাধিক শীট

যখন আপনাকে দুটির বেশি শীটের মধ্যে সন্ধান করতে হবে, তখন সবচেয়ে সহজ সমাধান হল IFERROR এর সাথে একত্রে VLOOKUP ব্যবহার করা। একের পর এক একাধিক ওয়ার্কশীট চেক করার জন্য অনেকগুলি IFERROR ফাংশন নেস্ট করার ধারণাটি হল: যদি প্রথম VLOOKUP প্রথম শীটে একটি মিল খুঁজে না পায়, তাহলে পরবর্তী শীটে অনুসন্ধান করুন এবং আরও অনেক কিছু৷

IFERROR(VLOOKUP(…), IFERROR(VLOOKUP(…), …, " পাওয়া যায়নি "))

এই পদ্ধতিটি বাস্তব জীবনের ডেটাতে কীভাবে কাজ করে তা দেখতে, আসুন নিম্নলিখিত উদাহরণটি বিবেচনা করি। নীচে সারাংশ টেবিলটি রয়েছে যা আমরা পশ্চিম এবং পূর্ব শীটে অর্ডার নম্বরটি সন্ধান করে আইটেমের নাম এবং পরিমাণগুলি পূরণ করতে চাই:

প্রথম, আমরা আইটেম টানতে যাচ্ছি। এর জন্য, আমরা VLOOKUP সূত্রকে East শীটে A2-এ অর্ডার নম্বর অনুসন্ধান করতে নির্দেশ দিই এবং কলাম B ( table_array A2:C6-এ ২য় কলাম) থেকে মান ফেরত দিই। যদি একটি সঠিক মিল পাওয়া না যায়, তাহলে পশ্চিম শীটে অনুসন্ধান করুন। যদি উভয় Vlookup ব্যর্থ হয়, তাহলে "না পাওয়া যায়" ফেরত দিন।

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 2, FALSE), "Not found"))

পরিমাণ ফেরত দিতে,কেবল কলামের সূচী নম্বর 3 এ পরিবর্তন করুন:

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 3, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 3, FALSE), "Not found"))

টিপ। প্রয়োজনে, আপনি বিভিন্ন VLOOKUP ফাংশনের জন্য বিভিন্ন টেবিল অ্যারে নির্দিষ্ট করতে পারেন। এই উদাহরণে, উভয় লুকআপ শীটে একই সংখ্যক সারি রয়েছে (A2:C6), কিন্তু আপনার ওয়ার্কশীট আকারে ভিন্ন হতে পারে।

একাধিক ওয়ার্কবুকে ভিলুকআপ করুন

দুই বা ততোধিক ওয়ার্কবুকের মধ্যে ভিলুকআপ করতে, ওয়ার্কবুকের নামটি বর্গাকার বন্ধনীতে আবদ্ধ করুন এবং শীটের নামের আগে রাখুন। উদাহরণস্বরূপ, এখানে আপনি কিভাবে দুটি ভিন্ন ফাইল ( Book1 এবং Book2 ) একটি একক সূত্র দিয়ে Vlookup করতে পারেন:

=IFERROR(VLOOKUP(A2, [Book1.xlsx]East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, [Book2.xlsx]West!$A$2:$C$6, 2, FALSE),"Not found"))

Vlookup মাল্টিপল কলামে কলাম ইন্ডেক্স নম্বরকে ডায়নামিক করুন

যে পরিস্থিতিতে আপনাকে অনেকগুলি কলাম থেকে ডেটা ফেরত দিতে হবে, col_index_num ডায়নামিক করে কিছু সময় বাঁচাতে পারে৷ এখানে কয়েকটি সমন্বয় করতে হবে:

• col_index_num আর্গুমেন্টের জন্য, COLUMNS ফাংশনটি ব্যবহার করুন যা একটি নির্দিষ্ট অ্যারেতে কলামের সংখ্যা প্রদান করে: COLUMNS($A$1 :B$1)। (সারি স্থানাঙ্ক আসলে কোন ব্যাপার নয়, এটি যেকোন সারি হতে পারে।)
• lookup_value আর্গুমেন্টে, কলাম রেফারেন্সটিকে $ চিহ্ন ($A2) দিয়ে লক করুন, তাই এটি থাকে অন্য কলামে সূত্র অনুলিপি করার সময় স্থির।

ফলস্বরূপ, আপনি এক ধরনের গতিশীল সূত্র পাবেন যা বিভিন্ন কলাম থেকে মিলিত মান বের করে, সূত্রটি কোন কলামে অনুলিপি করা হয়েছে তার উপর নির্ভর করে:

=IFERROR(VLOOKUP($A2, East!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), IFERROR(VLOOKUP($A2, West!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), "Not found"))

যখন B কলামে প্রবেশ করা হয়, COLUMNS($A$1:B$1)VLOOKUP কে টেবিল অ্যারেতে ২য় কলাম থেকে একটি মান ফেরত দিতে বলে 2-কে মূল্যায়ন করে।

কলাম C-তে কপি করা হলে (অর্থাৎ আপনি সূত্রটি B2 থেকে C2-তে টেনে এনেছেন), B$1 C$1 এ পরিবর্তিত হয় কারণ কলাম রেফারেন্স আপেক্ষিক. ফলস্বরূপ, COLUMNS($A$1:C$1) 3টি মূল্যায়ন করে VLOOKUP-কে 3য় কলাম থেকে একটি মান ফেরত দিতে বাধ্য করে৷

এই সূত্রটি 2 - 3টি লুকআপ শীটের জন্য দুর্দান্ত কাজ করে৷ আপনার যদি আরও বেশি থাকে, পুনরাবৃত্তিমূলক IFERRORগুলি খুব কষ্টকর হয়ে ওঠে। পরবর্তী উদাহরণটি একটু বেশি জটিল কিন্তু অনেক বেশি মার্জিত পদ্ধতির প্রদর্শন করে৷

ইনডাইরেক্ট দিয়ে একাধিক শীট দেখুন

এক্সেলের একাধিক শীটের মধ্যে VLOOKUP এবং VLOOKUP এর সংমিশ্রণ ব্যবহার করা আরও একটি উপায় INDIRECT ফাংশন। এই পদ্ধতির জন্য একটু প্রস্তুতির প্রয়োজন, কিন্তু শেষ পর্যন্ত, আপনার কাছে যেকোন সংখ্যক স্প্রেডশীটে Vlookup-এর আরও কমপ্যাক্ট সূত্র থাকবে।

শীট জুড়ে Vlookup-এর একটি জেনেরিক সূত্র নিম্নরূপ:

VLOOKUP( lookup_value , INDIRECT("'"&INDEX( Lookup_sheets , MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets &") '! lookup_range "), lookup_value )>0), 0)) & "'! table_array "), col_index_num , FALSE)

কোথায়:

• Lookup_sheets - একটি নামযুক্ত পরিসর যা লুকআপ শীটের নামগুলি নিয়ে গঠিত৷
• Lookup_value - the অনুসন্ধান করার মানমান।
• টেবিল_অ্যারে - লুকআপ শীটে ডেটা ব্যাপ্তি।
• Col_index_num - টেবিল অ্যারেতে কলামের সংখ্যা যা থেকে একটি মান ফেরত দিন।

সূত্রটি সঠিকভাবে কাজ করার জন্য, অনুগ্রহ করে নিম্নলিখিত সতর্কতাগুলি মনে রাখবেন:

• এটি একটি অ্যারে সূত্র, যা Ctrl + টিপে সম্পূর্ণ করতে হবে Shift + Enter কী একসাথে।
• সমস্ত শীটে অবশ্যই কলামের একই ক্রম থাকতে হবে।
• যেহেতু আমরা সব লুকআপ শীটের জন্য একটি টেবিল অ্যারে ব্যবহার করি, <12 উল্লেখ করুন>সবচেয়ে বড় পরিসর যদি আপনার শীটে বিভিন্ন সংখ্যক সারি থাকে।

কীভাবে শীট জুড়ে Vlookup করার সূত্রটি ব্যবহার করবেন

এক সময়ে একাধিক শীট Vlookup করতে, এইগুলি সম্পাদন করুন ধাপ:

1. আপনার ওয়ার্কবুকের কোথাও সব লুকআপ শীটের নাম লিখুন এবং সেই রেঞ্জের নাম দিন (আমাদের ক্ষেত্রে লুকআপ_শীট )।

<0

আপনার ডেটার জন্য জেনেরিক সূত্র সামঞ্জস্য করুন। এই উদাহরণে, আমরা হব:

• A2 মান ( lookup_value )
• পরিসরে A2:A6 ( lookup_range ) এর মধ্যে চারটি ওয়ার্কশীট ( পূর্ব , উত্তর , দক্ষিণ এবং পশ্চিম ), এবং
• কলাম B থেকে মানানসই মান টানুন, যেটি কলাম 2 ( col_index_num ) ডেটা পরিসরে A2:C6 ( টেবিল_অ্যারে )।

উপরের আর্গুমেন্টগুলির সাথে, সূত্রটি এই আকার নেয়:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

অনুগ্রহ করে লক্ষ্য করুন যে আমরা উভয় রেঞ্জ ($A$2:$A$6 এবং $A$2:$C$6) পরম সেল রেফারেন্স সহ লক করেছি।

এন্টার করুন সূত্রউপরের কক্ষে (এই উদাহরণে B2) এবং এটি সম্পূর্ণ করতে Ctrl + Shift + Enter টিপুন।

কলামের নিচে সূত্রটি অনুলিপি করতে ফিল হ্যান্ডেলটিতে ডাবল ক্লিক করুন বা টেনে আনুন।

যেমন ফলস্বরূপ, আমরা 4টি শীটে অর্ডার নম্বর দেখতে এবং সংশ্লিষ্ট আইটেমটি পুনরুদ্ধার করার সূত্র পেয়েছি। যদি একটি নির্দিষ্ট অর্ডার নম্বর পাওয়া না যায়, একটি #N/A ত্রুটি 14 সারির মত প্রদর্শিত হয়:

পরিমাণ ফেরত দিতে, col_index_num এ 3 দিয়ে 2 প্রতিস্থাপন করুন সারণির অ্যারের 3য় কলামে পরিমাণ হিসাবে যুক্তি:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE)

আপনি যদি স্ট্যান্ডার্ড #N/A ত্রুটির স্বরলিপি আপনার নিজের পাঠ্যের সাথে প্রতিস্থাপন করতে চান তবে মোড়ানো করুন IFNA ফাংশনের সূত্র:

=IFNA(VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE), "Not found")

ওয়ার্কবুকগুলির মধ্যে একাধিক শীট দেখুন

এই জেনেরিক সূত্রটি (বা এর যে কোনও পরিবর্তন)ও ব্যবহার করা যেতে পারে একটি ভিন্ন ওয়ার্কবুক -এ একাধিক শীট Vlookup করতে। এর জন্য, নীচের সূত্রে দেখানো মত INDIRECT-এর ভিতরে ওয়ার্কবুকের নাম সংযুক্ত করুন:

=IFNA(VLOOKUP($A2, INDIRECT("'[Book1.xlsx]" & INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'[Book1.xlsx]" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 2, FALSE), "Not found")

শীটগুলির মধ্যে দেখুন এবং একাধিক কলাম ফেরত দিন

যদি আপনি কয়েকটি থেকে ডেটা তুলতে চান কলাম, একটি মাল্টি-সেল অ্যারে সূত্র এটি একযোগে করতে পারে। এই ধরনের একটি সূত্র তৈরি করতে, col_index_num আর্গুমেন্টের জন্য একটি অ্যারে ধ্রুবক সরবরাহ করুন।

এই উদাহরণে, আমরা আইটেমের নাম (কলাম B) এবং পরিমাণ (কলাম C) ফেরত দিতে চাই, যা টেবিল অ্যারেতে যথাক্রমে ২য় এবং ৩য় কলাম। সুতরাং, প্রয়োজনীয় অ্যারে হল{2,3}।

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets &"'!$A$2:$C$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), {2,3}, FALSE)

একাধিক কক্ষে সঠিকভাবে সূত্র লিখতে, আপনাকে এটি করতে হবে:

• প্রথম সারিতে, পপুলেট করার জন্য সমস্ত সেল নির্বাচন করুন (আমাদের উদাহরণে B2:C2)।
• সূত্রটি টাইপ করুন এবং Ctrl + Shift + Enter টিপুন। এটি নির্বাচিত কক্ষগুলিতে একই সূত্র প্রবেশ করে, যা প্রতিটি কলামে একটি ভিন্ন মান প্রদান করবে।
• সূত্রটিকে অবশিষ্ট সারিতে টেনে আনুন।

এই সূত্রটি কীভাবে কাজ করে

যুক্তিটি আরও ভালভাবে বোঝার জন্য, আসুন এই মৌলিক সূত্রটিকে পৃথক ফাংশনে ভেঙে দেওয়া যাক:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

ভিতর থেকে কাজ করা, এখানে সূত্রটি কী করে:

COUNTIF এবং INDIRECT

সংক্ষেপে, INDIRECT সমস্ত লুকআপ শীটের জন্য রেফারেন্স তৈরি করে এবং COUNTIF লুকআপের ঘটনাগুলিকে গণনা করে প্রতিটি শীটে মান (A2):

--(COUNTIF( INDIRECT("'"&Lookup_sheets&"'!$A$2:$A$6"), $A2)>0)

আরো বিস্তারিতভাবে:

প্রথমে, আপনি পরিসরের নাম (লুকআপ_শীট) এবং রেঞ্জ রেফারেন্স ($A$2: $A$6), একটি বাহ্যিক রেফারেন্স তৈরি করার জন্য সঠিক স্থানে অ্যাপোস্ট্রোফ এবং বিস্ময়বোধক বিন্দু যোগ করুন এবং প্রাপ্ত টেক্সট স্ট্রিংটিকে INDIRECT ফাংশনে ফিড করুন যাতে ডায়নামিকভাবে লুকআপ শীটগুলি উল্লেখ করা যায়:

INDIRECT({"'East'!$A$2:$A$6"; "'South'!$A$2:$A$6"; "'North'!$A$2:$A$6"; "'West'!$A$2:$A$6"})

COUNTIF প্রতিটি লুকআপ শীটে A2:A6 রেঞ্জের প্রতিটি ঘর চেক করে মূলে A2-এর মানের বিপরীতে শীট এবং প্রতিটি শীটের জন্য মিলের গণনা প্রদান করে। আমাদের ডেটাসেটে, A2 (101) এর অর্ডার নম্বরটি পশ্চিম শীটে পাওয়া যায়, যানাম পরিসর, তাই COUNTIF এই অ্যারেটি প্রদান করে:

{0;0;0;1}

এরপর, আপনি উপরের অ্যারের প্রতিটি উপাদানের সাথে 0:

--({0; 0; 0; 1}>0)

এর সাথে তুলনা করেন TRUE (0-এর চেয়ে বড়) এবং FALSE (0-এর সমান) মানগুলির একটি অ্যারে, যা আপনি একটি ডবল ইউনারি (--) ব্যবহার করে 1 এবং 0 এর সাথে জোর করেন এবং ফলাফল হিসাবে নিম্নলিখিত অ্যারে পান:

{0; 0; 0; 1}

এই অপারেশনটি এমন একটি পরিস্থিতি পরিচালনা করার জন্য একটি অতিরিক্ত সতর্কতা যখন একটি লুকআপ শীটে লুকআপ মানের বেশ কয়েকটি ঘটনা থাকে, সেক্ষেত্রে COUNTIF 1 এর থেকে বেশি একটি গণনা প্রদান করবে, যখন আমরা কেবলমাত্র 1 এবং 0 চাই চূড়ান্ত অ্যারে (এক মুহূর্তের মধ্যে, আপনি কেন বুঝতে পারবেন)।

এই সমস্ত রূপান্তরের পরে, আমাদের সূত্রটি নিম্নরূপ দেখায়:

VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, {0;0;0;1} , 0)) &"'!$A$2:$C$6"), 2, FALSE)

INDEX এবং ম্যাচ

এই মুহুর্তে, একটি ক্লাসিক INDEX ম্যাচ সংমিশ্রণ ধাপে ধাপে:

INDEX(Lookup_sheets, MATCH(1, {0;0;0;1}, 0))

সঠিক মিলের জন্য কনফিগার করা MATCH ফাংশনটি (শেষ আর্গুমেন্টে 0) অ্যারেতে 1 মানটির সন্ধান করে { 0;0;0;1} এবং তার অবস্থান প্রদান করে, যা হল 4:

INDEX(Lookup_sheets, 4)

INDEX ফাংশনটি প্রত্যাবর্তিত সংখ্যা ব্যবহার করে সারি নম্বর আর্গুমেন্ট (row_num) হিসাবে MATCH দ্বারা, এবং Lookup_sheets নামক পরিসরে 4র্থ মান প্রদান করে, যা হল পশ্চিম ।

সুতরাং, সূত্রটি আরও হ্রাস করে থেকে:

VLOOKUP($A2, INDIRECT("'"&" West "&"'!$A$2:$C$6"), 2, FALSE)

VLOOKUP এবং INDIRECT

INDIRECT ফাংশন এটির ভিতরে টেক্সট স্ট্রিং প্রক্রিয়া করে:

INDIRECT("'"&"West"&"'!$A$2:$C$6")

এবং এটি রূপান্তরিত করে একটি রেফারেন্সে যা টেবিল_অ্যারে এর আর্গুমেন্টে যায়