Artikuluak Excel-en gehienezko balioa lortzeko modu desberdin batzuk erakusten ditu zuk zehazten dituzun baldintza batean edo batzuetan oinarrituta.

Gure aurreko tutorialean, erabilera arruntak aztertu ditugu. Datu multzo bateko kopuru handiena itzultzeko diseinatuta dagoen MAX funtzioarena. Zenbait egoeratan, ordea, baliteke zure datuak gehiago sakondu behar izatea irizpide batzuen arabera gehienezko balioa aurkitzeko. Hau formula ezberdin batzuk erabiliz egin daiteke, eta artikulu honek modu posible guztiak azaltzen ditu.

Excel MAX IF formula

Duela gutxi arte, Microsoft Excel-ek ez zuen MAX IF funtzio integratua baldintzen araberako balio maximoa lortzeko. MAXIFS Excel 2019-n sartzearekin batera, baldintza maximoak modu erraz batean egin ditzakegu.

Excel 2016 eta aurreko bertsioetan, oraindik zure array formula sortu behar duzu MAX konbinatuz. funtzioa IF adierazpenarekin:

MAX generiko hau nola Formula datu errealetan funtzionatzen badu, kontuan hartu hurrengo adibidea. Demagun, hainbat ikasleren luzera jauziaren emaitzak dituen taula bat duzula. Taulak hiru txandetako datuak biltzen ditu, eta kirolari jakin baten emaitza onena bilatzen ari zarela esan du Jacobek. Ikasleen izenak A2:A10-n eta distantziak C2:C10-n, formulak forma hau hartzen du:

=MAX(IF(A2:A10="Jacob", C2:C10))

Kontuan izan array formula bat dela.beti sartu behar da Ctrl + Shift + Sartu teklak aldi berean sakatuz. Ondorioz, beheko pantaila-argazkian erakusten den moduko kortxete kizkurrez inguratzen da automatikoki (giltza eskuz idazteak ez du funtzionatuko!).

Bizitza errealeko lan-orrietan, komenigarriagoa da irizpidea sartzea batzuetan. gelaxka, egoera erraz alda dezakezu formula aldatu gabe. Beraz, nahi dugun izena idatziko dugu F1-en eta emaitza hau lortzen dugu:

=MAX(IF(A2:A10=F1, C2:C10))

Nola funtzionatzen duen formula

Logikoan IF funtzioaren proba, izenen zerrenda (A2:A10) xede-izenarekin (F1) konparatzen dugu. Eragiketa honen emaitza EGIA eta GEZURRA array bat da, non TRUE balioek xede-izenarekin (Jacob) bat datozen izenak adierazten dituztenak:

{FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;FALSE;FALSE}

value_ if_true argumentua, luzera jauziaren emaitzak ematen ditugu (C2:C10), beraz, proba logikoa EGIA dela ebaluatzen bada, C zutabetik dagokion zenbakia itzultzen da. value_ if_false argumentua alde batera utzi da, hau da, FALSE balio bat izango du baldintza betetzen ez den lekuan:

{FALSE;FALSE;FALSE;5.48;5.42;5.57;FALSE;FALSE;FALSE}

Matrize hau MAX funtzioari ematen zaio. Gezurrezko balioak alde batera utzita gehienezko kopurua itzultzen du.

Aholkua. Goian aztertutako barne-matrizeak ikusteko, hautatu zure lan-orrian formulari dagokion zatia eta sakatu F9 tekla. Formula ebaluatzeko modutik irteteko, sakatu Esc tekla.

MAX IF formula anitz batekinirizpideak

Baldintza batean baino gehiagotan oinarritutako gehienezko balioa aurkitu behar duzun egoeran, hauxe egin dezakezu:

Erabili IF adierazpen habiaratuak irizpide gehigarriak sartzeko:

Edo kudeatu hainbat irizpide biderketa eragiketa erabiliz:

Demagun nesken eta mutilen emaitzak taula bakar batean dituzula eta 3. txandan nesken artean jauzirik luzeena aurkitu nahi duzula. Hori egin dadin. , lehenengo irizpidea (emakumezkoa) G1-en sartuko dugu, bigarren irizpidea (3) G2-n, eta formula hauek erabiliko ditugu gehienezko balioa lantzeko:

=MAX(IF(B2:B16=G1, IF(C2:C16=G2, D2:D16)))

=MAX(IF((B2:B16=G1)*(C2:C16=G2), D2:D16))

Biak matrize formulak direnez, gogoratu Ctrl + Shift + Sartu sakatu behar dituzula ondo osatzeko.

Beheko pantaila-argazkian agertzen den moduan, formulek emaitza bera sortzen dute, beraz, zein bat erabili zure kontua zure lehentasun pertsonala. Niretzat, logika boolearra duen formula errazagoa da irakurtzeko eta eraikitzeko; nahi adina baldintza gehitzeko aukera ematen du IF funtzio gehigarriak habiaratu gabe.

Nola funtzionatzen duten formula hauek.

Lehenengo formulak IF funtzio habiaratu bi erabiltzen ditu bi irizpide ebaluatzeko. Lehenengo IF adierazpenaren proba logikoan, Genero zutabeko balioak konparatzen ditugu(B2:B16) G1 ("Emakumezkoa") irizpidearekin. Emaitza TRUE eta FALSE balioen matrize bat da, non TRUE irizpidearekin bat datozen datuak adierazten dituena:

{FALSE; FALSE; FALSE; TRUE; TRUE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; TRUE; TRUE; TRUE}

Antzeko modu batean, bigarren IF funtzioak Biribildutako zutabeko balioak egiaztatzen ditu (C2 :C16) G2-ko irizpidearen aurka.

Bigarren IF adierazpeneko value_if_true argumenturako, luzera jauziaren emaitzak ematen ditugu (D2:D16), eta horrela elementuak lortzen ditugu. dagozkien posizioetan EGIA duten lehenengo bi matrizeetan (hau da, generoa "emakumezkoa" eta biribila 3 den elementuak):

{FALSE; FALSE; FALSE; FALSE; FALSE; 4.63; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; 4.52}

Azken matrize hau MAX funtziora doa eta zenbaki handiena itzultzen du.

Bigarren formulak baldintza berdinak ebaluatzen ditu proba logiko bakar baten barruan eta biderketa-eragiketak AND eragilearen antzera funtzionatzen du:

Egia eta GEZUR balioak edozeinetan erabiltzen direnean. eragiketa aritmetikoa, 1 eta 0 bihurtzen dira, hurrenez hurren. Eta 0z biderkatzeak beti zero ematen duelako, ondoriozko arrayak 1 du baldintza guztiak EGIA direnean soilik. Array hau IF funtzioaren proba logikoan ebaluatzen da, 1 (EGIA) elementuei dagozkien distantziak itzultzen dituena.

MAX IF matrizerik gabe

Excel-eko erabiltzaile asko, ni barne, dira. array formulen aurkako aurreiritziak eta saiatu kentzen ahal den guztietan. Zorionez, Microsoft Excel-ek array modu naturalean kudeatzen duten funtzio batzuk ditu, eta bat erabil dezakegufuntzio horien, hots, SUMPRODUCT, MAX inguruko "bilgarri" moduko gisa.

Matrizerik gabeko MAX IF formula generikoa hau da:

Jakina, barruti/irizpide bikote gehiago gehi ditzakezu baldin eta behar da.

Formula martxan ikusteko, aurreko adibideko datuak erabiliko ditugu. Helburua 3. txandan emakumezko kirolari baten jauzia maximoa lortzea da:

=SUMPRODUCT(MAX(((B2:B16=G1) * (C2:C16=G2) * (D2:D16))))

Formula hau Sartu tekla sakatu normal batekin lehiatzen da eta array MAX IF formularen emaitza bera ematen du:

Goiko pantaila-argazkiari begirada zehatzago bat emanez, aurreko adibideetan "x"-rekin markatutako jauzi baliogabeak 0 balio dutela ohar zaitezke orain 3, 11 eta 15 errenkadetan. , eta hurrengo atalean zergatik azaltzen da.

Formula honek nola funtzionatzen duen

MAX IF formularekin gertatzen den bezala, bi irizpide ebaluatzen ditugu Genero (B2:B16) eta Biribilduko (B2:B16) balio bakoitza alderatuz ( C2:C16) G1 eta G2 gelaxketako irizpideak dituzten zutabeak. Emaitza TRUE eta FALSE balioen bi matrize dira. Matrizeen elementuak posizio beretan biderkatzeak EGIA eta GEZURRA 1 eta 0 bihurtzen ditu, hurrenez hurren, non 1ak bi irizpideak betetzen dituzten elementuak adierazten dituen. Hirugarren matrize biderkatuak luzera jauziaren emaitzak ditu (D2:D16). Eta 0z biderkatzeak zero ematen duelako, dagozkien posizioetan 1 (EGIA) duten elementuak soilikbizirauteko:

{0; 0; 0; 0; 0; 4.63; 0; 0; 0; 0; 0; 0; 0; 0; 4.52}

max_range testu-balioren bat badu kasuetan, biderketa-eragiketak #VALUE errorea itzultzen du, formula osoak ez baitu funtzionatuko.

MAX funtzioak hemendik hartzen du eta zehaztutako baldintzak betetzen dituen zenbakirik handiena itzultzen du. {4.63} elementu bakar batez osatutako matrizea SUMPRODUCT funtziora doa eta gehienezko zenbakia ateratzen du gelaxka batean.

Oharra. Bere logika espezifikoa dela eta, formulak ohar hauekin funtzionatzen du:

• Balio handiena bilatzen duzun barrutiak zenbakiak soilik izan behar ditu. Testu-baliorik badago, #BALIOA! errorea itzultzen da.
• Formulak ezin du "zeroaren berdina" baldintza ebaluatu datu multzo negatibo batean. Zeroak alde batera utzita balio maximoa aurkitzeko, erabili MAX IF formula edo MAXIFS funtzioa.

Excel MAX IF formula EDO logikarekin

Maximo balioa aurkitzeko edozein betetzen da, erabili dagoeneko ezaguna den array MAX IF formula logika boolearrarekin, baina gehitu baldintzak biderkatu beharrean.

Bestela, matrizea ez den hurrengo formula erabil dezakezu :

Adibide gisa, lan egin dezagunemaitzarik onena 2. eta 3. txandetan. Kontuan izan Excel hizkuntzan, zeregina modu ezberdinean formulatuta dagoela: itzuli gehienezko balioa biribila 2 edo 3 bada.

B2:B10 zerrendatutako txandekin. , emaitzak C2:C10 eta F1 eta H1 irizpideak, formula honela doa:

=MAX(IF((B2:B10=F1) + (B2:B10=H1), C2:C10))

Sartu formula Ctrl + Shift + Sartu tekla konbinazioa sakatuz eta lortuko duzu emaitza hau:

Baldintza berdinak dituen gehienezko balioa ere aurki daiteke matrizea ez den formula hau erabiliz:

=SUMPRODUCT(MAX(((B2:B10=F1) + (B2:B10=H1)) * C2:C10))

Hala ere, C zutabeko "x" balio guztiak zeroekin ordezkatu behar ditugu kasu honetan SUMPRODUCT MAX zenbakizko datuekin soilik funtzionatzen duelako:

Nola funtzionatzen duten formula hauek

Matrizearen formulak MAX IF-ren modu berean funtzionatzen du ETA logikarekin, irizpideak batzen dituzula biderketaren ordez batuketa eragiketa erabiliz izan ezik. Array-formuletan, batuketak OR eragile gisa funtzionatzen du:

EGIA eta GEZURRA (B2:B10-ko balioak F1 eta H1-ko irizpideen arabera egiaztatzearen ondoriozko bi matrize gehitzeak) 1-eko matrize bat sortzen du eta 0 da non 1 baldintzaren bat EGIA den elementuak adierazten dituen eta 0 bi baldintzak GEZURRA duten elementuak adierazten dituena. Ondorioz, IF funtzioak edozein baldintza TRUE den C2:C10 ( value_if_true ) elementu guztiak "mantentzen" ditu; gainerako elementuak FALSE-rekin ordezkatzen dira value_if_false argumentua ez da zehaztu.

Matrizea ez den formulak antzera funtzionatzen du. Ezberdintasuna da IF-ren proba logikoaren ordez, 1 eta 0-en arrayko elementuak biderkatzen dituzula luzera jauziaren emaitzen arrayko elementuekin (C2:C10) dagozkien posizioetan. Honek inongo baldintza betetzen ez duten elementuak baliogabetzen ditu (lehen matrizean 0 dute) eta baldintzaren bat betetzen duten elementuak mantentzen dira (lehen matrizean 1 dute).

MAXIFS – altuena aurkitzeko modu erraza. Baldintzekin balioa

Excel 2019, 2021 eta Excel 365-en erabiltzaileek matrizeak domatzeko arazorik ez dute beren MAX IF formula propioa eraikitzeko. Excel-en bertsio hauek denbora luzean itxaroten den MAXIFS funtzioa eskaintzen dute, balio handiena aurkitzea haurrentzako baldintzekin.

MAXIFS-en lehen argumentuan, gehienezko balioa aurkitu behar den barrutia sartzen duzu (D2: D16 gure kasuan), eta ondorengo argumentuetan 126 barruti/irizpide bikote sar ditzakezu. Adibidez:

=MAXIFS(D2:D16, B2:B16, G1, C2:C16, G2)

Beheko pantaila-argazkian erakusten den moduan, formula sinple honek ez du arazorik zenbakizko eta testu-balioak dituen barrutia prozesatzeko:

Funtzio honi buruzko informazio zehatza lortzeko, ikus Excel MAXIFS funtzioa formula adibideekin.

Horrela aurki dezakezu gehienezko balioa Excel-en baldintzekin. Eskerrik asko irakurtzeagatik eta hurrengoan gure blogean ikustea espero dutastea!

Landu lan-koadernoa deskargatzeko

Excel MAX IF formula adibideak (.xlsx fitxategia)