TOCOL فنکشن کے ساتھ کسی صف یا رینج کو کالم میں تبدیل کرنے کا ایک آسان طریقہ۔

کالم سے قطاروں میں اور ریورس میں ڈیٹا منتقل کرنے کی صلاحیت ایکسل میں کافی عرصے سے موجود ہے۔ تھوڑی دیر کے. لیکن خلیوں کی ایک رینج کو ایک کالم میں تبدیل کرنا کریک کرنا ایک مشکل کام تھا۔ اب، یہ آخر میں بدل رہا ہے. مائیکروسافٹ نے ایک نیا فنکشن متعارف کرایا ہے، جسے TOCOL کہا جاتا ہے، جو پلک جھپکتے ہی ایک صف سے کالم کی تبدیلی کر سکتا ہے۔ ذیل میں ان کاموں کی فہرست ہے جنہیں یہ نیا فنکشن آسانی سے حل کر سکتا ہے۔

Excel TOCOL فنکشن

ایکسل میں TOCOL فنکشن سیلز کی ایک صف یا رینج کو ایک سنگل میں تبدیل کرتا ہے۔ کالم۔

فنکشن تین آرگومنٹس لیتا ہے، لیکن صرف پہلی کی ضرورت ہے۔>Array (ضروری) - ایک صف یا رینج جسے کالم میں تبدیل کرنا ہے۔

نظر انداز کریں (اختیاری) - یہ وضاحت کرتا ہے کہ آیا خالی جگہوں کو نظر انداز کرنا ہے یا/اور غلطیوں کو۔ ان اقدار میں سے ایک ہو سکتی ہے:

• 0 یا چھوڑ دیا گیا (پہلے سے طے شدہ) - تمام اقدار کو رکھیں
• 1 - خالی جگہوں کو نظر انداز کریں
• 2 - غلطیوں کو نظر انداز کریں
• 3 - خالی جگہوں اور غلطیوں کو نظر انداز کریں

Scan_by_column (اختیاری) - اس بات کا تعین کرتا ہے کہ سرنی کو افقی یا عمودی طور پر اسکین کرنا ہے:

• غلط یا چھوڑ دیا گیا (پہلے سے طے شدہ) - صف کو بائیں سے دائیں تک اسکین کریں۔
• TRUE - اوپر سے نیچے تک کالم کے لحاظ سے سرنی کو اسکین کریں۔

تجاویز:

• ایک صف کو ایک قطار میں تبدیل کرنے کے لیے، TOROW کا استعمال کریں۔فنکشن۔
• مخالف کالم سے صف میں تبدیلی کرنے کے لیے، کالم کے حساب سے لپیٹنے کے لیے WRAPCOLS فنکشن یا قطار کے حساب سے لپیٹنے کے لیے WRAPROWS فنکشن کا استعمال کریں۔
• کسی صف کو افقی سے میں منتقل کرنے کے لیے عمودی یا اس کے برعکس، یعنی قطاروں کو کالموں میں تبدیل کریں، TRANSPOSE فنکشن کا استعمال کریں۔

TOCOL کی دستیابی

TOCOL ایک نیا فنکشن ہے، جو Microsoft 365 کے لیے Excel میں تعاون یافتہ ہے (ونڈوز کے لیے اور میک) اور ویب کے لیے ایکسل۔

رینج کو کالم میں تبدیل کرنے کے لیے بنیادی TOCOL فارمولہ

TOCOL فارمولے کو اس کی آسان ترین شکل میں صرف ایک دلیل کی ضرورت ہے - array مثال کے طور پر، 3 کالموں اور 4 قطاروں پر مشتمل دو جہتی صف کو ایک کالم میں رکھنے کے لیے، فارمولہ یہ ہے:

=TOCOL(A2:C5)

فارمولہ صرف ایک سیل میں درج کیا جاتا ہے (E2 in یہ مثال) اور نیچے کے خلیوں میں خود بخود پھیل جاتی ہے۔ ایکسل کے لحاظ سے، نتیجہ کو اسپل رینج کہا جاتا ہے۔

یہ فارمولا کیسے کام کرتا ہے:

تکنیکی طور پر، رینج A2:C5 کو پہلے دو جہتی صف میں تبدیل کیا جاتا ہے۔ براہ کرم سیمی کالون سے الگ کی گئی قطاروں اور کوما سے الگ کردہ کالم دیکھیں:

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL فنکشن صف کو بائیں سے دائیں اسکین کرتا ہے اور اسے ایک جہتی عمودی صف میں تبدیل کرتا ہے:

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

نتیجہ سیل E2 میں رکھا جاتا ہے، جہاں سے یہ نیچے کے خلیوں میں پھیل جاتا ہے۔

ایکسل میں TOCOL فنکشن کو کیسے استعمال کیا جائے - فارمولہ کی مثالیں

کی مزید تفہیم حاصل کرنے کے لیےTOCOL فنکشن کے امکانات اور یہ کن کاموں کا احاطہ کر سکتا ہے، آئیے کچھ فارمولے کی مثالوں پر ایک نظر ڈالتے ہیں۔

خالی خالی جگہوں اور غلطیوں کو نظر انداز کرتے ہوئے صف کو کالم میں تبدیل کریں

جیسا کہ آپ نے پچھلی مثال میں دیکھا ہوگا۔ , پہلے سے طے شدہ TOCOL فارمولہ ماخذ صف سے تمام قدروں کو رکھتا ہے، بشمول خالی خلیات اور غلطیاں۔

نتیجے میں آنے والی صف میں، خالی خلیات کو زیرو سے ظاہر کیا جاتا ہے، جو کافی الجھا ہوا ہو سکتا ہے، خاص طور پر اگر اصل صف میں 0 اقدار۔ اس کا حل یہ ہے کہ خالی جگہوں کو چھوڑ دیں ۔ اس کے لیے، آپ دوسری دلیل کو 1:

=TOCOL(A2:C5, 1)

غلطیوں کو نظر انداز کریں پر سیٹ کریں، دوسری دلیل کو 2:

=TOCOL(A2:C5, 2) <3 پر سیٹ کریں۔

دونوں کو خارج کرنے کے لیے، خالی جگہیں اور خرابیاں ، نظر انداز کریں دلیل کے لیے 3 استعمال کریں:

=TOCOL(A2:C5, 3)

افقی یا عمودی طور پر سرنی کو اسکین کریں

ڈیفالٹ scan_by_column دلیل (FALSE یا چھوڑ دیا گیا) کے ساتھ، TOCOL فنکشن قطار کو افقی طور پر اسکین کرتا ہے۔ کالم کے لحاظ سے ویلیوز پر کارروائی کرنے کے لیے، اس دلیل کو TRUE یا 1 پر سیٹ کریں۔ مثال کے طور پر:

=TOCOL(A2:C5, ,TRUE)

یاد رکھیں کہ، دونوں صورتوں میں، لوٹائی گئی صفیں ایک ہی سائز کی ہیں، لیکن قدروں کو ترتیب دیا گیا ہے۔ ایک مختلف ترتیب میں.

متعدد رینجز کو ایک کالم میں یکجا کریں

اگر آپ کئی غیر متصل رینجز کے ساتھ کام کر رہے ہیں، تو آپ پہلے VSTACK فنکشن کی مدد سے رینجز کو عمودی طور پر ایک ہی صف میں جوڑ سکتے ہیں، اور پھر مشترکہ صف کو کالم میں تبدیل کرنے کے لیے TOCOL کا استعمال کریں۔

فرض کریں کہ پہلی رینج A2:C4 ہے اور دوسری رینج A8:C9 ہے، فارمولہ یہ فارم لیتا ہے:

=TOCOL(VSTACK(A2:C4, A8:C9))

یہ فارمولہ پہلے سے طے شدہ رویے کو ظاہر کرتا ہے - مشترکہ صفوں کو بائیں سے افقی طور پر پڑھتا ہے۔ دائیں طرف جیسا کہ نیچے کی تصویر میں کالم E میں دکھایا گیا ہے۔

اوپر سے نیچے تک اقدار کو عمودی طور پر پڑھنے کے لیے، آپ TOCOL کی تیسری دلیل کو TRUE پر سیٹ کرتے ہیں:

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

براہ کرم توجہ دیں کہ، اس صورت میں، فارمولہ پہلے دونوں صفوں کے کالم A سے، پھر کالم B سے، اور اسی طرح کی قدریں لوٹاتا ہے۔ وجہ یہ ہے کہ TOCOL ایک ہی اسٹیک شدہ صف کو اسکین کرتا ہے، اصل انفرادی حدود کو نہیں۔

اگر آپ کے کاروباری منطق کے لیے اصل رینجز کو عمودی کے بجائے افقی طور پر اسٹیک کرنے کی ضرورت ہے، تو VSTACK کے بجائے HSTACK فنکشن استعمال کریں۔

ہر بعد والی صف کو پچھلی صف کے دائیں جانب جوڑنے کے لیے اور پڑھیں افقی طور پر مشترکہ صفوں کو، فارمولہ یہ ہے:

=TOCOL(HSTACK(A2:C4, A8:C10))

پچھلی صف کے دائیں جانب ہر بعد کی صف کو شامل کرنے اور مشترکہ صفوں کو عمودی طور پر اسکین کرنے کے لیے، فارمولہ یہ ہے:

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

ملٹی کالم رینج سے منفرد قدریں نکالیں

Excel UNIQUE فنکشن آسانی سے کسی ایک کالم یا قطار میں منفردات تلاش کر سکتا ہے اور ساتھ ہی منفرد قطاریں واپس کر سکتا ہے، لیکن یہ اس سے منفرد قدریں نہیں نکال سکتا ایک کثیر کالم سرنی. حل یہ ہے کہ اسے TOCOL فنکشن کے ساتھ استعمال کیا جائے۔

مثال کے طور پر، رینج سے تمام مختلف (مختلف) قدروں کو نکالناA2:C7، فارمولہ یہ ہے:

=UNIQUE(TOCOL(A2:C7))

اس کے علاوہ، آپ SORT فنکشن میں مندرجہ بالا فارمولے کو لپیٹ کر حروف تہجی کی ترتیب میں واپس آنے والی صف کو ترتیب دے سکتے ہیں:

=SORT(UNIQUE(TOCOL(A2:C7)))

ایکسل 365 - 2010 میں رینج کو کالم میں کیسے تبدیل کیا جائے

ایکسل ورژن میں جہاں TOCOL فنکشن تعاون یافتہ نہیں ہے، وہاں سیلز کی رینج کو کالم میں تبدیل کرنے کے چند متبادل طریقے موجود ہیں۔ یہ حل کافی مشکل ہیں، لیکن بہرحال کام کر رہے ہیں۔

رینج کو قطار کے لحاظ سے پڑھنے کے لیے:

INDEX( range ، QUOTIENT(ROW(A1)-1، COLUMNS( رینج ))+1، MOD(ROW(A1)-1، COLUMNS( range ))+1)

رینج کو کالم کے لحاظ سے پڑھنے کے لیے:

INDEX( حد ، MOD(ROW(A1)-1، ROWS( range ))+1، QUOTIENT(ROW(A1)-1، ROWS( range ))+1 )

ہمارے نمونہ ڈیٹاسیٹ کے لیے، فارمولے درج ذیل ہیں:

رینج کو اسکین کرنے کے لیے افقی طور پر بائیں سے دائیں :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

یہ فارمولہ TOCOL فنکشن کے برابر ہے جس میں تیسری دلیل FALSE پر سیٹ کی گئی ہے یا چھوڑ دی گئی ہے:

=TOCOL(A2:C5)

رینج کو اسکین کرنے کے لیے اوپر سے نیچے تک عمودی طور پر :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

یہ فارمولہ TOCOL فنکشن سے موازنہ کرنے والا ہے جس میں تیسری دلیل TRUE پر سیٹ کی گئی ہے:

=TOCOL(A2:C5, ,TRUE)

TOCOL کے برعکس، ہر ایک میں متبادل فارمولے درج کیے جانے چاہئیں۔ سیل جہاں آپ چاہتے ہیں کہ نتائج ظاہر ہوں۔ ہمارے معاملے میں، فارمولے سیلز E2 (قطار کے لحاظ سے) اور G2 (کالم کے لحاظ سے) پر جاتے ہیں، اور پھر قطار 13 میں کاپی کیے جاتے ہیں۔

اگر فارمولے ضرورت سے زیادہ قطاروں میں کاپی کیے جاتے ہیں، a#REF! غلطی "اضافی" خلیوں میں ظاہر ہوگی۔ ایسا ہونے سے روکنے کے لیے، آپ IFERROR فنکشن میں فارمولوں کو اس طرح سے گھوںسلا کر سکتے ہیں:

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

نوٹ کریں کہ فارمولوں کو صحیح طریقے سے کاپی کرنے کے لیے، ہم مطلق سیل حوالہ جات ($) کا استعمال کرتے ہوئے رینج کو لاک کرتے ہیں۔ A$2:$C$5)۔ اس کے بجائے، آپ ایک نامزد رینج استعمال کر سکتے ہیں۔

یہ فارمولے کیسے کام کرتے ہیں

ذیل میں پہلے فارمولے کا تفصیلی بریک ڈاؤن ہے جو سیلز کو قطار کے لحاظ سے ترتیب دیتا ہے:

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

خیال یہ ہے کہ INDEX فنکشن کا استعمال رینج میں اس کے رشتہ دار قطار اور کالم نمبروں کی بنیاد پر کسی مخصوص سیل کی قدر واپس کرنے کے لیے کیا جائے۔

صف نمبر کا حساب اس مجموعہ سے کیا جاتا ہے۔ :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT ایک ڈویژن کا عددی حصہ لوٹاتا ہے۔

عدد کے لیے، آپ ROW(A1)-1 کا استعمال کرتے ہیں، جو a لوٹاتا ہے۔ سیریل نمبر E2 میں 0 سے (پہلا سیل جہاں فارمولہ درج کیا گیا) E13 میں 11 تک (آخری سیل جہاں فارمولہ درج کیا گیا) $2:$C$5)) مستقل ہے اور آپ کی رینج میں کالموں کی تعداد کے برابر ہے (ہمارے معاملے میں 3)۔

اب، اگر آپ پہلے 3 سیلز (E2:E4) کے لیے QUOTIENT کا نتیجہ چیک کرتے ہیں۔ ، آپ دیکھیں گے کہ یہ 0 کے برابر ہے (کیونکہ تقسیم کا عددی حصہ صفر ہے)۔ 1 کو شامل کرنے سے قطار نمبر 1 ملتا ہے۔

اگلے 3 سیلز (E5:E5) کے لیے، QUOTIENT 1 لوٹاتا ہے، اور +1 آپریشن قطار نمبر 2 فراہم کرتا ہے۔ اور اسی طرح۔

دوسرے لفظوں میں، فارمولے کا یہ حصہ ایک تکرار پیدا کرتا ہے۔نمبر کی ترتیب جیسے 1,1,1,2,2,2,3,3,3,4,4,4,… ہر نمبر جتنی بار آپ کی رینج میں کالم ہیں دہرایا جاتا ہے۔

تک کالم نمبر کا حساب لگائیں، آپ MOD فنکشن کا استعمال کرتے ہوئے ایک مناسب نمبر ترتیب بناتے ہیں:

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

چونکہ ہماری رینج (A2:C5) میں 3 کالم ہیں، ترتیب 1,2,3,1,2,3،…

MOD فنکشن تقسیم کے بعد بقیہ کو لوٹاتا ہے۔

E2 میں، MOD(ROW(A1)-1، COLUMNS ($A$2:$C$5))+1)

بنتا ہے

MOD(1-1, 3)+1)

اور 1 لوٹتا ہے۔

E3 میں، MOD(ROW(A2)-1، COLUMNS($A$2:$C$5))+1)

بن جاتا ہے

MOD(2-1, 3) +1)

اور 2 لوٹاتا ہے :$C$5, 1, 1) پہلی قطار اور حوالہ شدہ رینج کے پہلے کالم سے قدر لوٹاتا ہے، یعنی سیل A2 سے۔

E3 میں، INDEX($A$2:$C$5, 1 , 2) پہلی قطار اور دوسرے کالم سے ویلیو لوٹاتا ہے، یعنی سیل B2 سے۔

اور اسی طرح آگے۔

دوسرا فارمولا جو حد کو c سے اسکین کرتا ہے۔ olumn، اسی طرح کام کرتا ہے۔ فرق یہ ہے کہ یہ قطار نمبر حاصل کرنے کے لیے MOD اور کالم نمبر حاصل کرنے کے لیے QUOTIENT کا استعمال کرتا ہے۔

TOCOL فنکشن کام نہیں کر رہا ہے

اگر TOCOL فنکشن غلطی پھینکتا ہے، تو اس کا زیادہ امکان ہے ان وجوہات میں سے ایک ہونا:

TOCOL آپ کے Excel میں تعاون یافتہ نہیں ہے

جب آپ کو #NAME ملتا ہے؟ غلطی، فنکشن کے نام کی صحیح ہجے پہلی چیز ہے۔چیک کریں اگر نام درست ہے لیکن خرابی برقرار ہے تو، فنکشن آپ کے Excel کے ورژن میں دستیاب نہیں ہے۔ اس صورت میں، ایک TOCOL متبادل استعمال کرنے پر غور کریں۔

Array بہت بڑی ہے

#NUM کی خرابی بتاتی ہے کہ صف کالم میں فٹ نہیں ہوسکتی ہے۔ ایک عام معاملہ اس وقت ہوتا ہے جب آپ پورے کالموں یا قطاروں کا حوالہ دیتے ہیں۔

کافی خالی سیل نہیں ہیں

جب #SPILL کی خرابی واقع ہوتی ہے، تو چیک کریں کہ وہ کالم جہاں فارمولہ درج کیا گیا ہے۔ نتائج سے بھرنے کے لیے کافی خالی خلیات ہیں۔ اگر خلیے بصری طور پر خالی ہیں، تو یقینی بنائیں کہ ان میں کوئی خالی جگہ اور دیگر غیر پرنٹنگ حروف موجود نہیں ہیں۔ مزید معلومات کے لیے ملاحظہ کریں کہ ایکسل میں #SPILL کی خرابی کو کیسے ٹھیک کیا جائے۔

اس طرح آپ ایکسل 365 میں TOCOL فنکشن اور سابقہ ​​ورژنز میں متبادل حل استعمال کر سکتے ہیں تاکہ 2-جہتی صف کو ایک کالم میں تبدیل کر سکیں۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ آپ کو اگلے ہفتے ہمارے بلاگ پر ملوں گا!

پریکٹس ورک بک

Excel TOCOL فنکشن - فارمولہ مثالیں (.xlsx فائل)