TOCOL प्रकार्यको साथ एरे वा दायरालाई स्तम्भमा रूपान्तरण गर्ने सजिलो तरिका।

स्तम्भहरूबाट पङ्क्तिहरूमा र रिभर्समा डाटा ट्रान्सपोज गर्ने क्षमता धेरै समयदेखि Excel मा रहेको छ। एकै छिन। तर सेलहरूको दायरालाई एकल स्तम्भमा रूपान्तरण गर्नु क्र्याक गर्न गाह्रो काम थियो। अब, त्यो अन्ततः परिवर्तन हुँदैछ। माइक्रोसफ्टले एउटा नयाँ प्रकार्य पेश गरेको छ, TOCOL भनिन्छ, जसले एक पलकमा एरे-टु-कोलम रूपान्तरण गर्न सक्छ। तल यस नयाँ प्रकार्यले सजिलै समाधान गर्न सक्ने कार्यहरूको सूची छ।

Excel TOCOL प्रकार्य

Excel मा TOCOL प्रकार्यले एरे वा कक्षहरूको दायरालाई एकलमा रूपान्तरण गर्दछ। स्तम्भ।

प्रकार्यले तीन तर्कहरू लिन्छ, तर पहिलो मात्र आवश्यक छ।

TOCOL(array, [ignore], [scan_by_column])

कहाँ:

एरे (आवश्यक) - स्तम्भमा रूपान्तरण गर्नको लागि एरे वा दायरा।

उपेक्षा गर्नुहोस् (वैकल्पिक) - खाली ठाउँ वा/र त्रुटिहरूलाई बेवास्ता गर्ने कि भनेर परिभाषित गर्दछ। यी मानहरू मध्ये एउटा हुन सक्छ:

• 0 वा हटाइएको (पूर्वनिर्धारित) - सबै मानहरू राख्नुहोस्
• 1 - खाली ठाउँहरू उपेक्षा गर्नुहोस्
• 2 - त्रुटिहरू उपेक्षा गर्नुहोस्
• 3 - खाली ठाउँ र त्रुटिहरूलाई बेवास्ता गर्नुहोस्

Scan_by_column (वैकल्पिक) - एरेलाई तेर्सो वा ठाडो रूपमा स्क्यान गर्ने कि गर्ने भनेर निर्धारण गर्दछ:

• FALSE वा मेटिएको (पूर्वनिर्धारित) - बायाँ देखि दायाँ पङ्क्ति द्वारा एरे स्क्यान गर्नुहोस्।
• TRUE - माथि देखि तल सम्म स्तम्भ द्वारा एरे स्क्यान गर्नुहोस्।

सुझाव:

• एरेलाई एकल पङ्क्तिमा रूपान्तरण गर्न, TOROW प्रयोग गर्नुहोस्प्रकार्य।
• विपरीत स्तम्भ-देखि-एरे रूपान्तरण गर्न, कि त स्तम्भद्वारा लपेट्न WRAPCOLS प्रकार्य वा पङ्क्तिद्वारा लपेट्न WRAPROWS प्रकार्य प्रयोग गर्नुहोस्।
• एर्रेलाई तेर्सोबाट स्थानान्तरण गर्न ठाडो वा उल्टो, अर्थात् पङ्क्तिहरूलाई स्तम्भहरूमा परिवर्तन गर्नुहोस्, TRANSPOSE प्रकार्य प्रयोग गर्नुहोस्।

TOCOL उपलब्धता

TOCOL एउटा नयाँ प्रकार्य हो, जुन Microsoft 365 को लागि Excel मा समर्थित छ (विन्डोजका लागि र म्याक) र वेबको लागि एक्सेल।

दायरालाई स्तम्भमा रूपान्तरण गर्न आधारभूत TOCOL सूत्र

TOCOL सूत्रलाई यसको सरल रूपमा एउटा तर्क चाहिन्छ - array । उदाहरण को लागी, एकल स्तम्भ मा 3 स्तम्भ र 4 पङ्क्तिहरु सम्मिलित दुई-आयामी एरे राख्न को लागी, सूत्र हो:

=TOCOL(A2:C5)

सूत्र एक कक्षमा मात्र प्रविष्ट गरिएको छ (E2 मा यो उदाहरण) र तलको कक्षहरूमा स्वचालित रूपमा फैलिन्छ। एक्सेलको सन्दर्भमा, नतिजालाई स्पिल दायरा भनिन्छ।

यस सूत्रले कसरी काम गर्छ:

प्राविधिक रूपमा, दायरा A2:C5 लाई पहिले दुई-आयामी एरेमा रूपान्तरण गरिन्छ। कृपया अर्धविराम-विभाजित पङ्क्तिहरू र अल्पविराम-डिलिमिटेड स्तम्भहरूमा ध्यान दिनुहोस्:

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL प्रकार्यले एरेलाई बायाँबाट दायाँ स्क्यान गर्छ र यसलाई एक-आयामी ठाडो एरेमा रूपान्तरण गर्दछ:

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

नतिजा सेल E2 मा राखिएको छ, जसबाट यो तलका कक्षहरूमा फैलिन्छ।

> एक्सेलमा TOCOL प्रकार्य कसरी प्रयोग गर्ने - सूत्र उदाहरणहरू

को थप समझ प्राप्त गर्नTOCOL प्रकार्यको सम्भावनाहरू र यसले कस्ता कार्यहरू कभर गर्न सक्छ, केही सूत्र उदाहरणहरू हेरौं।

एरेलाई खाली ठाउँ र त्रुटिहरूलाई बेवास्ता गर्दै स्तम्भमा रूपान्तरण गर्नुहोस्

तपाईंले अघिल्लो उदाहरणमा देख्नु भएको छ। , पूर्वनिर्धारित TOCOL सूत्रले खाली कक्षहरू र त्रुटिहरू सहित स्रोत एरेबाट सबै मानहरू राख्छ।

नतिजा एरेमा, खाली कक्षहरूलाई शून्यद्वारा प्रतिनिधित्व गरिन्छ, जुन धेरै भ्रमित हुन सक्छ, विशेष गरी यदि मूल एरेमा ० मानहरू। समाधान खाली ठाउँ छोड्नु हो । यसका लागि, तपाईंले दोस्रो तर्कलाई 1:

=TOCOL(A2:C5, 1)

त्रुटिहरूलाई बेवास्ता गर्नुहोस् मा सेट गर्नुभयो, दोस्रो आर्गुमेन्टलाई 2:

=TOCOL(A2:C5, 2) <3 मा सेट गर्नुहोस्।

दुबै बहिष्कार गर्न, खाली र त्रुटिहरू , बेवास्ता गर्नुहोस् तर्कको लागि 3 प्रयोग गर्नुहोस्:

=TOCOL(A2:C5, 3)

एरे तेर्सो वा ठाडो रूपमा स्क्यान गर्नुहोस्

पूर्वनिर्धारित scan_by_column तर्क (FALSE वा छोडिएको) संग, TOCOL प्रकार्यले पङ्क्तिद्वारा तेर्सो रूपमा एरे स्क्यान गर्दछ। स्तम्भ द्वारा मानहरू प्रशोधन गर्न, यो तर्कलाई TRUE वा 1 मा सेट गर्नुहोस्। उदाहरणका लागि:

=TOCOL(A2:C5, ,TRUE)

ध्यान दिनुहोस् कि, दुवै अवस्थामा, फर्काइएका एरेहरू समान आकारका छन्, तर मानहरू व्यवस्थित छन्। फरक क्रममा।

एउटै स्तम्भमा धेरै दायराहरू मिलाउनुहोस्

यदि तपाइँ धेरै गैर-सन्निधित दायराहरूसँग काम गर्दै हुनुहुन्छ भने, तपाइँ पहिले VSTACK प्रकार्यको मद्दतले दायराहरूलाई ठाडो रूपमा एकल एरेमा संयोजन गर्न सक्नुहुन्छ, र त्यसपछि संयुक्त एरेलाई स्तम्भमा रूपान्तरण गर्न TOCOL प्रयोग गर्नुहोस्।

पहिलो दायरा A2:C4 हो र दोस्रो दायरा A8:C9 हो, सूत्रले यो फारम लिन्छ:

=TOCOL(VSTACK(A2:C4, A8:C9))

यो सूत्रले पूर्वनिर्धारित व्यवहार देखाउँछ - संयुक्त एरेहरूलाई बाँयाबाट तेर्सो रूपमा पढ्छ। तलको छविमा स्तम्भ E मा देखाइए अनुसार दायाँतिर।

माथिदेखि तलसम्म ठाडो रूपमा मानहरू पढ्न, तपाईंले TOCOL को तेस्रो तर्कलाई TRUE मा सेट गर्नुहुन्छ:

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

कृपया ध्यान दिनुहोस् कि, यस अवस्थामा, सूत्रले पहिले दुबै एरेहरूको स्तम्भ A बाट मानहरू फर्काउँछ, त्यसपछि स्तम्भ B बाट, र यस्तै। कारण यो हो कि TOCOL ले एकल स्ट्याक्ड एरे स्क्यान गर्दछ, मूल व्यक्तिगत दायराहरू होइन।

यदि तपाईंको व्यापार तर्कले ठाडो भन्दा तेर्सो रूपमा मूल दायराहरू स्ट्याक गर्न आवश्यक छ भने, त्यसपछि VSTACK को सट्टा HSTACK प्रकार्य प्रयोग गर्नुहोस्।

अघिल्लो एरेको दायाँमा प्रत्येक अर्को एरे जोड्न र पढ्नुहोस् संयुक्त एरेहरू तेर्सो रूपमा, सूत्र हो:

=TOCOL(HSTACK(A2:C4, A8:C10))

प्रत्येक पछिल्लो एरेलाई अघिल्लो एरेको दायाँमा थप्न र संयुक्त एरेहरूलाई ठाडो रूपमा स्क्यान गर्न, सूत्र हो:

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

बहु-स्तम्भ दायराबाट अद्वितीय मानहरू निकाल्नुहोस्

Excel UNIQUE प्रकार्यले सजिलैसँग एकल स्तम्भ वा पङ्क्तिमा अद्वितीयहरू फेला पार्न सक्छ र अद्वितीय पङ्क्तिहरू फर्काउन सक्छ, तर यसले बाट अद्वितीय मानहरू निकाल्न सक्दैन। बहु-स्तम्भ एरे। समाधान भनेको TOCOL प्रकार्यसँग सँगै प्रयोग गर्नु हो।

उदाहरणका लागि, दायराबाट सबै फरक (भिन्न) मानहरू निकाल्नA2:C7, सूत्र हो:

=UNIQUE(TOCOL(A2:C7))

थप रूपमा, तपाईले माथिको सूत्रलाई SORT प्रकार्यमा र्‍याप गर्न सक्नुहुन्छ फिर्ता गरिएको एरेलाई वर्णमालाको क्रममा मिलाउन:

=SORT(UNIQUE(TOCOL(A2:C7)))

Excel 365 - 2010 मा दायरालाई स्तम्भमा कसरी रूपान्तरण गर्ने

TOCOL प्रकार्य समर्थित नभएको Excel संस्करणहरूमा, त्यहाँ कक्षहरूको दायरालाई स्तम्भमा रूपान्तरण गर्ने केही वैकल्पिक तरिकाहरू छन्। यी समाधानहरू निकै कठिन छन्, तर जे भए पनि काम गर्दै छन्।

पङ्क्तिद्वारा दायरा पढ्नको लागि:

INDEX( दायरा , QUOTIENT(ROW(A1)-1, COLUMNS( दायरा ))+1, MOD(ROW(A1)-1, COLUMNS( range ))+1)

स्तम्भ अनुसार दायरा पढ्नको लागि:

INDEX( दायरा , MOD(ROW(A1)-1, ROWS( range ))+1, QUOTIENT(ROW(A1)-1, ROWS( range ))+1 )

हाम्रो नमूना डेटासेटको लागि, सूत्रहरू निम्नानुसार छन्:

दायरा स्क्यान गर्न तेर्सो रूपमा बाँया देखि दायाँ :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

यो सूत्र FALSE मा सेट गरिएको तेस्रो तर्कसँग TOCOL प्रकार्यसँग बराबर छ वा छोडिएको छ:

=TOCOL(A2:C5)

दायरा स्क्यान गर्न ठाडो रूपमा माथिदेखि तल :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

यो सूत्र TOCOL प्रकार्यसँग तुलना गर्न सकिन्छ 3rd आर्गुमेन्ट TRUE मा सेट गरिएको छ:

=TOCOL(A2:C5, ,TRUE)

TOCOL विपरीत, वैकल्पिक सूत्रहरू प्रत्येकमा प्रविष्ट गर्नुपर्छ। सेल जहाँ तपाईं परिणामहरू देखा पर्न चाहनुहुन्छ। हाम्रो अवस्थामा, सूत्रहरू कक्षहरू E2 (पङ्क्तिद्वारा) र G2 (स्तम्भद्वारा) मा जान्छन्, र त्यसपछि पङ्क्ति 13 मा प्रतिलिपि हुन्छन्।

यदि सूत्रहरू आवश्यकताभन्दा बढी पङ्क्तिहरूमा प्रतिलिपि गरिएका छन् भने, a#REF! त्रुटि "अतिरिक्त" कक्षहरूमा देखा पर्नेछ। यो हुनबाट रोक्नको लागि, तपाईंले IFERROR प्रकार्यमा यसरी सूत्रहरू नेस्ट गर्न सक्नुहुन्छ:

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

ध्यान दिनुहोस् कि सूत्रहरू सही रूपमा प्रतिलिपि गर्नका लागि, हामी निरपेक्ष कक्ष सन्दर्भहरू ($) प्रयोग गरेर दायरा लक गर्छौं। A$2:$C$5)। यसको सट्टा, तपाइँ नामित दायरा प्रयोग गर्न सक्नुहुन्छ।

यी सूत्रहरूले कसरी काम गर्दछ

पङ्क्तिद्वारा कक्षहरूलाई व्यवस्थित गर्ने पहिलो सूत्रको विस्तृत ब्रेक-डाउन तल दिइएको छ:

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

विचार INDEX प्रकार्य प्रयोग गरी दायरामा रहेको सापेक्षिक पङ्क्ति र स्तम्भ संख्याहरूको आधारमा निश्चित कक्षको मान फर्काउने हो।

पङ्क्ति नम्बर यो संयोजनद्वारा गणना गरिन्छ। :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT ले भागको पूर्णांक भाग फर्काउँछ।

अंक को लागि, तपाईँले ROW(A1)-1 प्रयोग गर्नुहुन्छ, जसले a फर्काउँछ। क्रम संख्या ० बाट E2 मा (पहिलो कक्ष जहाँ सूत्र प्रविष्ट गरियो) बाट E13 मा 11 सम्म (अन्तिम कक्ष जहाँ सूत्र प्रविष्ट गरियो)।

डिनोमिनेटर COLUMNS($A) द्वारा ब्रो $2:$C$5)) स्थिर छ र तपाईंको दायरामा स्तम्भहरूको संख्या बराबर हुन्छ (हाम्रो अवस्थामा ३)।

अब, यदि तपाईंले पहिलो ३ कक्षहरू (E2:E4) को लागि QUOTIENT को नतिजा जाँच गर्नुभयो भने। , तपाईले देख्नुहुनेछ कि यो ० बराबर छ (किनभने डिभिजनको पूर्णांक भाग शून्य हो)। १ थप्दा पङ्क्ति नम्बर १ दिन्छ।

अर्को ३ कक्षहरू (E5:E5) को लागि, QUOTIENT ले १ फर्काउँछ, र +1 सञ्चालनले पङ्क्ति नम्बर २ प्रदान गर्दछ। र यस्तै।

अर्को शब्दमा, सूत्रको यो भागले दोहोरिने बनाउँछसंख्या अनुक्रम जस्तै 1,1,1,2,2,2,3,3,3,4,4,4,… प्रत्येक संख्या तपाईको दायरामा स्तम्भहरू भए जति पटक दोहोरिन्छ।

प्रति स्तम्भ नम्बर गणना गर्नुहोस्, तपाईंले MOD प्रकार्य प्रयोग गरेर उपयुक्त संख्या अनुक्रम निर्माण गर्नुहुन्छ:

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

हाम्रो दायरामा ३ वटा स्तम्भहरू छन् (A2:C5), अनुक्रम 1,2,3,1,2,3,…

MOD प्रकार्यले विभाजन पछि बाँकी फर्काउँछ।

E2 मा, MOD(ROW(A1)-1, COLUMNS ($A$2:$C$5))+1)

बन्छ

MOD(1-1, 3)+1)

र 1 फर्काउँछ।

E3 मा, MOD(ROW(A2)-1, COLUMNS($A$2:$C$5))+1)

बन्छ

MOD(2-1, 3) +1)

र 2 फर्काउँछ।

पङ्क्ति र स्तम्भ संख्याहरू स्थापना भएकोमा, INDEX लाई आवश्यक मान ल्याउन कुनै समस्या छैन।

E2 मा, INDEX($A$2) :$C$5, 1, 1) ले पहिलो पङ्क्ति र सन्दर्भ दायराको पहिलो स्तम्भबाट मान फर्काउँछ, अर्थात् कक्ष A2 बाट।

E3 मा, INDEX($A$2:$C$5, 1 , 2) पहिलो पङ्क्ति र दोस्रो स्तम्भबाट मान फर्काउँछ, अर्थात् सेल B2 बाट।

र यस्तै।

दोस्रो सूत्र जसले दायरालाई c द्वारा स्क्यान गर्छ। olumn, समान रूपमा काम गर्दछ। भिन्नता यो हो कि यसले पङ्क्ति नम्बर प्राप्त गर्न MOD र स्तम्भ नम्बर प्राप्त गर्न QUOTIENT प्रयोग गर्दछ।

TOCOL प्रकार्यले काम गरिरहेको छैन

यदि TOCOL प्रकार्यले त्रुटि फ्याँक्यो भने, यो प्रायः सम्भव छ। यी कारणहरू मध्ये एक हुन:

TOCOL तपाईंको Excel मा समर्थित छैन

जब तपाइँ #NAME पाउनुहुन्छ? त्रुटि, प्रकार्यको नामको सही हिज्जे पहिलो कुरा होजाँच गर्नुहोस्। यदि नाम सही छ तर त्रुटि रहिरह्यो भने, कार्य Excel को तपाइँको संस्करणमा उपलब्ध छैन। यस अवस्थामा, TOCOL विकल्प प्रयोग गर्ने विचार गर्नुहोस्।

एरे धेरै ठूलो छ

#NUM त्रुटिले एरे स्तम्भमा फिट हुन सक्दैन भन्ने संकेत गर्छ। जब तपाइँ सम्पूर्ण स्तम्भ वा पङ्क्तिहरू सन्दर्भ गर्नुहुन्छ एक सामान्य केस हो।

त्यहाँ पर्याप्त खाली कक्षहरू छैनन्

जब #SPILL त्रुटि देखा पर्दछ, सूत्र प्रविष्ट गरिएको स्तम्भ जाँच गर्नुहोस्। नतिजाहरू भर्न पर्याप्त खाली कक्षहरू छन्। यदि कक्षहरू दृश्यात्मक रूपमा खाली छन् भने, निश्चित गर्नुहोस् कि त्यहाँ कुनै खाली ठाउँहरू र अन्य गैर-मुद्रण वर्णहरू छैनन्। थप जानकारीको लागि, Excel मा #SPILL त्रुटि कसरी समाधान गर्ने हेर्नुहोस्।

यसैले तपाईंले Excel 365 मा TOCOL प्रकार्य र अघिल्लो संस्करणहरूमा वैकल्पिक समाधानहरू एकल स्तम्भमा २-आयामी एरे रूपान्तरण गर्न प्रयोग गर्न सक्नुहुन्छ। पढ्नुभएकोमा म तपाईंलाई धन्यवाद दिन्छु र अर्को हप्ता हाम्रो ब्लगमा भेट्ने आशा गर्छु!

अभ्यास कार्यपुस्तिका

Excel TOCOL प्रकार्य - सूत्र उदाहरणहरू (.xlsx फाइल)