Bagaimana mengubah huruf kolom menjadi angka di Excel

Michael Brown

01-06-2023 Excel
  • Bagikan Ini
Michael Brown

Tutorial ini berbicara tentang cara mengembalikan nomor kolom di Excel menggunakan rumus dan cara memberi nomor kolom secara otomatis.

Minggu lalu, kita membahas rumus paling efektif untuk mengubah nomor kolom menjadi alfabet. Jika Anda memiliki tugas yang berlawanan untuk dilakukan, di bawah ini adalah teknik terbaik untuk mengubah nama kolom menjadi angka.

    Cara mengembalikan nomor kolom di Excel

    Untuk mengonversi huruf kolom menjadi nomor kolom di Excel, Anda dapat menggunakan rumus umum ini:

    KOLOM (TIDAK LANGSUNG( surat & "1"))

    Misalnya, untuk mendapatkan jumlah kolom F, rumusnya adalah:

    =COLUMN(INDIRECT("F"& "1"))

    Dan inilah cara Anda dapat mengidentifikasi nomor kolom dengan input huruf dalam sel yang telah ditentukan sebelumnya (A2 hingga A7 dalam kasus kami):

    =COLUMN(INDIRECT(A2& "1"))

    Masukkan rumus di atas di B2, seret ke sel lain di kolom, dan Anda akan mendapatkan hasil ini:

    Bagaimana formula ini bekerja:

    Pertama, Anda membuat string teks yang mewakili referensi sel. Untuk ini, Anda menggabungkan huruf dan angka 1. Kemudian, Anda menyerahkan string ke fungsi INDIRECT untuk mengubahnya menjadi referensi Excel yang sebenarnya. Terakhir, Anda meneruskan referensi ke fungsi COLUMN untuk mendapatkan nomor kolom.

    Cara mengonversi huruf kolom ke angka (rumus non-volatile)

    Menjadi fungsi yang mudah menguap, INDIRECT dapat memperlambat Excel Anda secara signifikan jika digunakan secara luas di buku kerja. Untuk menghindarinya, Anda dapat mengidentifikasi nomor kolom menggunakan alternatif non-volatile yang sedikit lebih kompleks:

    MATCH ( surat & "1", ADDRESS(1, COLUMN($1:$1), 4), 0)

    Ini berfungsi dengan sempurna dalam array dinamis Excel (365 dan 2021). Dalam versi yang lebih lama, Anda harus memasukkannya sebagai rumus array (Ctrl + Shift + Enter) agar berfungsi.

    Contohnya:

    =MATCH(A2& "1", ADDRESS(1, COLUMN($1:$1), 4), 0)

    Atau Anda dapat menggunakan rumus non-larik ini di semua versi Excel:

    =MATCH(A2& "1", INDEX(ADDRESS(1, INDEX(COLUMN($1:$1), ), 4), ), 0)

    Bagaimana formula ini bekerja:

    Pertama, Anda menggabungkan huruf di A2 dan nomor baris "1" untuk membuat referensi gaya "A1" standar. Dalam contoh ini, kita memiliki huruf "A" di A2, sehingga string yang dihasilkan adalah "A1".

    Selanjutnya, Anda mendapatkan larik string yang mewakili semua alamat sel di baris pertama, dari "A1" hingga "XFD1". Untuk ini, Anda menggunakan fungsi COLUMN($1:$1), yang menghasilkan urutan nomor kolom, dan meneruskan larik tersebut ke fungsi column_num argumen dari fungsi ADDRESS:

    ALAMAT(1, {1,2,3,4,5,..., 16384), 4)

    Mengingat bahwa row_num (argumen pertama) diatur ke 1 dan abs_num (argumen ke-3) disetel ke 4 (artinya Anda menginginkan referensi relatif), fungsi ADDRESS memberikan larik ini:

    {"A1","B1","C1","D1",…,"XFD1"}

    Terakhir, Anda membuat rumus MATCH yang mencari string gabungan dalam larik di atas dan mengembalikan posisi nilai yang ditemukan, yang sesuai dengan nomor kolom yang Anda cari:

    MATCH("A1", {"A1", "B1", "C1", "D1",..., "XFD1"}, 0)

    Mengubah huruf kolom menjadi angka menggunakan fungsi kustom

    "Kesederhanaan adalah kecanggihan tertinggi," kata seniman dan ilmuwan besar Leonardo da Vinci. Untuk mendapatkan nomor kolom dari sebuah huruf dengan cara yang mudah, Anda bisa membuat fungsi kustom Anda sendiri.

    Sepenuhnya sejalan dengan prinsip di atas, kode fungsi ini sesederhana mungkin:

    Public Function ColumnNumber(col_letter As String ) As Long ColumnNumber = Columns(col_letter).Column End Function

    Sisipkan kode di editor VBA Anda seperti yang dijelaskan di sini, dan fungsi baru Anda bernama ColumnNumber siap digunakan.

    Fungsi ini hanya memerlukan satu argumen, col_letter yang merupakan huruf kolom yang akan dikonversi menjadi angka:

    ColumnLetter(col_letter)

    Rumus Anda yang sebenarnya adalah sebagai berikut:

    =ColumnNumber(A2)

    Jika Anda membandingkan hasil yang dikembalikan oleh fungsi kustom kami dan fungsi asli Excel, Anda akan memastikan bahwa hasilnya persis sama:

    Kembalikan nomor kolom dari sel tertentu

    Untuk mendapatkan nomor kolom sel tertentu, cukup gunakan fungsi COLUMN:

    COLUMN( cell_address )

    Misalnya, untuk mengidentifikasi nomor kolom sel B3, rumusnya adalah:

    =COLUMN(B3)

    Jelas, hasilnya adalah 2.

    Dapatkan huruf kolom dari sel saat ini

    Untuk mengetahui nomor kolom sel saat ini, gunakan fungsi COLUMN () dengan argumen kosong, sehingga mengacu pada sel tempat rumus berada:

    =COLUMN()

    Cara menampilkan nomor kolom di Excel

    Secara default, Excel menggunakan gaya referensi A1 dan melabeli judul kolom dengan huruf dan baris dengan angka. Untuk mendapatkan kolom berlabel angka, ubah gaya referensi default dari A1 ke R1C1. Begini caranya:

    1. Di Excel Anda, klik Berkas > Opsi .
    2. Dalam Opsi Excel kotak dialog, pilih Rumus di panel kiri.
    3. Di bawah Bekerja dengan formula , periksa Gaya referensi R1C1 kotak, dan klik OK .

    Label kolom akan segera berubah dari huruf ke angka:

    Harap diperhatikan, bahwa memilih opsi ini tidak hanya akan mengubah label kolom - alamat sel juga akan berubah dari referensi A1 ke R1C1, di mana R berarti "baris" dan C berarti "kolom". Contohnya, R1C1 mengacu ke sel di baris 1 kolom 1, yang sesuai dengan referensi A1. R2C3 mengacu ke sel di baris 2 kolom 3, yang sesuai dengan referensi C2.

    Dalam rumus yang ada, referensi sel akan diperbarui secara otomatis, sedangkan dalam rumus baru Anda harus menggunakan gaya referensi R1C1.

    Tip. kembali ke gaya A1 , hapus centang pada Gaya referensi R1C1 kotak centang di Opsi Excel .

    Cara memberi nomor kolom di Excel

    Jika Anda tidak terbiasa dengan gaya referensi R1C1 dan ingin menyimpan referensi A1 dalam rumus Anda, maka Anda dapat menyisipkan angka di baris pertama lembar kerja kami, sehingga Anda memiliki keduanya - kolom huruf dan angka. Ini dapat dengan mudah dilakukan dengan bantuan fitur Isi Otomatis.

    Berikut ini langkah-langkah yang terperinci:

    1. Di A1, ketik nomor 1.
    2. Di B1, ketik nomor 2.
    3. Pilih sel A1 dan B1.
    4. Arahkan kursor ke atas kotak kecil di sudut kanan bawah sel B1, yang disebut Isi pegangan Saat Anda melakukan ini, kursor akan berubah menjadi tanda silang hitam tebal.
    5. Seret gagang isian ke kanan hingga ke kolom yang Anda perlukan.

    Hasilnya, Anda akan mempertahankan label kolom sebagai huruf, dan di bawah huruf Anda akan memiliki nomor kolom.

    jenis. Untuk menjaga agar nomor kolom tetap terlihat saat menggulir ke area di bawah lembar kerja, Anda dapat membekukan baris atas.

    Itulah cara mengembalikan nomor kolom di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

    Buku kerja latihan untuk diunduh

    Nomor kolom Excel - contoh (file .xlsm)

    Postingan sebelumnya Dasar-dasar Google Sheets: mengedit, mencetak, dan mengunduh file di Google Sheets
    Postingan berikutnya Cara menghapus karakter khusus / yang tidak diinginkan di Excel

    Michael Brown adalah penggemar teknologi berdedikasi dengan hasrat untuk menyederhanakan proses kompleks menggunakan perangkat lunak. Dengan pengalaman lebih dari satu dekade di industri teknologi, dia telah mengasah keahliannya di Microsoft Excel dan Outlook, serta Google Spreadsheet dan Dokumen. Blog Michael didedikasikan untuk berbagi pengetahuan dan keahliannya dengan orang lain, memberikan tip dan tutorial yang mudah diikuti untuk meningkatkan produktivitas dan efisiensi. Apakah Anda seorang profesional berpengalaman atau pemula, blog Michael menawarkan wawasan berharga dan saran praktis untuk mendapatkan hasil maksimal dari perangkat lunak penting ini.