Njia rahisi ya kubadilisha safu au safu kuwa safu wima yenye chaguo la kukokotoa la TOCOL.

Uwezo wa kubadilisha data kutoka safu wima hadi safu mlalo na kinyume umekuwa katika Excel kwa muda mrefu. kitambo. Lakini kubadilisha safu ya visanduku kuwa safu wima moja ilikuwa kazi gumu kugawanyika. Sasa, hiyo inabadilika hatimaye. Microsoft imeanzisha chaguo mpya la kukokotoa, linaloitwa TOCOL, ambalo linaweza kufanya mageuzi ya safu-kwa-safu kwa kufumba na kufumbua. Ifuatayo ni orodha ya kazi ambazo chaguo hili mpya la kukokotoa linaweza kutatua kwa urahisi.

Kitendaji cha Excel TOCOL

Kitendaji cha TOCOL katika Excel hubadilisha safu au safu ya visanduku kuwa moja. safu.

Chaguo za kukokotoa huchukua hoja tatu, lakini ni ya kwanza pekee inayohitajika.

TOCOL(safu, [puuza], [changanua_kwa_safu_wima])

Wapi:

Msururu (inahitajika) - safu au fungu la visanduku ili kubadilika kuwa safu.

Puuza (si lazima) - inafafanua iwapo itapuuza nafasi zilizo wazi au/na hitilafu. Inaweza kuwa mojawapo ya thamani hizi:

• 0 au imeachwa (chaguomsingi) - weka thamani zote
• 1 - puuza nafasi zilizoachwa wazi
• 2 - puuza makosa
• 3 - kupuuza nafasi zilizoachwa wazi na hitilafu

Scan_by_column (si lazima) - huamua kama kuchanganua safu kwa mlalo au wima:

• FALSE au kuachwa. (changanuo-msingi) - changanua safu kwa safu mlalo kutoka kushoto kwenda kulia.
• TRUE - changanua safu kwa safu kutoka juu hadi chini.

Vidokezo:

• Ili kubadilisha safu kuwa safu mlalo moja, tumia TOROWkipengele cha kukokotoa.
• Ili kufanya ugeuzaji wa safu wima hadi safu kinyume, tumia kitendakazi cha WRAPCOLS kukunja kwa safu wima au kitendakazi cha WRAPROWS kukunja kwa safu mlalo.
• Ili kupitisha safu kutoka mlalo hadi kwenye safu mlalo. wima au kinyume chake, yaani, badilisha safu mlalo hadi safu wima, tumia kitendakazi cha TRANSPOSE.

Upatikanaji wa TOCOL

TOCOL ni chaguo mpya la kukokotoa, ambalo linatumika katika Excel kwa Microsoft 365 (kwa Windows. na Mac) na Excel kwa wavuti.

Mchanganyiko wa TOCOL wa kubadilisha safu kuwa safuwima

Fomula ya TOCOL katika umbo rahisi zaidi inahitaji hoja moja tu - safu . Kwa mfano, ili kuweka safu ya pande mbili inayojumuisha safu wima 3 na safu mlalo 4 kwenye safu wima moja, fomula ni:

=TOCOL(A2:C5)

Fomula imeingizwa katika kisanduku kimoja pekee (E2 in mfano huu) na kumwagika kwenye seli zilizo chini kiotomatiki. Kwa upande wa Excel, matokeo huitwa safu ya kumwagika.

Jinsi fomula hii inavyofanya kazi:

Kitaalam, masafa ya A2:C5 hubadilishwa kwanza kuwa safu ya pande mbili. Tafadhali angalia safu mlalo zilizotenganishwa nusu-koloni na safu wima zilizotenganishwa kwa koma:

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

Chaguo za kukokotoa za TOCOL huchanganua safu kutoka kushoto kwenda kulia na kuibadilisha kuwa safu wima ya mwelekeo mmoja:

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

Matokeo yake yamewekwa kwenye seli E2, ambapo humiminika hadi kwenye seli zilizo chini.

Jinsi ya kutumia kitendakazi cha TOCOL katika Excel - mifano ya fomula

0>Ili kupata ufahamu zaidi wauwezekano wa chaguo za kukokotoa za TOCOL na ni kazi gani inaweza kushughulikia, hebu tuangalie baadhi ya mifano ya fomula.

Badilisha safu hadi safu wima ya kupuuza nafasi zilizo wazi na makosa

Kama ulivyoona katika mfano uliopita. , fomula chaguomsingi ya TOCOL huhifadhi thamani zote kutoka kwa safu chanzo, ikijumuisha visanduku tupu na hitilafu.

Katika safu inayotokana, seli tupu zinawakilishwa na sufuri, jambo ambalo linaweza kutatanisha, hasa ikiwa safu asili ina. 0 maadili. Suluhisho ni kuruka nafasi zilizo wazi . Kwa hili, unaweka hoja ya 2 kuwa 1:

=TOCOL(A2:C5, 1)

Ili kupuuza makosa , weka hoja ya 2 kuwa 2:

=TOCOL(A2:C5, 2)

Ili kuwatenga zote mbili, tupu na hitilafu , tumia 3 kwa hoja ya puuza :

=TOCOL(A2:C5, 3)

Changanua safu mlalo au wima

Kwa hoja chaguomsingi ya scan_by_column (FALSE au imeachwa), chaguo-msingi za TOCOL huchanganua safu mlalo kwa safu mlalo. Ili kuchakata thamani kwa safu wima, weka hoja hii kuwa TRUE au 1. Kwa mfano:

=TOCOL(A2:C5, ,TRUE)

Ona kwamba, katika hali zote mbili, safu zilizorejeshwa ni za ukubwa sawa, lakini thamani zimepangwa. kwa utaratibu tofauti.

Changanisha safu nyingi katika safu wima moja

Ikiwa unashughulika na safu kadhaa zisizofungamana, basi unaweza kwanza kuchanganya masafa kiwima hadi safu moja kwa usaidizi wa chaguo za kukokotoa za VSTACK, na kisha utumie TOCOL kubadilisha safu iliyounganishwa kuwa safu.

Kwa kuchukulia masafa ya kwanza ni A2:C4 na safu ya pili ni A8:C9, fomula inachukua fomu hii:

=TOCOL(VSTACK(A2:C4, A8:C9))

Fomula hii inaonyesha tabia chaguomsingi - husoma safu zilizounganishwa kwa mlalo kutoka kushoto. kulia kama inavyoonyeshwa katika safu wima E kwenye picha iliyo hapa chini.

Ili kusoma thamani kiwima kutoka juu hadi chini, umeweka hoja ya 3 ya TOCOL kuwa TRUE:

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

Tafadhali zingatia kwamba, katika kesi hii, fomula kwanza inarudisha maadili kutoka safu A ya safu zote mbili, kisha kutoka safu B, na kadhalika. Sababu ni kwamba TOCOL huchanganua safu moja iliyorundikwa, si safu mahususi asili.

Ikiwa mantiki ya biashara yako inahitaji kuweka safu asili kwa mlalo badala ya wima, basi tumia chaguo la kukokotoa la HSTACK badala ya VSTACK.

Ili kuambatisha kila safu inayofuata upande wa kulia wa safu iliyotangulia na usome safu zilizounganishwa kwa mlalo, fomula ni:

=TOCOL(HSTACK(A2:C4, A8:C10))

Ili kuongeza kila safu inayofuata upande wa kulia wa safu iliyotangulia na kuchanganua safu zilizounganishwa kiwima, fomula ni:

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE) . safu ya safu wima nyingi. Suluhisho ni kuitumia pamoja na kitendakazi cha TOCOL.

Kwa mfano, kutoa thamani zote tofauti (tofauti) kutoka kwa safu.A2:C7, fomula ni:

=UNIQUE(TOCOL(A2:C7))

Zaidi ya hayo, unaweza kufunga fomula iliyo hapo juu katika chaguo la kukokotoa la SORT ili kupanga safu iliyorejeshwa kwa mpangilio wa alfabeti:

=SORT(UNIQUE(TOCOL(A2:C7)))

Jinsi ya kubadilisha fungu la visanduku kuwa safu wima katika Excel 365 - 2010

Katika matoleo ya Excel ambapo kitendakazi cha TOCOL hakitumiki, kuna njia kadhaa mbadala za kubadilisha safu ya visanduku kuwa safu. Suluhu hizi ni gumu sana, lakini zinafanya kazi.

Ili kusoma masafa kwa safu mlalo:

INDEX( fungu , QUOTIENT(ROW(A1)-1, COLUMNS( ) masafa ))+1, MOD(ROW(A1)-1, COLUMNS( fungu )))+1)

Kusoma masafa kwa safu:

INDEX( safu , MOD(ROW(A1)-1, SAFU( safu ))+1, QUOTIENT(ROW(A1)-1, ROWS( safu ))+1 )

Kwa sampuli ya seti yetu ya data, fomula ni kama ifuatavyo:

Kuchanganua masafa mlalo kutoka kushoto kwenda kulia :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

Fomula hii ni sawa na chaguo za kukokotoa za TOCOL na hoja ya 3 imewekwa kuwa FALSE au imeachwa:

=TOCOL(A2:C5)

Ili kuchanganua masafa wima kutoka juu hadi chini :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

Mchanganyiko huu unalinganishwa na chaguo za kukokotoa za TOCOL na hoja ya 3 imewekwa kuwa TRUE:

=TOCOL(A2:C5, ,TRUE)

Tofauti na TOCOL, fomula mbadala zinapaswa kuandikwa katika kila moja. seli ambapo ungependa matokeo yaonekane. Kwa upande wetu, fomula huenda kwa seli E2 (kwa safu mlalo) na G2 (kwa safu wima), na kisha kunakiliwa hadi safu mlalo ya 13.

Ikiwa fomula zitanakiliwa kwa safu mlalo zaidi kuliko inavyohitajika, a.#KUMBUKUMBU! hitilafu itaonekana katika seli "ziada". Ili kuzuia hili kutokea, unaweza kuweka fomula katika chaguo za kukokotoa za IFERROR kama hii:

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

Tambua kwamba ili fomula zinakili kwa usahihi, tunafunga fungu la visanduku kwa kutumia marejeleo kamili ya seli ($ A$2:$C$5). Badala yake, unaweza kutumia safu iliyotajwa.

Jinsi fomula hizi zinavyofanya kazi

Hapa chini kuna uchanganuzi wa kina wa fomula ya kwanza ambayo hupanga visanduku kwa safu mlalo:

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

Wazo ni kutumia chaguo la kukokotoa INDEX kurudisha thamani ya kisanduku fulani kulingana na safu mlalo na nambari zake za safu wima katika safu.

Nambari ya safu huhesabiwa kwa mchanganyiko huu. :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT hurejesha sehemu kamili ya kitengo.

Kwa nambari , unatumia ROW(A1)-1, ambayo hurejesha a nambari ya mfululizo kutoka 0 katika E2 (kisanduku cha kwanza ambapo fomula iliingia) hadi 11 katika E13 (kisanduku cha mwisho ambapo fomula iliingia).

denominata inatolewa na COLUMNS($A $2:$C$5)) haibadiliki na ni sawa na idadi ya safu wima katika safu yako (kwa upande wetu 3).

Sasa, ukiangalia matokeo ya QUOTIENT ya seli 3 za kwanza (E2:E4) , utaona kuwa ni sawa na 0 (kwa sababu sehemu kamili ya mgawanyiko ni sifuri). Kuongeza 1 kunatoa nambari ya safu mlalo 1.

Kwa seli 3 zinazofuata (E5:E5), QUOTIENT hurejesha 1, na operesheni ya +1 hutoa safu mlalo nambari 2. Na kadhalika.

Kwa maneno mengine, sehemu hii ya fomula inaunda kurudiamfuatano wa nambari kama vile 1,1,1,2,2,2,3,3,3,4,4,4,… Kila nambari hurudia mara nyingi kama kuna safu wima katika safu yako.

Kwa kukokotoa nambari ya safuwima , unaunda mfuatano wa nambari ufaao kwa kutumia kitendakazi cha MOD:

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

Kwa vile kuna safu wima 3 katika safu yetu (A2:C5), a mfuatano lazima uwe 1,2,3,1,2,3,…

Kitendaji cha MOD hurejesha salio baada ya kugawanya.

Katika E2, MOD(ROW(A1)-1, COLUMNS ($A$2:$C$5))+1)

inakuwa

MOD(1-1, 3)+1)

na kurejesha 1.

Katika E3, MOD(ROW(A2)-1, COLUMNS($A$2:$C$5))+1)

inakuwa

MOD(2-1, 3) +1)

na kurejesha 2.

Nambari za safu mlalo na safu wima zikiwa zimeanzishwa, INDEX haina matatizo katika kuleta thamani inayohitajika.

Katika E2, INDEX($A$2 :$C$5, 1, 1) hurejesha thamani kutoka safu mlalo ya 1 na safu wima ya 1 ya safu inayorejelewa, yaani kutoka kisanduku A2.

Katika E3, INDEX($A$2:$C$5, 1 , 2) hurejesha thamani kutoka safu mlalo ya 1 na safu wima ya 2, yaani kutoka kisanduku B2.

Na kadhalika.

Mfumo wa pili unaochanganua masafa kwa c. olumn, inafanya kazi kwa njia sawa. Tofauti ni kwamba hutumia MOD kupata nambari ya safu mlalo na QUOTIENT ili kupata nambari ya safu wima.

Kitendakazi cha TOCOL hakifanyi kazi

Chaguo la kukokotoa la TOCOL likitupa hitilafu, kuna uwezekano mkubwa. kuwa mojawapo ya sababu hizi:

TOCOL haitumiki katika Excel yako

Unapopata #JINA? kosa, tahajia sahihi ya jina la chaguo la kukokotoa ndilo jambo la kwanza kufanyaangalia. Ikiwa jina ni sahihi lakini hitilafu inaendelea, chaguo la kukokotoa halipatikani katika toleo lako la Excel. Katika hali hii, zingatia kutumia mbadala wa TOCOL.

Mkusanyiko ni mkubwa mno

Hitilafu ya #NUM inaonyesha kuwa safu haiwezi kutoshea kwenye safu. Hali ya kawaida ni unaporejelea safu wima au safu mlalo nzima.

Hakuna visanduku tupu vya kutosha

Hitilafu ya #SPILL inapotokea, hakikisha kuwa safu wima ambapo fomula imeingizwa. ina seli tupu za kutosha kujazwa na matokeo. Ikiwa seli ziko wazi, hakikisha hakuna nafasi na vibambo vingine visivyo vya uchapishaji ndani yake. Kwa maelezo zaidi, angalia Jinsi ya kurekebisha hitilafu ya #SPILL katika Excel.

Hivyo ndivyo unavyoweza kutumia kitendakazi cha TOCOL katika Excel 365 na suluhu mbadala katika matoleo ya awali ili kubadilisha safu ya 2-dimensional kuwa safu wima moja. Ninakushukuru kwa kusoma na natumai kukuona kwenye blogu yetu wiki ijayo!

Jiandikishe kwa kitabu cha mazoezi

kitendaji cha Excel TOCOL - mifano ya fomula (faili.xlsx)