TOCOL فنڪشن سان هڪ آري يا رينج کي ڪالمن ۾ تبديل ڪرڻ جو هڪ آسان طريقو.

ڊيٽا کي ڪالمن کان قطارن ۽ ريورس ۾ منتقل ڪرڻ جي صلاحيت ڪافي عرصي کان Excel ۾ آهي توري دير. پر سيلز جي هڪ حد کي هڪ ڪالم ۾ تبديل ڪرڻ هڪ مشڪل ڪم هو. هاڻي، اهو آخرڪار تبديل ٿي رهيو آهي. Microsoft هڪ نئون فنڪشن متعارف ڪرايو آهي، جنهن کي TOCOL سڏيو ويندو آهي، جيڪو هڪ جھلڪ ۾ هڪ صف کان ڪالم جي تبديلي ڪري سگهي ٿو. هيٺ ڏنل ڪمن جي هڪ فهرست آهي جنهن کي هي نئون فنڪشن آساني سان حل ڪري سگهي ٿو.

Excel TOCOL فنڪشن

Excel ۾ TOCOL فنڪشن هڪ صف يا سيلن جي حد کي هڪ واحد ۾ تبديل ڪري ٿو. ڪالم.

فڪشن ٽي آرگيومينٽس وٺي ٿو، پر رڳو پھريون ھڪ گھربل آھي.

TOCOL(array, [ignore], [scan_by_column])

ڪٿي:

Array (گهربل) - ھڪ صف يا رينج ھڪڙي ڪالمن ۾ تبديل ڪرڻ لاءِ.

نظر انداز ڪريو (اختياري) - وضاحت ڪري ٿو ته ڇا خالن کي نظرانداز ڪرڻ يا/۽ غلطيون. ٿي سگھي ٿو انھن مان ھڪ قدر 10>3 - خالن ۽ غلطين کي نظر انداز ڪريو

Scan_by_column (اختياري) - اهو طئي ڪري ٿو ته ڇا اسڪين کي افقي يا عمودي طور تي اسڪين ڪيو وڃي:

• FALSE يا ختم ڪيو ويو (ڊفالٽ) - قطار جي قطار کي کاٻي کان ساڄي تائين اسڪين ڪريو.
• TRUE - ڪالمن ذريعي صف کي مٿي کان هيٺ تائين اسڪين ڪريو.

تجويزون:

4>

هڪ صف کي هڪ قطار ۾ تبديل ڪرڻ لاءِ، TOROW استعمال ڪريوفنڪشن.

سڀني ڪالمن کان صف ۾ تبديلي ڪرڻ لاءِ، يا ته ڪالمن سان لفافي ڪرڻ لاءِ WRAPCOLS فنڪشن يا قطار سان لفافي ڪرڻ لاءِ WRAPROWS فنڪشن استعمال ڪريو.

افقي مان هڪ صف کي منتقل ڪرڻ لاءِ عمودي يا ان جي برعڪس، يعني قطارن کي ڪالمن ۾ تبديل ڪريو، TRANSPOSE فنڪشن استعمال ڪريو.

TOCOL جي دستيابي

TOCOL ھڪڙو نئون فنڪشن آھي، جيڪو Microsoft 365 لاءِ Excel ۾ سپورٽ ڪيو ويو آھي (ونڊوز لاءِ ۽ ميڪ) ۽ ويب لاءِ Excel.

بنيادي ٽوڪول فارمولا رينج کي ڪالمن ۾ تبديل ڪرڻ لاءِ

TOCOL فارمولا ان جي آسان ترين فارم ۾ صرف هڪ دليل جي ضرورت آهي - ار . مثال طور، ھڪڙي ڪالمن ۾ 3 ڪالمن ۽ 4 قطارن تي مشتمل ھڪڙي ٻه طرفي صف کي رکڻ لاء، فارمولا آھي:

=TOCOL(A2:C5)

فارمولا صرف ھڪڙي سيل ۾ داخل ڪيو ويو آھي (E2 ۾ ھي مثال) ۽ ھيٺ ڏنل سيلز ۾ خودڪار طور تي پھچي ٿو. Excel جي اصطلاحن ۾، نتيجو سڏيو ويندو آهي اسپل رينج.

هي فارمولا ڪيئن ڪم ڪندو آهي:

ٽيڪنيڪل طور تي، حد A2:C5 پهريون ڀيرو ٻه طرفي صف ۾ بدلجي ويندي آهي. مھرباني ڪري نوٽ ڪريو سيمي ڪالون کان ڌار ڪيل قطارون ۽ ڪاما سان الڳ ٿيل ڪالمن:

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL فنڪشن آري کي کاٻي کان ساڄي تائين اسڪين ڪري ٿو ۽ ان کي ھڪڙي طرفي عمودي صف ۾ تبديل ڪري ٿو:

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

نتيجو سيل E2 ۾ رکيل آهي، جتان اهو هيٺ ڏنل سيلن ۾ ڦهلجي ٿو.

TOCOL فنڪشن کي Excel ۾ ڪيئن استعمال ڪجي - فارمولا مثال

وڌيڪ سمجھڻ لاءِTOCOL فنڪشن جا امڪان ۽ ڪهڙن ڪمن کي ڍڪي سگهي ٿو، اچو ته ڪجهه فارمولا مثالن تي هڪ نظر وجهون.

صفن کي ڪالم ۾ تبديل ڪريو خالي ۽ نقص کي نظر انداز ڪري

جيئن توهان اڳئين مثال ۾ محسوس ڪيو هوندو , ڊفالٽ TOCOL فارمولا سڀني قدرن کي ماخذ صفن مان رکي ٿو، بشمول خالي سيلز ۽ غلطيون.

نتيجي ۾، خالي سيلز زيرو سان ظاھر ڪيا ويا آھن، جيڪي ڪافي مونجھارو ٿي سگھن ٿا، خاص طور تي جيڪڏھن اصل صف آھي 0 قدر. حل اهو آهي ته خالي کي ڇڏي ڏيو . ان لاءِ، توهان 2nd آرگيومينٽ سيٽ ڪيو 1:

=TOCOL(A2:C5, 1)

ڪرڻ لاءِ غلطين کي نظر انداز ڪريو ، ٻئي دليل کي 2 تي سيٽ ڪريو:

=TOCOL(A2:C5, 2)

ٻنهي کي خارج ڪرڻ لاءِ، خالي ۽ غلطيون ، استعمال ڪريو 3 لاءِ نظرانداز ڪريو دليل:

=TOCOL(A2:C5, 3) 16>افقي يا عمودي طور اسڪين اسڪين

ڊفالٽ سان scan_by_column دليل (FALSE يا ختم ٿيل)، TOCOL فنڪشن قطار کي افقي طور تي اسڪين ڪري ٿو. ڪالمن جي حساب سان قدرن تي عمل ڪرڻ لاءِ، ھن دليل کي TRUE يا 1 تي سيٽ ڪريو. مثال طور:

=TOCOL(A2:C5, ,TRUE)

نوٽ ڪريو ته، ٻنهي صورتن ۾، موٽايل صفون ساڳيا سائيز آھن، پر قدر ترتيب ڏنل آھن هڪ مختلف ترتيب ۾.

گهڻن حدن کي هڪ ڪالمن ۾ گڏ ڪريو

جيڪڏهن توهان ڪيترن ئي غير متضاد حدن سان ڪم ڪري رهيا آهيو، ته پوءِ توهان VSTACK فنڪشن جي مدد سان پهرين حدن کي عمودي طور تي هڪ صف ۾ گڏ ڪري سگهو ٿا، ۽ پوءِ گڏيل صف کي ڪالمن ۾ تبديل ڪرڻ لاءِ TOCOL استعمال ڪريو.

فرض ڪري پهرين رينج A2:C4 آهي ۽ ٻي رينج A8:C9 آهي، فارمولا هي فارم وٺي ٿو:

=TOCOL(VSTACK(A2:C4, A8:C9))

هي فارمولا ڊفالٽ رويي کي ظاهر ڪري ٿو - گڏيل صفن کي کاٻي کان افقي طور تي پڙهي ٿو ساڄي طرف جيئن هيٺ ڏنل تصوير ۾ ڪالم E ۾ ڏيکاريل آهي.

ويلز کي مٿي کان هيٺ تائين عمودي طور تي پڙهڻ لاءِ، توهان TOCOL جو ٽيون دليل TRUE تي سيٽ ڪيو:

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

مھرباني ڪري ڌيان ڏيو ته، ھن صورت ۾، فارمولا پھريون قدر واپس آڻيندو آھي ڪالمن A مان ٻنهي صفن جي، پوءِ ڪالم B مان، وغيره. سبب اهو آهي ته TOCOL هڪ واحد اسٽيڪ ٿيل صف کي اسڪين ڪري ٿو، نه اصل انفرادي حدن کي.

جيڪڏهن توهان جي ڪاروباري منطق کي اصل حدن کي اسٽيڪ ڪرڻ جي ضرورت آهي عمودي بجاءِ افقي طور تي، پوءِ استعمال ڪريو HSTACK فنڪشن بجاءِ VSTACK.

هر ايندڙ صف کي شامل ڪرڻ لاءِ پوئين صف جي ساڄي پاسي ۽ پڙهو گڏيل صفن کي افقي طور تي، فارمولا آهي:

=TOCOL(HSTACK(A2:C4, A8:C10))

هر ايندڙ آري کي پوئين صف جي ساڄي پاسي شامل ڪرڻ ۽ گڏيل صفن کي عمودي طور تي اسڪين ڪرڻ لاءِ، فارمولا آهي:

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

ملٽي ڪالمن رينج مان منفرد قدرن کي ڪڍيو

Excel UNIQUE فنڪشن آساني سان ھڪڙي ڪالمن يا قطار ۾ منفردن کي ڳولي سگھي ٿو ۽ ان سان گڏوگڏ منفرد قطارون واپس ڪري سگھي ٿو، پر اھو ان مان منفرد قدر ڪڍي نٿو سگھي. هڪ گھڻن ڪالمن واري صف. حل اهو آهي ته ان کي TOCOL فنڪشن سان گڏ استعمال ڪيو وڃي.

مثال طور، سڀني مختلف (مختلف) قدرن کي رينج مان ڪڍڻ لاءِA2:C7، فارمولا آهي:

=UNIQUE(TOCOL(A2:C7))

اضافي طور تي، توهان مٿي ڏنل فارمولا کي SORT فنڪشن ۾ لپي سگهو ٿا ته جيئن واپس ڪيل صف کي الفابيٽ جي ترتيب ۾ ترتيب ڏيو:

=SORT(UNIQUE(TOCOL(A2:C7)))

سليم 365 - 2010 ۾ رينج کي ڪالمن ۾ ڪيئن بدلجي

Excel ورزن ۾ جتي TOCOL فنڪشن سپورٽ نه آهي، اتي سيلز جي حد کي ڪالمن ۾ تبديل ڪرڻ جا ٻه متبادل طريقا موجود آهن. اهي حل ڪافي مشڪل آهن، پر بهرحال ڪم ڪري رهيا آهن.

رينج کي قطار ذريعي پڙهڻ لاءِ:

INDEX( range ، QUOTIENT(ROW(A1)-1، COLUMNS( حد ))+1، MOD(ROW(A1)-1، COLUMNS( range ))+1)

علامت پڙهڻ لاءِ ڪالمن طرفان:

INDEX( حد ، MOD(ROW(A1)-1، ROWS( range ))+1، QUOTIENT(ROW(A1)-1، ROWS( range ))+1 )

اسان جي نموني ڊيٽا سيٽ لاءِ، فارمولا هن ريت آهن:

رينج کي اسڪين ڪرڻ لاءِ افقي طور کاٻي کان ساڄي :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

هي فارمولا TOCOL فنڪشن جي برابر آهي 3rd آرگيومينٽ سان FALSE تي سيٽ ڪيو ويو آهي يا ختم ڪيو ويو آهي:

=TOCOL(A2:C5)

رينج کي اسڪين ڪرڻ لاءِ عمودي طور تي مٿي کان هيٺ تائين :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

هي فارمولا TOCOL فنڪشن سان 3rd آرگيومينٽ سان ٺهڪندڙ آهي TRUE:

=TOCOL(A2:C5, ,TRUE)

TOCOL جي برعڪس، هر هڪ ۾ متبادل فارمولو داخل ڪيو وڃي. سيل جتي توهان چاهيو ٿا ته نتيجا ظاهر ٿين. اسان جي حالت ۾، فارمولا سيلز E2 (قطار جي ذريعي) ۽ G2 (ڪالمن طرفان) ڏانهن ويندا آهن، ۽ پوء هيٺ ڏنل قطار 13 ڏانهن نقل ڪيا ويندا آهن.

جيڪڏهن فارمولن کي ضرورت کان وڌيڪ قطار ۾ نقل ڪيو وڃي، a#ريف! غلطي "اضافي" سيلز ۾ ظاهر ٿيندي. ائين ٿيڻ کان روڪڻ لاءِ، توهان فارمولين کي IFERROR فنڪشن ۾ هن طرح نسٽ ڪري سگهو ٿا:

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

ياد رکو ته فارمولن جي صحيح نقل ڪرڻ لاءِ، اسان مطلق سيل حوالن ($) استعمال ڪندي حد کي بند ڪريون ٿا A$2:$C$5). ان جي بدران، توھان استعمال ڪري سگھو ٿا ھڪڙي نالي واري حد.

هي فارمولا ڪيئن ڪم ڪن ٿا

هيٺ ڏنل پهرئين فارمولي جو تفصيلي بريڪ ڊائون آهي جيڪو سيلن کي قطار سان ترتيب ڏئي ٿو:

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

خيال اهو آهي ته INDEX فنڪشن کي استعمال ڪرڻ لاءِ هڪ مخصوص سيل جي قيمت واپس ڪرڻ لاءِ ان جي حد ۾ ان جي لاڳاپي واري قطار ۽ ڪالمن نمبرن جي بنياد تي.

هن ميلاپ سان قطار نمبر ڳڻيو ويندو آهي. :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT ھڪڙي ڀاڱي جو پورو حصو واپس ڏئي ٿو.

عددي لاءِ، توھان استعمال ڪريو ROW(A1) -1، جيڪو موٽائي ٿو a سيريل نمبر E2 ۾ 0 کان (پهريون سيل جتي فارمولا داخل ڪيو ويو) E13 ۾ 11 تائين (آخري سيل جتي فارمولا داخل ڪيو ويو).

The Denominator brough by COLUMNS($A $2:$C$5)) مستقل آهي ۽ توهان جي حد ۾ ڪالمن جي تعداد جي برابر آهي (3 اسان جي ڪيس ۾).

هاڻي، جيڪڏهن توهان پهرين 3 سيلز (E2:E4) لاءِ QUOTIENT جو نتيجو چيڪ ڪريو. ، توهان ڏسندا ته اهو 0 جي برابر آهي (ڇاڪاڻ ته ڊويزن جو پورو حصو صفر آهي). 1 کي شامل ڪرڻ سان قطار نمبر 1 ملي ٿو.

ايندڙ 3 سيلز (E5:E5) لاءِ، QUOTIENT 1 ڏي ٿو، ۽ +1 آپريشن قطار نمبر 2 ڏي ٿو. وغيره.

ٻين لفظن ۾، فارمولا جو هي حصو ٻيهر ورجائي ٿوانگن جو سلسلو جيئن ته 1,1,1,2,2,2,3,3,4,4,4,… هر نمبر جيترا ڀيرا ورجائجي ٿو جيترا ڪالم توهان جي حد ۾ آهن.

ڪرڻ کالم نمبر جي حساب سان، توهان MOD فنڪشن کي استعمال ڪندي هڪ مناسب نمبر ترتيب ٺاهيندا آهيو:

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

جيئن ته اسان جي حد ۾ 3 ڪالمن آهن (A2:C5)، تسلسل ضرور هجڻ گهرجي 1,2,3,1,2,3,…

MOD فنڪشن باقي کي ورجائي ٿو تقسيم کان پوءِ.

E2 ۾، MOD(ROW(A1)-1، COLUMNS ($A$2:$C$5))+1)

بنجي ٿو

MOD(1-1, 3)+1)

۽ واپسي 1.

0 +1)

۽ موٽائي ٿو 2.

قطار ۽ ڪالمن جي نمبرن سان، INDEX کي گهربل قدر حاصل ڪرڻ ۾ ڪو مسئلو ناهي.

E2 ۾، INDEX($A$2) :$C$5, 1, 1) قيمت ڏي ٿو پهرين قطار مان ۽ حوالو ڏنل رينج جي پهرين ڪالمن مان، يعني سيل A2 کان.

E3 ۾، INDEX($A$2:$C$5, 1 , 2) پھرين قطار ۽ 2 ڪالم مان قدر واپس ڪري ٿو، يعني سيل B2 مان.

۽ ائين اڳتي.

ٻيو فارمولا جيڪو اسڪين ڪري ٿو حد تائين c. olumn، ساڳيء طرح ڪم ڪري ٿو. فرق اهو آهي ته اهو قطار نمبر حاصل ڪرڻ لاءِ MOD استعمال ڪري ٿو ۽ ڪالمن نمبر حاصل ڪرڻ لاءِ QUOTIENT.

TOCOL فنڪشن ڪم نه ڪري رهيو آهي

جيڪڏهن TOCOL فنڪشن غلطي ڪري ٿو، اهو تمام گهڻو امڪان آهي انهن سببن مان هڪ هجڻ لاءِ:

TOCOL توهان جي Excel ۾ سپورٽ ناهي

جڏهن توهان هڪ #NAME حاصل ڪندا آهيو؟ غلطي، فنڪشن جي نالي جي صحيح اسپيلنگ پهرين شيء آهيچيڪ. جيڪڏهن نالو صحيح آهي پر غلطي جاري رهي، فنڪشن توهان جي ايڪسل جي نسخي ۾ موجود ناهي. ھن حالت ۾، ھڪ TOCOL متبادل استعمال ڪرڻ تي غور ڪريو.

Array تمام وڏي آھي

ھڪڙو #NUM نقص ظاهر ڪري ٿو ته صف ھڪڙي ڪالمن ۾ مناسب نه ٿي سگھي. هڪ عام صورت آهي جڏهن توهان سڄي ڪالمن يا قطار جو حوالو ڏيو.

ڪافي خالي سيل نه آهن

جڏهن هڪ #SPILL غلطي ٿئي ٿي، چيڪ ڪريو ته ڪالم جتي فارمولا داخل ڪيو ويو آهي نتيجن سان ڀرجي وڃڻ لاءِ ڪافي خالي خانا آهن. جيڪڏهن سيلز بصري طور تي خالي آهن، پڪ ڪريو ته انهن ۾ ڪو به خال ۽ ٻيا غير ڇپيل اکر نه آهن. وڌيڪ معلومات لاءِ، ڏسو ڪيئن ڪجي ايڪسل ۾ #SPILL غلطي کي درست ڪجي.

اهڙيءَ طرح توهان استعمال ڪري سگهو ٿا TOCOL فنڪشن کي Excel 365 ۾ ۽ متبادل حل اڳين ورزن ۾ 2-dimensional array کي هڪ ڪالمن ۾ تبديل ڪرڻ لاءِ. مان توهان جي پڙهڻ لاءِ مهرباني ڪريان ٿو ۽ اميد اٿم ته توهان کي ايندڙ هفتي اسان جي بلاگ تي ڏسندا!

پریکٹس ورڪ بڪ

Excel TOCOL فنڪشن - فارمولا مثال (.xlsx فائل)