Der heutige Blogbeitrag zeigt alle Möglichkeiten, 2 Google Sheets zusammenzuführen. Sie werden VLOOKUP, INDEX/MATCH, QUERY und das Add-on Merge Sheets verwenden, um Zellen in einem Blatt mit Datensätzen aus einem anderen zu aktualisieren, basierend auf Übereinstimmungen in gemeinsamen Spalten.

Zusammenführen von Google-Blättern mit der VLOOKUP-Funktion

Wenn Sie zwei Google-Tabellen abgleichen und zusammenführen möchten, können Sie sich zunächst an die VLOOKUP-Funktion wenden.

Syntax & Verwendung

Diese Funktion durchsucht eine von Ihnen angegebene Spalte nach einem bestimmten Schlüsselwert und zieht einen der Bezugsdatensätze aus derselben Zeile in eine andere Tabelle oder ein Blatt.

Obwohl Google Sheets VLOOKUP in der Regel als eine der schwierigsten Funktionen angesehen wird, ist sie eigentlich ganz einfach und sogar leicht, wenn man sie erst einmal kennengelernt hat.

Werfen wir einen kurzen Blick auf seine Bestandteile:

• such_schlüssel ist der gesuchte Schlüsselwert, der eine beliebige Zeichenkette, eine Zahl oder ein Zellbezug sein kann.
• Bereich ist die Gruppe von Zellen (oder eine Tabelle), in der Sie nach dem such_schlüssel und woher Sie die Bezugsdatensätze beziehen werden.

  Hinweis: VLOOKUP in Google Sheets durchsucht immer die erste Spalte der Bereich für die such_schlüssel .

• Index ist die Nummer der Spalte innerhalb dieser Bereich woher Sie die Daten beziehen wollen.

  Wenn Ihr Suchbereich z. B. A2:E20 ist und Sie die Daten aus Spalte E benötigen, geben Sie 5 ein, aber wenn Ihr Bereich D2:E20 ist, müssen Sie 2 eingeben, um Datensätze aus Spalte E zu erhalten.

• [is_sortiert] ist das einzige Argument, das Sie weglassen können. Es wird verwendet, um anzugeben, ob die Spalte mit den Schlüsselwerten sortiert ist (TRUE) oder nicht (FALSE). Wenn TRUE, arbeitet die Funktion mit der nächstliegenden Übereinstimmung, wenn FALSE - mit einer vollständigen. Wenn es weggelassen wird, wird standardmäßig TRUE verwendet.

Tipp: Wir haben einen ausführlichen Leitfaden zu VLOOKUP in Google Sheets. Darin erfahren Sie mehr über die Funktion, ihre Besonderheiten & Grenzen und erhalten weitere Formelbeispiele.

Mit diesen Argumenten im Hinterkopf wollen wir VLOOKUP verwenden, um zwei Google-Blätter zusammenzuführen.

Nehmen wir an, ich habe eine kleine Tabelle mit Beeren und ihren IDs in Sheet2. Die Verfügbarkeit der Bestände ist jedoch unbekannt:

Nennen wir diese Tabelle die Haupttabelle, denn mein Ziel ist es, sie auszufüllen.

Es gibt noch eine weitere Tabelle in Sheet1 mit allen Daten, einschließlich der Verfügbarkeit des Bestands:

Ich nenne es die Nachschlagetabelle, da ich die Daten aus ihr abrufen werde.

Ich werde die Funktion VLOOKUP von Google Sheets verwenden, um diese beiden Blätter zusammenzuführen. Die Funktion wird die Beeren in beiden Tabellen abgleichen und die entsprechenden "Bestandsinformationen" aus der Nachschlagetabelle in die Haupttabelle ziehen.

=VLOOKUP(B2,Blatt1!$B$2:$C$10,2,FALSE)

Mit dieser Formel werden zwei Google-Blätter exakt zusammengeführt:

1. Es wird nach dem Wert aus B2 (Hauptblatt) in Spalte B auf Blatt1 (Referenzblatt) gesucht.

   Hinweis: Denken Sie daran, dass VLOOKUP die 1. Spalte des angegebenen Bereichs durchsucht. Blatt1!$B$2:$C$10 .

   Hinweis: Ich verwende absolute Verweise für den Bereich, weil ich die Formel die Spalte hinunter kopiere und dieser Bereich daher in jeder Zeile gleich bleiben muss, damit das Ergebnis nicht bricht.

2. FALSE am Ende bedeutet, dass die Daten in Spalte B (im Nachschlagewerk) nicht sortiert sind und nur exakte Übereinstimmungen berücksichtigt werden.
3. Sobald es eine Übereinstimmung gibt, zieht Google Sheets VLOOKUP den Bezugsdatensatz aus der zweiten Spalte dieses Bereichs (Spalte C).

Von VLOOKUP in Google Sheets zurückgegebene Fehler ausblenden - IFERROR

Aber was ist mit diesen #N/A-Fehlern?

Man sieht sie in den Zeilen, in denen Beeren keine Übereinstimmungen in einem anderen Blatt haben und es nichts zurückzugeben gibt. Zum Glück gibt es eine Möglichkeit, solche Zellen stattdessen leer zu halten.

Wickeln Sie Ihr Google Sheets VLOOKUP einfach in IFERROR ein:

=IFERROR(VLOOKUP(B2,Blatt1!$B$2:$C$10,2,FALSE),"")

Tipp: Fangen und beheben Sie andere Fehler, die Ihr Google Sheets VLOOKUP zurückgeben kann, mit den Lösungen aus diesem Leitfaden.

Match & Datensätze für die gesamte Spalte auf einmal aktualisieren - ArrayFormula

Eine weitere Sache, die ich erwähnen möchte, ist, wie man Google Sheets-Daten für die gesamte Spalte auf einmal abgleichen und zusammenführen kann.

Nichts Ausgefallenes hier, nur eine weitere Funktion - ArrayFormula.

Ersetzen Sie einfach Ihren einzelligen Schlüsseldatensatz in Google Sheets VLOOKUP durch die gesamte Spalte und setzen Sie diese gesamte Formel in ArrayFormula ein:

=ArrayFormula(IFERROR(VLOOKUP(B2:B10,Sheet1!$B$2:$C$10,2,FALSE),""))

Auf diese Weise brauchen Sie die Formel nicht in die Spalte zu kopieren, sondern ArrayFormula liefert sofort das richtige Ergebnis für jede Zelle.

Obwohl VLOOKUP in Google Sheets perfekt für solche einfachen Aufgaben geeignet ist, hat es einige Grenzen. Hier ist einer der Nachteile: Es kann nicht auf die linke Seite schauen. Egal, welchen Bereich Sie angeben, es durchsucht immer die erste Spalte.

Wenn Sie also 2 Google Sheets zusammenführen und IDs (Daten der 1. Spalte) auf der Grundlage von Beeren (2. Spalte) abrufen müssen, hilft Ihnen VLOOKUP nicht weiter. Sie werden einfach nicht in der Lage sein, eine korrekte Formel zu erstellen.

In solchen Fällen kommt INDEX MATCH für Google Sheets ins Spiel.

Abgleichen & Zusammenführen von Google Sheets mit INDEX MATCH duo

INDEX MATCH, oder vielmehr INDEX & MATCH, sind eigentlich zwei verschiedene Google Sheets Funktionen, aber wenn sie zusammen verwendet werden, ist es wie ein VLOOKUP der nächsten Stufe.

Ja, sie führen auch Google Sheets zusammen: Sie aktualisieren Zellen in einer Tabelle mit Datensätzen aus einer anderen Tabelle auf der Grundlage gemeinsamer Schlüsseldaten.

Aber sie machen das viel besser, da sie all die Einschränkungen von VLOOKUP ignorieren.

Ich werde heute nicht alle Grundlagen behandeln, da ich das bereits in diesem Blog-Beitrag getan habe. Aber ich werde Ihnen ein paar Beispiele für INDEX MATCH-Formeln geben, damit Sie sehen können, wie sie direkt in Google-Tabellen funktionieren. Ich werde dieselben Beispieltabellen von oben verwenden.

INDEX MATCH in Aktion in Google Sheets

Lassen Sie uns zunächst diese Google-Sheets zusammenführen und die Bestandsverfügbarkeit für alle passenden Beeren aktualisieren:

=INDEX(Blatt1!$C$1:$C$10,MATCH(B2,Blatt1!$B$1:$B$10,0))

Wie funktionieren INDEX & MATCH, wenn sie so zusammen verwendet werden?

1. MATCH sucht in B2 nach genau demselben Datensatz in Spalte B auf Blatt1 und gibt dann die Nummer der Zeile zurück, die diesen Wert enthält - in meinem Fall 10.
2. INDEX bezieht sich ebenfalls auf diese 10. Zeile auf Blatt 1, nur wird der Wert aus einer anderen Spalte - C - übernommen.

Jetzt wollen wir INDEX MATCH mit dem testen, was Google Sheets VLOOKUP nicht kann - Blätter zusammenführen und die Spalte ganz links mit den erforderlichen IDs aktualisieren:

=INDEX(Blatt1!$A$2:$A$10,MATCH(B2,Blatt1!$B$2:$B$10,0))

Kinderleicht :)

Behandlung von Fehlern, die von INDEX MATCH in Google Sheets zurückgegeben werden

Gehen wir noch einen Schritt weiter und beseitigen wir die Fehler in Zellen ohne Übereinstimmungen. Auch hier hilft IFERROR. Geben Sie einfach Ihr Google Sheets INDEX MATCH als erstes Argument an.

Beispiel 1.

=IFERROR(INDEX(Blatt1!$C$1:$C$10,MATCH(B2,Blatt1!$B$1:$B$10,0)),"")

Beispiel 2.

=IFERROR(INDEX(Blatt1!$A$2:$A$10,MATCH(B2,Blatt1!$B$2:$B$10,0)),"")

Wie kann man nun diese Google Sheets mit INDEX MATCH zusammenführen und alle Zellen in der gesamten Spalte auf einmal aktualisieren?

Es gibt da ein kleines Problem: ArrayFormula funktioniert nicht mit diesen beiden.

Sie müssen die INDEX MATCH Formel in die Spalte kopieren oder alternativ die Google Sheets QUERY Funktion verwenden.

Google Sheets zusammenführen & Zellen mit QUERY aktualisieren

Google Sheets QUERY ist die mächtigste Funktion in Tabellenkalkulationen, und so ist es nicht verwunderlich, dass sie eine Möglichkeit bietet, Tabellen zusammenzuführen - Match & Werte aus verschiedenen Tabellen zusammenführen.

Tipp: Wenn Sie noch nie mit Google Sheets QUERY gearbeitet haben, können Sie sich in diesem Lernprogramm mit der besonderen Sprache vertraut machen.

Wie sollte die QUERY-Formel aussehen, um die Lagerbestand Spalte mit den aktuellen Daten?

=QUERY(Sheet1!$A$2:$C$10, "select C where&Sheet4!$B2:$B$10&""")

• Google Sheets QUERY schaut auf mein Lookup Sheet (Sheet1 mit den Datensätzen, die ich in meine Haupttabelle ziehen muss)
• und gibt alle Zellen aus Spalte C zurück, bei denen Spalte B mit Beeren in meiner Haupttabelle übereinstimmt

Lassen Sie mich diese Fehler für Zellen ohne Übereinstimmungen einfach löschen:

=IFERROR(QUERY(Sheet1!$A$2:$C$10, "select C where&Sheet4!$B2:$B$10&"""),"")

Na, das ist schon besser :)

Zusammenführen von Tabellen aus verschiedenen Google-Arbeitsblättern - Funktion IMPORTRANGE

Es gibt noch eine weitere Funktion, die ich erwähnen möchte: Sie ist wichtig, weil Sie damit Blätter zusammenführen können, die sich in verschiedenen Google-Arbeitsblättern (Dateien) befinden.

Die Funktion heißt IMPORTRANGE:

• Ersteres ist der Link zu der Tabelle, aus der Sie die Daten beziehen
• Letzteres ist das Blatt & der Bereich, den Sie aus diesem Arbeitsblatt nehmen wollen

Hinweis: Ich empfehle dringend, die Google-Dokumente zu dieser Funktion durchzusehen, damit Sie keine wichtige Nuance ihrer Arbeit verpassen.

Stellen Sie sich vor, Ihr Nachschlagewerk (mit den Referenzdaten) befindet sich in Tabellenblatt 2 (auch Nachschlagewerk genannt), Ihr Hauptblatt in Tabellenblatt 1 (Haupttabellenblatt).

Hinweis: Damit IMPORTRANGE funktioniert, müssen Sie beide Dateien miteinander verbinden. Und obwohl Google Sheet eine Schaltfläche dafür vorschlägt, nachdem Sie Ihre Formel in eine Zelle eingegeben und auf Eingabe Für die nachstehenden Formeln müssen Sie das eventuell vorher tun. Diese Schritt-für-Schritt-Anleitung wird Ihnen dabei helfen.

Im Folgenden finden Sie Beispiele für das Zusammenführen von Google Sheets aus verschiedenen Dateien mit IMPORTRANGE und den einzelnen Funktionen, die Sie heute gelernt haben.

Beispiel 1: IMPORTRANGE + VLOOKUP

Verwenden Sie IMPORTRAGE als Bereich in VLOOKUP, um 2 separate Google-Tabellenblätter zusammenzuführen:

=ArrayFormula(IFERROR(VLOOKUP(B2:B10,IMPORTRANGE("//docs.google.com/spreadsheets/d/1Sq...j7o/edit", "Sheet1!$B$2:$C$10"),2,FALSE),""))

Beispiel 2: IMPORTRANGE + INDEX MATCH

Bei INDEX MATCH & IMPORTRANGE wird die Formel umfangreicher, da Sie zweimal auf ein anderes Arbeitsblatt verweisen müssen: als Bereich für INDEX und als Bereich für MATCH:

=IFERROR(INDEX(IMPORTRANGE("//docs.google.com/spreadsheets/d/1Sq...j7o/edit", "Sheet1!$A$1:$A$10"),MATCH(B2,IMPORTRANGE("//docs.google.com/spreadsheets/d/1Sq...j7o/edit", "Sheet1!$B$2:$B$10"),0)),"")

Beispiel 3: IMPORTRANGE + QUERY

Dieses Formeltandem ist mein persönlicher Favorit. Wenn sie zusammen verwendet werden, können sie fast alles in Tabellenkalkulationen bewältigen. Das Zusammenführen von Google-Blättern aus separaten Tabellenkalkulationen ist keine Ausnahme.

=IFERROR(QUERY(IMPORTRANGE("//docs.google.com/spreadsheets/d/1Sq...j7o/edit", "Sheet1!$A$2:$C$10"), "select Col3 where&QUERY!$B2:$B$10&"""),"")

Uff!

Das ist alles für Funktionen & Formeln.

Sie können eine beliebige Funktion wählen & erstellen Sie Ihre eigene Formel anhand der obigen Beispiele...

oder...

...versuchen Sie ein spezielles Tool, das Google Sheets für Sie zusammenführt ;)

Formel-freier Weg zum Abgleichen & Zusammenführen von Daten - Merge Sheets Add-on für Google Sheets

Wenn Sie keine Zeit haben, Formeln zu erstellen oder gar zu lernen, oder wenn Sie einfach nur nach der einfachsten Möglichkeit suchen, Daten auf der Grundlage gemeinsamer Datensätze zu verknüpfen, ist Merge Sheets die perfekte Lösung.

Alles, was Sie tun müssen, ist, die Kästchen in 5 benutzerfreundlichen Schritten anzukreuzen:

1. Wählen Sie Ihr Hauptblatt
2. wählen Sie Ihr Lookup-Sheet
3. Schlüsselspalten (die Datensätze enthalten, die abgeglichen werden sollen) mit Kontrollkästchen markieren
4. wählen Sie die zu aktualisierenden Spalten aus:

Es besteht sogar die Möglichkeit, alle ausgewählten Optionen in einem Szenario zu speichern und es bei Bedarf wiederzuverwenden:

Sehen Sie sich dieses 3-minütige Demo-Video an, um zu erfahren, wie es funktioniert:

Ich empfehle Ihnen, Ihre Merge Sheets aus dem Google Sheets Store zu installieren und diese Anweisungen zu befolgen, um zu versuchen, Ihre eigene Tabelle mit den Informationen aus einem anderen Blatt zu aktualisieren.

Tabellenkalkulation mit Formelbeispielen

Google Sheets zusammenführen & Daten aktualisieren - Formelbeispiele (Kopie der Datei erstellen)