Զանգվածը կամ ընդգրկույթը TOCOL ֆունկցիայով սյունակի վերածելու հեշտ միջոց:

Տվյալները սյունակներից տողեր և հակառակը փոխադրելու հնարավորությունը եղել է Excel-ում բավականին երկար ժամանակ: որոշ ժամանակ. Բայց մի շարք բջիջների մեկ սյունակի վերածելը բարդ խնդիր էր: Հիմա, դա վերջապես փոխվում է: Microsoft-ը ներկայացրել է TOCOL-ի նոր գործառույթը, որը կարող է մի ակնթարթում կատարել զանգվածից սյունակ փոխակերպում: Ստորև ներկայացված է առաջադրանքների ցանկը, որոնք այս նոր գործառույթը հեշտությամբ կարող է լուծել:

Excel TOCOL ֆունկցիան

Excel-ում TOCOL ֆունկցիան փոխակերպում է զանգվածը կամ բջիջների տիրույթը մեկ միասնական սյունակ:

Ֆունկցիան վերցնում է երեք արգումենտ, սակայն պահանջվում է միայն առաջինը:

TOCOL(զանգված, [անտեսել], [սկան_ըստ_սյունակ])

Որտեղ՝

Զանգված (պահանջվում է) - զանգված կամ տիրույթ սյունակի վերածվելու համար:

Անտեսել (ըստ ցանկության) - սահմանում է, թե արդյոք անտեսել բացերը կամ/կամ սխալները: Կարող է լինել հետևյալ արժեքներից մեկը.

• 0 կամ բաց թողնված (կանխադրված) - պահել բոլոր արժեքները
• 1 - անտեսել դատարկերը
• 2 - անտեսել սխալները
• 3 - անտեսել բացերը և սխալները

Scan_by_column (ըստ ցանկության) - որոշում է՝ սկանավորել զանգվածը հորիզոնական, թե ուղղահայաց.

• FALSE կամ բաց թողնված (կանխադրված) - սկանավորեք զանգվածն ըստ տողի ձախից աջ:
• ՃԻՇՏ - սկանավորեք զանգվածն ըստ սյունակի վերևից ներքև:

Խորհուրդներ՝

• Զանգվածը մեկ տողի վերածելու համար օգտագործեք TOROWֆունկցիան։
• Հակառակ սյունակից զանգված փոխակերպումը կատարելու համար օգտագործեք կամ WRAPCOLS ֆունկցիան՝ ըստ սյունակի փաթաթելու կամ WRAPROWS ֆունկցիան՝ տողով փաթաթելու համար։
• Զանգվածը հորիզոնականից փոխադրելու համար ուղղահայաց կամ հակառակը, այսինքն՝ փոխել տողերը սյունակների, օգտագործել TRANSPOSE ֆունկցիան:

TOCOL-ի առկայությունը

TOCOL-ը նոր ֆունկցիա է, որն աջակցվում է Excel-ում Microsoft 365-ի համար (Windows-ի համար և Mac) և Excel համացանցի համար:

Հիմնական TOCOL բանաձևը միջակայքը սյունակի վերածելու համար

TOCOL բանաձևն իր ամենապարզ ձևով պահանջում է ընդամենը մեկ փաստարկ՝ զանգված . Օրինակ, 3 սյունակից և 4 տողից բաղկացած երկչափ զանգվածը մեկ սյունակում տեղադրելու համար բանաձևը հետևյալն է.

=TOCOL(A2:C5)

Բանաձևը մուտքագրվում է միայն մեկ բջիջում (E2 այս օրինակը) և ինքնաբերաբար թափվում է ներքևի բջիջների մեջ: Excel-ի առումով արդյունքը կոչվում է արտահոսքի տիրույթ:

Ինչպես է աշխատում այս բանաձևը.

Տեխնիկապես A2:C5 միջակայքը սկզբում վերածվում է երկչափ զանգվածի: Խնդրում ենք նկատի ունենալ ստորակետով բաժանված տողերը և ստորակետերով սահմանազատված սյունակները.

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL ֆունկցիան սկանավորում է զանգվածը ձախից աջ և վերածում այն ​​միաչափ ուղղահայաց զանգվածի.

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

Արդյունքը տեղադրվում է E2 բջիջում, որտեղից այն թափվում է ներքևի բջիջների մեջ:

Ինչպես օգտագործել TOCOL ֆունկցիան Excel-ում - բանաձևի օրինակներ

Ավելի շատ հասկանալու համարTOCOL ֆունկցիայի հնարավորությունները և այն առաջադրանքները, որոնք այն կարող է ընդգրկել, եկեք տեսնենք մի քանի բանաձևի օրինակներ:

Զանգվածը վերածեք սյունակի՝ անտեսելով բացերը և սխալները

Ինչպես կարող եք նկատել նախորդ օրինակում: , լռելյայն TOCOL բանաձևը պահպանում է աղբյուրի զանգվածի բոլոր արժեքները, ներառյալ դատարկ բջիջները և սխալները:

Ստացված զանգվածում դատարկ բջիջները ներկայացված են զրոներով, ինչը կարող է բավականին շփոթեցնող լինել, հատկապես, եթե սկզբնական զանգվածն ունի 0 արժեք: Լուծումը բաց թողնելն է : Դրա համար 2-րդ արգումենտը սահմանում եք 1:

=TOCOL(A2:C5, 1)

սխալները անտեսելու համար , 2-րդ արգումենտը սահմանեք 2:

=TOCOL(A2:C5, 2)

Երկուսն էլ, դատարկներն ու սխալները բացառելու համար օգտագործեք 3 անտեսել արգումենտի համար.

=TOCOL(A2:C5, 3)

Սկանավորեք զանգվածը հորիզոնական կամ ուղղահայաց

Լռելյայն scan_by_column արգումենտով (FALSE կամ բաց թողնված), TOCOL ֆունկցիան սկանավորում է զանգվածը հորիզոնական՝ ըստ տողերի: Արժեքները ըստ սյունակի մշակելու համար այս արգումենտը սահմանեք TRUE կամ 1: Օրինակ՝

=TOCOL(A2:C5, ,TRUE)

Ուշադրություն դարձրեք, որ երկու դեպքում էլ վերադարձված զանգվածները նույն չափի են, բայց արժեքները դասավորված են: այլ կարգով:

Միավորել մի քանի միջակայք մեկ սյունակում

Եթե գործ ունեք մի քանի ոչ իրար հաջորդող տիրույթների հետ, ապա կարող եք նախ ուղղահայաց տիրույթները միավորել մեկ զանգվածի մեջ VSTACK ֆունկցիայի օգնությամբ, և ապա օգտագործեք TOCOL՝ համակցված զանգվածը սյունակի վերածելու համար:

Ենթադրելով, որ առաջին միջակայքը A2:C4 է, իսկ երկրորդ միջակայքը՝ A8:C9, բանաձևը ստանում է հետևյալ ձևը. դեպի աջ, ինչպես ցույց է տրված ստորև նկարում E սյունակում:

Արժեքները վերևից ներքև ուղղահայաց կարդալու համար դուք TOCOL-ի 3-րդ արգումենտը սահմանում եք TRUE.

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

Խնդրում ենք ուշադրություն դարձնել, որ այս դեպքում բանաձևը սկզբում արժեքներ է վերադարձնում երկու զանգվածների A սյունակից, այնուհետև B սյունակից և այլն: Պատճառն այն է, որ TOCOL-ը սկանավորում է մեկ կուտակված զանգված, այլ ոչ թե բնօրինակ առանձին տիրույթները:

Եթե ձեր բիզնեսի տրամաբանությունը պահանջում է սկզբնական տիրույթները հավաքել հորիզոնական, այլ ոչ թե ուղղահայաց, ապա VSTACK-ի փոխարեն օգտագործեք HSTACK ֆունկցիան:

Յուրաքանչյուր հաջորդ զանգվածը նախորդ զանգվածի աջ կողմում ավելացնելու և կարդալու համար համակցված զանգվածները հորիզոնական, բանաձևը հետևյալն է.

=TOCOL(HSTACK(A2:C4, A8:C10))

Յուրաքանչյուր հաջորդ զանգվածը նախորդ զանգվածից աջ ավելացնելու և համակցված զանգվածները ուղղահայաց սկանավորելու համար բանաձևը հետևյալն է.

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

Արտահանել եզակի արժեքներ բազմասյունակ միջակայքից

Excel UNIQUE ֆունկցիան կարող է հեշտությամբ գտնել եզակիներ մեկ սյունակում կամ տողում, ինչպես նաև վերադարձնել եզակի տողեր, սակայն այն չի կարող եզակի արժեքներ հանել բազմասյուն զանգված։ Լուծումը TOCOL ֆունկցիայի հետ միասին օգտագործելն է։

Օրինակ՝ ընդգրկույթից բոլոր տարբեր (տարբեր) արժեքները հանելը։A2:C7, բանաձևը հետևյալն է.

=UNIQUE(TOCOL(A2:C7))

Բացի այդ, դուք կարող եք փաթաթել վերը նշված բանաձևը SORT ֆունկցիայի մեջ՝ վերադարձված զանգվածը այբբենական կարգով դասավորելու համար.

=SORT(UNIQUE(TOCOL(A2:C7)))

Ինչպես փոխարկել միջակայքը սյունակի Excel 365 - 2010

Excel-ի տարբերակներում, որտեղ TOCOL ֆունկցիան չի ապահովվում, կան մի քանի այլընտրանքային եղանակներ՝ մի շարք բջիջներ սյունակի վերածելու համար: Այս լուծումները բավականին բարդ են, բայց, այնուամենայնիվ, աշխատում են:

Տողն ըստ տող կարդալու համար՝

INDEX( ընդգրկույթ , QUOTIENT(ROW(A1)-1, COLUMNS( միջակայք ))+1, MOD(ROW(A1)-1, COLUMNS( ընդգրկույթ ))+1)

Ընդհանուր սյունակ կարդալու համար՝

INDEX( միջակայք , MOD(ROW(A1)-1, ROWS( միջակայք ))+1, QUOTIENT(ROW(A1)-1, ROWS( միջակայք ))+1 )

Մեր նմուշային տվյալների բազայի համար բանաձևերը հետևյալն են.

Տարածքը հորիզոնական կերպով ձախից աջ սկանավորելու համար .

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

Այս բանաձևը համարժեք է TOCOL ֆունկցիային, որի 3-րդ արգումենտը դրված է FALSE-ի կամ բաց թողնված՝

=TOCOL(A2:C5)

Տարածքը ուղղահայաց վերևից ներքև սկանավորելու համար :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

Այս բանաձևը համեմատելի է TOCOL ֆունկցիայի հետ 3-րդ արգումենտով սահմանված է TRUE.

=TOCOL(A2:C5, ,TRUE)

Ի տարբերություն TOCOL-ի, այլընտրանքային բանաձևերը պետք է մուտքագրվեն յուրաքանչյուրում: բջիջ, որտեղ ցանկանում եք, որ արդյունքները հայտնվեն: Մեր դեպքում բանաձևերը գնում են E2 բջիջներ (ըստ տող) և G2 (ըստ սյունակի), այնուհետև պատճենվում են մինչև 13-րդ տող:

Եթե բանաձևերը պատճենվում են ավելի շատ տողեր, քան անհրաժեշտ է,#REF! սխալը կհայտնվի «լրացուցիչ» բջիջներում: Որպեսզի դա տեղի չունենա, կարող եք IFERROR ֆունկցիայի բանաձևերը տեղադրել հետևյալ կերպ.

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

Ուշադրություն դարձրեք, որ բանաձևերը ճիշտ պատճենելու համար մենք կողպում ենք միջակայքը՝ օգտագործելով բացարձակ բջջային հղումներ ($ A$2:$C$5): Փոխարենը, դուք կարող եք օգտագործել անվանված տիրույթ:

Ինչպես են աշխատում այս բանաձևերը

Ստորև ներկայացված է առաջին բանաձևի մանրամասն նկարագրությունը, որը դասավորում է բջիջներն ըստ տողերի.

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

Գաղափարն այն է, որ օգտագործենք INDEX ֆունկցիան՝ որոշակի բջիջի արժեքը վերադարձնելու համար՝ հիմնված նրա հարաբերական տողերի և սյունակների թվերի վրա միջակայքում:

տողի համարը հաշվարկվում է այս համադրությամբ: :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT-ը վերադարձնում է բաժանման ամբողջական մասը:

համարիչ -ի համար դուք օգտագործում եք ROW(A1)-1, որը վերադարձնում է սերիական համարը E2-ում 0-ից (առաջին բջիջը, որտեղ մուտքագրվել է բանաձևը) մինչև 11-ը E13-ում (վերջին բջիջը, որտեղ մուտքագրվել է բանաձևը):

հայտարարը ըստ COLUMNS ($A) $2:$C$5)) հաստատուն է և հավասար է ձեր տիրույթի սյունակների թվին (մեր դեպքում 3):

Այժմ, եթե ստուգեք QUOTIENT-ի արդյունքը առաջին 3 բջիջների համար (E2:E4) , կտեսնեք, որ այն հավասար է 0-ի (որովհետև բաժանման ամբողջական մասը զրո է)։ 1-ի ավելացումով ստացվում է 1 տողի համարը:

Հաջորդ 3 բջիջների համար (E5:E5) QUOTIENT-ը վերադարձնում է 1-ը, իսկ +1 գործողությունը՝ 2-րդ տողի համարը: Եվ այսպես շարունակ:

Այլ կերպ ասած, բանաձեւի այս մասը ստեղծում է կրկնությունթվերի հաջորդականություն, ինչպիսիք են 1,1,1,2,2,2,3,3,3,4,4,4,… Յուրաքանչյուր թիվ կրկնվում է այնքան անգամ, որքան սյունակներ կան ձեր տիրույթում:

Դեպի հաշվարկեք սյունակի համարը , դուք կառուցում եք համապատասխան թվային հաջորդականություն՝ օգտագործելով MOD ֆունկցիան.

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

Քանի որ մեր տիրույթում կա 3 սյունակ (A2:C5), հաջորդականությունը պետք է լինի 1,2,3,1,2,3,…

MOD ֆունկցիան վերադարձնում է մնացորդը բաժանումից հետո:

E2, MOD(ROW(A1)-1, COLUMNS ($A$2:$C$5))+1)

դառնում է

MOD(1-1, 3)+1)

և վերադարձնում է 1:

E3-ում MOD(ROW(A2)-1, COLUMNS($A$2:$C$5))+1)

դառնում է

MOD(2-1, 3) +1)

և վերադարձնում է 2-ը:

Տողերի և սյունակների համարների հաստատման դեպքում INDEX-ը պահանջվող արժեքը ստանալու հետ կապված խնդիրներ չունի:

E2-ում, INDEX($A$2) :$C$5, 1, 1) վերադարձնում է արժեքը նշված միջակայքի 1-ին տողից և 1-ին սյունակից, այսինքն՝ A2 բջիջից:

E3, INDEX($A$2:$C$5, 1) , 2) վերադարձնում է արժեքը 1-ին շարքից և 2-րդ սյունակից, այսինքն՝ B2 բջիջից:

Եվ այսպես շարունակ:

Երկրորդ բանաձևը, որը սկանավորում է միջակայքը c-ով: սյունը, աշխատում է նույն կերպ: Տարբերությունն այն է, որ այն օգտագործում է MOD՝ տողի համարը ստանալու համար, իսկ QUOTIENT՝ սյունակի համարը ստանալու համար:

TOCOL ֆունկցիան չի աշխատում

Եթե TOCOL ֆունկցիան սխալ է թույլ տալիս, դա ամենայն հավանականությամբ լինել հետևյալ պատճառներից մեկը.

TOCOL-ը չի աջակցվում ձեր Excel-ում

Երբ դուք ստանում եք #NAME: սխալ, ֆունկցիայի անվան ճիշտ ուղղագրությունն առաջինն էստուգել. Եթե ​​անունը ճիշտ է, բայց սխալը պահպանվում է, գործառույթը հասանելի չէ Excel-ի ձեր տարբերակում: Այս դեպքում մտածեք TOCOL այլընտրանքի օգտագործման մասին:

Զանգվածը չափազանց մեծ է

#NUM սխալը ցույց է տալիս, որ զանգվածը չի կարող տեղավորվել սյունակի մեջ: Տիպիկ դեպքն այն է, երբ հղում եք կատարում ամբողջ սյունակներին կամ տողերին:

Չկան բավարար դատարկ բջիջներ

Երբ #SPILL սխալ է տեղի ունենում, ստուգեք, որ այն սյունակը, որտեղ մուտքագրված է բանաձևը: ունի բավականաչափ դատարկ բջիջներ՝ արդյունքներով լցվելու համար: Եթե ​​վանդակները տեսողականորեն դատարկ են, համոզվեք, որ դրանցում բացատներ և այլ չտպող նիշեր չկան: Լրացուցիչ տեղեկությունների համար տե՛ս Ինչպես շտկել #SPILL սխալը Excel-ում:

Այդպես կարող եք օգտագործել TOCOL ֆունկցիան Excel 365-ում և այլընտրանքային լուծումները ավելի վաղ տարբերակներում՝ երկչափ զանգվածը մեկ սյունակի վերածելու համար: Շնորհակալ եմ կարդալու համար և հուսով եմ, որ հաջորդ շաբաթ կտեսնենք ձեզ մեր բլոգում:

Զբաղվեք աշխատանքային գրքույկով

Excel TOCOL ֆունկցիան - բանաձևի օրինակներ (.xlsx ֆայլ)

>