მარტივი გზა მასივის ან დიაპაზონის სვეტად გარდაქმნის TOCOL ფუნქციით.

მონაცემების გადატანის შესაძლებლობა სვეტებიდან მწკრივებში და პირიქით, Excel-ში საკმაოდ დიდი ხანია არსებობს. დროის მონაკვეთი. მაგრამ უჯრედების დიაპაზონის ერთ სვეტად გადაქცევა რთული ამოცანა იყო. ახლა, ეს საბოლოოდ იცვლება. მაიკროსოფტმა დანერგა ახალი ფუნქცია, სახელწოდებით TOCOL, რომელსაც შეუძლია განახორციელოს მასივი-სვეტის ტრანსფორმაცია თვალის დახამხამებაში. ქვემოთ მოცემულია ამოცანების სია, რომელთა გადაჭრაც ამ ახალ ფუნქციას ადვილად შეუძლია.

Excel TOCOL ფუნქცია

TOCOL ფუნქცია Excel-ში გარდაქმნის მასივს ან უჯრედების დიაპაზონს ერთად სვეტი.

ფუნქცია იღებს სამ არგუმენტს, მაგრამ მხოლოდ პირველია საჭირო.

TOCOL(მასივი, [იგნორირება], [სკანირება_სვეტის მიხედვით])

სად:

Array (საჭირო) - მასივი ან დიაპაზონი, რომელიც გარდაიქმნება სვეტად.

იგნორირება (სურვილისამებრ) - განსაზღვრავს თუ არა იგნორირებას უკეთებს ბლანკებს ან/და შეცდომებს. შეიძლება იყოს ერთ-ერთი ასეთი მნიშვნელობიდან:

• 0 ან გამოტოვებული (ნაგულისხმევი) - ყველა მნიშვნელობის შენარჩუნება
• 1 - ცარიელი ადგილების იგნორირება
• 2 - შეცდომების იგნორირება
• 3 - ბლანკების და შეცდომების იგნორირება

Scan_by_column (სურვილისამებრ) - განსაზღვრავს მასივის სკანირება ჰორიზონტალურად თუ ვერტიკალურად:

• FALSE ან გამოტოვებული (ნაგულისხმევი) - დაასკანირეთ მასივი მწკრივის მიხედვით მარცხნიდან მარჯვნივ.
• TRUE - დაასკანირეთ მასივი სვეტის მიხედვით ზემოდან ქვემოდან.

რჩევები:

• მაივის ერთ მწკრივად გადასაყვანად გამოიყენეთ TOROWფუნქცია.
• სვეტიდან მასივში საპირისპირო ტრანსფორმაციის შესასრულებლად გამოიყენეთ WRAPCOLS ფუნქცია სვეტის მიხედვით გადასახვევად ან WRAPROWS ფუნქცია მწკრივის მიხედვით გადასატანად.
• მაივი ჰორიზონტალურიდან გადასატანად ვერტიკალური ან პირიქით, ანუ შეცვალეთ რიგები სვეტებად, გამოიყენეთ TRANSPOSE ფუნქცია.

TOCOL ხელმისაწვდომობა

TOCOL არის ახალი ფუნქცია, რომელიც მხარდაჭერილია Excel-ში Microsoft 365-ისთვის (Windows-ისთვის და Mac) და Excel ვებისთვის.

ძირითადი TOCOL ფორმულა დიაპაზონის სვეტად გარდაქმნისთვის

TOCOL ფორმულა თავის უმარტივეს ფორმაში მოითხოვს მხოლოდ ერთ არგუმენტს - მასივი . მაგალითად, 3 სვეტისა და 4 მწკრივისაგან შემდგარი ორგანზომილებიანი მასივის ერთ სვეტში განთავსებისთვის, ფორმულა არის:

=TOCOL(A2:C5)

ფორმულა შეყვანილია მხოლოდ ერთ უჯრედში (E2 in ეს მაგალითი) და ავტომატურად იღვრება ქვემოთ მოცემულ უჯრედებში. Excel-ის თვალსაზრისით, შედეგს ეწოდება დაღვრის დიაპაზონი.

როგორ მუშაობს ეს ფორმულა:

ტექნიკურად, A2:C5 დიაპაზონი პირველად გარდაიქმნება ორგანზომილებიან მასივად. ყურადღება მიაქციეთ მძიმით გამოყოფილი რიგები და მძიმით გამოყოფილი სვეტები:

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL ფუნქცია სკანირებს მასივს მარცხნიდან მარჯვნივ და გარდაქმნის მას ერთგანზომილებიან ვერტიკალურ მასივად:

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

შედეგი მოთავსებულია E2 უჯრედში, საიდანაც ის იღვრება ქვემოთ მოცემულ უჯრედებში.

როგორ გამოვიყენოთ TOCOL ფუნქცია Excel-ში - ფორმულის მაგალითები

უფრო მეტი გაგების მისაღებადTOCOL ფუნქციის შესაძლებლობები და რა ამოცანების დაფარვა შეუძლია მას, მოდით გადავხედოთ ფორმულების რამდენიმე მაგალითს.

გადაცვალეთ მასივი სვეტად ცარიელი ადგილებისა და შეცდომების უგულებელყოფით

როგორც თქვენ შენიშნეთ წინა მაგალითში , ნაგულისხმევი TOCOL ფორმულა ინახავს ყველა მნიშვნელობას წყაროს მასივიდან, მათ შორის ცარიელ უჯრედებსა და შეცდომებს.

მიღებულ მასივში ცარიელი უჯრედები წარმოდგენილია ნულებით, რაც შეიძლება საკმაოდ დამაბნეველი იყოს, განსაკუთრებით თუ თავდაპირველი მასივი აქვს 0 მნიშვნელობები. გამოსავალი არის ბლანკების გამოტოვება . ამისათვის თქვენ დააყენეთ მე-2 არგუმენტი 1-ზე:

=TOCOL(A2:C5, 1)

შეცდომების უგულებელყოფისთვის , დააყენეთ მე-2 არგუმენტი 2:

=TOCOL(A2:C5, 2)

ორივე, სუფთა და შეცდომების გამოსარიცხად გამოიყენეთ 3 არგუმენტისთვის იგნორირება :

=TOCOL(A2:C5, 3)

მაივი ჰორიზონტალურად ან ვერტიკალურად სკანირეთ

ნაგულისხმევი scan_by_column არგუმენტით (FALSE ან გამოტოვებული), TOCOL ფუნქცია სკანირებს მასივს ჰორიზონტალურად მწკრივის მიხედვით. მნიშვნელობების სვეტის მიხედვით დასამუშავებლად, დააყენეთ ეს არგუმენტი TRUE ან 1. მაგალითად:

=TOCOL(A2:C5, ,TRUE)

გაითვალისწინეთ, რომ ორივე შემთხვევაში, დაბრუნებული მასივები იგივე ზომისაა, მაგრამ მნიშვნელობები განლაგებულია განსხვავებული თანმიმდევრობით.

გაერთიანეთ მრავალი დიაპაზონი ერთ სვეტში

თუ საქმე გაქვთ რამდენიმე არამიმართულ დიაპაზონთან, მაშინ შეგიძლიათ ჯერ ვერტიკალურად დააკავშიროთ დიაპაზონები ერთ მასივში VSTACK ფუნქციის დახმარებით და შემდეგ გამოიყენეთ TOCOL კომბინირებული მასივის სვეტად გადასაქცევად.

ვივარაუდოთ, რომ პირველი დიაპაზონი არის A2:C4 და მეორე დიაპაზონი არის A8:C9, ფორმულა იღებს ამ ფორმას:

=TOCOL(VSTACK(A2:C4, A8:C9))

ეს ფორმულა აჩვენებს ნაგულისხმევ ქცევას - კითხულობს კომბინირებულ მასივებს ჰორიზონტალურად მარცხნიდან. მარჯვნივ, როგორც ნაჩვენებია E სვეტში ქვემოთ მოცემულ სურათზე.

მნიშვნელობების ვერტიკალურად წასაკითხად ზემოდან ქვემოდან, თქვენ დააყენეთ TOCOL-ის მე-3 არგუმენტი TRUE-ზე:

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

გთხოვთ, ყურადღება მიაქციოთ, რომ ამ შემთხვევაში ფორმულა ჯერ აბრუნებს მნიშვნელობებს ორივე მასივის A სვეტიდან, შემდეგ B სვეტიდან და ა.შ. მიზეზი ის არის, რომ TOCOL სკანირებს ერთ დაწყობილ მასივს და არა თავდაპირველ ცალკეულ დიაპაზონებს.

თუ თქვენი ბიზნეს ლოგიკა მოითხოვს ორიგინალური დიაპაზონების დაწყობას ჰორიზონტალურად და არა ვერტიკალურად, მაშინ გამოიყენეთ HSTACK ფუნქცია VSTACK-ის ნაცვლად.

რომ დაურთოთ ყოველი მომდევნო მასივი წინა მასივის მარჯვნივ და წაიკითხოთ კომბინირებული მასივები ჰორიზონტალურად, ფორმულა არის:

=TOCOL(HSTACK(A2:C4, A8:C10))

რომ დაამატოთ ყოველი მომდევნო მასივი წინა მასივის მარჯვნივ და კომბინირებული მასივები ვერტიკალურად სკანიროთ, ფორმულა არის:

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

უნიკალური მნიშვნელობების ამოღება მრავალსვეტიანი დიაპაზონიდან

Excel UNIQUE ფუნქცია ადვილად იპოვის უნიკალურებს ერთ სვეტში ან მწკრივში, ასევე დააბრუნებს უნიკალურ რიგებს, მაგრამ მას არ შეუძლია უნიკალური მნიშვნელობების ამოღება. მრავალსვეტიანი მასივი. გამოსავალი არის მისი გამოყენება TOCOL ფუნქციასთან ერთად.

მაგალითად, დიაპაზონიდან ყველა განსხვავებული (განსხვავებული) მნიშვნელობების ამოღება.A2:C7, ფორმულა არის:

=UNIQUE(TOCOL(A2:C7))

გარდა ამისა, შეგიძლიათ ზემოთ ჩამოთვლილი ფორმულა გადაიტანოთ SORT ფუნქციაში დაბრუნებული მასივის ანბანური თანმიმდევრობით დასალაგებლად:

=SORT(UNIQUE(TOCOL(A2:C7)))

როგორ გადავიტანოთ დიაპაზონი სვეტად Excel 365-ში - 2010

Excel-ის ვერსიებში, სადაც TOCOL ფუნქცია არ არის მხარდაჭერილი, არსებობს უჯრედების დიაპაზონის სვეტად გარდაქმნის რამდენიმე ალტერნატიული გზა. ეს გადაწყვეტილებები საკმაოდ რთულია, მაგრამ მაინც მუშაობს.

დიაპაზონის მწკრივის მიხედვით წასაკითხად:

INDEX( დიაპაზონი , QUOTIENT(ROW(A1)-1, COLUMNS( დიაპაზონი ))+1, MOD(ROW(A1)-1, COLUMNS( დიაპაზონი ))+1)

დიაპაზონის წასაკითხად სვეტების მიხედვით:

INDEX( დიაპაზონი , MOD(ROW(A1)-1, ROWS( დიაპაზონი ))+1, QUOTIENT(ROW(A1)-1, ROWS( დიაპაზონი ))+1 )

ჩვენი ნიმუშის ნაკრებისთვის ფორმულები შემდეგია:

დიაპაზონის ჰორიზონტალურად სკანირებისთვის მარცხნიდან მარჯვნივ :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

ეს ფორმულა ექვივალენტურია TOCOL ფუნქციის მე-3 არგუმენტით დაყენებულია FALSE ან გამოტოვებული:

=TOCOL(A2:C5)

დიაპაზონის სკანირება ვერტიკალურად ზემოდან ქვემოდან :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

ეს ფორმულა შედარებულია TOCOL ფუნქციასთან მე-3 არგუმენტით დაყენებულია TRUE:

=TOCOL(A2:C5, ,TRUE)

განსხვავებით TOCOL-ისგან, ალტერნატიული ფორმულები უნდა იყოს შეყვანილი თითოეულში. უჯრედი, სადაც გსურთ შედეგების გამოჩენა. ჩვენს შემთხვევაში, ფორმულები გადადის უჯრედებში E2 (მწკრივის მიხედვით) და G2 (სვეტის მიხედვით) და შემდეგ კოპირდება მე-13 მწკრივში.

თუ ფორმულები დაკოპირებულია საჭიროზე მეტ რიგზე,#REF! შეცდომა გამოჩნდება "ზედმეტ" უჯრედებში. ამის თავიდან ასაცილებლად, შეგიძლიათ ფორმულების ჩასმა IFERROR ფუნქციაში შემდეგნაირად:

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

გაითვალისწინეთ, რომ ფორმულების სწორად კოპირების მიზნით, ჩვენ ვბლოკავთ დიაპაზონს უჯრედის აბსოლუტური მითითებების გამოყენებით ($ A$2:$C$5). ამის ნაცვლად, შეგიძლიათ გამოიყენოთ დასახელებული დიაპაზონი.

როგორ მუშაობს ეს ფორმულები

ქვემოთ მოცემულია პირველი ფორმულის დეტალური აღწერა, რომელიც აწყობს უჯრედებს მწკრივის მიხედვით:

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

იდეა გამოვიყენოთ INDEX ფუნქცია გარკვეული უჯრედის მნიშვნელობის დასაბრუნებლად დიაპაზონში მისი შედარებითი მწკრივისა და სვეტის ნომრებზე დაყრდნობით.

მწკრივის ნომერი გამოითვლება ამ კომბინაციით. :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT აბრუნებს გაყოფის მთელ ნაწილს.

მრიცხველისთვის , თქვენ იყენებთ ROW(A1)-1, რომელიც აბრუნებს სერიული ნომერი 0-დან E2-ში (პირველი უჯრედი, სადაც შეყვანილია ფორმულა) 11-მდე E13-ში (ბოლო უჯრედი, სადაც ფორმულა შევიდა).

მნიშვნელი მიიღება COLUMNS($A-ით) $2:$C$5)) არის მუდმივი და უდრის თქვენს დიაპაზონში სვეტების რაოდენობას (ჩვენს შემთხვევაში 3).

ახლა, თუ შეამოწმებთ QUOTIENT-ის შედეგს პირველი 3 უჯრედისთვის (E2:E4) , დაინახავთ, რომ ის უდრის 0-ს (რადგან გაყოფის მთელი რიცხვი ნულის ტოლია). 1-ის მიმატებით მიიღება მწკრივის ნომერი 1.

შემდეგი 3 უჯრედისთვის (E5:E5), QUOTIENT აბრუნებს 1-ს, ხოლო ოპერაცია +1 აწვდის მწკრივის ნომერს 2. და ასე შემდეგ.

სხვა სიტყვებით რომ ვთქვათ, ფორმულის ეს ნაწილი ქმნის განმეორებასრიცხვების თანმიმდევრობა, როგორიცაა 1,1,1,2,2,2,3,3,3,4,4,4,… თითოეული რიცხვი მეორდება იმდენჯერ, რამდენჯერაც არის სვეტები თქვენს დიაპაზონში.

გამოთვალეთ სვეტის ნომერი , თქვენ ქმნით შესაბამის რიცხვთა თანმიმდევრობას MOD ფუნქციის გამოყენებით:

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

რადგან ჩვენს დიაპაზონში 3 სვეტია (A2:C5), თანმიმდევრობა უნდა იყოს 1,2,3,1,2,3,…

MOD ფუნქცია აბრუნებს დანარჩენს გაყოფის შემდეგ.

E2, MOD(ROW(A1)-1, COLUMNS ($A$2:$C$5))+1)

იქცევა

MOD(1-1, 3)+1)

და აბრუნებს 1.

E3-ში MOD(ROW(A2)-1, COLUMNS($A$2:$C$5))+1)

იქცევა

MOD(2-1, 3) +1)

და აბრუნებს 2-ს.

მწკრივისა და სვეტის ნომრების დადგენით, INDEX-ს არ აქვს პრობლემა საჭირო მნიშვნელობის მოპოვებისას.

E2, INDEX($A$2) :$C$5, 1, 1) აბრუნებს მნიშვნელობას მითითებული დიაპაზონის 1-ლი მწკრივიდან და 1-ლი სვეტიდან, ანუ A2 უჯრედიდან.

E3-ში, INDEX($A$2:$C$5, 1 , 2) აბრუნებს მნიშვნელობას 1-ლი მწკრივიდან და მე-2 სვეტიდან, ანუ B2 უჯრედიდან.

და ასე შემდეგ.

მეორე ფორმულა, რომელიც სკანირებს დიაპაზონს c-ით. სვეტი, მუშაობს ანალოგიურად. განსხვავება ისაა, რომ ის იყენებს MOD-ს მწკრივის ნომრის მისაღებად და QUOTIENT-ს სვეტის ნომრის მისაღებად.

TOCOL ფუნქცია არ მუშაობს

თუ TOCOL ფუნქცია უშვებს შეცდომას, დიდი ალბათობით. ეს იყოს ერთ-ერთი ასეთი მიზეზი:

TOCOL არ არის მხარდაჭერილი თქვენს Excel-ში

როცა მიიღებთ #NAME-ს? შეცდომა, ფუნქციის სახელის სწორი მართლწერა პირველიაჩეკი. თუ სახელი სწორია, მაგრამ შეცდომა შენარჩუნებულია, ფუნქცია არ არის ხელმისაწვდომი Excel-ის თქვენს ვერსიაში. ამ შემთხვევაში განიხილეთ TOCOL ალტერნატივის გამოყენება.

მასივი ძალიან დიდია

#NUM შეცდომა მიუთითებს, რომ მასივი ვერ ჯდება სვეტში. ტიპიური შემთხვევაა, როდესაც თქვენ მიმართავთ მთელ სვეტებს ან მწკრივებს.

არ არის საკმარისი ცარიელი უჯრედები

როდესაც #SPILL შეცდომა ხდება, შეამოწმეთ, რომ სვეტი, სადაც არის შეყვანილი ფორმულა. აქვს საკმარისი ცარიელი უჯრედები შედეგებით შესავსებად. თუ უჯრედები ვიზუალურად ცარიელია, დარწმუნდით, რომ მათში არ არის სივრცეები და სხვა არასაბეჭდი სიმბოლოები. დამატებითი ინფორმაციისთვის იხილეთ როგორ გამოვასწოროთ #SPILL შეცდომა Excel-ში.

ასე შეგიძლიათ გამოიყენოთ TOCOL ფუნქცია Excel 365-ში და ალტერნატიული გადაწყვეტილებები ადრინდელ ვერსიებში 2-განზომილებიანი მასივის ერთ სვეტად გადაქცევისთვის. მადლობას გიხდით რომ კითხულობთ და იმედი მაქვს მომავალ კვირას გნახავთ ჩვენს ბლოგზე!

სავარჯიშო სამუშაო წიგნი

Excel TOCOL ფუნქცია - ფორმულის მაგალითები (ფაილი .xlsx)