Leer formules en formulevrije manieren om spaties te trimmen, speciale symbolen te verwijderen (zelfs de eerste/laatste N-tekens) en dezelfde tekststrings voor/na bepaalde tekens uit meerdere cellen tegelijk.

Het verwijderen van hetzelfde deel van de tekst uit meerdere cellen tegelijk kan net zo belangrijk en lastig zijn als het toevoegen ervan. Zelfs als u sommige manieren kent, zult u in de blogpost van vandaag zeker nieuwe manieren vinden. Ik deel tal van functies en hun kant-en-klare formules en zoals altijd bewaar ik de gemakkelijkste - formulevrij - voor het laatst ;)

Formules voor Google Sheets om tekst uit cellen te verwijderen

Ik ga beginnen met de standaardfuncties voor Google Sheets die uw tekststrings en tekens uit cellen verwijderen. Er is geen universele functie voor dit, dus ik zal verschillende formules en hun combinaties geven voor verschillende gevallen.

Google Sheets: spaties verwijderen

Spaties kunnen gemakkelijk in cellen terechtkomen na het importeren of als meerdere gebruikers het blad tegelijkertijd bewerken. Extra spaties komen zelfs zo vaak voor dat Google Sheets een speciaal hulpmiddel heeft om alle spaties te verwijderen.

Selecteer gewoon alle Google Sheets-cellen waar u witruimte wilt verwijderen en kies Data> Trim whitespace in het spreadsheet menu:

Als u op de optie klikt, worden alle voorloop- en naloopspaties in de selectie volledig weggenomen, terwijl alle extra spaties tussen de gegevens worden teruggebracht tot één:

Andere speciale tekens verwijderen uit tekststrings in Google Sheets

Helaas biedt Google Sheets geen tool om andere tekens dan spaties te 'trimmen'. Je moet het hier doen met formules.

Tip. Of gebruik in plaats daarvan ons hulpmiddel - Power Tools maakt uw bereik vrij van alle tekens die u met een klik opgeeft, inclusief spaties.

Hier heb ik aangesproken met hashtags voor de appartementnummers en telefoonnummers met streepjes en haakjes ertussen:

Ik zal formules gebruiken om die speciale tekens te verwijderen.

De functie SUBSTITUTE helpt me daarbij. Die wordt normaal gebruikt om een teken te vervangen door een ander, maar je kunt dat in je voordeel ombuigen en de ongewenste tekens vervangen door... nou ja, niets :) Met andere woorden, verwijderen.

Laten we eens kijken welk argument de functie nodig heeft:

• tekst_naar_zoeken is ofwel de te verwerken tekst ofwel een cel die die tekst bevat. Vereist.
• zoeken is dat karakter dat je wilt vinden en verwijderen. Vereist.
• vervangen door - een karakter dat u wilt invoegen in plaats van het ongewenste symbool. Vereist.
• voorval_nummer - als er meerdere instanties zijn van het karakter dat u zoekt, kunt u hier aangeven welke moet worden vervangen. Het is volledig optioneel, en als u dit argument weglaat, worden alle instanties vervangen door iets nieuws ( vervangen voor ).

Dus laten we spelen. Ik moet een hashtag vinden ( # ) in A1 en vervang het door "niets" dat in spreadsheets wordt gemarkeerd met dubbele aanhalingstekens ( "" ). Met dat alles in gedachten kan ik de volgende formule opstellen:

=SUBSTITUTE(A1,"#","")

Tip. De hashtag staat ook tussen dubbele aanhalingstekens omdat dit de manier is waarop je tekststrings in Google Sheets-formules moet noemen.

Kopieer dan deze formule in de kolom als Google Sheets dat niet automatisch doet, en je krijgt je adressen zonder de hashtags:

Maar hoe zit het met die streepjes en haakjes? Moet u extra formules maken? Helemaal niet! Als u meerdere SUBSTITUTE-functies in één Google Sheets-formule nestelt, verwijdert u al deze tekens uit elke cel:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1,"#",""),"(",""),"",""),"-","").

Deze formule verwijdert tekens één voor één en elke SUBSTITUTE, beginnend in het midden, wordt het bereik waarnaar moet worden gekeken voor de volgende SUBSTITUTE:

Tip. U kunt dit bovendien in een ArrayFormula verpakken en de hele kolom in één keer behandelen. In dat geval verandert u de celverwijzing ( A1 ) aan uw gegevens in kolom ( A1:A7 ) ook:

=ArrayFormula(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1:A7,"#",""),"(",""),"",""),"-","")).

Specifieke tekst verwijderen uit cellen in Google Sheets

Hoewel je de eerder genoemde SUBSTITUTE-functie voor Google Sheets kunt gebruiken om tekst uit cellen te verwijderen, wil ik ook een andere functie laten zien - REGEXREPLACE.

De naam is een acroniem van 'regular expression replace'. En ik ga de reguliere expressies gebruiken om de te verwijderen strings te zoeken en te vervangen door ' niets" ( "" ).

Tip. Als je niet geïnteresseerd bent in het gebruik van reguliere expressies, beschrijf ik aan het eind van deze blogpost een veel eenvoudigere manier.

Tip. Als u op zoek bent naar manieren om duplicaten in Google Sheets te vinden en te verwijderen, bezoek dan deze blogpost. REGEXREPLACE(tekst, reguliere_expressie, vervanging)

Zoals je ziet zijn er drie argumenten voor de functie:

• tekst - is waar je de te verwijderen tekststring zoekt. Het kan de tekst zelf zijn tussen dubbele aanhalingstekens of een verwijzing naar een cel/bereik met tekst.
• regelmatige_expressie - uw zoekpatroon dat bestaat uit verschillende tekencombinaties. U zoekt naar alle tekenreeksen die met dit patroon overeenkomen. Dit argument is waar al het plezier gebeurt, als ik het zo mag zeggen.
• vervanging - een nieuwe gewenste tekststring.

Stel dat mijn cellen met gegevens ook de naam van het land bevatten ( US ) als verschillende plaatsen in de cellen:

Hoe zal REGEXREPLACE me helpen het te verwijderen?

=REGEXREPLACE(A1,"(.*)US(.*)","$1 $2")

Dit is hoe de formule precies werkt:

• scant het de inhoud van de cel A1
• voor overeenkomsten met dit masker: "(.*)US(.*)"

  Dit masker vertelt de functie te zoeken naar de US ongeacht het aantal andere tekens dat voorafgaat aan (.*) of volg (.*) de naam van het land.

  En het hele masker wordt tussen dubbele aanhalingstekens gezet volgens de functie-eisen :)

• het laatste argument - "$1 $2" - is wat ik in plaats daarvan wil krijgen. $1 en $2 vertegenwoordigen elk een van die 2 groepen karakters - (.*) - van het vorige argument. U moet die groepen in het derde argument op deze manier vermelden, zodat de formule alles kan teruggeven wat mogelijk voor en na de US

  Wat betreft de US zelf, ik vermeld het gewoon niet in het 3e argument - dat wil zeggen, ik wil alles terug van A1 zonder de US .

Tip. Er is een speciale pagina die u kunt raadplegen om verschillende reguliere expressies te maken en te zoeken naar de tekst in verschillende posities van cellen.

Tip. Wat die resterende komma's betreft, de hierboven beschreven SUBSTITUTE-functie zal helpen die weg te werken ;) U kunt zelfs REGEXREPLACE omsluiten met SUBSTITUTE en alles oplossen met één formule:

=SUBSTITUTE(REGEXREPLACE(A1,"(.*)US(.*)","$1 $2"),",","")

Verwijder tekst voor/na bepaalde tekens in alle geselecteerde cellen

Voorbeeld 1. REGEXREPLACE-functie voor Google Sheets

Om alles voor en na bepaalde tekens weg te werken, helpt REGEXREPLACE ook. Vergeet niet dat de functie 3 argumenten vereist:

En, zoals ik hierboven al zei bij de introductie van de functie, is het de tweede die je correct moet gebruiken, zodat de functie weet wat hij moet vinden en verwijderen.

Dus hoe kan ik de adressen verwijderen en alleen de telefoonnummers in de cellen houden?

Hier is de formule die ik zal gebruiken:

=REGEXREPLACE(A1,".*\n.*(\+.*)","$1")

• Hier is de reguliere expressie die ik in dit geval gebruik: ".*\n.*(\+.*)"

  In het eerste deel - .*\n.* - Ik gebruik backslash+n om aan te geven dat mijn cel meer dan één rij heeft. Dus ik wil dat de functie alles voor en na die regeleinde verwijdert (inclusief die).

  Het tweede deel dat tussen haakjes staat (\+.*) zegt dat ik het plusteken en alles wat erop volgt intact wil houden. Ik neem dit deel tussen haakjes om het te groeperen en in gedachten te houden voor later.

  Tip. De backslash wordt gebruikt vóór de plus om er een teken van te maken waarnaar je zoekt. Zonder de backslash zou de plus slechts een deel van de uitdrukking zijn dat staat voor enkele andere tekens (zoals bijvoorbeeld een sterretje).

• Het laatste argument - $1 - zorgt ervoor dat de functie alleen die groep van het tweede argument teruggeeft: het plusteken en alles wat daarop volgt. (\+.*) .

Op dezelfde manier kunt u alle telefoonnummers verwijderen, maar de adressen behouden:

=REGEXREPLACE(A1,"(.*\n).*","$1")

Alleen deze keer vertel je de functie om alles voor het regeleinde te groeperen (en terug te sturen) en de rest te verwijderen:

Voorbeeld 2. RIGHT+LEN+FIND

Er zijn nog een paar functies in Google Sheets waarmee je de tekst vóór een bepaald teken kunt verwijderen. Dat zijn RECHTS, LEN en FIND.

Opmerking: deze functies helpen alleen als de te bewaren records dezelfde lengte hebben, zoals telefoonnummers in mijn geval. Als dat niet zo is, gebruik dan REGEXREPLACE of, nog beter, het eenvoudiger hulpmiddel dat aan het eind wordt beschreven.

Als ik dit trio in een bepaalde volgorde gebruik, krijg ik hetzelfde resultaat en verwijder ik de hele tekst vóór een teken - een plusteken:

=RIGHT(A1,(LEN(A1)-(FIND("+",A1)-1)))

Laat me uitleggen hoe deze formule werkt:

• FIND("+",A1)-1 zoekt het positienummer van het plusteken in A1 ( 24 ) en trekt er 1 af zodat het totaal niet de plus zelf omvat: 23 .
• LEN(A1)-(FIND("+",A1)-1) controleert het totale aantal tekens in A1 ( 40 ) en trekt er 23 van af (geteld door FIND): 17 .
• En dan geeft RIGHT 17 tekens terug vanaf het einde (rechts) van A1.

Helaas zal deze manier in mijn geval niet veel helpen om de tekst na het regeleinde te verwijderen (telefoonnummers wissen en adressen bewaren), omdat de adressen van verschillende lengte zijn.

Nou, dat geeft niet. Het gereedschap aan het eind doet dit werk toch beter ;)

De eerste/laatste N-tekens uit tekenreeksen verwijderen in Google Sheets

Wanneer u een bepaald aantal verschillende tekens aan het begin of het einde van een cel moet verwijderen, helpen REGEXREPLACE en RIGHT/LEFT+LEN ook.

Opmerking: omdat ik deze functies hierboven al heb geïntroduceerd, zal ik dit punt kort houden en enkele kant-en-klare formules geven. Of voel je vrij om naar de gemakkelijkste oplossing te springen die helemaal aan het eind wordt beschreven.

Dus, hoe kan ik de codes van deze telefoonnummers wissen? Of, met andere woorden, de eerste 9 tekens uit de cellen verwijderen:

• Gebruik REGEXREPLACE. Maak een reguliere uitdrukking die alles tot en met het 9e teken vindt en verwijdert (inclusief dat 9e teken):

  =REGEXREPLACE(A1,"(.{9})(.*)","$2")

  .

  Tip. Om de laatste N tekens te verwijderen, verwisselt u de groepen in de reguliere expressie:

  =REGEXREPLACE(A1,"(.*)(.{9})","$1")

• RIGHT/LEFT+LEN telt ook het aantal te verwijderen tekens en geeft het resterende deel terug van respectievelijk het einde of het begin van een cel:

  =RIGHT(A1,LEN(A1)-9)

  

  Tip. Om de laatste 9 tekens uit de cellen te verwijderen, vervangt u RECHTS door LINKS:

  =LEFT(A1,LEN(A1)-9)

• Tenslotte is er de functie REPLACE, die de 9 karakters vanaf links vervangt door niets ( "" ):

  =REPLACE(A1,1,9,"")

  

  Opmerking. Omdat REPLACE een startpositie vereist om de tekst te verwerken, zal het niet werken als u N tekens van het einde van een cel moet verwijderen.

Formulevrije manier om specifieke tekst in Google Sheets te verwijderen - Power Tools add-on

Functies en alles is goed wanneer je tijd te doden hebt. Maar weet je dat er een speciale tool is die alle bovengenoemde manieren omarmt en het enige wat je hoeft te doen is het gewenste keuzerondje selecteren? :) Geen formules, geen extra kolommen - je kunt je geen betere sidekick wensen ;D

Je hoeft me niet op mijn woord te geloven, installeer Power Tools en zie het zelf:

1. Met de eerste groep kunt u meerdere substrings of afzonderlijke tekens verwijderen vanaf elke positie in alle geselecteerde cellen tegelijk:

Een ander hulpmiddel van Power Tools verwijdert tijd- en datumeenheden uit tijdstempels. Het heet Split Date & Time:

Wat heeft het splitsingsgereedschap te maken met het verwijderen van tijd- en datumeenheden? Wel, om tijd uit tijdstempels te verwijderen, selecteert u Datum omdat het een onderdeel is dat je wilt behouden en ook wilt afvinken Brongegevens vervangen net als op de schermafbeelding hierboven.

De tool haalt de datumeenheid eruit en vervangt daarmee de hele tijdstempel. Met andere woorden, deze add-on voor Google Sheets verwijdert de tijdseenheid uit de tijdstempel:

U kunt over al deze en meer dan 30 andere tijdbesparingen voor spreadsheets beschikken door de add-on uit de Google Store te installeren. De eerste 30 dagen zijn volledig gratis en volledig functioneel, zodat u de tijd hebt om te beslissen of het een investering waard is.

Als je vragen hebt over een onderdeel van deze blogpost, dan zie ik je hieronder in het commentaargedeelte!