TOCOL ফাংচনৰ সৈতে এটা এৰে বা ৰেঞ্জক এটা স্তম্ভলৈ ৰূপান্তৰিত কৰাৰ এটা সহজ উপায়।

স্তম্ভৰ পৰা শাৰীলৈ আৰু বিপৰীতভাৱে তথ্য ট্ৰেন্সপ'জ কৰাৰ ক্ষমতা Excel ত যথেষ্ট দিনৰ পৰা আছে ক্ষন্তেক. কিন্তু কোষৰ এটা পৰিসৰক এটা স্তম্ভলৈ ৰূপান্তৰ কৰাটো ফাটি পেলোৱাটো এটা কৌশলী কাম আছিল। এতিয়া, অৱশেষত সেইটো সলনি হৈছে। মাইক্ৰ’ছফটে TOCOL নামৰ এটা নতুন ফাংচন প্ৰৱৰ্তন কৰিছে, যিয়ে এটা পলকতে এৰেৰ পৰা স্তম্ভলৈ ৰূপান্তৰ কৰিব পাৰে। তলত এই নতুন ফাংচনে সহজে সমাধান কৰিব পৰা কামৰ তালিকা দিয়া হৈছে।

Excel TOCOL ফাংচন

এক্সেলত TOCOL ফাংচনে এটা এৰে বা কোষৰ পৰিসৰক এটালৈ ৰূপান্তৰ কৰে স্তম্ভ।

ফাংচনে তিনিটা যুক্তি লয়, কিন্তু কেৱল প্ৰথমটোৰ প্ৰয়োজন।

TOCOL(array, [ignore], [scan_by_column])

ক'ত:

এৰে (প্ৰয়োজনীয়) - এটা স্তম্ভলৈ ৰূপান্তৰিত কৰিবলে এটা এৰে বা পৰিসীমা।

আওকাণ কৰক (ঐচ্ছিক) - খালী বা/আৰু ভুলসমূহ আওকাণ কৰিব নে নকৰে সংজ্ঞায়িত কৰে। এই মানসমূহৰ এটা হ'ব পাৰে:

• 0 বা বাদ দিয়া হৈছে (অবিকল্পিত) - সকলো মান ৰাখক
• 1 - খালী ঠাই আওকাণ কৰক
• 2 - ভুলসমূহ আওকাণ কৰক
• 3 - খালী আৰু ভুলসমূহ আওকাণ কৰক

Scan_by_column (ঐচ্ছিক) - এৰে অনুভূমিকভাৱে বা উলম্বভাৱে স্কেন কৰিব নে নকৰে নিৰ্ধাৰণ কৰে:

• FALSE বা বাদ দিয়া হৈছে (অবিকল্পিত) - বাওঁফালৰ পৰা সোঁফাললৈ শাৰী অনুসৰি এৰে স্কেন কৰক।
• TRUE - এৰেক ওপৰৰ পৰা তললৈ স্তম্ভ অনুসৰি স্কেন কৰক।

টিপচ্:

• এটা এৰেক এটা শাৰীলৈ ৰূপান্তৰ কৰিবলৈ, TOROW ব্যৱহাৰ কৰকফাংচন।
• বিপৰীত স্তম্ভ-টু-এৰে ৰূপান্তৰ কৰিবলৈ, হয় স্তম্ভ অনুসৰি ৰেপ কৰিবলৈ WRAPCOLS ফাংচন বা শাৰী অনুসৰি ৰেপ কৰিবলৈ WRAPROWS ফাংচন ব্যৱহাৰ কৰক।
• এটা এৰে অনুভূমিকৰ পৰা ট্ৰেন্সপ'জ কৰিবলৈ উলম্ব বা বিপৰীতভাৱে, অৰ্থাৎ শাৰীসমূহ স্তম্ভলৈ সলনি কৰক, TRANSPOSE ফাংচন ব্যৱহাৰ কৰক।

TOCOL উপলব্ধতা

TOCOL এটা নতুন ফাংচন, যি Microsoft 365 ৰ বাবে Excel ত সমৰ্থিত (Windows ৰ বাবে আৰু মেক) আৰু ৱেবৰ বাবে এক্সেল।

পৰিসৰক স্তম্ভলৈ ৰূপান্তৰিত কৰিবলে মূল TOCOL সূত্ৰ

TOCOL সূত্ৰৰ সৰলতম ৰূপত মাত্ৰ এটা যুক্তিৰ প্ৰয়োজন - এৰে . উদাহৰণস্বৰূপে, ৩টা স্তম্ভ আৰু ৪টা শাৰীৰে গঠিত এটা দ্বিমাত্ৰিক এৰে এটা স্তম্ভত ৰাখিবলৈ, সূত্ৰটো হ'ল:

=TOCOL(A2:C5)

সূত্ৰটো কেৱল এটা কোষতহে প্ৰৱেশ কৰা হয় (E2 in এই উদাহৰণটো) আৰু তলৰ কোষবোৰলৈ স্বয়ংক্ৰিয়ভাৱে ছিটিকি পৰে। এক্সেলৰ ক্ষেত্ৰত ফলাফলটোক স্পিল ৰেঞ্জ বোলা হয়।

এই সূত্ৰটোৱে কেনেকৈ কাম কৰে:

কাৰিকৰীভাৱে, পৰিসৰ A2:C5 প্ৰথমে এটা দ্বিমাত্ৰিক এৰেলৈ ৰূপান্তৰ কৰা হয়। অনুগ্ৰহ কৰি ছেমিকলন-বিভাজিত শাৰীসমূহ আৰু কমা-সীমিত স্তম্ভসমূহ লক্ষ্য কৰক:

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL ফলনে এৰে বাওঁফালৰ পৰা সোঁফালে স্কেন কৰে আৰু ইয়াক এটা একমাত্ৰিক উলম্ব এৰেলৈ ৰূপান্তৰ কৰে:

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

ফলাফলটো E2 কোষত ৰখা হয়, য'ৰ পৰা ই তলৰ কোষবোৰলৈ ছিটিকি পৰে।

এক্সেলত TOCOL ফাংচন কেনেকৈ ব্যৱহাৰ কৰিব - সূত্ৰৰ উদাহৰণ

<০>ৰ বিষয়ে অধিক বুজাবুজি লাভ কৰিবলৈTOCOL ফাংচনৰ সম্ভাৱনা আৰু ই কি কাম সামৰি ল'ব পাৰে, কিছুমান সূত্ৰৰ উদাহৰণ চাওঁ আহক।

খালী আৰু ভুল আওকাণ কৰি এৰেক স্তম্ভলৈ ৰূপান্তৰ কৰক

আপুনি পূৰ্বৰ উদাহৰণত লক্ষ্য কৰা ধৰণে , অবিকল্পিত TOCOL সূত্ৰই উৎস এৰেৰ পৰা সকলো মান ৰাখে, খালী ঘৰ আৰু ভুলসমূহ অন্তৰ্ভুক্ত কৰি।

ফলাফল এৰেত, খালী ঘৰসমূহক শূন্যৰে প্ৰতিনিধিত্ব কৰা হয়, যি যথেষ্ট বিভ্ৰান্তিকৰ হ'ব পাৰে, বিশেষকৈ যদি মূল এৰে আছে 0 মান। সমাধান হ'ল খালী ঠাই এৰি দিয়া । ইয়াৰ বাবে, আপুনি ২য় যুক্তিক 1:

=TOCOL(A2:C5, 1)

লে সংহতি কৰে ত্ৰুটি আওকাণ কৰক লৈ, দ্বিতীয় যুক্তি 2:

=TOCOL(A2:C5, 2) <3 লে সংহতি কৰক>

দুয়োটাকে বাদ দিবলৈ, খালী আৰু ভুল , ignore যুক্তিৰ বাবে 3 ব্যৱহাৰ কৰক:

=TOCOL(A2:C5, 3)

এৰে অনুভূমিক বা উলম্বভাৱে স্কেন কৰক

অবিকল্পিত scan_by_column যুক্তিৰ সৈতে (FALSE বা বাদ দিয়া হৈছে), TOCOL ফলনে এৰেক শাৰীৰ দ্বাৰা অনুভূমিকভাৱে স্কেন কৰে। স্তম্ভ অনুসৰি মানসমূহ প্ৰক্ৰিয়া কৰিবলে, এই যুক্তি TRUE বা 1 লে সংহতি কৰক। উদাহৰণস্বৰূপ:

=TOCOL(A2:C5, ,TRUE)

মন কৰক যে, দুয়োটা ক্ষেত্ৰতে, ঘূৰাই দিয়া এৰেসমূহ একে আকাৰৰ, কিন্তু মানসমূহ সজোৱা হৈছে বেলেগ ক্ৰমত।

এটা স্তম্ভত একাধিক পৰিসীমা একত্ৰিত কৰক

যদি আপুনি কেইবাটাও অসংলগ্ন পৰিসীমাৰ সৈতে কাম কৰি আছে, তেন্তে আপুনি প্ৰথমে পৰিসীমাসমূহক উলম্বভাৱে এটা এৰেত VSTACK ফলনৰ সহায়ত একত্ৰিত কৰিব পাৰিব, আৰু তাৰ পিছত সংযুক্ত এৰেক এটা স্তম্ভলৈ ৰূপান্তৰ কৰিবলে TOCOL ব্যৱহাৰ কৰকপ্ৰথম পৰিসীমা A2:C4 আৰু দ্বিতীয় পৰিসীমা A8:C9 বুলি ধৰিলে, সূত্ৰই এই ৰূপ লয়:

=TOCOL(VSTACK(A2:C4, A8:C9))

এই সূত্ৰই অবিকল্পিত আচৰণ প্ৰদৰ্শন কৰে - সংযুক্ত এৰেসমূহ বাওঁফালৰ পৰা অনুভূমিকভাৱে পঢ়ে তলৰ ছবিত E স্তম্ভত দেখুওৱাৰ দৰে সোঁফালে।

মানসমূহ ওপৰৰ পৰা তললৈ উলম্বভাৱে পঢ়িবলৈ, আপুনি TOCOL ৰ তৃতীয় যুক্তিক TRUE লে সংহতি কৰে:

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

অনুগ্ৰহ কৰি মন কৰক যে, এই ক্ষেত্ৰত, সূত্ৰই প্ৰথমে দুয়োটা এৰেৰ স্তম্ভ A ৰ পৰা মান ঘূৰাই দিয়ে, তাৰ পিছত স্তম্ভ B ৰ পৰা, ইত্যাদি। কাৰণটো হ'ল TOCOL এ এটা ষ্টেক কৰা এৰে স্কেন কৰে, মূল ব্যক্তিগত পৰিসীমাসমূহ নহয়।

যদি আপোনাৰ ব্যৱসায়িক যুক্তিয়ে মূল পৰিসীমাসমূহ উলম্বভাৱে নহয় অনুভূমিকভাৱে ষ্টেক কৰাৰ প্ৰয়োজন হয়, তেন্তে VSTACK ৰ পৰিবৰ্তে HSTACK ফলন ব্যৱহাৰ কৰক সংযুক্ত এৰেসমূহ অনুভূমিকভাৱে, সূত্ৰটো হ'ল:

=TOCOL(HSTACK(A2:C4, A8:C10))

পূৰ্বৰ এৰেৰ সোঁফালে প্ৰতিটো পৰৱৰ্তী এৰে যোগ কৰিবলৈ আৰু সংযুক্ত এৰেসমূহ উলম্বভাৱে স্কেন কৰিবলৈ, সূত্ৰটো হ'ল:

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

এটা বহু-স্তম্ভ পৰিসীমাৰ পৰা অনন্য মানসমূহ উলিয়াওক

Excel UNIQUE ফাংচনে এটা স্তম্ভ বা শাৰীত অনন্য বিচাৰি পোৱাৰ লগতে অনন্য শাৰীসমূহ ঘূৰাই দিব পাৰে, কিন্তু ই ইয়াৰ পৰা অনন্য মানসমূহ উলিয়াব নোৱাৰে এটা বহু-স্তম্ভ এৰে। সমাধানটো হ'ল ইয়াক TOCOL ফাংচনৰ সৈতে একেলগে ব্যৱহাৰ কৰা।

উদাহৰণস্বৰূপে, পৰিসীমাৰ পৰা সকলো বিভিন্ন (সুত্ক) মান উলিয়াবলৈA2:C7, সূত্ৰটো হ'ল:

=UNIQUE(TOCOL(A2:C7))

অতিৰিক্তভাৱে, আপুনি ওপৰৰ সূত্ৰটো SORT ফাংচনত ৰেপ কৰিব পাৰে ঘূৰাই দিয়া এৰেক বৰ্ণানুক্ৰমিক ক্ৰমত সজাবলৈ:

=SORT(UNIQUE(TOCOL(A2:C7)))

এক্সেল 365 - 2010 ত ৰেঞ্জক স্তম্ভলৈ কেনেকৈ ৰূপান্তৰ কৰিব

এক্সেল সংস্কৰণত য'ত TOCOL ফাংচন সমৰ্থিত নহয়, কোষৰ এটা পৰিসৰক এটা স্তম্ভলৈ ৰূপান্তৰিত কৰাৰ দুটামান বিকল্প উপায় আছে। এই সমাধানসমূহ যথেষ্ট কৌশলী, কিন্তু যিয়েই নহওক কাম কৰে।

শাৰী অনুসৰি পৰিসীমা পঢ়িবলৈ:

INDEX( range , QUOTIENT(ROW(A1)-1, COLUMNS( )। পৰিসীমা ))+1, MOD(ROW(A1)-1, COLUMNS( পৰিসৰ ))+1)

স্তম্ভ অনুসৰি পৰিসীমা পঢ়িবলৈ:

INDEX( ৰেঞ্জ , MOD(ROW(A1)-1, ROWS( পৰিসৰ ))+1, QUOTIENT(ROW(A1)-1, ROWS( পৰিসৰ ))+1 )

আমাৰ নমুনা ডাটাছেটৰ বাবে সূত্ৰসমূহ হ'ল:

বাওঁফালৰ পৰা সোঁফাললৈ অনুভূমিকভাৱে পৰিসৰ স্কেন কৰিবলৈ :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

এই সূত্ৰটো TOCOL ফাংচনৰ সমতুল্য আৰু তৃতীয় যুক্তিটো FALSE লে সংহতি কৰা হৈছে বা বাদ দিয়া হৈছে:

=TOCOL(A2:C5)

পৰিসীমা ওপৰৰ পৰা তললৈ উলম্বভাৱে স্কেন কৰিবলে :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

এই সূত্ৰটো TOCOL ফাংচনৰ সৈতে তুলনাযোগ্য আৰু তৃতীয় যুক্তিটো TRUE লে সংহতি কৰা হৈছে:

=TOCOL(A2:C5, ,TRUE)

TOCOL ৰ দৰে নহয়, বিকল্প সূত্ৰসমূহ প্ৰতিটোতে প্ৰৱেশ কৰিব লাগে চেল য'ত আপুনি ফলাফলসমূহ দেখা দিব বিচাৰে। আমাৰ ক্ষেত্ৰত সূত্ৰবোৰ E2 (শাৰী অনুসৰি) আৰু G2 (স্তম্ভ অনুসৰি) কোষলৈ যায়, আৰু তাৰ পিছত ১৩ নং শাৰীলৈ কপি কৰা হয়।

যদি সূত্ৰবোৰ প্ৰয়োজনতকৈ অধিক শাৰীলৈ কপি কৰা হয়, a#REF! "অতিৰিক্ত" কোষত ভুল দেখা যাব। এইটো ৰোধ কৰিবলৈ, আপুনি IFERROR ফাংচনত সূত্ৰসমূহক এনেদৰে নেষ্ট কৰিব পাৰে:

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

মন কৰিব যে সূত্ৰসমূহে সঠিকভাৱে কপি কৰিবলৈ, আমি নিৰপেক্ষ কোষ প্ৰসংগসমূহ ($) ব্যৱহাৰ কৰি পৰিসীমা লক কৰোঁ A$2:$C$5)। ইয়াৰ পৰিৱৰ্তে, আপুনি এটা নামকৰণ কৰা পৰিসীমা ব্যৱহাৰ কৰিব পাৰে।

এই সূত্ৰবোৰে কেনেকৈ কাম কৰে

তলত কোষবোৰক শাৰী অনুসৰি সজাই তোলা প্ৰথম সূত্ৰটোৰ বিশদ বিভাজন দিয়া হৈছে:

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

আইডিয়াটো হ'ল INDEX ফাংচন ব্যৱহাৰ কৰি এটা নিৰ্দিষ্ট কোষৰ মান পৰিসীমাত ইয়াৰ আপেক্ষিক শাৰী আৰু স্তম্ভ সংখ্যাৰ ওপৰত ভিত্তি কৰি ঘূৰাই দিয়া।

শাৰী সংখ্যা এই সংমিশ্ৰণৰ দ্বাৰা গণনা কৰা হয় :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT এ এটা বিভাজনৰ পূৰ্ণসংখ্যা অংশ ঘূৰাই দিয়ে।

numerator ৰ বাবে, আপুনি ROW(A1)-1 ব্যৱহাৰ কৰে, যি a ঘূৰাই দিয়ে ক্ৰমিক নম্বৰ E2 ত 0 (প্ৰথম কোষ য'ত in সূত্ৰ প্ৰৱেশ কৰা হৈছিল) E13 ত 11 (শেষ কোষ য'ত in সূত্ৰ প্ৰৱেশ কৰা হৈছিল)।

হৰ COLUMNS($A $2:$C$5)) ধ্ৰুৱক আৰু আপোনাৰ পৰিসীমাৰ স্তম্ভৰ সংখ্যাৰ সমান (আমাৰ ক্ষেত্ৰত 3)।

এতিয়া, যদি আপুনি প্ৰথম 3 টা কোষৰ বাবে QUOTIENT ৰ ফলাফল পৰীক্ষা কৰে (E2:E4) , আপুনি দেখিব যে ই 0 ৰ সমান (কাৰণ বিভাজনৰ পূৰ্ণসংখ্যা অংশ শূন্য)। 1 যোগ কৰিলে শাৰী সংখ্যা 1 পোৱা যায়।

পৰৱৰ্তী 3 টা কোষৰ বাবে (E5:E5), QUOTIENT এ 1 ঘূৰাই দিয়ে, আৰু +1 কাৰ্য্যই শাৰী সংখ্যা 2 প্ৰদান কৰে অৰ্থাৎ সূত্ৰৰ এই অংশই পুনৰাবৃত্তিৰ সৃষ্টি কৰেসংখ্যাৰ ক্ৰম যেনে 1,1,1,2,2,2,3,3,3,4,4,4,... প্ৰতিটো সংখ্যাই আপোনাৰ পৰিসীমাত স্তম্ভ থকা যিমানবাৰ পুনৰাবৃত্তি কৰে।

To স্তম্ভ সংখ্যা গণনা কৰক, আপুনি MOD ফাংচন ব্যৱহাৰ কৰি এটা উপযুক্ত সংখ্যা ক্ৰম নিৰ্মাণ কৰে:

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

যিহেতু আমাৰ পৰিসীমাত 3 টা স্তম্ভ আছে (A2:C5),... ক্ৰম ১,২,৩,১,২,৩ হ'ব লাগিব,...

MOD ফাংচনে বিভাজনৰ পিছত বাকীখিনি ঘূৰাই দিয়ে।

E2, MOD(ROW(A1)-1, COLUMNS ত ($A$2:$C$5))+1)

হয়

MOD(1-1, 3)+1)

আৰু 1.

ঘূৰাই দিয়ে

E3 ত MOD(ROW(A2)-1, COLUMNS($A$2:$C$5))+1)

হয়

MOD(2-1, 3) +1)

আৰু 2 ঘূৰাই দিয়ে।

শাৰী আৰু স্তম্ভ সংখ্যাসমূহ প্ৰতিষ্ঠা কৰাৰ লগে লগে, INDEX ৰ প্ৰয়োজনীয় মান আনিবলৈ কোনো সমস্যা নাই।

E2 ত, INDEX($A$2 :$C$5, 1, 1) এ প্ৰসংগ কৰা পৰিসীমাৰ 1st শাৰী আৰু 1st স্তম্ভৰ পৰা মান ঘূৰাই দিয়ে, অৰ্থাৎ A2 কোষৰ পৰা।

E3 ত, INDEX($A$2:$C$5, 1 , ২) ১ম শাৰী আৰু ২য় স্তম্ভৰ পৰা মান ঘূৰাই দিয়ে, অৰ্থাৎ B2 কোষৰ পৰা।

আৰু ইত্যাদি।

দ্বিতীয় সূত্ৰ যিয়ে পৰিসীমা c দ্বাৰা স্কেন কৰে olumn, একে ধৰণে কাম কৰে। পাৰ্থক্যটো হ'ল ই শাৰী সংখ্যা পাবলৈ MOD আৰু স্তম্ভ সংখ্যা পাবলৈ QUOTIENT ব্যৱহাৰ কৰে।

TOCOL ফাংচনে কাম কৰা নাই

যদি TOCOL ফাংচনে এটা ভুল নিক্ষেপ কৰে, তেন্তে ইয়াৰ সম্ভাৱনা বেছি এই কাৰণসমূহৰ এটা হ'বলৈ:

আপোনাৰ Excel ত TOCOL সমৰ্থিত নহয়

যেতিয়া আপুনি এটা #NAME পায়? error, ফাংচনৰ নামৰ সঠিক বানানটোৱেই প্ৰথম কামপৰীক্ষা কৰক. যদি নামটো শুদ্ধ কিন্তু ভুলটো স্থায়ী হয়, তেন্তে আপোনাৰ Excel সংস্কৰণত ফাংচনটো উপলব্ধ নহয়। এই ক্ষেত্ৰত, এটা TOCOL বিকল্প ব্যৱহাৰ কৰাৰ কথা চিন্তা কৰক।

এৰে অতি ডাঙৰ

এটা #NUM ভুলে সূচায় যে এৰে এটা স্তম্ভত সোমাব নোৱাৰে। এটা সাধাৰণ ক্ষেত্ৰ হ'ল যেতিয়া আপুনি সম্পূৰ্ণ স্তম্ভ বা শাৰীসমূহ উল্লেখ কৰে।

পৰ্যাপ্ত খালী কোষ নাই

যেতিয়া এটা #SPILL ত্ৰুটি ঘটে, পৰীক্ষা কৰক যে স্তম্ভটো য'ত সূত্ৰ প্ৰৱেশ কৰা হৈছে ফলাফলৰে ভৰাই ল’ব পৰাকৈ যথেষ্ট খালী কোষ আছে। যদি ঘৰসমূহ দৃশ্যমানভাৱে খালী হয়, নিশ্চিত কৰক যে ইয়াত কোনো স্থান আৰু অন্য প্ৰিন্ট নকৰা আখৰ নাই। অধিক তথ্যৰ বাবে, Excel ত #SPILL ত্ৰুটি কেনেকৈ সমাধান কৰিব চাওক।

এনেকৈ আপুনি Excel 365 ত TOCOL ফাংচন আৰু পূৰ্বৰ সংস্কৰণসমূহত বিকল্প সমাধানসমূহ ব্যৱহাৰ কৰিব পাৰে এটা 2-মাত্ৰিক এৰেক এটা স্তম্ভলৈ ৰূপান্তৰ কৰিবলে। মই আপোনাক পঢ়াৰ বাবে ধন্যবাদ জনাইছো আৰু অহা সপ্তাহত আমাৰ ব্লগত আপোনাক লগ পাম বুলি আশা কৰিছো!

অভ্যাস কাৰ্য্যপুস্তিকা

Excel TOCOL ফাংচন - সূত্ৰৰ উদাহৰণ (.xlsx ফাইল)