အခင်းအကျင်း သို့မဟုတ် အပိုင်းအခြားတစ်ခုအား TOCOL လုပ်ဆောင်ချက်ပါရှိသော ကော်လံတစ်ခုအဖြစ်သို့ ပြောင်းလဲရန် လွယ်ကူသောနည်းလမ်းတစ်ခုဖြစ်သည်။

ကော်လံများမှ ဒေတာများကို အတန်းများဆီသို့ ကူးပြောင်းခြင်းနှင့် ပြောင်းပြန်လှန်နိုင်စွမ်းသည် Excel တွင် အတော်လေးကြာခဲ့ပြီဖြစ်သည်။ ခဏကြာ။ သို့သော် ဆဲလ်အကွာအဝေးကို ကော်လံတစ်ခုတည်းအဖြစ်သို့ ပြောင်းလဲခြင်းသည် အက်ကွဲရန် ခက်ခဲသည်။ အခုနောက်ဆုံးတော့ ပြောင်းလဲသွားပြီ။ Microsoft သည် မှိတ်တုတ်မှိတ်တုတ်အတွင်း array-to-column အသွင်ကူးပြောင်းမှုကို လုပ်ဆောင်နိုင်သည့် TOCOL ဟုခေါ်သော လုပ်ဆောင်ချက်အသစ်ကို မိတ်ဆက်ပေးခဲ့သည်။ အောက်တွင် ဤလုပ်ဆောင်ချက်အသစ်သည် အလွယ်တကူဖြေရှင်းနိုင်သော လုပ်ဆောင်စရာများစာရင်းဖြစ်သည်။

Excel TOCOL လုပ်ဆောင်ချက်

Excel ရှိ TOCOL လုပ်ဆောင်ချက်သည် array သို့မဟုတ် ဆဲလ်အကွာအဝေးကို တစ်ခုတည်းအဖြစ်သို့ ပြောင်းလဲပေးသည် ကော်လံ။

လုပ်ဆောင်ချက်သည် အကြောင်းပြချက်သုံးခုကိုယူသည်၊ သို့သော် ပထမတစ်ခုသာလိုအပ်ပါသည်။

TOCOL(array၊ [ignore]၊ [scan_by_column])

Where:

Array (လိုအပ်သည်) - ကော်လံတစ်ခုအသွင်ပြောင်းရန် array သို့မဟုတ် အပိုင်းအခြား။

လျစ်လျူရှု (ချန်လှပ်ထားနိုင်သည်) - ကွက်လပ်များ သို့မဟုတ်/နှင့် အမှားများကို လျစ်လျူရှုခြင်းရှိမရှိ သတ်မှတ်သည်။ ဤတန်ဖိုးများထဲမှ တစ်ခု ဖြစ်နိုင်သည်-

• 0 သို့မဟုတ် ချန်လှပ်ထား (မူလ) - တန်ဖိုးများအားလုံးကို သိမ်းဆည်းပါ
• 1 - ကွက်လပ်များကို လျစ်လျူရှုပါ
• 2 - အမှားများကို လျစ်လျူရှုပါ
• 3 - ကွက်လပ်နှင့် အမှားများကို လျစ်လျူရှုပါ

Scan_by_column (ချန်လှပ်ထားနိုင်သည်) - အခင်းအကျင်းကို အလျားလိုက် သို့မဟုတ် ဒေါင်လိုက်စကင်န်လုပ်ခြင်းရှိမရှိ ဆုံးဖြတ်သည်-

• မှားသည် သို့မဟုတ် ချန်လှပ်ထားပါသည် (ပုံသေ) - ဘယ်မှညာသို့ အတန်းအလိုက် array ကို စကင်န်ဖတ်ပါ။
• TRUE - ကော်လံကို အပေါ်မှအောက်ခြေအထိ စကင်န်ဖတ်ပါ။

အကြံပြုချက်များ-

• array တစ်ခုအား အတန်းတစ်ခုသို့ပြောင်းရန် TOROW ကိုသုံးပါ။လုပ်ဆောင်ချက်။
• ဆန့်ကျင်ဘက် ကော်လံမှ အခင်းအကျင်း အသွင်ကူးပြောင်းမှုကို ပြုလုပ်ရန်၊ ကော်လံအလိုက် ပတ်ရန် သို့မဟုတ် WRAPROWS လုပ်ဆောင်ချက်ကို အတန်းအလိုက် ပတ်ရန် WRAPCOLS လုပ်ဆောင်ချက်ကို အသုံးပြုပါ။
• အခင်းအကျင်းတစ်ခုအား အလျားလိုက်သို့ ကူးပြောင်းရန် ဒေါင်လိုက် သို့မဟုတ် အပြန်အလှန်အားဖြင့် ဆိုလိုသည်မှာ အတန်းများကို ကော်လံများပြောင်းကာ TRANSPOSE လုပ်ဆောင်ချက်ကို အသုံးပြုပါ။

TOCOL ရရှိနိုင်မှု

TOCOL သည် Microsoft 365 အတွက် Excel တွင် ပံ့ပိုးပေးထားသည့် လုပ်ဆောင်ချက်အသစ်တစ်ခု (Windows အတွက် နှင့် Mac) နှင့် ဝဘ်အတွက် Excel။

အကွာအဝေးကို ကော်လံအဖြစ် ပြောင်းလဲရန် အခြေခံ TOCOL ဖော်မြူလာ

၎င်း၏ အရိုးရှင်းဆုံးပုံစံရှိ TOCOL ဖော်မြူလာသည် အကြောင်းပြချက်တစ်ခုသာ လိုအပ်သည် - Array ဥပမာအားဖြင့်၊ ကော်လံ 3 ခုနှင့် အတန်း 4 တန်းပါဝင်သော နှစ်ဘက်မြင် array တစ်ခုကို ကော်လံတစ်ခုတည်းတွင် ထားရှိရန်၊ ဖော်မြူလာမှာ-

=TOCOL(A2:C5)

ဖော်မြူလာကို ဆဲလ်တစ်ခုတွင်သာ ထည့်သွင်းသည် (E2 in ဤဥပမာ) သည် အောက်ဖော်ပြပါဆဲလ်များထဲသို့ အလိုအလျောက် ယိုဖိတ်သွားသည်။ Excel ၏စည်းကမ်းချက်များအရ၊ ရလဒ်ကို spill range ဟုခေါ်သည်။

ဤဖော်မြူလာ အလုပ်လုပ်ပုံ-

နည်းပညာအရ၊ အပိုင်းအခြား A2:C5 ကို ပထမဆုံး နှစ်ဖက်မြင် ခင်းကျင်းတစ်ခုအဖြစ်သို့ ပြောင်းလဲပါသည်။ ကျေးဇူးပြု၍ semicolon ခြားထားသော အတန်းများနှင့် ကော်မာ-ခြားထားသော ကော်လံများကို သတိပြုပါ-

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL လုပ်ဆောင်ချက်သည် array ကို ဘယ်မှညာသို့ စကင်န်ဖတ်ပြီး ၎င်းကို တစ်ဖက်မြင် ဒေါင်လိုက် အခင်းအကျင်းအဖြစ် ပြောင်းလဲပေးသည်-

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

ရလဒ်ကို ဆဲလ် E2 တွင် ထားရှိကာ ၎င်းသည် အောက်ဆဲလ်များအတွင်းသို့ စိမ့်ဝင်သွားပါသည်။

Excel တွင် TOCOL လုပ်ဆောင်ချက်ကို အသုံးပြုနည်း - ဖော်မြူလာနမူနာများ

ပို၍နားလည်ရန်TOCOL လုပ်ဆောင်ချက်၏ ဖြစ်နိုင်ချေများနှင့် ၎င်းသည် မည်သည့်လုပ်ငန်းတာဝန်များကို ထမ်းဆောင်နိုင်သည်၊ ဖော်မြူလာနမူနာအချို့ကို ကြည့်ကြပါစို့။

ကွက်လပ်များနှင့် အမှားများကို လျစ်လျူရှုထားသော ကော်လံအဖြစ် array သို့ပြောင်းပါ

ယခင်ဥပမာတွင် သင်သတိပြုမိခဲ့သည့်အတိုင်း ၊ မူရင်း TOCOL ဖော်မြူလာသည် ဆဲလ်အလွတ်များနှင့် အမှားအယွင်းများ အပါအဝင် အရင်းအမြစ်ခင်းကျင်းမှုမှ တန်ဖိုးအားလုံးကို သိမ်းဆည်းထားသည်။

ရလဒ်ထွက်ရှိသော ခင်းကျင်းတွင်၊ ဆဲလ်အလွတ်များကို သုညဖြင့် ကိုယ်စားပြုသည်၊၊ အထူးသဖြင့် မူလ ခင်းကျင်းတွင် အလွန်ရှုပ်ထွေးနေပါက၊ ဘ၀တန်ဖိုးများ။ ဖြေရှင်းချက်မှာ ကွက်လပ်များကို ကျော်ရန် ဖြစ်သည်။ ၎င်းအတွက်၊ သင်သည် 2nd argument ကို 1 အဖြစ် သတ်မှတ်သည်-

=TOCOL(A2:C5, 1)

အမှားများကို လျစ်လျူရှုရန် ၊ 2nd argument ကို 2:

=TOCOL(A2:C5, 2)

နှစ်ခုလုံးကို ဖယ်ထုတ်ရန် ကွက်လပ်များနှင့် အမှားအယွင်းများ ၊ ignore အငြင်းအခုံအတွက် 3 ကိုသုံးပါ-

=TOCOL(A2:C5, 3)

အခင်းအကျင်းကို အလျားလိုက် သို့မဟုတ် ဒေါင်လိုက်စကင်န်လုပ်ပါ

ပုံသေ scan_by_column အကြောင်းပြချက်ဖြင့် (FALSE သို့မဟုတ် ချန်လှပ်ထား) သည် TOCOL လုပ်ဆောင်ချက်သည် array ကို အလျားလိုက် အတန်းလိုက် စကင်န်ဖတ်သည်။ ကော်လံအလိုက် တန်ဖိုးများကို လုပ်ဆောင်ရန်၊ ဤအငြင်းအခုံကို TRUE သို့မဟုတ် 1 ဟု သတ်မှတ်ပါ။ ဥပမာ-

=TOCOL(A2:C5, ,TRUE)

ဖြစ်ရပ်နှစ်ခုစလုံးတွင် ပြန်ပေးထားသော array များသည် အရွယ်အစားတူသော်လည်း တန်ဖိုးများကို စီစဉ်ပေးထားကြောင်း သတိပြုပါ။ ကွဲပြားခြားနားသောအမိန့်၌။

အများအပြားကို ကော်လံတစ်ခုသို့ ပေါင်းစပ်ပါ

သင်သည် ဆက်နွှယ်မှုမရှိသော အပိုင်းအခြားများစွာနှင့် ဆက်ဆံနေပါက အပိုင်းအခြားများကို VSTACK လုပ်ဆောင်ချက်၏အကူအညီဖြင့် တစ်ခုတည်းသော ခင်းကျင်းတစ်ခုသို့ ဒေါင်လိုက်ပေါင်းစပ်နိုင်ပြီး၊ ထို့နောက် ပေါင်းစပ် ခင်းကျင်းမှုကို ကော်လံအဖြစ် ပြောင်းလဲရန် TOCOL ကို အသုံးပြုပါ။

ပထမအကွာအဝေးသည် A2:C4 ဖြစ်ပြီး ဒုတိယအပိုင်းသည် A8:C9 ဖြစ်သည်ဟု ယူဆပါက၊ ဖော်မြူလာသည် ဤပုံစံကို ယူဆောင်သည်-

=TOCOL(VSTACK(A2:C4, A8:C9))

ဤဖော်မြူလာသည် ပုံသေအပြုအမူကို သရုပ်ပြသည် - ပေါင်းစပ် array များကို ဘယ်ဘက်မှ အလျားလိုက်ဖတ်သည် အောက်ပုံရှိ ကော်လံ E တွင် ပြထားသည့်အတိုင်း ညာဘက်သို့။

တန်ဖိုးများကို အပေါ်မှအောက်ခြေအထိ ဒေါင်လိုက်ဖတ်ရန်၊ သင်သည် TOCOL ၏ တတိယမြောက် အကြောင်းပြချက်ကို TRUE ဟု သတ်မှတ်သည်-

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

ဤကိစ္စတွင်၊ ဖော်မြူလာသည် ခင်းကျင်းနှစ်ခုလုံး၏ ကော်လံ A မှ တန်ဖိုးများကို ဦးစွာပြန်ပေးသည်၊ ထို့နောက် ကော်လံ B မှ စသည်ဖြင့် ပြန်ပေးကြောင်း ကျေးဇူးပြု၍ သတိပြုပါ။ အကြောင်းရင်းမှာ TOCOL သည် မူရင်းတစ်ဦးချင်းစီအပိုင်းအခြားများမဟုတ်ဘဲ တစ်ခုတည်းသော stacked array တစ်ခုကို စကင်န်ဖတ်သောကြောင့်ဖြစ်သည်။

သင့်လုပ်ငန်း၏ ယုတ္တိဗေဒသည် ဒေါင်လိုက်မဟုတ်ဘဲ မူလအပိုင်းအခြားများကို အလျားလိုက် ထပ်စီရန် လိုအပ်ပါက၊ ထို့နောက် VSTACK အစား HSTACK လုပ်ဆောင်ချက်ကို အသုံးပြုပါ။

ယခင် array တစ်ခုစီ၏ ညာဘက်တွင် နောက်ဆက်တွဲ array တစ်ခုစီကို ပေါင်းထည့်ရန် နှင့် ဖတ်ရန် ပေါင်းစပ် array များကို အလျားလိုက်၊ ဖော်မြူလာမှာ-

=TOCOL(HSTACK(A2:C4, A8:C10))

နောက်ဆက်တွဲ array တစ်ခုစီကို ယခင် array ၏ညာဘက်တွင် ပေါင်းထည့်ရန်နှင့် ပေါင်းစပ် array များကို ဒေါင်လိုက်စကင်န်ပြုလုပ်ရန်၊ ဖော်မြူလာမှာ-

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

ကော်လံမျိုးစုံအကွာအဝေးမှ ထူးခြားသောတန်ဖိုးများကို ထုတ်ယူပါ

Excel UNIQUE လုပ်ဆောင်ချက်သည် ကော်လံတစ်ခု သို့မဟုတ် အတန်းတစ်ခုတွင် ထူးခြားမှုများကို အလွယ်တကူ ရှာဖွေနိုင်သည့်အပြင် ထူးခြားသောအတန်းများကို ပြန်ပေးသော်လည်း ၎င်းမှ သီးသန့်တန်ဖိုးများကို ထုတ်ယူ၍မရပါ။ multi-column array တစ်ခု။ ဖြေရှင်းချက်မှာ TOCOL လုပ်ဆောင်ချက်နှင့် တွဲသုံးရန်ဖြစ်သည်။

ဥပမာအားဖြင့်၊ အပိုင်းအခြားမှ မတူညီသော (ကွဲပြားသော) တန်ဖိုးများကို ထုတ်ယူရန်၊A2:C7၊ ဖော်မြူလာမှာ-

=UNIQUE(TOCOL(A2:C7))

ထို့အပြင်၊ သင်သည် ပြန်လာသော array ကို အက္ခရာစဉ်အလိုက် စီစဉ်ရန် အထက်ဖော်ပြပါ ဖော်မြူလာကို SORT လုပ်ဆောင်ချက်တွင် ခြုံထားနိုင်သည်-

=SORT(UNIQUE(TOCOL(A2:C7)))

Excel 365 - 2010 တွင် အပိုင်းအခြားကို ကော်လံအဖြစ်သို့ ပြောင်းနည်း

TOCOL လုပ်ဆောင်ချက်ကို ပံ့ပိုးမထားသည့် Excel ဗားရှင်းများတွင်၊ ဆဲလ်အကွာအဝေးကို ကော်လံတစ်ခုအဖြစ် ပြောင်းလဲရန် အခြားနည်းလမ်းအချို့ ရှိပါသည်။ ဤဖြေရှင်းနည်းများသည် ခက်ခဲသော်လည်း မည်သို့ပင်ဖြစ်စေ အလုပ်ဖြစ်ပါမည်။

အတန်းအလိုက် အပိုင်းအခြားကို ဖတ်ရန်-

INDEX( အပိုင်းအခြား ၊ QUOTIENT(ROW(A1)-1၊ COLUMNS( ) အပိုင်းအခြား ))+1၊ MOD(ROW(A1)-1၊ COLUMNS( အပိုင်းအခြား ))+1)

ကော်လံအလိုက် အပိုင်းအခြားကို ဖတ်ရန်-

INDEX( အပိုင်းအခြား ၊ MOD(ROW(A1)-1၊ ROWS( အပိုင်းအခြား ))+1၊ QUOTIENT(ROW(A1)-1၊ ROWS( အပိုင်းအခြား ))+1 )

ကျွန်ုပ်တို့၏နမူနာဒေတာအတွဲအတွက်၊ ဖော်မြူလာများမှာ အောက်ပါအတိုင်းဖြစ်သည်-

အကွာအဝေး ဘယ်မှညာသို့ အလျားလိုက်စကန်ဖတ်ရန် :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

ဤဖော်မြူလာသည် FALSE ဟုသတ်မှတ်ထားသော 3rd အငြင်းအခုံဖြင့် TOCOL လုပ်ဆောင်ချက်နှင့် ညီမျှသည်-

=TOCOL(A2:C5)

အကွာအဝေးကို စကင်န်ဖတ်ရန် အပေါ်မှအောက်ခြေသို့ဒေါင်လိုက် :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

ဤဖော်မြူလာသည် TOCOL လုပ်ဆောင်ချက်ကို TRUE ဟုသတ်မှတ်ထားသည့် 3rd အကြောင်းပြချက်ဖြင့် TOCOL လုပ်ဆောင်ချက်နှင့် နှိုင်းယှဉ်နိုင်သည်-

=TOCOL(A2:C5, ,TRUE)

TOCOL နှင့်မတူဘဲ၊ တစ်ခုစီတွင် အစားထိုးဖော်မြူလာများကို ထည့်သွင်းသင့်သည် ရလဒ်များ ပေါ်လာစေလိုသည့် ဆဲလ်။ ကျွန်ုပ်တို့၏အခြေအနေတွင်၊ ဖော်မြူလာများကို ဆဲလ် E2 (အတန်းအလိုက်) နှင့် G2 (ကော်လံအလိုက်) သို့သွားပြီး အတန်း 13 သို့ ကူးယူပါသည်။

ဖော်မြူလာများကို လိုအပ်သည်ထက်ပို၍ အတန်းများသို့ကူးယူပါက၊#REF အမှားသည် "အပို" ဆဲလ်များတွင်ပေါ်လာလိမ့်မည်။ ထိုသို့မဖြစ်ပွားစေရန်အတွက်၊ သင်သည် ဤကဲ့သို့သော IFERROR လုပ်ဆောင်ချက်တွင် ဖော်မြူလာများကို စုစည်းနိုင်သည်-

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

ဖော်မြူလာများကို မှန်ကန်စွာ ကူးယူရန်အတွက်၊ ကျွန်ုပ်တို့သည် absolute cell ကိုးကားချက်များသုံးပြီး အပိုင်းအခြားကို လော့ခ်ချနိုင်သည် ($ A$2:$C$5)။ ယင်းအစား၊ သင်သည် အမည်ပေးထားသော အပိုင်းအခြားကို အသုံးပြုနိုင်သည်။

ဤဖော်မြူလာများ အလုပ်လုပ်ပုံ

အောက်တွင် ဆဲလ်များကို အတန်းအလိုက် စီစဉ်ပေးသည့် ပထမဖော်မြူလာ၏ အသေးစိတ်ခွဲခြမ်းစိတ်ဖြာချက်ဖြစ်သည်-

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

အကွာအဝေးရှိ ၎င်း၏ဆွေမျိုးအတန်းနှင့် ကော်လံနံပါတ်များကို အခြေခံ၍ ဆဲလ်တစ်ခု၏တန်ဖိုးကို ပြန်ပေးရန်အတွက် INDEX လုပ်ဆောင်ချက်ကို အသုံးပြုရန် စိတ်ကူးဖြစ်သည်။

အတန်းနံပါတ် ကို ဤပေါင်းစပ်မှုဖြင့် တွက်ချက်ပါသည်။ :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT သည် ပိုင်းခြားမှုတစ်ခု၏ ကိန်းပြည့်အပိုင်းကို ပြန်ပေးသည်။

ပိုင်းခြား အတွက်၊ သင်သည် ROW(A1)-1 ကိုသုံးသည်၊ ၎င်းကို ပြန်ပေးသည် E2 တွင် 0 မှ နံပါတ်စဉ် (ဖော်မြူလာထည့်သွင်းသည့် ပထမဆဲလ်) မှ E13 တွင် 11 (ဖော်မြူလာထည့်သွင်းသည့် နောက်ဆုံးဆဲလ်) သို့)

ပိုင်းခြေ သည် COLUMNS($A) မှ ပေးပို့သည်။ $2:$C$5)) သည် အဆက်မပြတ်ဖြစ်ပြီး သင့်အပိုင်းအခြားရှိ ကော်လံအရေအတွက် (ကျွန်ုပ်တို့၏ကိစ္စတွင် 3) နှင့် ညီမျှပါသည်။

ယခု၊ သင်သည် ပထမဆဲလ် 3 ခုအတွက် QUOTIENT ရလဒ်ကို စစ်ဆေးပါက (E2:E4) ၎င်းသည် 0 နှင့် ညီမျှကြောင်း သင်တွေ့လိမ့်မည် (ကိန်းပြည့်အပိုင်းသည် သုညဖြစ်သောကြောင့်)။ 1 ကို ပေါင်းထည့်ခြင်းသည် အတန်းနံပါတ် 1 ကိုပေးသည်။

နောက်ထပ် ဆဲလ် 3 ခု (E5:E5) အတွက် QUOTIENT သည် 1 နှင့် +1 လုပ်ဆောင်ချက်သည် အတန်းနံပါတ် 2 ကို ပေးသည်။ စသည်တို့ဖြစ်သည်။

တစ်နည်းဆိုရသော် ဖော်မြူလာ၏ ဤအပိုင်းသည် ထပ်ခါထပ်ခါ ပြုလုပ်သည်။1,1,1,2,2,2,3,3,3,4,4,4, ကဲ့သို့သော နံပါတ် sequence... နံပါတ်တစ်ခုစီသည် သင့်အပိုင်းအခြားရှိ ကော်လံများရှိသကဲ့သို့ အကြိမ်များစွာ ထပ်လုပ်ပါသည်။

သို့ ကော်လံနံပါတ် ကို တွက်ချက်ပါ၊ MOD လုပ်ဆောင်ချက်ကို အသုံးပြု၍ သင့်လျော်သော နံပါတ်စဉ်တစ်ခုကို သင်တည်ဆောက်ပါသည်-

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

ကျွန်ုပ်တို့၏အပိုင်းအခြား (A2:C5) တွင် ကော်လံ 3 ခုပါသောကြောင့်၊ sequence သည် 1,2,3,1,2,3,…

MOD လုပ်ဆောင်ချက်သည် ပိုင်းခြားပြီးနောက် အကြွင်းကို ပြန်ပေးသည်။

E2၊ MOD(ROW(A1)-1၊ COLUMNS ($A$2:$C$5))+1)

ဖြစ်လာသည်

MOD(1-1၊ 3)+1)

ပြီး 1 ပြန်လာသည်။

E3၊ MOD(ROW(A2)-1၊ COLUMNS($A$2:$C$5))+1)

ဖြစ်လာသည်

MOD(2-1၊ 3) +1)

ပြီး 2 ကို ပြန်ပေးသည်။

အတန်းနှင့် ကော်လံ နံပါတ်များကို သတ်မှတ်ပေးခြင်းဖြင့် INDEX သည် လိုအပ်သောတန်ဖိုးကို ရယူရာတွင် ပြဿနာမရှိပါ။

E2 တွင် INDEX($A$2 :$C$5၊ 1၊ 1) သည် ရည်ညွှန်းထားသော အပိုင်းအခြား၏ 1st အတန်းနှင့် 1st ကော်လံမှ တန်ဖိုးကို ပြန်ပေးသည်၊ ဆိုလိုသည်မှာ ဆဲလ် A2 မှ။

E3 တွင်၊ INDEX($A$2:$C$5၊ 1၊ ၊ 2) 1st row နှင့် 2nd ကော်လံမှ တန်ဖိုးကို ပြန်ပေးသည်၊ ဆိုလိုသည်မှာ ဆဲလ် B2 မှဖြစ်သည်။

ထို့အပြင် အခြားသောပုံသေနည်း။

အပိုင်းအခြားကို c ဖြင့် စကင်န်ဖတ်သော ဒုတိယဖော်မြူလာ olumn, အလားတူနည်းလမ်းဖြင့်အလုပ်လုပ်ပါတယ်။ ကွာခြားချက်မှာ အတန်းနံပါတ်နှင့် QUOTIENT ကိုရရန် MOD ကို အသုံးပြုရခြင်းမှာ ကော်လံနံပါတ်ကို ရယူရန်ဖြစ်သည်။

TOCOL လုပ်ဆောင်ချက် အလုပ်မလုပ်ပါ

TOCOL လုပ်ဆောင်ချက်သည် အမှားအယွင်းတစ်ခု ကျရောက်ပါက ဖြစ်နိုင်ချေများပါသည်။ ဤအကြောင်းအရင်းများထဲမှတစ်ခုဖြစ်သည်-

TOCOL ကို သင်၏ Excel တွင် ပံ့ပိုးမထားပါ

#NAME ရရှိသည့်အခါတွင်၊ အမှားအယွင်း၊ function ၏အမည်၏မှန်ကန်သောစာလုံးပေါင်းသည်ပထမဆုံးအရာဖြစ်သည်။စစ်ဆေးပါ။ အမည်မှန်သော်လည်း အမှားဆက်လက်ရှိနေပါက၊ လုပ်ဆောင်ချက်ကို သင်၏ Excel ဗားရှင်းတွင် မရရှိနိုင်ပါ။ ဤကိစ္စတွင်၊ TOCOL အခြားရွေးချယ်စရာကို အသုံးပြုရန် စဉ်းစားပါ။

Array သည် ကြီးလွန်းသည်

A #NUM အမှားက array သည် ကော်လံတစ်ခုနှင့် မကိုက်ညီကြောင်း ညွှန်ပြပါသည်။ ပုံမှန်ကိစ္စတစ်ခုသည် ကော်လံများ သို့မဟုတ် အတန်းတစ်ခုလုံးကို ရည်ညွှန်းသည့်အခါဖြစ်သည်။

အချည်းနှီးသောဆဲလ်များ မလုံလောက်ပါ

#SPILL အမှားအယွင်းတစ်ခုဖြစ်ပေါ်သောအခါ၊ ဖော်မြူလာထည့်သွင်းသည့်ကော်လံကို စစ်ဆေးပါ ရလဒ်များနှင့် ပြည့်ရန် ဆဲလ်အလွတ်များ လုံလောက်စွာ ရှိသည်။ ဆဲလ်များသည် အမြင်အားဖြင့် ကွက်လပ်ဖြစ်နေပါက၊ ၎င်းတို့တွင် နေရာလွတ်များနှင့် အခြားပုံနှိပ်မဟုတ်သော စာလုံးများ မရှိကြောင်း သေချာပါစေ။ ပိုမိုသိရှိလိုပါက၊ Excel တွင် #SPILL အမှားကို ပြုပြင်နည်းကို ကြည့်ပါ။

ထို့ကြောင့် သင်သည် Excel 365 ရှိ TOCOL လုပ်ဆောင်ချက်နှင့် 2-ဖက်မြင် array တစ်ခုကို ကော်လံတစ်ခုတည်းအဖြစ်သို့ ပြောင်းလဲရန် အစောပိုင်းဗားရှင်းများရှိ TOCOL လုပ်ဆောင်ချက်ကို သင်အသုံးပြုနိုင်သည့်ပုံဖြစ်သည်။ ကျွန်ုပ်တို့၏ဘလော့ဂ်တွင် ဖတ်ရှုပြီး နောက်အပတ်တွင် ဆုံတွေ့ခွင့်ရရန် မျှော်လင့်သည့်အတွက် ကျေးဇူးတင်ပါသည်။

လေ့ကျင့်ခန်းစာအုပ်

Excel TOCOL လုပ်ဆောင်ချက် - ဖော်မြူလာနမူနာများ (.xlsx ဖိုင်)