Enhavtabelo
Facila maniero transformi tabelon aŭ gamon en kolumnon per la funkcio TOCOL.
La kapablo transmeti datumojn de kolumnoj al vicoj kaj inverse estis en Excel dum sufiĉe da tempo. iom da tempo. Sed konverti gamon da ĉeloj en ununuran kolumnon estis malfacila tasko por fendi. Nun, tio finfine ŝanĝiĝas. Mikrosofto enkondukis novan funkcion, nomitan TOCOL, kiu povas fari tabelan transformon en palpebrume. Malsupre estas listo de taskoj kiujn ĉi tiu nova funkcio povas facile solvi.
Excel TOCOL-funkcio
La TOCOL-funkcio en Excel konvertas tabelon aŭ gamon da ĉeloj en unuopa. kolumno.
La funkcio prenas tri argumentojn, sed nur la unua estas bezonata.
TOKOL(tabelo, [ignori], [skani_per_kolumno])Kie:
Tabelo (postula) - tabelo aŭ intervalo por transformi en kolumnon.
Ignori (laŭvola) - difinas ĉu ignori malplenajn aŭ/kaj erarojn. Povas esti unu el ĉi tiuj valoroj:
- 0 aŭ ellasita (defaŭlte) - konservu ĉiujn valorojn
- 1 - ignoru malplenajn
- 2 - ignoru erarojn
- 3 - ignori malplenajn kaj erarojn
Skani_per_kolumno (laŭvola) - determinas ĉu skani la tabelon horizontale aŭ vertikale:
- FALSA aŭ ellasita (defaŭlte) - skani la tabelon laŭ vico de maldekstre dekstren.
- VERA - skani la tabelon laŭ kolumno de supre ĝis malsupre.
Konsiletoj:
<; 4>TOCOL havebleco
TOCOL estas nova funkcio, kiu estas subtenata en Excel por Microsoft 365 (por Vindozo). kaj Mac) kaj Excel por la reto.
Baza TOCOL-formulo por transformi gamon en kolumnon
La TOCOL-formulo en sia plej simpla formo postulas nur unu argumenton - tabelo . Ekzemple, por meti dudimensian tabelon konsistantan el 3 kolumnoj kaj 4 vicoj en unu kolumnon, la formulo estas:
=TOCOL(A2:C5)
La formulo estas enigita nur en unu ĉelo (E2 en ĉi tiu ekzemplo) kaj verŝas en la subajn ĉelojn aŭtomate. Koncerne Excel, la rezulto nomiĝas verŝintervalo. 
Kiel ĉi tiu formulo funkcias:
Teknike, la gamo A2:C5 unue estas konvertita en dudimensian tabelon. Bonvolu rimarki la punktokomo-disigitajn vicojn kaj komo-limigitajn kolumnojn:
{"Apple","Banana","Cherry";1,0,3;4,#N/A,6;7,8,9}
La TOKOL-funkcio skanas la tabelon de maldekstre dekstren kaj transformas ĝin en unudimensian vertikalan tabelon:
{"Apple";"Banana";"Cherry";1;0;3;4;#N/A;6;7;8;9}
La rezulto estas metita en ĉelon E2, el kiu ĝi disverŝas en la subajn ĉelojn.
Kiel uzi TOCOL-funkcion en Excel - formulokzemploj
Por akiri pli da kompreno pri laeblecoj de la funkcio TOCOL kaj kiajn taskojn ĝi povas kovri, ni rigardu kelkajn formulekzemplojn.
Transformu tabelon al kolumno ignorante malplenajn kaj erarojn
Kiel vi eble rimarkis en la antaŭa ekzemplo , la defaŭlta TOCOL-formulo konservas ĉiujn valorojn de la fonta tabelo, inkluzive de malplenaj ĉeloj kaj eraroj.
En la rezulta tabelo, malplenaj ĉeloj estas reprezentitaj per nuloj, kiuj povas esti sufiĉe konfuzaj, precipe se la origina tabelo havas 0 valoroj. La solvo estas salti malplenajn . Por tio, vi starigas la duan argumenton al 1:
=TOCOL(A2:C5, 1)
Por ignori erarojn , agordu la duan argumenton al 2:
=TOCOL(A2:C5, 2)
Por ekskludi ambaŭ, blankojn kaj erarojn , uzu 3 por la argumento ignori :
=TOCOL(A2:C5, 3) 
Skanu tabelon horizontale aŭ vertikale
Kun la defaŭlta argumento scan_by_column (FALSA aŭ ellasita), la funkcio TOCOL skanas la tabelon horizontale laŭ vico. Por prilabori valorojn laŭ kolumno, agordu ĉi tiun argumenton al VERA aŭ 1. Ekzemple:
=TOCOL(A2:C5, ,TRUE)
Rimarku, ke, en ambaŭ kazoj, la revenitaj tabeloj estas samgrandaj, sed la valoroj estas aranĝitaj. en malsama ordo. 
Kombinu plurajn gamojn en unu kolumnon
Se vi traktas plurajn ne-nuntajn intervalojn, tiam vi povas unue kombini la gamojn vertikale en ununuran tabelon helpe de la funkcio VSTACK, kaj poste uzu TOKOL por transformi la kombinitan tabelon en kolumnon.
Supozante, ke la unua gamo estas A2:C4 kaj la dua gamo estas A8:C9, la formulo prenas ĉi tiun formon:
=TOCOL(VSTACK(A2:C4, A8:C9))
Ĉi tiu formulo montras la defaŭltan konduton - legas la kombinitajn tabelojn horizontale de maldekstre. dekstren kiel montrite en kolumno E en la suba bildo.
Por legi valorojn vertikale de supre malsupre, vi agordas la 3-an argumenton de TOKOL al VERA:
=TOCOL(VSTACK(A2:C4, A8:C9), ,TRUE)
Bonvolu atenti, ke, en ĉi tiu kazo, la formulo unue resendas valorojn de kolumno A de ambaŭ tabeloj, poste de kolumno B, ktp. La kialo estas, ke TOCOL skanas ununuran stakitan tabelon, ne la originajn individuajn intervalojn. 
Se via komerca logiko postulas stakigi la originalajn intervalojn horizontale prefere ol vertikale, tiam uzu la funkcion HSTACK anstataŭ VSTACK.
Por almeti ĉiun postan tabelon dekstre de la antaŭa tabelo kaj legu la kombinitaj tabeloj horizontale, la formulo estas:
=TOCOL(HSTACK(A2:C4, A8:C10))
Por aldoni ĉiun postan tabelon dekstre de la antaŭa tabelo kaj skani la kombinitajn tabelojn vertikale, la formulo estas:
=TOCOL(HSTACK(A2:C4, A8:C10), ,TRUE) 
Eltiri unikajn valorojn el plurkolumna gamo
La Excel UNIKA funkcio povas facile trovi unikaĵojn en ununura kolumno aŭ vico kaj ankaŭ redoni unikajn vicojn, sed ĝi ne povas ĉerpi unikajn valorojn el plurkolumna tabelo. La solvo estas uzi ĝin kune kun la funkcio TOCOL.
Ekzemple, ĉerpi ĉiujn malsamajn (distingajn) valorojn el la intervalo.A2:C7, la formulo estas:
=UNIQUE(TOCOL(A2:C7))
Aldone, vi povas envolvi la supran formulon en la funkcio SORT por aranĝi la redonitan tabelon en alfabeta ordo:
=SORT(UNIQUE(TOCOL(A2:C7))) 
Kiel konverti gamon al kolumno en Excel 365 - 2010
En Excel-versioj kie la funkcio TOCOL ne estas subtenata, ekzistas kelkaj alternativaj manieroj transformi gamon da ĉeloj en kolumnon. Ĉi tiuj solvoj estas sufiĉe malfacilaj, sed ĉiukaze funkcias.
Por legi la gamon laŭ vico:
INDEX( gamo , KVOCIENTO(VICO(A1)-1, KOLUMNOS( ) intervalo ))+1, MOD(VICO(A1)-1, KOLUMNOS( gamo ))+1)Por legi la intervalon laŭ kolumno:
INDEX ( intervalo , MOD(VICO(A1)-1, VICOJ( intervalo ))+1, KVOCIENTO(VICO(A1)-1, VICJO( intervalo ))+1 )Por nia ekzempla datumaro, la formuloj estas jenaj:
Por skani la intervalon horizontale de maldekstre dekstren :
=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)
Ĉi tiu formulo estas ekvivalenta al la funkcio TOCOL kun la 3-a argumento agordita al FALSO aŭ ellasita:
=TOCOL(A2:C5)
Por skani la intervalon vertike de supre ĝis malsupre :
=INDEX($A$2:$C$5, MOD(ROW(A1)-1, ROWS($A$2:$C$5))+1, QUOTIENT(ROW(A1)-1, ROWS($A$2:$C$5))+1)
Tiu ĉi formulo estas komparebla al la funkcio TOCOL kun la 3-a argumento agordita al VERA:
=TOCOL(A2:C5, ,TRUE)
Malsame al TOCOL, la alternativaj formuloj estu enmetitaj en ĉiu. ĉelo kie vi volas ke la rezultoj aperu. En nia kazo, la formuloj iras al ĉeloj E2 (laŭ vico) kaj G2 (laŭ kolumno), kaj poste estas kopiitaj malsupren al la vico 13.
Se la formuloj estas kopiitaj al pli da vicoj ol bezonate, a#REF! eraro aperos en "ekstraj" ĉeloj. Por eviti ke tio okazu, vi povas nesti la formulojn en la funkcio IFERROR tiel:
=IFERROR(INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1), "")
Rimarku, ke por ke la formuloj kopiu ĝuste, ni ŝlosas la intervalon uzante absolutajn ĉelreferencojn ($ A$2:$C$5). Anstataŭe, vi povas uzi nomitan gamon. 
Kiel funkcias ĉi tiuj formuloj
Malsupre estas detala malkonstruo de la unua formulo, kiu ordigas ĉelojn laŭ vico:
=INDEX($A$2:$C$5, QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1, MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1)
La ideo estas uzi la funkcion INDEX por redoni la valoron de certa ĉelo surbaze de ĝiaj relativaj vicoj kaj kolumnombroj en la intervalo.
La vicnumero estas kalkulita per ĉi tiu kombinaĵo. :
QUOTIENT(ROW(A1)-1, COLUMNS($A$2:$C$5))+1
QUOCIENT liveras la entjeran parton de divido.
Por numero , vi uzas ROW(A1)-1, kiu liveras seria numero de 0 en E2 (unua ĉelo kie la formulo eniris) ĝis 11 en E13 (la lasta ĉelo kie la formulo eniris). $2:$C$5)) estas konstanta kaj egalas al la nombro da kolumnoj en via intervalo (3 en nia kazo).
Nun, se vi kontrolas la rezulton de la KVOCIENTO por la unuaj 3 ĉeloj (E2:E4) , vi vidos, ke ĝi estas egala al 0 (ĉar la entjera parto de la divido estas nulo). Aldonante 1 oni donas la vicon numeron 1.
Por la sekvaj 3 ĉeloj (E5:E5), KVOCIENTO donas 1, kaj la +1 operacio liveras la vicon numeron 2. Kaj tiel plu.
Alivorte, ĉi tiu parto de la formulo kreas ripetonnombra sinsekvo kiel 1,1,1,2,2,2,3,3,3,4,4,4,... Ĉiu nombro ripetas tiom da fojoj kiom estas kolumnoj en via intervalo.
Al kalkulu la kolumnan numeron , vi konstruas taŭgan nombrosekvencon uzante la MOD-funkcion:
MOD(ROW(A1)-1, COLUMNS($A$2:$C$5))+1
Ĉar estas 3 kolumnoj en nia gamo (A2:C5), la sinsekvo devas esti 1,2,3,1,2,3,...
La MOD-funkcio liveras la reston post divido.
En E2, MOD(VICO(A1)-1, KOlumnoj. ($A$2:$C$5))+1)
iĝas
MOD(1-1, 3)+1)
kaj redonas 1.
En E3, MOD(VICO(A2)-1, KOLUMNOS($A$2:$C$5))+1)
iĝas
MOD(2-1, 3) +1)
kaj liveras 2.
Kun la vicoj kaj kolumnumeroj establitaj, INDEX ne havas problemojn por preni la postulatan valoron.
En E2, INDEX($A$2 :$C$5, 1, 1) resendas la valoron de la 1-a vico kaj la 1-a kolumno de la referenca intervalo, t.e. de ĉelo A2.
En E3, INDEX($A$2:$C$5, 1). , 2) redonas la valoron de la 1-a vico kaj la 2-a kolumno, t.e. de la ĉelo B2.
Kaj tiel plu.
La dua formulo, kiu skanas la intervalon per c. olumn, funkcias en simila maniero. La diferenco estas, ke ĝi uzas MOD por akiri la vican numeron kaj KVOCIENTO por ricevi la kolumnumeron.
TOCOL-funkcio ne funkcias
Se la TOCOL-funkcio ĵetas eraron, ĝi estas plej verŝajne. esti unu el ĉi tiuj kialoj:
TOCOL ne estas subtenata en via Excel
Kiam vi ricevas #NOMO? eraro, la ĝusta literumo de la nomo de la funkcio estas la unua aferokontroli. Se la nomo estas ĝusta sed la eraro daŭras, la funkcio ne disponeblas en via versio de Excel. En ĉi tiu kazo, konsideru uzi TOCOL-alternativon.
Tabelo estas tro granda
#NUM-eraro indikas ke la tabelo ne povas konveni en kolumnon. Tipa kazo estas kiam vi rilatas al tutaj kolumnoj aŭ vicoj.
Ne estas sufiĉe da malplenaj ĉeloj
Kiam #SPILL-eraro okazas, kontrolu, ke la kolumno kie la formulo estas enigita havas sufiĉe da malplenaj ĉeloj por esti plenigitaj kun la rezultoj. Se la ĉeloj estas videble malplenaj, certigu, ke ne estas spacoj kaj aliaj ne-presantaj signoj en ili. Por pliaj informoj, vidu Kiel ripari la #SPILL-eraron en Excel.
Tiel vi povas uzi la funkcion TOCOL en Excel 365 kaj alternativajn solvojn en pli fruaj versioj por transformi 2-dimensian tabelon en ununuran kolumnon. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!
Praktiki laborlibron
Excel TOCOL-funkcio - formulekzemploj (.xlsx-dosiero)
