Ef þú ert að leita að Excel aðgerð til að fá vikudag frá dagsetningu, hefurðu lent á réttri síðu. Þessi kennsla mun kenna þér hvernig á að nota WEEKDAY formúluna í Excel til að breyta dagsetningu í nafn virka daga, sía, auðkenna og telja helgar eða virka daga og fleira.

Það eru margvíslegar aðgerðir til að vinna með dagsetningar í Excel. Vikudagsaðgerðin (WEEKDAY) er sérstaklega gagnleg við áætlanagerð og tímasetningu, til dæmis til að ákvarða tímaramma verkefnis og fjarlægja helgar sjálfkrafa úr heildarupphæðinni. Svo skulum við renna í gegnum dæmin í einu og sjá hvernig þau geta hjálpað þér að takast á við ýmis dagatengd verkefni í Excel.

VIKADAGUR - Excel aðgerð fyrir daginn vika

Excel WEEKDAY aðgerðin er notuð til að skila vikudegi frá tiltekinni dagsetningu.

Niðurstaðan er heil tala, sjálfgefið á bilinu 1 (sunnudagur) til 7 (laugardagur) . Ef viðskiptarökfræði þín krefst annarrar upptalningar geturðu stillt formúluna þannig að hún byrjar að telja með hverjum öðrum vikudegi.

VIRKUDAGUR aðgerðin er fáanleg í öllum útgáfum Excel 365 til 2000.

Setningafræði WEEKDAY fallsins er sem hér segir:

WEEKDAY(raðnúmer, [return_type])

Hvar:

Raðnúmer (áskilið) - dagsetningin sem þú vilt umreikna í virkadagsnúmerið. Það er hægt að fá það sem raðnúmer sem táknar dagsetninguna, sem textastreng á formisem Excel skilur, sem tilvísun í reitinn sem inniheldur dagsetninguna, eða með því að nota DATE fallið.

Return_type (valfrjálst) - ákvarðar hvaða vikudag á að nota sem fyrsta dag . Ef því er sleppt er sjálfgefið Sun-Sat viku.

Hér er listi yfir öll studd return_type gildi:

Return_type	Tölu skilað
1 eða sleppt	Frá 1 (sunnudag) til 7 (laugardag)
2	Frá 1 (mánudagur) til 7 (sunnudagur)
3	Frá 0 (mánudagur) til 6 (sunnudagur)
11	Frá 1 (mánudagur) til 7 (sunnudagur)
12	Frá 1 (þriðjudagur) til 7 (mánudagur)
13	Frá 1 (miðvikudagur) til 7 (þriðjudagur)
14	Frá 1 (fimmtudagur) til 7 (miðvikudagur)
15	Frá 1 (föstudagur) til 7 (fimmtudagur)
16	Frá 1 (laugardag) til 7 (föstudagur)
17	Frá 1 (sunnudagur) til 7 (laugardagur)

Athugið. return_type gildin 11 til 17 voru kynnt í Excel 2010 og því ekki hægt að nota þau í fyrri útgáfum.

Grunnformúla WEEKDAY í Excel

Til að byrja með skulum við sjá hvernig að nota WEEKDAY formúluna í sinni einföldustu mynd til að fá dagnúmerið frá dagsetningu.

Til dæmis, til að fá virkan dag frá dagsetningu í C4 með sjálfgefna sunnudags - laugardagsviku, er formúlan:

=WEEKDAY(C4)

Ef þú ert með raðnúmersem táknar dagsetninguna (t.d. með DATEVALUE fallinu), þú getur slegið þá tölu beint inn í formúluna:

=WEEKDAY(45658)

Einnig er hægt að slá inn dagsetninguna sem textastreng innan gæsalappa beint í formúlunni. Vertu bara viss um að nota dagsetningarsniðið sem Excel býst við og getur túlkað:

=WEEKDAY("1/1/2025")

Eða gefðu upp upprunadagsetninguna á 100% áreiðanlegan hátt með því að nota DATE aðgerðina:

=WEEKDAY(DATE(2025, 1,1))

Til að nota dagkortunina aðra en sjálfgefna sun-lau, sláðu inn viðeigandi tölu í seinni frumbreytuna. Til dæmis, til að byrja að telja daga frá mánudegi, er formúlan:

=WEEKDAY(C4, 2)

Á myndinni hér að neðan skila allar formúlurnar vikudegi sem samsvarar 1. janúar 2025, sem er geymt sem númer 45658 innbyrðis í Excel. Það fer eftir gildinu sem er stillt í seinni röksemdinni gefa formúlurnar mismunandi niðurstöður.

Við fyrstu sýn kann að virðast að tölurnar sem WEEKDAY fallið skilar hafi mjög lítið hagnýtt vit. En við skulum líta á það frá öðru sjónarhorni og ræða nokkrar formúlur sem leysa raunveruleikaverkefni.

Hvernig á að umbreyta Excel dagsetningu í nafn virkadags

Að hönnun Excel WEEKDAY fallið skilar vikudegi sem tölu. Notaðu TEXT-aðgerðina til að breyta vikudagsnúmerinu í dagheitið.

Til að fá heilsdagsnöfn skaltu nota "dddd" sniðkóðann:

TEXT(WEEKDAY( dagsetning ), "dddd")

Til að skila skammstafaðdagnöfn , sniðkóði er "ddd":

TEXT(VIKUDAGUR( dagsetning ), "ddd")

Til dæmis til að umbreyta dagsetningunni í A3 í nafn virkadags , formúlan er:

=TEXT(WEEKDAY(A3), "dddd")

Eða

=TEXT(WEEKDAY(A3), "ddd")

Önnur möguleg lausn er að nota WEEKDAY ásamt CHOOSE aðgerðinni.

Til dæmis, til að fá skammstafað virkadagsnafn frá dagsetningu í A3, er formúlan svona:

=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")

Hér skilar WEEKDAY raðnúmeri frá 1 (sun) til 7 (lau. ) og CHOOSE velur samsvarandi gildi af listanum. Þar sem dagsetningin í A3 (miðvikudagur) samsvarar 4, gefur VELJA út "Wed", sem er 4. gildið á listanum.

Þó að CHOOSE formúlan sé örlítið erfiðari að stilla, þá veitir hún meiri sveigjanleika sem gerir þér kleift að birta dagnöfnin á hvaða sniði sem þú vilt. Í dæminu hér að ofan sýnum við styttu dagnöfnin. Þess í stað geturðu sent full nöfn, sérsniðnar skammstafanir eða jafnvel dagnöfn á öðru tungumáli.

Ábending. Önnur auðveld leið til að breyta dagsetningu í nafn virka daga er með því að nota sérsniðið dagsetningarsnið. Til dæmis mun kóðasniðið „dddd, mmmm d, yyyy“ sýna dagsetninguna „ Föstudagur, 3. janúar 2025 “ á meðan „dddd“ sýnir bara „ Föstudagur “ .

Excel WEEKDAY formúla til að finna og sía virka daga og helgar

Þegar þú átt við langan lista af dagsetningum gætirðu viljað vita hverjir eru virkir dagar og hverjar eru helgar.

Til að greina helgar og virka daga í Excel skaltu búa til IF yfirlýsingu með hreiðri WEEKDAY fallinu. Til dæmis:

=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")

Þessi formúla fer í reit A3 og er afrituð niður í eins margar hólf og þarf.

Í WEEKDAY formúlunni stillirðu return_type til 2, sem samsvarar mán-sun vikunni þar sem mánudagur er dagur 1. Þannig að ef númer virka daga er minna en 6 (mánudagur til föstudags), skilar formúlan "Virkudagur", annars - "Helgi".

Til að sía helgar eða virka daga skaltu nota Excel síu á gagnasafnið þitt ( Gögn flipinn > Sía ) og velja annað hvort "Helgi" eða "Vinnudagur".

Í skjámyndinni hér að neðan erum við með virka daga síaða út, þannig að aðeins helgar eru sýnilegar:

Ef einhver svæðisskrifstofa fyrirtækis þíns vinnur á annarri áætlun þar sem hvíldardagar eru aðrir en laugardagur og sunnudagur, getur þú auðveldlega stillt WEEKDAY formúluna að þínum þörfum með því að tilgreina aðra afkomugerð .

Til dæmis til að meðhöndla laugardag og Mánudagur sem helgar, stilltu return_type á 12, svo þú færð "þriðjudagur (1) til mánudags (7)" vikutegundina:

=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")

Hvernig á að auðkenna helgar virka daga og í Excel

Til að koma auga á helgar og virka daga á vinnublaðinu þínu í fljótu bragði geturðu fengið þá sjálfkrafa skyggða í mismunandi litum. Til þess, notaðu vikudags/helgarformúluna sem fjallað var um í fyrra dæmi meðExcel skilyrt snið. Eins og skilyrðið er gefið í skyn, þurfum við aðeins kjarna WEEKDAY aðgerðina án IF-umbúðirnar.

Til að merkja helgar (laugardag og sunnudag):

=WEEKDAY($A2, 2)<6

Til að amerkja vinnudaga (mánudagur - föstudagur):

=WEEKDAY($A2, 2)>5

Þar sem A2 er efri vinstra hólfið á valnu sviði.

Til settu upp skilyrt sniðsregluna, skrefin eru:

1. Veldu lista yfir dagsetningar (A2:A15 í okkar tilfelli).
2. Á flipanum Heima , í hópnum Stílar , smelltu á Skilyrt snið > Ný regla .
3. Í glugganum Ný sniðregla veldu Notaðu formúlu til að ákvarða hvaða frumur á að forsníða .
4. Í Sniðgildi þar sem þessi formúla er satt skaltu slá inn ofangreinda formúlu fyrir helgar eða virka daga.
5. Smelltu á hnappinn Format og veldu sniðið sem þú vilt.
6. Smelltu á OK tvisvar til að vista breytingarnar og loka glugganum.

Fyrir nákvæmar upplýsingar um hvert skref, vinsamlegast sjá Hvernig á að setja upp skilyrt snið með formúlu.

Útkoman lítur nokkuð vel út, er það ekki?

Hvernig á að telja virka daga og helgar í Excel

Til að fá fjölda virka daga eða helgar á lista yfir dagsetningar er hægt að nota WEEKDAY aðgerðina ásamt SUM. Til dæmis:

Til að telja helgar er formúlan í D3:

=SUM(--(WEEKDAY(A3:A20, 2)>5))

Til að telja virka daga ,formúlan í D4 er á þessa leið:

=SUM(--(WEEKDAY(A3:A20, 2)<6))

Í Excel 365 og Excel 2021 sem meðhöndla fylki innbyggt, virkar þetta sem venjuleg formúla eins og sýnt er á skjámyndinni hér að neðan. Í Excel 2019 og eldri, ýttu á Ctrl + Shift + Enter til að gera það að fylkisformúlu.

Hvernig þessar formúlur virka:

WEEKDAY fallið með return_type stillt á 2 skilar dagnúmeri frá 1 (mán) til 7 (sun) ) fyrir hverja dagsetningu á bilinu A3:A20. Rökfræðilega segðin athugar hvort tölurnar sem skilað er séu hærri en 5 (fyrir helgar) eða færri en 6 (fyrir virka daga). Niðurstaða þessarar aðgerðar er fylki af SÖNNUM og FALSKum gildum.

Tvöfalda neitunin (--) þvingar rökrænu gildin í 1 og 0. Og SUM aðgerðin bætir þeim saman. Í ljósi þess að 1 (TRUE) táknar dagana sem á að telja og 0 (FALSE) dagana sem á að hunsa, færðu þá niðurstöðu sem þú vilt.

Ábending. Til að reikna virka daga á milli tveggja dagsetninga , notaðu NETWORKDAYS eða NETWORKDAYS.INTL fallið.

Ef virkur dagur þá, ef laugardagur eða sunnudagur þá

Að lokum skulum við ræða aðeins meira sérstakt tilvik sem sýnir hvernig á að ákvarða vikudaginn, og ef það er laugardagur eða sunnudagur, gerðu þá eitthvað, ef virkur dagur þá gerðu eitthvað annað.

IF(WEEKDAY( cell , 2)> 5, ef_helgi_þá , ef_vikudagur_þá )

Segjum að þú sért að reikna út greiðslur fyrir starfsmenn sem hafa unnið aukavinnu á frídögum sínum, svo þú þarftað beita mismunandi greiðslutöxtum fyrir virka daga og helgar. Þetta er hægt að gera með því að nota eftirfarandi IF setningu:

• Í logical_test röksemdinni skaltu hreiðra WEEKDAY fallið sem athugar hvort tiltekinn dagur sé vinnudagur eða helgi.
• Í gildi_ef_satt röksemdinni skal margfalda fjölda vinnustunda með helgarhlutfalli (G4).
• Í gildi_ef_ósatt röksemdinni skal margfalda fjölda vinnustunda miðað við vinnudagstaxta (G3).

Heildarformúlan í D3 er á þessu formi:

=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)

Til að formúlan afriti rétt í hólf hér að neðan, vertu viss um að læsa gengisföngunum með $ tákninu (eins og $G$4).

WEEKDAY aðgerð virkar ekki

Almennt eru tvær algengar villur sem WEEKDAY formúla gæti skilað:

#VALUE! villa kemur upp ef annaðhvort:

• Raðnúmer eða skilategund er ekki tölulegt.
• Raðnúmer er utan stutt dagsetningarbil (1900 til 9999).

#NUM! villa kemur upp þegar return_type er utan leyfilegs bils (1-3 eða 11-17).

Svona á að nota WEEKDAY aðgerðina í Excel til að vinna með vikudaga. Í næstu grein munum við kanna Excel aðgerðir til að starfa á stærri tímaeiningum eins og vikum, mánuðum og árum. Endilega fylgist með og takk fyrir að lesa!

Æfingabók til niðurhals

VIKUDAGS uppskrift í Excel - dæmi (.xlsxskrá)