टीओसीओएल फ़ंक्शन के साथ किसी सरणी या श्रेणी को कॉलम में बदलने का एक आसान तरीका।

डेटा को कॉलम से पंक्तियों में और रिवर्स में स्थानांतरित करने की क्षमता एक्सेल में काफी समय से है कुछ समय। लेकिन कोशिकाओं की एक श्रृंखला को एक कॉलम में परिवर्तित करना क्रैक करने के लिए एक मुश्किल काम था। अब, यह अंततः बदल रहा है। Microsoft ने TOCOL नामक एक नया फ़ंक्शन पेश किया है, जो पलक झपकते ही एक सरणी-से-स्तंभ परिवर्तन कर सकता है। नीचे उन कार्यों की एक सूची दी गई है जिन्हें यह नया फ़ंक्शन आसानी से हल कर सकता है। column.

फ़ंक्शन में तीन तर्क होते हैं, लेकिन केवल पहले वाले की आवश्यकता होती है।

TOCOL(array, [ignore], [scan_by_column])

कहाँ:

ऐरे (आवश्यक) - एक कॉलम में बदलने के लिए एक सरणी या श्रेणी।

अनदेखा करें (वैकल्पिक) - परिभाषित करता है कि रिक्त स्थान या/और त्रुटियों को अनदेखा करना है या नहीं। इनमें से कोई एक मान हो सकता है:

• 0 या छोड़ा गया (डिफ़ॉल्ट) - सभी मान रखें
• 1 - रिक्त स्थान की उपेक्षा करें
• 2 - त्रुटियों की उपेक्षा करें
• 3 - रिक्त स्थान और त्रुटियों को अनदेखा करें

Scan_by_column (वैकल्पिक) - यह निर्धारित करता है कि सरणी को क्षैतिज रूप से स्कैन करना है या लंबवत:

• गलत या छोड़ा गया (डिफ़ॉल्ट) - पंक्ति द्वारा पंक्ति को बाएँ से दाएँ स्कैन करें।
• TRUE - ऊपर से नीचे तक कॉलम द्वारा सरणी को स्कैन करें। 4>
• किसी सरणी को एकल पंक्ति में बदलने के लिए, TOROW का उपयोग करेंफ़ंक्शन।
• विपरीत कॉलम-टू-एरे ट्रांसफ़ॉर्मेशन करने के लिए, या तो WRAPCOLS फ़ंक्शन का उपयोग कॉलम द्वारा रैप करने के लिए या WRAPROWS फ़ंक्शन को पंक्ति द्वारा रैप करने के लिए करें।
• किसी सरणी को क्षैतिज से स्थानांतरित करने के लिए वर्टिकल या इसके विपरीत, यानी पंक्तियों को कॉलम में बदलें, TRANSPOSE फ़ंक्शन का उपयोग करें।

TOCOL उपलब्धता

TOCOL एक नया फ़ंक्शन है, जो Microsoft 365 (Windows के लिए) के लिए Excel में समर्थित है और मैक) और वेब के लिए एक्सेल।

श्रेणी को कॉलम में बदलने के लिए बेसिक TOCOL फॉर्मूला

TOCOL फॉर्मूला अपने सरलतम रूप में केवल एक तर्क की आवश्यकता है - सरणी । उदाहरण के लिए, एक कॉलम में 3 कॉलम और 4 पंक्तियों वाली द्वि-आयामी सरणी रखने के लिए, सूत्र है:

=TOCOL(A2:C5)

सूत्र केवल एक सेल में दर्ज किया गया है (E2 में यह उदाहरण) और स्वचालित रूप से नीचे की कोशिकाओं में फैल जाता है। एक्सेल के संदर्भ में, परिणाम को स्पिल रेंज कहा जाता है।

यह सूत्र कैसे काम करता है:

तकनीकी रूप से, श्रेणी A2:C5 को पहले द्वि-आयामी सरणी में परिवर्तित किया जाता है। कृपया अर्धविराम से अलग की गई पंक्तियों और अल्पविराम से अलग किए गए स्तंभों पर ध्यान दें:

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL फ़ंक्शन सरणी को बाएं से दाएं स्कैन करता है और इसे एक-आयामी लंबवत सरणी में बदल देता है:

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

परिणाम सेल E2 में रखा जाता है, जिससे यह नीचे की कोशिकाओं में फैल जाता है।

Excel में TOCOL फ़ंक्शन का उपयोग कैसे करें - सूत्र उदाहरण

के बारे में अधिक समझ हासिल करने के लिएTOCOL फ़ंक्शन की संभावनाएं और यह कौन से कार्यों को कवर कर सकता है, आइए कुछ सूत्र उदाहरणों पर एक नज़र डालें। , डिफ़ॉल्ट TOCOL सूत्र स्रोत सरणी से सभी मानों को रखता है, जिसमें रिक्त कक्ष और त्रुटियाँ शामिल हैं। 0 मान। समाधान रिक्त स्थान छोड़ना है। इसके लिए, आप दूसरे तर्क को 1 पर सेट करें:

=TOCOL(A2:C5, 1)

त्रुटियों को अनदेखा करने के लिए , दूसरे तर्क को 2 पर सेट करें:

=TOCOL(A2:C5, 2) <3

दोनों को बाहर करने के लिए, रिक्त और त्रुटियां , अनदेखा तर्क के लिए 3 का उपयोग करें:

=TOCOL(A2:C5, 3)

क्षैतिज या लंबवत रूप से सरणी स्कैन करें

डिफ़ॉल्ट scan_by_column तर्क (FALSE या छोड़े गए) के साथ, TOCOL फ़ंक्शन पंक्ति द्वारा क्षैतिज रूप से सरणी को स्कैन करता है। कॉलम द्वारा मानों को प्रोसेस करने के लिए, इस तर्क को TRUE या 1 पर सेट करें। उदाहरण के लिए:

=TOCOL(A2:C5, ,TRUE)

ध्यान दें कि, दोनों मामलों में, लौटाई गई सरणियाँ समान आकार की होती हैं, लेकिन मान व्यवस्थित होते हैं एक अलग क्रम में।

एक कॉलम में कई श्रेणियों को मिलाएं

यदि आप कई गैर-सन्निहित श्रेणियों के साथ काम कर रहे हैं, तो आप पहले VSTACK फ़ंक्शन की मदद से श्रेणियों को लंबवत रूप से एक सरणी में जोड़ सकते हैं, और फिर संयुक्त सरणी को कॉलम में बदलने के लिए TOCOL का उपयोग करें।

यह मानते हुए कि पहली श्रेणी A2:C4 है और दूसरी श्रेणी A8:C9 है, सूत्र यह रूप लेता है:

=TOCOL(VSTACK(A2:C4, A8:C9))

यह सूत्र डिफ़ॉल्ट व्यवहार प्रदर्शित करता है - संयुक्त सरणियों को बाईं ओर से क्षैतिज रूप से पढ़ता है दाईं ओर जैसा कि नीचे दी गई छवि में कॉलम E में दिखाया गया है।

मानों को ऊपर से नीचे लंबवत पढ़ने के लिए, आप TOCOL के तीसरे तर्क को TRUE पर सेट करते हैं:

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

कृपया ध्यान दें कि, इस मामले में, सूत्र पहले दोनों सरणियों के स्तंभ A से, फिर स्तंभ B से, और इसी तरह से मान देता है। इसका कारण यह है कि TOCOL एकल स्टैक्ड सरणी को स्कैन करता है, न कि मूल अलग-अलग श्रेणियों को।

यदि आपके व्यावसायिक तर्क को लंबवत के बजाय क्षैतिज रूप से मूल श्रेणियों को ढेर करने की आवश्यकता है, तो VSTACK के बजाय HSTACK फ़ंक्शन का उपयोग करें।

प्रत्येक अनुवर्ती सरणी को पिछली सरणी के दाईं ओर जोड़ने के लिए और पढ़ें संयुक्त सरणियों को क्षैतिज रूप से, सूत्र है:

=TOCOL(HSTACK(A2:C4, A8:C10))

प्रत्येक अनुवर्ती सरणी को पिछले सरणी के दाईं ओर जोड़ने और संयुक्त सरणी को लंबवत रूप से स्कैन करने के लिए, सूत्र है:

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

एक बहु-स्तंभ श्रेणी से अद्वितीय मान निकालें

एक्सेल UNIQUE फ़ंक्शन आसानी से एक एकल स्तंभ या पंक्ति में अद्वितीय खोज सकता है और साथ ही अद्वितीय पंक्तियाँ लौटा सकता है, लेकिन यह अद्वितीय मान नहीं निकाल सकता एक बहु-स्तंभ सरणी। TOCOL फ़ंक्शन के साथ इसका उपयोग करने का समाधान है।

उदाहरण के लिए, श्रेणी से सभी भिन्न (अलग) मान निकालने के लिएA2:C7, सूत्र है:

=UNIQUE(TOCOL(A2:C7))

इसके अतिरिक्त, आप दिए गए सरणी को वर्णानुक्रम में व्यवस्थित करने के लिए उपरोक्त सूत्र को SORT फ़ंक्शन में लपेट सकते हैं:

=SORT(UNIQUE(TOCOL(A2:C7)))

Excel 365 - 2010

Excel के उन संस्करणों में जहां TOCOL फ़ंक्शन समर्थित नहीं है, रेंज को कॉलम में कैसे बदलें, सेल की रेंज को कॉलम में बदलने के कुछ वैकल्पिक तरीके मौजूद हैं। ये समाधान काफी मुश्किल हैं, लेकिन वैसे भी काम कर रहे हैं।

पंक्ति द्वारा श्रेणी को पढ़ने के लिए:

INDEX( श्रेणी , QUOTIENT(ROW(A1)-1, COLUMNS( ) श्रेणी ))+1, MOD(ROW(A1)-1, COLUMNS( श्रेणी ))+1)

स्तंभ द्वारा सीमा पढ़ने के लिए:

INDEX( रेंज , एमओडी(आरओडब्ल्यू(ए1)-1, आरओडब्ल्यूएस( रेंज ))+1, क्वाटिएंट(आरओडब्ल्यू(ए1)-1, आरओडब्ल्यूएस( रेंज ))+1 )

हमारे नमूना डेटासेट के लिए, सूत्र इस प्रकार हैं:

श्रेणी स्कैन करने के लिए क्षैतिज रूप से बाएं से दाएं :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

यह सूत्र तीसरे तर्क के साथ TOCOL फ़ंक्शन के समतुल्य है जिसे FALSE पर सेट किया गया है या छोड़ा गया है:

=TOCOL(A2:C5)

श्रेणी को स्कैन करने के लिए ऊपर से नीचे तक लंबवत :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

यह सूत्र तीसरे तर्क के साथ TOCOL फ़ंक्शन से तुलनीय है, जो TRUE पर सेट है:

=TOCOL(A2:C5, ,TRUE)

TOCOL के विपरीत, प्रत्येक में वैकल्पिक सूत्र दर्ज किए जाने चाहिए सेल जहां आप परिणाम दिखाना चाहते हैं। हमारे मामले में, सूत्र कक्ष E2 (पंक्ति द्वारा) और G2 (स्तंभ द्वारा) में जाते हैं, और फिर नीचे पंक्ति 13 में कॉपी किए जाते हैं।

यदि सूत्र आवश्यकता से अधिक पंक्तियों में कॉपी किए जाते हैं, तो a#संदर्भ! त्रुटि "अतिरिक्त" कोशिकाओं में दिखाई देगी। ऐसा होने से रोकने के लिए, आप IFERROR फ़ंक्शन में सूत्रों को इस तरह से नेस्ट कर सकते हैं:

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

ध्यान दें कि सूत्रों को सही ढंग से कॉपी करने के लिए, हम निरपेक्ष सेल संदर्भ ($ का उपयोग करके श्रेणी को लॉक कर देते हैं ए$2:$सी$5). इसके बजाय, आप नामित श्रेणी का उपयोग कर सकते हैं।

ये सूत्र कैसे काम करते हैं

नीचे पहले सूत्र का विस्तृत विवरण दिया गया है जो सेल को पंक्ति के अनुसार व्यवस्थित करता है:

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

आइडिया यह है कि INDEX फ़ंक्शन का उपयोग रेंज में इसकी सापेक्ष पंक्ति और कॉलम नंबरों के आधार पर एक निश्चित सेल के मान को वापस करने के लिए किया जाए।

इस संयोजन द्वारा पंक्ति संख्या की गणना की जाती है :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT भाग का पूर्णांक भाग लौटाता है।

अंश के लिए, आप ROW(A1)-1 का उपयोग करते हैं, जो एक देता है E2 में 0 से सीरियल नंबर (पहला सेल जहां सूत्र दर्ज किया गया है) से E13 में 11 तक (अंतिम सेल जहां फॉर्मूला दर्ज किया गया है)।

हर COLUMNS($A) $2:$C$5)) स्थिर है और आपकी श्रेणी में कॉलम की संख्या के बराबर है (हमारे मामले में 3)।

अब, यदि आप पहले 3 सेल के लिए QUOTIENT के परिणाम की जांच करते हैं (E2:E4) , आप देखेंगे कि यह 0 के बराबर है (क्योंकि विभाजन का पूर्णांक भाग शून्य है)। 1 जोड़ने पर पंक्ति संख्या 1 मिलती है।

अगले 3 सेल (E5:E5) के लिए, QUOTIENT 1 लौटाता है, और +1 ऑपरेशन पंक्ति संख्या 2 देता है। और इसी तरह आगे।

दूसरे शब्दों में, सूत्र का यह भाग एक दोहराव पैदा करता हैसंख्या अनुक्रम जैसे 1,1,1,2,2,2,3,3,3,4,4,4,… प्रत्येक संख्या उतनी बार दोहराती है जितनी बार आपकी श्रेणी में कॉलम हैं।

प्रति स्तंभ संख्या की गणना करें, आप एमओडी फ़ंक्शन का उपयोग करके एक उचित संख्या अनुक्रम बनाते हैं:

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

चूंकि हमारी सीमा (A2:C5) में 3 स्तंभ हैं, इसलिए अनुक्रम 1,2,3,1,2,3,…

MOD फ़ंक्शन विभाजन के बाद शेषफल लौटाता है।

E2 में, MOD(ROW(A1)-1, COLUMNS) ($A$2:$C$5))+1)

MOD(1-1, 3)+1)

बन जाता है और 1 लौटाता है।

E3 में, MOD(ROW(A2)-1, COLUMNS($A$2:$C$5))+1)

बन जाता है

MOD(2-1, 3) +1)

और रिटर्न 2.

पंक्ति और कॉलम संख्या स्थापित होने के साथ, INDEX को आवश्यक मान प्राप्त करने में कोई समस्या नहीं है।

E2 में, INDEX($A$2) :$C$5, 1, 1) संदर्भित श्रेणी की पहली पंक्ति और पहले कॉलम से मान लौटाता है, यानी सेल A2 से।

E3 में, INDEX($A$2:$C$5, 1 , 2) पहली पंक्ति और दूसरे कॉलम से मान लौटाता है, यानी सेल बी 2 से। स्तंभ, इसी तरह काम करता है। अंतर यह है कि यह पंक्ति संख्या प्राप्त करने के लिए MOD का उपयोग करता है और स्तंभ संख्या प्राप्त करने के लिए QUOTIENT।

TOCOL फ़ंक्शन काम नहीं कर रहा है

यदि TOCOL फ़ंक्शन एक त्रुटि फेंकता है, तो इसकी सबसे अधिक संभावना है इन कारणों में से एक होने के लिए:

TOCOL आपके एक्सेल में समर्थित नहीं है

जब आपको #NAME मिलता है? त्रुटि, फ़ंक्शन के नाम की सही वर्तनी पहली बात हैजांच। यदि नाम सही है लेकिन त्रुटि बनी रहती है, तो फ़ंक्शन आपके Excel के संस्करण में उपलब्ध नहीं है। इस स्थिति में, TOCOL विकल्प का उपयोग करने पर विचार करें।

सरणी बहुत बड़ी है

एक #NUM त्रुटि इंगित करती है कि सरणी किसी स्तंभ में फ़िट नहीं हो सकती। एक विशिष्ट मामला तब होता है जब आप पूरे कॉलम या पंक्तियों को संदर्भित करते हैं।

पर्याप्त खाली सेल नहीं हैं

जब #SPILL त्रुटि होती है, तो जांचें कि वह कॉलम जहां सूत्र दर्ज किया गया है परिणामों से भरे जाने के लिए पर्याप्त खाली कक्ष हैं। यदि कक्ष नेत्रहीन रूप से रिक्त हैं, तो सुनिश्चित करें कि उनमें कोई रिक्त स्थान और अन्य गैर-मुद्रण वर्ण नहीं हैं। अधिक जानकारी के लिए, Excel में #SPILL त्रुटि को ठीक करने का तरीका देखें।

इसी तरह आप Excel 365 में TOCOL फ़ंक्शन का उपयोग कर सकते हैं और 2-आयामी सरणी को एकल कॉलम में बदलने के लिए पिछले संस्करणों में वैकल्पिक समाधान कर सकते हैं। पढ़ने के लिए मैं आपको धन्यवाद देता हूं और आशा करता हूं कि अगले सप्ताह आप हमारे ब्लॉग पर मिलेंगे!

अभ्यास कार्यपुस्तिका

एक्सेल TOCOL फ़ंक्शन - सूत्र उदाहरण (.xlsx फ़ाइल)