Mae'r tiwtorial yn dangos sut i ddefnyddio'r ffwythiant VLOOKUP i gopïo data o daflen waith neu lyfr gwaith arall, Vlookup mewn mwy nag un dalennau, ac edrych i fyny yn ddeinamig i ddychwelyd gwerthoedd o wahanol ddalennau i gelloedd gwahanol.

0> Wrth chwilio am rywfaint o wybodaeth yn Excel, mae'n achos prin pan fo'r holl ddata ar yr un ddalen. Yn amlach, bydd yn rhaid i chi chwilio ar draws taflenni lluosog neu hyd yn oed gwahanol lyfrau gwaith. Y newyddion da yw bod Microsoft Excel yn darparu mwy nag un ffordd o wneud hyn, a'r newyddion drwg yw bod yr holl ffyrdd ychydig yn fwy cymhleth na fformiwla VLOOKUP safonol. Ond gyda dim ond ychydig o amynedd, byddwn yn cyfrifo nhw :)

Sut i VLOOKUP rhwng dwy ddalen

I ddechrau, gadewch i ni ymchwilio i achos symlaf - gan ddefnyddio VLOOKUP i copïo data o daflen waith arall. Mae'n debyg iawn i fformiwla VLOOKUP rheolaidd sy'n chwilio ar yr un daflen waith. Y gwahaniaeth yw eich bod yn cynnwys enw'r ddalen yn y ddadl table_array i ddweud wrth eich fformiwla ym mha daflen waith mae'r ystod chwilio wedi'i lleoli.

Mae'r fformiwla generig i VLOOKUP o ddalen arall fel a ganlyn:

VLOOKUP(lookup_value, Sheet!range, col_index_num, [range_lookup])

Fel enghraifft, gadewch i ni dynnu'r ffigurau gwerthiant o Ionawr adroddiad i Crynodeb dalen. Ar gyfer hyn, rydym yn diffinio'r dadleuon canlynol: Mae

• lookup_values yng ngholofn A ar y ddalen Crynodeb , ac rydym niVLOOKUP:

  VLOOKUP($A2, 'West'!$A$2:$C$6 , 2, FALSE)

  Yn olaf, mae'r fformiwla VLOOKUP safonol iawn hon yn chwilio am y gwerth A2 yng ngholofn gyntaf yr amrediad A2:C6 ar y ddalen West ac yn dychwelyd a cyfatebol o'r 2il golofn. Dyna ni!

  VLOOKUP deinamig i ddychwelyd data o ddalennau lluosog i mewn i gelloedd gwahanol

  Yn gyntaf, gadewch i ni ddiffinio beth yn union mae'r gair "deinamig" yn ei olygu yn y cyd-destun hwn a sut mae'r fformiwla hon yn mynd i fod yn wahanol i'r rhai blaenorol.

  Rhag ofn bod gennych chi dalpiau mawr o ddata yn yr un fformat sydd wedi'u rhannu dros daenlenni lluosog, efallai y byddwch am dynnu gwybodaeth o wahanol ddalennau i mewn i gelloedd gwahanol. Mae'r ddelwedd isod yn dangos y cysyniad:

  

  Yn wahanol i'r fformiwlâu blaenorol a adalwodd gwerth o ddalen benodol yn seiliedig ar ddynodwr unigryw, y tro hwn rydym yn edrych i dynnu gwerthoedd o sawl tudalen ar a amser.

  Mae dau ateb gwahanol ar gyfer y dasg hon. Yn y ddau achos, mae angen i chi wneud ychydig o waith paratoi a chreu ystodau a enwir ar gyfer celloedd data ym mhob taflen chwilio. Ar gyfer yr enghraifft hon, fe wnaethom ddiffinio'r ystodau canlynol:

  • East_Sales - A2:B6 ar y ddalen Ddwyreiniol
  • North_Sales - A2: B6 ar ddalen y Gogledd
  • South_Sales - A2:B6 ar ddalen y De
  • West_Sales - A2:B6 ar y ddalen Orllewinol

  VLOOKUP ac IFs nythu

  Os oes gennych nifer rhesymol o ddalennau i edrych i fyny, gallwch ddefnyddio swyddogaethau IF nythui ddewis y ddalen yn seiliedig ar y geiriau allweddol yn y celloedd rhagddiffiniedig (celloedd B1 trwy D1 yn ein hachos ni).

  Gyda'r gwerth chwilio yn A2, mae'r fformiwla fel a ganlyn:

  =VLOOKUP($A2, IF(B$1="east", East_Sales, IF(B$1="north", North_Sales, IF(B$1="south", South_Sales, IF(B$1="west", West_Sales)))), 2, FALSE)

  Wedi'i chyfieithu i'r Saesneg, mae'r rhan IF yn darllen:

  Os yw B1 yn Dwyrain , edrychwch yn yr ystod a enwir East_Sales ; os yw B1 yn Gogledd , edrychwch yn yr amrediad a enwir North_Sales ; os yw B1 De , edrychwch yn yr amrediad a enwir South_Sales ; ac os yw B1 yn West , edrychwch yn yr amrediad a enwir West_Sales .

  Mae'r amrediad a ddychwelwyd gan IF yn mynd i table_array o VLOOKUP, sy'n tynnu gwerth cyfatebol o'r 2il golofn ar y ddalen gyfatebol.

  Defnydd clyfar o gyfeiriadau cymysg ar gyfer y gwerth am-edrych ($A2 - colofn absoliwt a rhes gymharol) a phrawf rhesymegol IF (B$1 - colofn gymharol a rhes absoliwt) yn caniatáu copïo'r fformiwla i gelloedd eraill heb unrhyw newidiadau - mae Excel yn addasu'r cyfeiriadau yn awtomatig yn seiliedig ar leoliad cymharol rhes a cholofn.

  Felly, rydyn ni'n nodi'r fformiwla yn B2, yn ei gopïo'n iawn ac lawr i gynifer o golofnau a rhesi ag sydd eu hangen, a chael y canlyniad canlynol:

  

  VLOOKUP INDIRECT

  Wrth weithio gyda llawer o ddalennau, gallai lefelau nythu lluosog wneud y fformiwla hefyd hir ac anodd ei ddarllen. Ffordd llawer gwell yw creu ystod vlookup deinamig gyda chymorth INDIRECT:

  =VLOOKUP($A2, INDIRECT(B$1&"_Sales"), 2, FALSE)

  Yma, rydym yn cydgatenu'r cyfeiriad at y gell sy'n cynnwys arhan unigryw o'r ystod a enwir (B1) a'r rhan gyffredin (_Sales). Mae hyn yn cynhyrchu llinyn testun fel "East_Sales", y mae INDIRECT yn ei drosi i'r enw amrediad sy'n ddealladwy gan Excel.

  O'r herwydd, fe gewch fformiwla gryno sy'n gweithio'n hyfryd ar unrhyw nifer o ddalennau:

  <0

  Dyna sut i Vlookup rhwng taflenni a ffeiliau yn Excel. Diolch i chi am ddarllen a gobeithio eich gweld ar ein blog wythnos nesaf!

  Gweithlyfr ymarfer i'w lawrlwytho

  Enghreifftiau o ddalenni lluosog Vlookup (ffeil .xlsx)

  cyfeiriwch at y gell ddata gyntaf, sef A2.
• Table_array yw'r amrediad A2:B6 ar y ddalen Ion. I gyfeirio ato, rhowch enw'r ddalen ar flaen y cyfeirnod amrediad ac yna'r pwynt ebychnod: Ion!$A$2:$B$6.

  Sylwch ein bod yn cloi'r amrediad gyda chyfeirnodau cell absoliwt i'w atal rhag newid wrth gopïo'r fformiwla i gelloedd eraill.

  Col_index_num yw 2 oherwydd rydym am gopïo gwerth o golofn B, sef yr 2il golofn yn yr arae tablau.

• Range_lookup wedi ei osod i ANGHYWIR i chwilio am union gyfatebiaeth.

Wrth roi'r dadleuon at ei gilydd, rydym yn cael y fformiwla hon:

=VLOOKUP(A2, Jan!$A$2:$B$6, 2, FALSE)

Llusgwch y fformiwla i lawr y golofn a byddwch yn cael y canlyniad hwn:

Mewn a mewn modd tebyg, gallwch Vlookup data o'r Chwefror a Maw dalennau:

=VLOOKUP(A2, Feb!$A$2:$B$6, 2, FALSE)

=VLOOKUP(A2, Mar!$A$2:$B$6, 2, FALSE)

0> Awgrymiadau a nodiadau:

• Os yw enw'r ddalen yn cynnwys bylchau neu nodau nad ydynt yn wyddor , rhaid ei hamgáu mewn dyfynodau sengl, fel 'Gwerthiant Ionawr'!$A$2:$B$6 . Am ragor o wybodaeth, gweler Sut i gyfeirio at ddalen arall yn Excel.
• Yn lle teipio enw dalen yn uniongyrchol mewn fformiwla, gallwch newid i'r daflen waith chwilio a dewis yr amrediad yno. Bydd Excel yn mewnosod cyfeiriad gyda'r gystrawen gywir yn awtomatig, gan arbed y drafferth i chi wirio'r enw a datrys problemau.

Vlookup o lyfr gwaith gwahanol

I VLOOKUP rhwng daullyfrau gwaith, cynhwyswch enw'r ffeil mewn cromfachau sgwâr, ac yna enw'r ddalen a'r pwynt ebychnod.

Er enghraifft, i chwilio am werth A2 yn yr ystod A2:B6 ar Ionawr dalen yn y llyfr gwaith Sales_reports.xlsx , defnyddiwch y fformiwla hon:

=VLOOKUP(A2, [Sales_reports.xlsx]Jan!$A$2:$B$6, 2, FALSE)

Am fanylion llawn, gweler VLOOKUP o lyfr gwaith arall yn Excel.

Vlookup across dalennau lluosog gydag IFERROR

Pan fydd angen i chi edrych i fyny rhwng mwy na dwy ddalen, yr ateb hawsaf yw defnyddio VLOOKUP ar y cyd ag IFERROR. Y syniad yw nythu sawl swyddogaeth IFERROR i wirio taflenni gwaith lluosog fesul un: os nad yw'r VLOOKUP cyntaf yn dod o hyd i gyfatebiaeth ar y ddalen gyntaf, chwiliwch yn y ddalen nesaf, ac ati.

IFERROR(VLOOKUP(…), IFERROR(VLOOKUP(…), …, " Heb ei ganfod "))

I weld sut mae'r dull hwn yn gweithio ar ddata bywyd go iawn, gadewch i ni ystyried yr enghraifft ganlynol. Isod mae'r tabl Crynodeb yr ydym am ei lenwi ag enwau'r eitemau a'r symiau drwy edrych i fyny'r rhif archeb yn y taflenni Gorllewin a Dwyrain :

0>

Yn gyntaf, rydyn ni'n mynd i dynnu'r eitemau. Ar gyfer hyn, rydym yn cyfarwyddo fformiwla VLOOKUP i chwilio am rif y gorchymyn yn A2 ar y ddalen Dwyrain a dychwelyd y gwerth o golofn B (2il golofn yn table_array A2: C6). Os na cheir hyd i union gyfatebiaeth, chwiliwch yn y ddalen West . Os bydd y ddau Vlookups yn methu, dychwelwch "Heb ei ganfod".

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 2, FALSE), "Not found"))

I ddychwelyd y swm,newidiwch rif mynegai'r golofn i 3:

=IFERROR(VLOOKUP(A2, East!$A$2:$C$6, 3, FALSE), IFERROR(VLOOKUP(A2, West!$A$2:$C$6, 3, FALSE), "Not found"))

Awgrym. Os oes angen, gallwch nodi gwahanol araeau tabl ar gyfer gwahanol swyddogaethau VLOOKUP. Yn yr enghraifft hon, mae gan y ddwy daflen chwilio yr un nifer o resi (A2:C6), ond gall eich taflenni gwaith fod yn wahanol o ran maint.

Vlookup mewn llyfrau gwaith lluosog

I Vlookup rhwng dau neu fwy o lyfrau gwaith, amgaewch enw'r llyfr gwaith mewn cromfachau sgwâr a'i roi cyn enw'r ddalen. Er enghraifft, dyma sut y gallwch chi Vlookup mewn dwy ffeil wahanol ( Llyfr1 a Book2 ) gydag un fformiwla:

=IFERROR(VLOOKUP(A2, [Book1.xlsx]East!$A$2:$C$6, 2, FALSE), IFERROR(VLOOKUP(A2, [Book2.xlsx]West!$A$2:$C$6, 2, FALSE),"Not found"))

Gwnewch rif mynegai colofn yn ddeinamig i golofnau lluosog Vlookup

Mewn sefyllfa pan fydd angen i chi ddychwelyd data o sawl colofn, gallai gwneud col_index_num deinamig arbed peth amser i chi. Mae cwpl o addasiadau i'w gwneud:

• Ar gyfer y ddadl col_index_num , defnyddiwch y ffwythiant COLUMNS sy'n dychwelyd nifer y colofnau mewn arae penodedig: COLUMNS($A$1 :B$1). (Nid yw'r cyfesuryn rhes o bwys mewn gwirionedd, gall fod yn unrhyw res yn unig.)
• Yn y ddadl lookup_value , clowch gyfeirnod y golofn gyda'r arwydd $ ($A2), felly mae'n aros sefydlog wrth gopïo'r fformiwla i golofnau eraill.

O'r herwydd, fe gewch chi fath o fformiwla ddeinamig sy'n tynnu gwerthoedd cyfatebol o wahanol golofnau, yn dibynnu ar ba golofn mae'r fformiwla yn cael ei chopïo iddi:

=IFERROR(VLOOKUP($A2, East!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), IFERROR(VLOOKUP($A2, West!$A$2:$C$6, COLUMNS($A$1:B$1), FALSE), "Not found"))

Wrth roi yng ngholofn B, COLUMNS($A$1:B$1)yn gwerthuso i 2 gan ddweud wrth VLOOKUP am ddychwelyd gwerth o'r 2il golofn yn yr arae tabl.

Wrth gopïo i golofn C (h.y. rydych wedi llusgo'r fformiwla o B2 i C2), mae B$1 yn newid i C$1 oherwydd mae cyfeirnod y golofn yn gymharol. O ganlyniad, mae COLUMNS($A$1:C$1) yn gwerthuso i 3 gan orfodi VLOOKUP i ddychwelyd gwerth o'r 3edd golofn.

Mae'r fformiwla hon yn gweithio'n wych ar gyfer 2 - 3 tudalen chwilio. Os oes gennych fwy, mae IFERRORs ailadroddus yn mynd yn rhy feichus. Mae'r enghraifft nesaf yn dangos ymagwedd ychydig yn fwy cymhleth ond yn llawer mwy cain.

Vlookup taflenni lluosog gyda INDIRECT

Un ffordd arall i Vlookup rhwng taflenni lluosog yn Excel yw defnyddio cyfuniad o VLOOKUP a Swyddogaethau INDIRECT. Mae angen ychydig o waith paratoi ar gyfer y dull hwn, ond yn y diwedd, bydd gennych fformiwla fwy cryno i Vlookup mewn unrhyw nifer o daenlenni.

Mae fformiwla generig i Vlookup ar draws dalennau fel a ganlyn:

VLOOKUP( gwerth_lookup , INDIRECT("'"&INDEX( Lookup_sheets , MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets &" '! lookup_range "), lookup_value )>0), 0)) & "'! table_array "), col_index_num , ANGHYWIR)

Lle:

• Lookup_sheets - ystod a enwir yn cynnwys enwau'r dalennau chwilio.
• Lookup_value - y gwerth i chwilio amdano.
• Lookup_range - yr amrediad colofn yn y dalennau chwilio ble i chwilio am y chwiliogwerth.
• Tabl_arae - yr amrediad data yn y dalennau chwilio.
• Col_index_num - rhif y golofn yn yr arae tabl i dychwelyd gwerth.

Er mwyn i'r fformiwla weithio'n gywir, cofiwch y cafeatau canlynol:

• Fformiwla arae yw hi, y mae'n rhaid ei chwblhau trwy wasgu Ctrl + Shift + Rhowch y bysellau gyda'i gilydd.
• Rhaid i bob tudalen fod â'r un drefn o golofnau .
• Wrth i ni ddefnyddio un arae tabl ar gyfer pob tudalen chwilio, nodwch y ystod fwyaf os oes gan eich dalennau niferoedd gwahanol o resi.

Sut i ddefnyddio'r fformiwla i Vlookup ar draws dalennau

I Vlookup dalennau lluosog ar y tro, gwnewch y rhain camau:

1. Ysgrifennwch holl enwau'r dalennau chwilio rhywle yn eich llyfr gwaith ac enwch yr ystod honno ( Taflenni_Lookup yn ein hachos ni).

<0

Addaswch y fformiwla generig ar gyfer eich data. Yn yr enghraifft hon, byddwn yn:

• chwilio am werth A2 ( lookup_value )
• yn yr ystod A2:A6 ( lookup_range ) yn pedair taflen waith ( Dwyrain , Gogledd , De a Gorllewin ), a
• tynnu gwerthoedd cyfatebol o golofn B, sef colofn 2 ( col_index_num ) yn yr ystod data A2:C6 ( table_array ).

Gyda'r dadleuon uchod, mae'r fformiwla yn cymryd y siâp hwn:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

Sylwch ein bod yn cloi'r ddwy ystod ($A$2:$A$6 a $A$2:$C$6) gyda chyfeiriadau cell absoliwt.

Rhowch y fformiwlayn y gell uchaf (B2 yn yr enghraifft hon) a gwasgwch Ctrl + Shift + Enter i'w chwblhau.

Cliciwch ddwywaith neu llusgwch y ddolen llenwi i gopïo'r fformiwla i lawr y golofn.

Fel y canlyniad, mae gennym y fformiwla i chwilio am y rhif archeb mewn 4 tudalen ac adalw'r eitem gyfatebol. Os na ddarganfyddir rhif archeb penodol, dangosir gwall # N/A fel yn rhes 14:

I ddychwelyd y swm, rhowch 3 yn lle 2 yn y col_index_num Arg gan fod y symiau yn nhrydedd golofn yr arae tabl:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE)

Os hoffech ddisodli'r nodiant gwall safonol #D/A gyda'ch testun eich hun, amlapiwch y fformiwla i'r ffwythiant IFNA:

=IFNA(VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 3, FALSE), "Not found")

Vlookup taflenni lluosog rhwng llyfrau gwaith

Gellir defnyddio'r fformiwla generig hon (neu ei amrywiad) hefyd i ddalenni lluosog Vlookup mewn gwahanol lyfr gwaith . Ar gyfer hyn, cydgatenwch enw'r llyfr gwaith y tu mewn i INDIRECT fel y dangosir yn y fformiwla isod:

=IFNA(VLOOKUP($A2, INDIRECT("'[Book1.xlsx]" & INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'[Book1.xlsx]" & Lookup_sheets & "'!$A$2:$A$6"), $A2)>0), 0)) & "'!$A$2:$C$6"), 2, FALSE), "Not found")

Vlookup rhwng dalennau a dychwelyd colofnau lluosog

Os ydych am dynnu data o sawl un colofnau, gall fformiwla arae aml-gell wneud hynny ar yr un pryd. I greu fformiwla o'r fath, darparwch gysonyn arae ar gyfer y arg col_index_num .

Yn yr enghraifft hon, rydym am ddychwelyd enwau'r eitemau (colofn B) a'r symiau (colofn C), sy'n yw'r 2il a'r 3edd golofn yn yr arae tablau, yn y drefn honno. Felly, yr amrywiaeth gofynnol yw{2,3}.

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets &"'!$A$2:$C$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), {2,3}, FALSE)

I fewnbynnu'r fformiwla yn gywir mewn celloedd lluosog, dyma beth sydd angen i chi ei wneud:

• Yn y rhes gyntaf, dewiswch yr holl gelloedd i'w llenwi (B2:C2 yn ein hesiampl).
• Teipiwch y fformiwla a gwasgwch Ctrl + Shift + Enter . Mae hwn yn mynd i mewn i'r un fformiwla yn y celloedd dethol, a fydd yn dychwelyd gwerth gwahanol ym mhob colofn.
• Llusgwch y fformiwla i lawr i'r rhesi sy'n weddill.

Sut mae'r fformiwla hon yn gweithio

I ddeall y rhesymeg yn well, gadewch i ni dorri'r fformiwla sylfaenol hon i lawr i'r ffwythiannau unigol:

=VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, --(COUNTIF(INDIRECT("'"& Lookup_sheets&"'!$A$2:$A$6"), $A2)>0), 0)) &"'!$A$2:$C$6"), 2, FALSE)

0>Gan weithio o'r tu mewn allan, dyma beth mae'r fformiwla yn ei wneud:

COUNTIF ac INDIRECT

Yn gryno, mae INDIRECT yn adeiladu'r cyfeiriadau ar gyfer pob tudalen chwilio, ac mae COUNTIF yn cyfrif digwyddiadau'r chwilio gwerth (A2) ym mhob dalen:

--(COUNTIF( INDIRECT("'"&Lookup_sheets&"'!$A$2:$A$6"), $A2)>0)

Yn fwy manwl:

Yn gyntaf, rydych chi'n cydgysylltu enw'r amrediad (Lookup_sheets) a chyfeirnod yr ystod ($A$2: $A$6), gan ychwanegu collnodau a'r pwynt ebychnod yn y mannau cywir i wneud cyfeiriad allanol, a bwydo'r llinyn testun canlyniadol i'r ffwythiant INDIRECT i gyfeirio'n ddeinamig at y taflenni chwilio:

INDIRECT({"'East'!$A$2:$A$6"; "'South'!$A$2:$A$6"; "'North'!$A$2:$A$6"; "'West'!$A$2:$A$6"})

Mae COUNTIF yn gwirio pob cell yn yr ystod A2:A6 ar bob dalen chwilio yn erbyn y gwerth yn A2 ar y brif dalen ac yn dychwelyd y cyfrif o gyfatebiaethau ar gyfer pob dalen. Yn ein set ddata, mae'r rhif trefn yn A2 (101) i'w gael yn y ddalen West , sef 4ydd yn yamrediad a enwir, felly mae COUNTIF yn dychwelyd yr arae hon:

{0;0;0;1}

Nesaf, rydych yn cymharu pob elfen o'r arae uchod gyda 0:

--({0; 0; 0; 1}>0)

Mae hyn yn ildio amrywiaeth o werthoedd GWIR (mwy na 0) a ANGHYWIR (sy'n hafal i 0), rydych chi'n eu gorfodi i 1's a 0's trwy ddefnyddio unary dwbl (--), a chewch yr arae ganlynol fel canlyniad:

{0; 0; 0; 1}

Mae'r gweithrediad hwn yn rhagofal ychwanegol i ymdrin â sefyllfa pan fo dalen chwilio yn cynnwys sawl digwyddiad o'r gwerth am-edrych, ac os felly byddai COUNTIF yn dychwelyd cyfrif sy'n fwy nag 1, tra rydym eisiau dim ond 1 a 0 yn y arae terfynol (mewn eiliad, byddwch yn deall pam).

Ar ôl yr holl drawsnewidiadau hyn, mae ein fformiwla yn edrych fel a ganlyn:

VLOOKUP($A2, INDIRECT("'"&INDEX(Lookup_sheets, MATCH(1, {0;0;0;1} , 0)) &"'!$A$2:$C$6"), 2, FALSE)

MYNEGAI a MATCH

Ar y pwynt hwn, mae cyfuniad MYNEGOL MATCH clasurol yn camu i mewn:

INDEX(Lookup_sheets, MATCH(1, {0;0;0;1}, 0))

Mae'r ffwythiant MATCH sydd wedi'i ffurfweddu ar gyfer cyfatebiaeth union (0 yn y ddadl olaf) yn edrych am y gwerth 1 yn yr arae { 0; 0; 0; 1} ac yn dychwelyd ei safle, sef 4:

INDEX(Lookup_sheets, 4)

Mae'r ffwythiant INDEX yn defnyddio'r rhif a ddychwelwyd gan MATCH fel yr arg rhif rhes (row_num), ac yn dychwelyd y 4ydd gwerth yn yr amrediad a enwir Lookup_sheets , sef Gorllewin .

Felly, mae'r fformiwla'n lleihau ymhellach i:

VLOOKUP($A2, INDIRECT("'"&" West "&"'!$A$2:$C$6"), 2, FALSE)

VLOOKUP ac INDIRECT

Mae'r ffwythiant INDIRECT yn prosesu'r llinyn testun y tu mewn iddo:

INDIRECT("'"&"West"&"'!$A$2:$C$6")

Ac yn ei drawsnewid i mewn i gyfeiriad sy'n mynd i'r arg table_array o