ਟੋਕੋਲ ਫੰਕਸ਼ਨ ਦੇ ਨਾਲ ਇੱਕ ਐਰੇ ਜਾਂ ਰੇਂਜ ਨੂੰ ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਬਦਲਣ ਦਾ ਇੱਕ ਆਸਾਨ ਤਰੀਕਾ।

ਕਾਲਮਾਂ ਤੋਂ ਕਤਾਰਾਂ ਵਿੱਚ ਅਤੇ ਉਲਟ ਵਿੱਚ ਡੇਟਾ ਟ੍ਰਾਂਸਪੋਜ਼ ਕਰਨ ਦੀ ਸਮਰੱਥਾ ਕਾਫ਼ੀ ਸਮੇਂ ਤੋਂ ਐਕਸਲ ਵਿੱਚ ਹੈ ਥੋੜ੍ਹੀ ਦੇਰ. ਪਰ ਸੈੱਲਾਂ ਦੀ ਇੱਕ ਰੇਂਜ ਨੂੰ ਇੱਕ ਸਿੰਗਲ ਕਾਲਮ ਵਿੱਚ ਬਦਲਣਾ ਕਰੈਕ ਕਰਨਾ ਇੱਕ ਮੁਸ਼ਕਲ ਕੰਮ ਸੀ। ਹੁਣ, ਇਹ ਆਖਰਕਾਰ ਬਦਲ ਰਿਹਾ ਹੈ. ਮਾਈਕਰੋਸਾਫਟ ਨੇ ਇੱਕ ਨਵਾਂ ਫੰਕਸ਼ਨ ਪੇਸ਼ ਕੀਤਾ ਹੈ, ਜਿਸਨੂੰ TOCOL ਕਿਹਾ ਜਾਂਦਾ ਹੈ, ਜੋ ਇੱਕ ਝਪਕਦਿਆਂ ਹੀ ਇੱਕ ਐਰੇ-ਟੂ-ਕਾਲਮ ਪਰਿਵਰਤਨ ਕਰ ਸਕਦਾ ਹੈ। ਹੇਠਾਂ ਉਹਨਾਂ ਕੰਮਾਂ ਦੀ ਇੱਕ ਸੂਚੀ ਹੈ ਜੋ ਇਹ ਨਵਾਂ ਫੰਕਸ਼ਨ ਆਸਾਨੀ ਨਾਲ ਹੱਲ ਕਰ ਸਕਦਾ ਹੈ।

Excel TOCOL ਫੰਕਸ਼ਨ

Excel ਵਿੱਚ TOCOL ਫੰਕਸ਼ਨ ਇੱਕ ਐਰੇ ਜਾਂ ਸੈੱਲਾਂ ਦੀ ਰੇਂਜ ਨੂੰ ਇੱਕ ਸਿੰਗਲ ਵਿੱਚ ਬਦਲਦਾ ਹੈ ਕਾਲਮ।

ਫੰਕਸ਼ਨ ਤਿੰਨ ਆਰਗੂਮੈਂਟਾਂ ਲੈਂਦਾ ਹੈ, ਪਰ ਸਿਰਫ਼ ਪਹਿਲੀ ਦੀ ਲੋੜ ਹੁੰਦੀ ਹੈ।

TOCOL(ਐਰੇ, [ਅਗਨੋਰ], [ਸਕੈਨ_ਬਾਈ_ਕਾਲਮ])

ਕਿੱਥੇ:

ਐਰੇ (ਲੋੜੀਂਦਾ) - ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਬਦਲਣ ਲਈ ਇੱਕ ਐਰੇ ਜਾਂ ਰੇਂਜ।

ਅਣਡਿੱਠਾ (ਵਿਕਲਪਿਕ) - ਪਰਿਭਾਸ਼ਿਤ ਕਰਦਾ ਹੈ ਕਿ ਖਾਲੀ ਥਾਂਵਾਂ ਜਾਂ/ਅਤੇ ਗਲਤੀਆਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰਨਾ ਹੈ ਜਾਂ ਨਹੀਂ। ਇਹਨਾਂ ਵਿੱਚੋਂ ਇੱਕ ਮੁੱਲ ਹੋ ਸਕਦਾ ਹੈ:

• 0 ਜਾਂ ਛੱਡਿਆ ਗਿਆ (ਡਿਫੌਲਟ) - ਸਾਰੇ ਮੁੱਲ ਰੱਖੋ
• 1 - ਖਾਲੀ ਥਾਂਵਾਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰੋ
• 2 - ਗਲਤੀਆਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰੋ
• 3 - ਖਾਲੀ ਥਾਂਵਾਂ ਅਤੇ ਤਰੁੱਟੀਆਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰੋ

ਸਕੈਨ_ਬਾਈ_ਕਾਲਮ (ਵਿਕਲਪਿਕ) - ਇਹ ਨਿਰਧਾਰਤ ਕਰਦਾ ਹੈ ਕਿ ਐਰੇ ਨੂੰ ਖਿਤਿਜੀ ਜਾਂ ਲੰਬਕਾਰੀ ਤੌਰ 'ਤੇ ਸਕੈਨ ਕਰਨਾ ਹੈ:

• ਗਲਤ ਜਾਂ ਛੱਡਿਆ ਗਿਆ (ਡਿਫਾਲਟ) - ਖੱਬੇ ਤੋਂ ਸੱਜੇ ਕਤਾਰ ਦੁਆਰਾ ਐਰੇ ਨੂੰ ਸਕੈਨ ਕਰੋ।
• ਸੱਚ - ਉੱਪਰ ਤੋਂ ਹੇਠਾਂ ਤੱਕ ਕਾਲਮ ਦੁਆਰਾ ਐਰੇ ਨੂੰ ਸਕੈਨ ਕਰੋ।

ਸੁਝਾਅ:

• ਇੱਕ ਐਰੇ ਨੂੰ ਇੱਕ ਕਤਾਰ ਵਿੱਚ ਬਦਲਣ ਲਈ, TOROW ਦੀ ਵਰਤੋਂ ਕਰੋਫੰਕਸ਼ਨ।
• ਵਿਪਰੀਤ ਕਾਲਮ-ਟੂ-ਐਰੇ ਪਰਿਵਰਤਨ ਕਰਨ ਲਈ, ਜਾਂ ਤਾਂ ਕਾਲਮ ਦੁਆਰਾ ਲਪੇਟਣ ਲਈ WRAPCOLS ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ ਜਾਂ ਕਤਾਰ ਦੁਆਰਾ ਸਮੇਟਣ ਲਈ WRAPROWS ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ।
• ਕਿਸੇ ਐਰੇ ਨੂੰ ਹਰੀਜੱਟਲ ਤੋਂ ਵਿੱਚ ਟ੍ਰਾਂਸਪੋਜ਼ ਕਰਨ ਲਈ ਲੰਬਕਾਰੀ ਜਾਂ ਉਲਟ, ਅਰਥਾਤ ਕਤਾਰਾਂ ਨੂੰ ਕਾਲਮਾਂ ਵਿੱਚ ਬਦਲੋ, TRANSPOSE ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ।

TOCOL ਉਪਲਬਧਤਾ

TOCOL ਇੱਕ ਨਵਾਂ ਫੰਕਸ਼ਨ ਹੈ, ਜੋ Microsoft 365 (Windows ਲਈ) ਲਈ Excel ਵਿੱਚ ਸਮਰਥਿਤ ਹੈ। ਅਤੇ ਮੈਕ) ਅਤੇ ਵੈੱਬ ਲਈ ਐਕਸਲ।

ਰੇਂਜ ਨੂੰ ਕਾਲਮ ਵਿੱਚ ਬਦਲਣ ਲਈ ਮੁੱਢਲਾ TOCOL ਫਾਰਮੂਲਾ

TOCOL ਫਾਰਮੂਲੇ ਨੂੰ ਇਸਦੇ ਸਰਲ ਰੂਪ ਵਿੱਚ ਸਿਰਫ਼ ਇੱਕ ਆਰਗੂਮੈਂਟ ਦੀ ਲੋੜ ਹੈ - ਐਰੇ । ਉਦਾਹਰਨ ਲਈ, ਇੱਕ ਸਿੰਗਲ ਕਾਲਮ ਵਿੱਚ 3 ਕਾਲਮ ਅਤੇ 4 ਕਤਾਰਾਂ ਵਾਲੀ ਦੋ-ਅਯਾਮੀ ਐਰੇ ਰੱਖਣ ਲਈ, ਫਾਰਮੂਲਾ ਹੈ:

=TOCOL(A2:C5)

ਫਾਰਮੂਲਾ ਸਿਰਫ਼ ਇੱਕ ਸੈੱਲ ਵਿੱਚ ਦਰਜ ਕੀਤਾ ਗਿਆ ਹੈ (E2 ਵਿੱਚ ਇਹ ਉਦਾਹਰਨ) ਅਤੇ ਹੇਠਾਂ ਦਿੱਤੇ ਸੈੱਲਾਂ ਵਿੱਚ ਆਟੋਮੈਟਿਕਲੀ ਫੈਲ ਜਾਂਦੀ ਹੈ। ਐਕਸਲ ਦੇ ਰੂਪ ਵਿੱਚ, ਨਤੀਜੇ ਨੂੰ ਇੱਕ ਸਪਿਲ ਰੇਂਜ ਕਿਹਾ ਜਾਂਦਾ ਹੈ।

ਇਹ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ:

ਤਕਨੀਕੀ ਤੌਰ 'ਤੇ, ਰੇਂਜ A2:C5 ਨੂੰ ਪਹਿਲਾਂ ਦੋ-ਅਯਾਮੀ ਐਰੇ ਵਿੱਚ ਬਦਲਿਆ ਜਾਂਦਾ ਹੈ। ਕਿਰਪਾ ਕਰਕੇ ਸੈਮੀਕੋਲਨ ਨਾਲ ਵੱਖ ਕੀਤੀਆਂ ਕਤਾਰਾਂ ਅਤੇ ਕੌਮਾ-ਸੀਮਤ ਕਾਲਮਾਂ ਵੱਲ ਧਿਆਨ ਦਿਓ:

{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}

TOCOL ਫੰਕਸ਼ਨ ਐਰੇ ਨੂੰ ਖੱਬੇ ਤੋਂ ਸੱਜੇ ਸਕੈਨ ਕਰਦਾ ਹੈ ਅਤੇ ਇਸਨੂੰ ਇੱਕ-ਅਯਾਮੀ ਲੰਬਕਾਰੀ ਐਰੇ ਵਿੱਚ ਬਦਲਦਾ ਹੈ:

{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}

ਨਤੀਜਾ ਸੈੱਲ E2 ਵਿੱਚ ਰੱਖਿਆ ਗਿਆ ਹੈ, ਜਿੱਥੋਂ ਇਹ ਹੇਠਲੇ ਸੈੱਲਾਂ ਵਿੱਚ ਫੈਲਦਾ ਹੈ।

ਐਕਸਲ ਵਿੱਚ TOCOL ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਿਵੇਂ ਕਰੀਏ - ਫਾਰਮੂਲਾ ਉਦਾਹਰਣ

ਦੀ ਵਧੇਰੇ ਸਮਝ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈTOCOL ਫੰਕਸ਼ਨ ਦੀਆਂ ਸੰਭਾਵਨਾਵਾਂ ਅਤੇ ਇਹ ਕਿਹੜੇ ਕੰਮਾਂ ਨੂੰ ਕਵਰ ਕਰ ਸਕਦਾ ਹੈ, ਆਓ ਕੁਝ ਫਾਰਮੂਲੇ ਉਦਾਹਰਨਾਂ 'ਤੇ ਇੱਕ ਨਜ਼ਰ ਮਾਰੀਏ।

ਐਰੇ ਨੂੰ ਖਾਲੀ ਥਾਂਵਾਂ ਅਤੇ ਤਰੁੱਟੀਆਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰਦੇ ਹੋਏ ਕਾਲਮ ਵਿੱਚ ਬਦਲੋ

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਪਿਛਲੀ ਉਦਾਹਰਨ ਵਿੱਚ ਦੇਖਿਆ ਹੋਵੇਗਾ , ਡਿਫਾਲਟ TOCOL ਫਾਰਮੂਲਾ ਸਰੋਤ ਐਰੇ ਦੇ ਸਾਰੇ ਮੁੱਲਾਂ ਨੂੰ ਰੱਖਦਾ ਹੈ, ਜਿਸ ਵਿੱਚ ਖਾਲੀ ਸੈੱਲ ਅਤੇ ਤਰੁੱਟੀਆਂ ਸ਼ਾਮਲ ਹਨ।

ਨਤੀਜੇ ਵਜੋਂ ਐਰੇ ਵਿੱਚ, ਖਾਲੀ ਸੈੱਲਾਂ ਨੂੰ ਜ਼ੀਰੋ ਦੁਆਰਾ ਦਰਸਾਇਆ ਜਾਂਦਾ ਹੈ, ਜੋ ਕਿ ਕਾਫ਼ੀ ਭੰਬਲਭੂਸੇ ਵਾਲਾ ਹੋ ਸਕਦਾ ਹੈ, ਖਾਸ ਕਰਕੇ ਜੇਕਰ ਅਸਲ ਐਰੇ ਵਿੱਚ 0 ਮੁੱਲ। ਹੱਲ ਹੈ ਖਾਲੀ ਥਾਂ ਛੱਡਣਾ । ਇਸਦੇ ਲਈ, ਤੁਸੀਂ ਦੂਜੀ ਆਰਗੂਮੈਂਟ ਨੂੰ 1:

=TOCOL(A2:C5, 1)

ਗਲਤੀਆਂ ਨੂੰ ਨਜ਼ਰਅੰਦਾਜ਼ ਕਰਨ ਲਈ, 2ਜੀ ਆਰਗੂਮੈਂਟ ਨੂੰ 2:

=TOCOL(A2:C5, 2) <3 'ਤੇ ਸੈੱਟ ਕਰੋ।>

ਦੋਨਾਂ ਨੂੰ ਬਾਹਰ ਕੱਢਣ ਲਈ, ਖਾਲੀ ਅਤੇ ਗਲਤੀਆਂ , ਅਣਡਿੱਠ ਕਰੋ ਆਰਗੂਮੈਂਟ ਲਈ 3 ਦੀ ਵਰਤੋਂ ਕਰੋ:

=TOCOL(A2:C5, 3)

ਐਰੇ ਨੂੰ ਖਿਤਿਜੀ ਜਾਂ ਵਰਟੀਕਲ ਸਕੈਨ ਕਰੋ

ਡਿਫੌਲਟ scan_by_column ਆਰਗੂਮੈਂਟ (FALSE ਜਾਂ ਛੱਡਿਆ) ਦੇ ਨਾਲ, TOCOL ਫੰਕਸ਼ਨ ਕਤਾਰ ਦੁਆਰਾ ਲੇਟਵੇਂ ਰੂਪ ਵਿੱਚ ਐਰੇ ਨੂੰ ਸਕੈਨ ਕਰਦਾ ਹੈ। ਕਾਲਮ ਦੁਆਰਾ ਮੁੱਲਾਂ 'ਤੇ ਪ੍ਰਕਿਰਿਆ ਕਰਨ ਲਈ, ਇਸ ਆਰਗੂਮੈਂਟ ਨੂੰ TRUE ਜਾਂ 1 'ਤੇ ਸੈੱਟ ਕਰੋ। ਉਦਾਹਰਨ ਲਈ:

=TOCOL(A2:C5, ,TRUE)

ਧਿਆਨ ਦਿਓ ਕਿ, ਦੋਵਾਂ ਮਾਮਲਿਆਂ ਵਿੱਚ, ਵਾਪਸ ਕੀਤੀਆਂ ਐਰੇ ਇੱਕੋ ਆਕਾਰ ਦੇ ਹਨ, ਪਰ ਮੁੱਲ ਵਿਵਸਥਿਤ ਕੀਤੇ ਗਏ ਹਨ। ਇੱਕ ਵੱਖਰੇ ਕ੍ਰਮ ਵਿੱਚ.

ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਕਈ ਰੇਂਜਾਂ ਨੂੰ ਜੋੜੋ

ਜੇਕਰ ਤੁਸੀਂ ਕਈ ਗੈਰ-ਸੰਬੰਧਿਤ ਰੇਂਜਾਂ ਨਾਲ ਕੰਮ ਕਰ ਰਹੇ ਹੋ, ਤਾਂ ਤੁਸੀਂ ਪਹਿਲਾਂ VSTACK ਫੰਕਸ਼ਨ ਦੀ ਮਦਦ ਨਾਲ ਰੇਂਜਾਂ ਨੂੰ ਇੱਕ ਸਿੰਗਲ ਐਰੇ ਵਿੱਚ ਲੰਬਕਾਰੀ ਰੂਪ ਵਿੱਚ ਜੋੜ ਸਕਦੇ ਹੋ, ਅਤੇ ਫਿਰ ਸੰਯੁਕਤ ਐਰੇ ਨੂੰ ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਬਦਲਣ ਲਈ TOCOL ਦੀ ਵਰਤੋਂ ਕਰੋ।

ਇਹ ਮੰਨ ਕੇ ਕਿ ਪਹਿਲੀ ਰੇਂਜ A2:C4 ਹੈ ਅਤੇ ਦੂਜੀ ਰੇਂਜ A8:C9 ਹੈ, ਫਾਰਮੂਲਾ ਇਹ ਫਾਰਮ ਲੈਂਦਾ ਹੈ:

=TOCOL(VSTACK(A2:C4, A8:C9))

ਇਹ ਫਾਰਮੂਲਾ ਪੂਰਵ-ਨਿਰਧਾਰਤ ਵਿਵਹਾਰ ਨੂੰ ਦਰਸਾਉਂਦਾ ਹੈ - ਸੰਯੁਕਤ ਐਰੇ ਨੂੰ ਖੱਬੇ ਤੋਂ ਖਿਤਿਜੀ ਰੂਪ ਵਿੱਚ ਪੜ੍ਹਦਾ ਹੈ ਹੇਠਾਂ ਚਿੱਤਰ ਵਿੱਚ ਕਾਲਮ E ਵਿੱਚ ਦਰਸਾਏ ਅਨੁਸਾਰ ਸੱਜੇ ਪਾਸੇ।

ਉੱਪਰ ਤੋਂ ਹੇਠਾਂ ਵੱਲ ਖੜ੍ਹਵੇਂ ਤੌਰ 'ਤੇ ਮੁੱਲਾਂ ਨੂੰ ਪੜ੍ਹਨ ਲਈ, ਤੁਸੀਂ TOCOL ਦੀ ਤੀਜੀ ਆਰਗੂਮੈਂਟ ਨੂੰ TRUE ਵਿੱਚ ਸੈੱਟ ਕਰਦੇ ਹੋ:

=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)

ਕਿਰਪਾ ਕਰਕੇ ਧਿਆਨ ਦਿਓ ਕਿ, ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਫਾਰਮੂਲਾ ਪਹਿਲਾਂ ਦੋਵਾਂ ਐਰੇ ਦੇ ਕਾਲਮ A ਤੋਂ ਮੁੱਲ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਫਿਰ ਕਾਲਮ B ਤੋਂ, ਅਤੇ ਇਸ ਤਰ੍ਹਾਂ ਹੋਰ। ਕਾਰਨ ਇਹ ਹੈ ਕਿ TOCOL ਇੱਕ ਸਿੰਗਲ ਸਟੈਕਡ ਐਰੇ ਨੂੰ ਸਕੈਨ ਕਰਦਾ ਹੈ, ਮੂਲ ਵਿਅਕਤੀਗਤ ਰੇਂਜਾਂ ਨੂੰ ਨਹੀਂ।

ਜੇਕਰ ਤੁਹਾਡੇ ਕਾਰੋਬਾਰੀ ਤਰਕ ਲਈ ਅਸਲ ਰੇਂਜਾਂ ਨੂੰ ਖੜ੍ਹਵੇਂ ਤੌਰ 'ਤੇ ਸਟੈਕ ਕਰਨ ਦੀ ਲੋੜ ਹੈ, ਤਾਂ VSTACK ਦੀ ਬਜਾਏ HSTACK ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ।

ਪਿਛਲੇ ਐਰੇ ਦੇ ਸੱਜੇ ਪਾਸੇ ਹਰੇਕ ਅਗਲੀ ਐਰੇ ਨੂੰ ਜੋੜਨ ਲਈ ਅਤੇ ਪੜ੍ਹੋ ਸੰਯੁਕਤ ਐਰੇ ਨੂੰ ਖਿਤਿਜੀ ਰੂਪ ਵਿੱਚ, ਫਾਰਮੂਲਾ ਹੈ:

=TOCOL(HSTACK(A2:C4, A8:C10))

ਪਿਛਲੀ ਐਰੇ ਦੇ ਸੱਜੇ ਪਾਸੇ ਹਰੇਕ ਅਗਲੀ ਐਰੇ ਨੂੰ ਜੋੜਨ ਲਈ ਅਤੇ ਸੰਯੁਕਤ ਐਰੇ ਨੂੰ ਲੰਬਕਾਰੀ ਤੌਰ 'ਤੇ ਸਕੈਨ ਕਰਨ ਲਈ, ਫਾਰਮੂਲਾ ਹੈ:

=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE)

ਇੱਕ ਮਲਟੀ-ਕਾਲਮ ਰੇਂਜ ਤੋਂ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਨੂੰ ਐਕਸਟਰੈਕਟ ਕਰੋ

ਐਕਸਲ ਯੂਨੀਕ ਫੰਕਸ਼ਨ ਇੱਕ ਸਿੰਗਲ ਕਾਲਮ ਜਾਂ ਕਤਾਰ ਵਿੱਚ ਵਿਲੱਖਣਤਾਵਾਂ ਨੂੰ ਆਸਾਨੀ ਨਾਲ ਲੱਭ ਸਕਦਾ ਹੈ ਅਤੇ ਨਾਲ ਹੀ ਵਿਲੱਖਣ ਕਤਾਰਾਂ ਨੂੰ ਵਾਪਸ ਕਰ ਸਕਦਾ ਹੈ, ਪਰ ਇਹ ਇਸ ਤੋਂ ਵਿਲੱਖਣ ਮੁੱਲ ਨਹੀਂ ਕੱਢ ਸਕਦਾ ਹੈ ਇੱਕ ਬਹੁ-ਕਾਲਮ ਐਰੇ। ਹੱਲ ਹੈ ਇਸਨੂੰ TOCOL ਫੰਕਸ਼ਨ ਦੇ ਨਾਲ ਵਰਤਣਾ।

ਉਦਾਹਰਨ ਲਈ, ਰੇਂਜ ਤੋਂ ਸਾਰੇ ਵੱਖ-ਵੱਖ (ਵੱਖਰੇ) ਮੁੱਲਾਂ ਨੂੰ ਕੱਢਣ ਲਈA2:C7, ਫਾਰਮੂਲਾ ਹੈ:

=UNIQUE(TOCOL(A2:C7))

ਇਸ ਤੋਂ ਇਲਾਵਾ, ਤੁਸੀਂ ਵਰਣਮਾਲਾ ਦੇ ਕ੍ਰਮ ਵਿੱਚ ਵਾਪਸੀ ਐਰੇ ਨੂੰ ਵਿਵਸਥਿਤ ਕਰਨ ਲਈ ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਨੂੰ SORT ਫੰਕਸ਼ਨ ਵਿੱਚ ਲਪੇਟ ਸਕਦੇ ਹੋ:

=SORT(UNIQUE(TOCOL(A2:C7)))

ਐਕਸਲ 365 - 2010 ਵਿੱਚ ਰੇਂਜ ਨੂੰ ਕਾਲਮ ਵਿੱਚ ਕਿਵੇਂ ਬਦਲਿਆ ਜਾਵੇ

ਐਕਸਲ ਸੰਸਕਰਣਾਂ ਵਿੱਚ ਜਿੱਥੇ TOCOL ਫੰਕਸ਼ਨ ਸਮਰਥਿਤ ਨਹੀਂ ਹੈ, ਉੱਥੇ ਸੈੱਲਾਂ ਦੀ ਰੇਂਜ ਨੂੰ ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਬਦਲਣ ਦੇ ਕੁਝ ਵਿਕਲਪਕ ਤਰੀਕੇ ਮੌਜੂਦ ਹਨ। ਇਹ ਹੱਲ ਕਾਫ਼ੀ ਔਖੇ ਹਨ, ਪਰ ਫਿਰ ਵੀ ਕੰਮ ਕਰ ਰਹੇ ਹਨ।

ਕਤਾਰ ਦੁਆਰਾ ਰੇਂਜ ਨੂੰ ਪੜ੍ਹਨ ਲਈ:

INDEX( ਰੇਂਜ , QUOTIENT(ROW(A1)-1, COLUMNS( ਰੇਂਜ ))+1, MOD(ROW(A1)-1, COLUMNS( ਰੇਂਜ ))+1)

ਕਾਲਮ ਦੁਆਰਾ ਰੇਂਜ ਨੂੰ ਪੜ੍ਹਨ ਲਈ:

INDEX( ਰੇਂਜ , MOD(ROW(A1)-1, ROWS( range ))+1, QuOTIENT(ROW(A1)-1, ROWS( ਰੇਂਜ ))+1 )

ਸਾਡੇ ਨਮੂਨਾ ਡੇਟਾਸੈਟ ਲਈ, ਫਾਰਮੂਲੇ ਇਸ ਤਰ੍ਹਾਂ ਹਨ:

ਰੇਂਜ ਨੂੰ ਸਕੈਨ ਕਰਨ ਲਈ ਖਿੱਜੀ ਤੌਰ 'ਤੇ ਖੱਬੇ ਤੋਂ ਸੱਜੇ :

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

ਇਹ ਫਾਰਮੂਲਾ TOCOL ਫੰਕਸ਼ਨ ਦੇ ਬਰਾਬਰ ਹੈ ਜਿਸ ਵਿੱਚ 3 ਆਰਗੂਮੈਂਟ ਨੂੰ FALSE 'ਤੇ ਸੈੱਟ ਕੀਤਾ ਗਿਆ ਹੈ ਜਾਂ ਛੱਡਿਆ ਗਿਆ ਹੈ:

=TOCOL(A2:C5)

ਰੇਂਜ ਨੂੰ ਸਕੈਨ ਕਰਨ ਲਈ ਉੱਪਰ ਤੋਂ ਹੇਠਾਂ ਤੱਕ ਲੰਬਕਾਰੀ :

=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)

ਇਹ ਫਾਰਮੂਲਾ TOCOL ਫੰਕਸ਼ਨ ਨਾਲ ਤੁਲਨਾਯੋਗ ਹੈ 3rd ਆਰਗੂਮੈਂਟ TRUE:

=TOCOL(A2:C5, ,TRUE)

TOCOL ਦੇ ਉਲਟ, ਹਰੇਕ ਵਿੱਚ ਵਿਕਲਪਕ ਫਾਰਮੂਲੇ ਦਰਜ ਕੀਤੇ ਜਾਣੇ ਚਾਹੀਦੇ ਹਨ। ਸੈੱਲ ਜਿੱਥੇ ਤੁਸੀਂ ਨਤੀਜੇ ਦਿਖਾਉਣਾ ਚਾਹੁੰਦੇ ਹੋ। ਸਾਡੇ ਕੇਸ ਵਿੱਚ, ਫਾਰਮੂਲੇ ਸੈੱਲ E2 (ਕਤਾਰ ਦੁਆਰਾ) ਅਤੇ G2 (ਕਾਲਮ ਦੁਆਰਾ) ਵਿੱਚ ਜਾਂਦੇ ਹਨ, ਅਤੇ ਫਿਰ ਕਤਾਰ 13 ਵਿੱਚ ਕਾਪੀ ਕੀਤੇ ਜਾਂਦੇ ਹਨ।

ਜੇ ਫਾਰਮੂਲੇ ਲੋੜ ਤੋਂ ਵੱਧ ਕਤਾਰਾਂ ਵਿੱਚ ਕਾਪੀ ਕੀਤੇ ਜਾਂਦੇ ਹਨ, a#REF! ਗਲਤੀ "ਵਾਧੂ" ਸੈੱਲਾਂ ਵਿੱਚ ਦਿਖਾਈ ਦੇਵੇਗੀ। ਅਜਿਹਾ ਹੋਣ ਤੋਂ ਰੋਕਣ ਲਈ, ਤੁਸੀਂ IFERROR ਫੰਕਸ਼ਨ ਵਿੱਚ ਫਾਰਮੂਲੇ ਨੂੰ ਇਸ ਤਰ੍ਹਾਂ ਨੇਸਟ ਕਰ ਸਕਦੇ ਹੋ:

=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")

ਧਿਆਨ ਦਿਓ ਕਿ ਫਾਰਮੂਲੇ ਨੂੰ ਸਹੀ ਢੰਗ ਨਾਲ ਕਾਪੀ ਕਰਨ ਲਈ, ਅਸੀਂ ਸੰਪੂਰਨ ਸੈੱਲ ਸੰਦਰਭਾਂ ($) ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਰੇਂਜ ਨੂੰ ਲਾਕ ਕਰਦੇ ਹਾਂ A$2:$C$5)। ਇਸਦੀ ਬਜਾਏ, ਤੁਸੀਂ ਇੱਕ ਨਾਮਿਤ ਰੇਂਜ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ।

ਇਹ ਫਾਰਮੂਲੇ ਕਿਵੇਂ ਕੰਮ ਕਰਦੇ ਹਨ

ਹੇਠਾਂ ਪਹਿਲੇ ਫਾਰਮੂਲੇ ਦਾ ਵਿਸਤ੍ਰਿਤ ਬ੍ਰੇਕ-ਡਾਉਨ ਹੈ ਜੋ ਸੈੱਲਾਂ ਨੂੰ ਕਤਾਰ ਦੁਆਰਾ ਵਿਵਸਥਿਤ ਕਰਦਾ ਹੈ:

=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)

ਇੰਡੈਕਸ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਰੇਂਜ ਵਿੱਚ ਇਸਦੀ ਸਾਪੇਖਿਕ ਕਤਾਰ ਅਤੇ ਕਾਲਮ ਸੰਖਿਆਵਾਂ ਦੇ ਅਧਾਰ ਤੇ ਇੱਕ ਖਾਸ ਸੈੱਲ ਦੇ ਮੁੱਲ ਨੂੰ ਵਾਪਸ ਕਰਨ ਲਈ ਹੈ।

ਕਤਾਰ ਸੰਖਿਆ ਦੀ ਗਣਨਾ ਇਸ ਸੁਮੇਲ ਦੁਆਰਾ ਕੀਤੀ ਜਾਂਦੀ ਹੈ। :

QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

QUOTIENT ਇੱਕ ਭਾਗ ਦਾ ਪੂਰਨ ਅੰਕ ਵਾਪਸ ਕਰਦਾ ਹੈ।

ਅੰਕ ਲਈ, ਤੁਸੀਂ ROW(A1)-1 ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹੋ, ਜੋ ਕਿ a ਵਾਪਸ ਕਰਦਾ ਹੈ E2 ਵਿੱਚ 0 ਤੋਂ ਸੀਰੀਅਲ ਨੰਬਰ (ਪਹਿਲਾ ਸੈੱਲ ਜਿੱਥੇ ਫਾਰਮੂਲਾ ਦਾਖਲ ਕੀਤਾ ਗਿਆ ਹੈ) ਤੋਂ E13 ਵਿੱਚ 11 ਤੱਕ (ਆਖਰੀ ਸੈੱਲ ਜਿੱਥੇ ਫਾਰਮੂਲਾ ਦਾਖਲ ਕੀਤਾ ਗਿਆ ਹੈ)।

ਡਨੋਮੀਨੇਟਰ COLUMNS($A) ਦੁਆਰਾ ਬ੍ਰੋ $2:$C$5)) ਸਥਿਰ ਹੈ ਅਤੇ ਤੁਹਾਡੀ ਰੇਂਜ (ਸਾਡੇ ਕੇਸ ਵਿੱਚ 3) ਵਿੱਚ ਕਾਲਮਾਂ ਦੀ ਸੰਖਿਆ ਦੇ ਬਰਾਬਰ ਹੈ।

ਹੁਣ, ਜੇਕਰ ਤੁਸੀਂ ਪਹਿਲੇ 3 ਸੈੱਲਾਂ (E2:E4) ਲਈ QUOTIENT ਦੇ ਨਤੀਜੇ ਦੀ ਜਾਂਚ ਕਰਦੇ ਹੋ। , ਤੁਸੀਂ ਦੇਖੋਗੇ ਕਿ ਇਹ 0 ਦੇ ਬਰਾਬਰ ਹੈ (ਕਿਉਂਕਿ ਭਾਗ ਦਾ ਪੂਰਨ ਅੰਕ ਜ਼ੀਰੋ ਹੈ)। 1 ਨੂੰ ਜੋੜਨ ਨਾਲ ਕਤਾਰ ਨੰਬਰ 1 ਮਿਲਦਾ ਹੈ।

ਅਗਲੇ 3 ਸੈੱਲਾਂ (E5:E5) ਲਈ, QUOTIENT 1 ਦਿੰਦਾ ਹੈ, ਅਤੇ +1 ਕਾਰਵਾਈ ਕਤਾਰ ਨੰਬਰ 2 ਪ੍ਰਦਾਨ ਕਰਦੀ ਹੈ। ਅਤੇ ਇਸ ਤਰ੍ਹਾਂ ਹੀ।

ਦੂਜੇ ਸ਼ਬਦਾਂ ਵਿਚ, ਫਾਰਮੂਲੇ ਦਾ ਇਹ ਹਿੱਸਾ ਦੁਹਰਾਉਣ ਵਾਲਾ ਬਣਾਉਂਦਾ ਹੈਸੰਖਿਆ ਕ੍ਰਮ ਜਿਵੇਂ ਕਿ 1,1,1,2,2,2,3,3,3,4,4,4,… ਹਰ ਇੱਕ ਸੰਖਿਆ ਓਨੀ ਵਾਰ ਦੁਹਰਾਉਂਦੀ ਹੈ ਜਿੰਨੀ ਵਾਰ ਤੁਹਾਡੀ ਰੇਂਜ ਵਿੱਚ ਕਾਲਮ ਹਨ।

ਨੂੰ ਕਾਲਮ ਨੰਬਰ ਦੀ ਗਣਨਾ ਕਰੋ, ਤੁਸੀਂ MOD ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਕੇ ਇੱਕ ਉਚਿਤ ਸੰਖਿਆ ਕ੍ਰਮ ਬਣਾਉਂਦੇ ਹੋ:

MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1

ਕਿਉਂਕਿ ਸਾਡੀ ਰੇਂਜ (A2:C5) ਵਿੱਚ 3 ਕਾਲਮ ਹਨ, ਕ੍ਰਮ 1,2,3,1,2,3,…

MOD ਫੰਕਸ਼ਨ ਵੰਡ ਤੋਂ ਬਾਅਦ ਬਾਕੀ ਨੂੰ ਵਾਪਸ ਕਰਦਾ ਹੈ।

E2 ਵਿੱਚ, MOD(ROW(A1)-1, COLUMNS ($A$2:$C$5))+1)

ਬਣਦਾ ਹੈ

MOD(1-1, 3)+1)

ਅਤੇ 1 ਵਾਪਸ ਕਰਦਾ ਹੈ।

E3 ਵਿੱਚ, MOD(ROW(A2)-1, COLUMNS($A$2:$C$5))+1)

ਬਣ ਜਾਂਦਾ ਹੈ

MOD(2-1, 3) +1)

ਅਤੇ ਰਿਟਰਨ 2.

ਸਥਾਪਿਤ ਕਤਾਰ ਅਤੇ ਕਾਲਮ ਨੰਬਰਾਂ ਦੇ ਨਾਲ, INDEX ਨੂੰ ਲੋੜੀਂਦਾ ਮੁੱਲ ਪ੍ਰਾਪਤ ਕਰਨ ਵਿੱਚ ਕੋਈ ਸਮੱਸਿਆ ਨਹੀਂ ਹੈ।

E2 ਵਿੱਚ, INDEX($A$2 :$C$5, 1, 1) ਪਹਿਲੀ ਕਤਾਰ ਅਤੇ ਹਵਾਲਾ ਰੇਂਜ ਦੇ ਪਹਿਲੇ ਕਾਲਮ ਤੋਂ ਮੁੱਲ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਜਿਵੇਂ ਕਿ ਸੈੱਲ A2 ਤੋਂ।

E3, INDEX ਵਿੱਚ($A$2:$C$5, 1 . olumn, ਇਸੇ ਤਰ੍ਹਾਂ ਕੰਮ ਕਰਦਾ ਹੈ। ਫਰਕ ਇਹ ਹੈ ਕਿ ਇਹ ਕਤਾਰ ਨੰਬਰ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ MOD ਅਤੇ ਕਾਲਮ ਨੰਬਰ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ QUOTIENT ਦੀ ਵਰਤੋਂ ਕਰਦਾ ਹੈ।

TOCOL ਫੰਕਸ਼ਨ ਕੰਮ ਨਹੀਂ ਕਰ ਰਿਹਾ

ਜੇਕਰ TOCOL ਫੰਕਸ਼ਨ ਇੱਕ ਗਲਤੀ ਸੁੱਟਦਾ ਹੈ, ਤਾਂ ਇਹ ਸਭ ਤੋਂ ਵੱਧ ਸੰਭਾਵਨਾ ਹੈ ਇਹਨਾਂ ਕਾਰਨਾਂ ਵਿੱਚੋਂ ਇੱਕ ਹੋਣ ਲਈ:

ਟੋਕੋਲ ਤੁਹਾਡੇ ਐਕਸਲ ਵਿੱਚ ਸਮਰਥਿਤ ਨਹੀਂ ਹੈ

ਜਦੋਂ ਤੁਸੀਂ ਇੱਕ #NAME ਪ੍ਰਾਪਤ ਕਰਦੇ ਹੋ? ਗਲਤੀ, ਫੰਕਸ਼ਨ ਦੇ ਨਾਮ ਦੀ ਸਹੀ ਸਪੈਲਿੰਗ ਸਭ ਤੋਂ ਪਹਿਲਾਂ ਹੈਚੈਕ. ਜੇਕਰ ਨਾਮ ਸਹੀ ਹੈ ਪਰ ਗਲਤੀ ਬਣੀ ਰਹਿੰਦੀ ਹੈ, ਤਾਂ ਫੰਕਸ਼ਨ ਤੁਹਾਡੇ ਐਕਸਲ ਦੇ ਸੰਸਕਰਣ ਵਿੱਚ ਉਪਲਬਧ ਨਹੀਂ ਹੈ। ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਇੱਕ TOCOL ਵਿਕਲਪ ਦੀ ਵਰਤੋਂ ਕਰਨ 'ਤੇ ਵਿਚਾਰ ਕਰੋ।

ਐਰੇ ਬਹੁਤ ਵੱਡਾ ਹੈ

ਇੱਕ #NUM ਗਲਤੀ ਦਰਸਾਉਂਦੀ ਹੈ ਕਿ ਐਰੇ ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਫਿੱਟ ਨਹੀਂ ਹੋ ਸਕਦਾ ਹੈ। ਇੱਕ ਆਮ ਕੇਸ ਉਦੋਂ ਹੁੰਦਾ ਹੈ ਜਦੋਂ ਤੁਸੀਂ ਪੂਰੇ ਕਾਲਮਾਂ ਜਾਂ ਕਤਾਰਾਂ ਦਾ ਹਵਾਲਾ ਦਿੰਦੇ ਹੋ।

ਇੱਥੇ ਕਾਫ਼ੀ ਖਾਲੀ ਸੈੱਲ ਨਹੀਂ ਹਨ

ਜਦੋਂ ਇੱਕ #SPILL ਗਲਤੀ ਆਉਂਦੀ ਹੈ, ਤਾਂ ਜਾਂਚ ਕਰੋ ਕਿ ਕਾਲਮ ਜਿੱਥੇ ਫਾਰਮੂਲਾ ਦਰਜ ਕੀਤਾ ਗਿਆ ਹੈ ਨਤੀਜਿਆਂ ਨਾਲ ਭਰੇ ਜਾਣ ਲਈ ਕਾਫ਼ੀ ਖਾਲੀ ਸੈੱਲ ਹਨ। ਜੇਕਰ ਸੈੱਲ ਦ੍ਰਿਸ਼ਟੀਗਤ ਤੌਰ 'ਤੇ ਖਾਲੀ ਹਨ, ਤਾਂ ਯਕੀਨੀ ਬਣਾਓ ਕਿ ਉਹਨਾਂ ਵਿੱਚ ਕੋਈ ਖਾਲੀ ਥਾਂ ਅਤੇ ਹੋਰ ਗੈਰ-ਪ੍ਰਿੰਟਿੰਗ ਅੱਖਰ ਨਹੀਂ ਹਨ। ਹੋਰ ਜਾਣਕਾਰੀ ਲਈ, ਐਕਸਲ ਵਿੱਚ #SPILL ਗਲਤੀ ਨੂੰ ਕਿਵੇਂ ਠੀਕ ਕਰਨਾ ਹੈ ਵੇਖੋ।

ਇਸ ਤਰ੍ਹਾਂ ਤੁਸੀਂ ਐਕਸਲ 365 ਵਿੱਚ TOCOL ਫੰਕਸ਼ਨ ਅਤੇ ਪੁਰਾਣੇ ਸੰਸਕਰਣਾਂ ਵਿੱਚ ਵਿਕਲਪਕ ਹੱਲਾਂ ਦੀ ਵਰਤੋਂ ਇੱਕ ਸਿੰਗਲ ਕਾਲਮ ਵਿੱਚ 2-ਅਯਾਮੀ ਐਰੇ ਨੂੰ ਬਦਲਣ ਲਈ ਕਰ ਸਕਦੇ ਹੋ। ਮੈਂ ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਕਰਦਾ ਹਾਂ ਅਤੇ ਅਗਲੇ ਹਫ਼ਤੇ ਤੁਹਾਨੂੰ ਸਾਡੇ ਬਲੌਗ 'ਤੇ ਮਿਲਣ ਦੀ ਉਮੀਦ ਕਰਦਾ ਹਾਂ!

ਪ੍ਰੈਕਟਿਸ ਵਰਕਬੁੱਕ

Excel TOCOL ਫੰਕਸ਼ਨ - ਫਾਰਮੂਲਾ ਉਦਾਹਰਨਾਂ (.xlsx ਫਾਈਲ)