ඔබ දින සිට සතියේ දින ලබා ගැනීමට Excel ශ්‍රිතයක් සොයන්නේ නම්, ඔබ නිවැරදි පිටුවට පැමිණ ඇත. මෙම නිබන්ධනය ඔබට Excel හි WEEKDAY සූත්‍රය භාවිතා කරමින් දිනයක් සතියේ දින නමක් බවට පරිවර්තනය කිරීම, පෙරීම, උද්දීපනය කිරීම සහ සති අන්ත හෝ වැඩ දින ගණන් කිරීම සහ තවත් බොහෝ දේ උගන්වනු ඇත.

විවිධ කාර්යයන් ඇත. Excel හි දිනයන් සමඟ වැඩ කරන්න. සතියේ දිනය (WEEKDAY) සැලසුම් කිරීම සහ කාලසටහන්ගත කිරීම සඳහා විශේෂයෙන් ප්‍රයෝජනවත් වේ, උදාහරණයක් ලෙස ව්‍යාපෘතියක කාලරාමුව තීරණය කිරීමට සහ මුළු සංඛ්‍යාවෙන් සති අන්ත ස්වයංක්‍රීයව ඉවත් කිරීමට. එබැවින්, අපි එක් වරකට උදාහරණ හරහා ගොස් Excel හි විවිධ දිනයට අදාළ කාර්යයන් සමඟ සාර්ථකව කටයුතු කිරීමට ඔබට උපකාර කරන්නේ කෙසේදැයි බලමු.

WEEKDAY - දින සඳහා Excel ශ්‍රිතය සතියේ

Excel WEEKDAY ශ්‍රිතය ලබා දී ඇති දිනයක සිට සතියේ දිනය ආපසු ලබා දීමට භාවිතා කරයි.

ප්‍රතිඵලය පෙරනිමියෙන් 1 (ඉරිදා) සිට 7 (සෙනසුරාදා) දක්වා වූ පූර්ණ සංඛ්‍යාවකි. . ඔබේ ව්‍යාපාර තර්කයට වෙනස් ගණන් කිරීමක් අවශ්‍ය නම්, ඔබට සතියේ වෙනත් ඕනෑම දිනයක් සමඟ ගණන් කිරීම ආරම්භ කිරීමට සූත්‍රය වින්‍යාසගත කළ හැක.

WEEKDAY ශ්‍රිතය Excel 365 සිට 2000 දක්වා සියලුම අනුවාද වල ඇත.

WEEKDAY ශ්‍රිතයේ වාක්‍ය ඛණ්ඩය පහත පරිදි වේ:

WEEKDAY(serial_number, [return_type])

කොහේද:

Serial_number (අවශ්‍ය) - ඔබට පරිවර්තනය කිරීමට අවශ්‍ය දිනය සතියේ දින අංකයට. එය ආකෘතියේ පෙළ තන්තුවක් ලෙස, දිනය නියෝජනය කරන අනුක්‍රමික අංකයක් ලෙස සැපයිය හැක.දිනය අඩංගු කොටුව වෙත යොමු කිරීමක් ලෙස හෝ DATE ශ්‍රිතය භාවිතයෙන් Excel තේරුම් ගනී.

Return_type (විකල්ප) - පළමු දිනය ලෙස භාවිතා කළ යුතු සතියේ කුමන දිනය තීරණය කරයි . ඉවත් කර ඇත්නම්, හිරු-සෙනසුරා සතියට පෙරනිමි වේ.

මෙන්න සියලු සහාය දක්වන return_type අගයන් ලැයිස්තුවක්:

18>1 (බ්‍රහස්පතින්දා) සිට 7 (බදාදා) දක්වා

Return_type	අංකය ආපසු
1 හෝ මඟ හැර ඇත	1 (ඉරිදා) සිට 7 (සෙනසුරාදා)
2	1 (සඳුදා) සිට 7 (ඉරිදා) දක්වා
3	0 (සඳුදා) සිට 6 දක්වා (ඉරිදා)
11	1 (සඳුදා) සිට 7 (ඉරිදා) දක්වා
12	1 (අඟහරුවාදා) සිට 7 (සඳුදා)
13	1 (බදාදා) සිට 7 (අඟහරුවාදා) දක්වා
14
15	1 (සිකුරාදා) සිට 7 දක්වා (බ්‍රහස්පතින්දා)
16	1 (සෙනසුරාදා) සිට 7 (සිකුරාදා) දක්වා
17	1 (ඉරිදා) සිට 7 (සෙනසුරාදා)

සටහන. return_type අගයන් 11 සිට 17 දක්වා Excel 2010 දී හඳුන්වා දී ඇති අතර එම නිසා ඒවා පෙර අනුවාද වල භාවිතා කළ නොහැක.

Excel හි මූලික WEEKDAY සූත්‍රය

ආරම්භකයින් සඳහා, අපි බලමු කොහොමද කියලා. දින සිට දින අංකය ලබා ගැනීමට WEEKDAY සූත්‍රය එහි සරලම ආකාරයෙන් භාවිතා කිරීමට.

උදාහරණයක් ලෙස, C4 හි පෙරනිමි ඉරිදා - සෙනසුරාදා සතිය සමඟ සතියේ දිනය ලබා ගැනීමට, සූත්‍රය වන්නේ:

=WEEKDAY(C4)

ඔබට අනුක්‍රමික අංකයක් තිබේ නම්දිනය නියෝජනය කරමින් (උදා: DATEVALUE ශ්‍රිතය මගින් ගෙන එන), ඔබට එම අංකය සෘජුවම සූත්‍රය තුළ ඇතුළත් කළ හැක:

=WEEKDAY(45658)

තවද, ඔබට උද්ධෘත ලකුණුවල අමුණා ඇති පෙළ පෙළක් ලෙස දිනය ටයිප් කළ හැක කෙලින්ම සූත්‍රයේ. Excel අපේක්ෂා කරන දින ආකෘතිය භාවිතා කිරීමට වග බලා ගන්න සහ අර්ථ දැක්විය හැක:

=WEEKDAY("1/1/2025")

නැතහොත්, DATE ශ්‍රිතය භාවිතයෙන් මූලාශ්‍ර දිනය 100% විශ්වාසදායක ආකාරයෙන් සපයන්න:

=WEEKDAY(DATE(2025, 1,1))

පෙරනිමි සන්-සැට් හැර වෙනත් දින සිතියම්කරණය භාවිතා කිරීමට, දෙවන තර්කයේ සුදුසු අංකයක් ඇතුළත් කරන්න. උදාහරණයක් ලෙස, සඳුදා සිට දින ගණන් කිරීම ආරම්භ කිරීමට, සූත්‍රය වන්නේ:

=WEEKDAY(C4, 2)

පහත රූපයේ, සියලුම සූත්‍ර 2025 ජනවාරි 1 ට අනුරූප සතියේ දිනය ලබා දෙයි, එනම් Excel හි අභ්‍යන්තරව 45658 අංකය ලෙස ගබඩා කර ඇත. දෙවන තර්කයේ ඇති අගය මත පදනම්ව, සූත්‍ර විවිධ ප්‍රතිඵල ප්‍රතිදානය කරයි.

මුලින්ම බැලූ බැල්මට, WEEKDAY ශ්‍රිතය මඟින් ආපසු ලබා දෙන සංඛ්‍යා ඉතා අඩු ප්‍රායෝගික හැඟීමක් ඇති බව පෙනේ. නමුත් අපි එය වෙනස් කෝණයකින් බලමු සහ සැබෑ ජීවිතයේ කාර්යයන් විසඳන සූත්‍ර කිහිපයක් සාකච්ඡා කරමු.

Excel දිනය සතියේ දින නමට පරිවර්තනය කරන්නේ කෙසේද

සැලසුම අනුව, Excel WEEKDAY ශ්‍රිතය සතියේ දිනය අංකයක් ලෙස ලබා දෙයි. සතියේ දින අංකය දින නම බවට පත් කිරීමට, TEXT ශ්‍රිතය භාවිතා කරන්න.

සම්පූර්ණ දින නම් ලබා ගැනීමට, "dddd" ආකෘති කේතය භාවිතා කරන්න:

TEXT(WEEKDAY( දිනය ), "dddd")

ආපසු යාමට කෙටියෙන්දින නම් , ආකෘති කේතය "ddd":

TEXT(WEEKDAY( දිනය ), "ddd")

උදාහරණයක් ලෙස, A3 හි දිනය සතියේ දින නමට පරිවර්තනය කිරීමට , සූත්‍රය වන්නේ:

=TEXT(WEEKDAY(A3), "dddd")

හෝ

=TEXT(WEEKDAY(A3), "ddd")

තවත් විය හැකි විසඳුමක් වන්නේ CHOOSE ශ්‍රිතය සමඟ WEEKDAY භාවිතා කිරීමයි.

උදාහරණයක් ලෙස, A3 හි දින සිට කෙටි සතියේ දින නමක් ලබා ගැනීම සඳහා, සූත්‍රය පහත පරිදි වේ:

=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")

මෙන්න, WEEKDAY 1 (ඉරු) සිට 7 (සෙනසුරාදා) දක්වා අනුක්‍රමික අංකයක් ලබා දෙයි. ) සහ CHOOSE ලැයිස්තුවෙන් අනුරූප අගය තෝරා ගනී. A3 හි දිනය (බදාදා) 4 ට අනුරූප වන බැවින්, ලැයිස්තුවේ 4 වන අගය වන "බදාදා" ප්‍රතිදානය තෝරන්න.

CHOOSE සූත්‍රය වින්‍යාස කිරීමට තරමක් අපහසු වුවද, ඔබට අවශ්‍ය ඕනෑම ආකෘතියකින් දින නම් ප්‍රතිදානය කිරීමට එය ඔබට වඩාත් නම්‍යශීලී බවක් ලබා දෙයි. ඉහත උදාහරණයේ දී, අපි සංක්ෂිප්ත දින නම් පෙන්වමු. ඒ වෙනුවට, ඔබට වෙනත් භාෂාවකින් සම්පූර්ණ නම්, අභිරුචි කෙටි යෙදුම් හෝ දින නම් පවා ලබා දිය හැක.

ඉඟිය. දිනයක් සතියේ දින නමට පරිවර්තනය කිරීමට තවත් පහසු ක්‍රමයක් නම් අභිරුචි දින ආකෘතියක් යෙදීමයි. උදාහරණයක් ලෙස, "dddd, mmmm d, yyyy" කේත ආකෘතියේ " සිකුරාදා, 2025 ජනවාරි 3 " ලෙස දින දර්ශනය වන අතර "dddd" " සිකුරාදා " පමණක් පෙන්වයි. .

වැඩදින සහ සති අන්ත සොයා ගැනීමට සහ පෙරීමට Excel WEEKDAY සූත්‍රය

දිගු දින ලැයිස්තුවක් සමඟ කටයුතු කරන විට, ඔබට වැඩ කරන දින මොනවාද සහ සති අන්ත මොනවාද යන්න දැන ගැනීමට අවශ්‍ය විය හැක.

Excel හි සති අන්ත සහ සතියේ දින හඳුනා ගැනීමට, කැදලි WEEKDAY ශ්‍රිතය සමඟ IF ප්‍රකාශයක් ගොඩනඟන්න. උදාහරණයක් ලෙස:

=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")

මෙම සූත්‍රය A3 කොටුවට යන අතර අවශ්‍ය තරම් සෛල ප්‍රමාණයක් හරහා පිටපත් කරනු ලැබේ.

WEEKDAY සූත්‍රය තුළ, ඔබ return_type සකසා ඇත. සිට 2 දක්වා, එය සඳුදා දින 1 වන සඳු-ඉරු සතියට අනුරූප වේ. එබැවින්, සතියේ දින අංකය 6 (සඳුදා සිට සිකුරාදා දක්වා) ට වඩා අඩු නම්, සූත්‍රය "වැඩ දිනය" ආපසු ලබා දෙයි, එසේ නොමැති නම් - "සති අන්තය".

සති අන්ත හෝ වැඩ දින පෙරීමට , ඔබේ දත්ත කට්ටලයට Excel පෙරහන යොදන්න ( දත්ත ටැබය > පෙරහන්න ) සහ "සති අන්තය" හෝ තෝරන්න "වැඩ දිනය".

පහත තිර පිටුවේ, අපි සතියේ දින පෙරා ඇත, එබැවින් සති අන්ත පමණක් දෘශ්‍යමාන වේ:

ඔබේ සංවිධානයේ සමහර ප්‍රාදේශීය කාර්යාලයක් විවේක දිනයන් වෙනස් කාලසටහනකට අනුව ක්‍රියා කරයි නම් සෙනසුරාදා සහ ඉරිදා හැර, ඔබට වෙනස් ආපසු_වර්ගය සඳහන් කිරීම මඟින් WEEKDAY සූත්‍රය පහසුවෙන් ඔබේ අවශ්‍යතා අනුව සකස් කළ හැක.

උදාහරණයක් ලෙස, සෙනසුරාදා සහ <10 සැලකීමට>සඳුදා සති අන්ත ලෙස, ආපසු_වර්ගය සිට 12 දක්වා සකසන්න, එවිට ඔබට "අඟහරුවාදා (1) සිට සඳුදා (7)" සතියේ වර්ගය ලැබෙනු ඇත:

=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")

සති අන්තයේ වැඩ කරන දින සහ Excel තුළ උද්දීපනය කරන්නේ කෙසේද

ඔබේ වැඩ පත්‍රිකාවේ සති අන්ත සහ වැඩ දින එක බැල්මකින් හඳුනා ගැනීමට, ඔබට ඒවා ස්වයංක්‍රීයව විවිධ වර්ණවලින් සෙවන ලබා ගත හැක. මේ සඳහා, සමඟ පෙර උදාහරණයේ සාකච්ඡා කර ඇති සතියේ දින/සති අන්ත සූත්‍රය භාවිතා කරන්නExcel කොන්දේසි සහිත හැඩතල ගැන්වීම. කොන්දේසිය ඇඟවුම් කර ඇති පරිදි, අපට අවශ්‍ය වන්නේ IF එතුම නොමැතිව මූලික WEEKDAY ශ්‍රිතය පමණි.

සති අන්ත උද්දීපනය කිරීමට (සෙනසුරාදා සහ ඉරිදා):

=WEEKDAY($A2, 2)<6

වැඩදින ඉස්මතු කිරීමට (සඳුදා - සිකුරාදා):

=WEEKDAY($A2, 2)>5

A2 යනු තෝරාගත් පරාසයේ ඉහළ වම් කොටුව වේ.

වෙත කොන්දේසිගත හැඩතල ගැන්වීමේ රීතිය සකසන්න, පියවර වනුයේ:

1. දින ලැයිස්තුව තෝරන්න (අපගේ නඩුවේ A2:A15).
2. මුල් ටැබය මත , Styles සමූහයේ, කොන්දේසි සහිත හැඩතල ගැන්වීම > නව රීතිය ක්ලික් කරන්න.
3. නව හැඩතල ගැන්වීමේ රීතිය සංවාදයේ කොටුව, තෝරන්න ආකෘතිකරණය කළ යුතු සෛල තීරණය කිරීමට සූත්‍රයක් භාවිතා කරන්න .
4. මෙම සූත්‍රය සත්‍ය කොටුවෙහි ආකෘති අගයන් තුළ, සති අන්ත සඳහා ඉහත සඳහන් සූත්‍රය ඇතුළු කරන්න. හෝ සතියේ දිනවල.
5. Format බොත්තම ක්ලික් කර අවශ්‍ය ආකෘතිය තෝරන්න.
6. වෙනස්කම් සුරැකීමට සහ සංවාද කවුළු වැසීමට OK දෙවරක් ක්ලික් කරන්න.

එක් එක් පියවර පිළිබඳ සවිස්තරාත්මක තොරතුරු සඳහා, කරුණාකර පිහිටුවන ආකාරය බලන්න සූත්‍රය සමඟ කොන්දේසි සහිත හැඩතල ගැන්වීම.

ප්‍රතිඵලය ඉතා ලස්සනයි වගේ නේද?

Excel හි සතියේ දින සහ සති අන්ත ගණන් කරන්නේ කෙසේද

දින ලැයිස්තුවේ සතියේ දින හෝ සති අන්ත ගණන ලබා ගැනීමට, ඔබට SUM සමඟ ඒකාබද්ධව WEEKDAY ශ්‍රිතය භාවිතා කළ හැක. උදාහරණයක් ලෙස:

සති අන්ත ගණන් කිරීමට , D3 හි සූත්‍රය වන්නේ:

=SUM(--(WEEKDAY(A3:A20, 2)>5))

සතියේ දින ගණන් කිරීමට ,D4 හි සූත්‍රය මෙම පෝරමය ගනී:

=SUM(--(WEEKDAY(A3:A20, 2)<6))

Excel 365 සහ Excel 2021 වලදී අරා ස්වදේශිකව හසුරුවයි, මෙය පහත තිර පිටුවේ පෙන්වා ඇති පරිදි සාමාන්‍ය සූත්‍රයක් ලෙස ක්‍රියා කරයි. Excel 2019 සහ ඊට පෙර, එය අරා සූත්‍රයක් කිරීමට Ctrl + Shift + Enter ඔබන්න.

මෙම සූත්‍ර ක්‍රියා කරන ආකාරය:

return_type 2 ලෙස සකසා ඇති WEEKDAY ශ්‍රිතය 1 (සදු) සිට 7 (ඉරු) දක්වා දින අංකයක් ලබා දෙයි ) A3:A20 පරාසයේ එක් එක් දිනය සඳහා. තාර්කික ප්‍රකාශනය ආපසු ලබා දුන් සංඛ්‍යා 5 ට වඩා වැඩි (සති අන්ත සඳහා) හෝ 6 ට වඩා අඩු (සතියේ දින සඳහා) පරීක්ෂා කරයි. මෙම මෙහෙයුමේ ප්‍රතිඵලය සත්‍ය සහ අසත්‍ය අගයන් අරාවකි.

ද්විත්ව නිෂේධනය (--) තාර්කික අගයන් 1 සහ 0 වෙත බල කරයි. SUM ශ්‍රිතය ඒවා එකතු කරයි. 1 (සත්‍ය) ගණන් කළ යුතු දින සහ 0 (අසත්‍ය) නොසලකා හැරිය යුතු දින නියෝජනය කරන බැවින්, ඔබට අපේක්ෂිත ප්‍රතිඵලය ලැබේ.

ඉඟිය. දින දෙකක් අතර සතියේ දින ගණනය කිරීමට, NETWORKDAYS හෝ NETWORKDAYS.INTL ශ්‍රිතය භාවිතා කරන්න.

සතියේ දින නම්, සෙනසුරාදා හෝ ඉරිදා නම්

අවසාන වශයෙන්, අපි තව ටිකක් සාකච්ඡා කරමු. සතියේ දිනය තීරණය කරන ආකාරය පෙන්වන විශේෂිත අවස්ථාව, සහ එය සෙනසුරාදා හෝ ඉරිදා නම් යමක් කරන්න, සතියේ දිනයක් නම් වෙනත් දෙයක් කරන්න.

IF(WEEKDAY( cell , 2)> 5, if_weekend_then , if_weekday_then )

ඔබ ඔවුන්ගේ නිවාඩු දිනවල අමතර වැඩ කිහිපයක් කර ඇති සේවකයින් සඳහා ගෙවීම් ගණනය කරන්නේ යැයි සිතන්න, එබැවින් ඔබට අවශ්‍ය වේවැඩ කරන දින සහ සති අන්ත සඳහා විවිධ ගෙවීම් අනුපාත යෙදීමට. මෙය පහත IF ප්‍රකාශය භාවිතයෙන් කළ හැක:

• logical_test තර්කය තුළ, ලබා දී ඇති දිනයක් වැඩ කරන දිනයක්ද සති අන්තයක්ද යන්න පරීක්ෂා කරන WEEKDAY ශ්‍රිතය නෙස්ට් කරන්න.
28> value_if_true තර්කය තුළ, වැඩ කරන පැය ගණන සති අන්ත අනුපාතයෙන් (G4) ගුණ කරන්න.
• value_if_false තර්කයේ, වැඩ කරන පැය ගණන ගුණ කරන්න. වැඩ දින අනුපාතය (G3) අනුව.

D3 හි සම්පූර්ණ සූත්‍රය මෙම ස්වරූපය ගනී:

=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)

සූත්‍රය පහත කොටුවලට නිවැරදිව පිටපත් කිරීමට, අනුපාත සෛල ලිපින $ ලකුණ සමඟ අගුලු දැමීමට වග බලා ගන්න ($G$4 වැනි).

WEEKDAY ශ්‍රිතය ක්‍රියා නොකරයි

සාමාන්‍යයෙන්, WEEKDAY සූත්‍රයක් ලබා දිය හැකි පොදු දෝෂ දෙකක් ඇත:

#VALUE! දෝශයක් ඇති වන්නේ:

• Serial_number හෝ return_type සංඛ්‍යාත්මක නොවන නම්.
• Serial_number සහාය දක්වන දින පරාසය (1900 සිට 9999 දක්වා).

#NUM! return_type අවසර ලත් පරාසයෙන් බැහැර වූ විට (1-3 හෝ 11-17) දෝෂයක් ඇතිවේ.

සතියේ දින හැසිරවීමට Excel හි WEEKDAY ශ්‍රිතය භාවිතා කරන ආකාරය මෙයයි. මීළඟ ලිපියෙන්, අපි සති, මාස සහ අවුරුදු වැනි විශාල කාල ඒකකවල ක්‍රියා කිරීමට Excel කාර්යයන් ගවේෂණය කරන්නෙමු. කරුණාකර රැඳී සිටින්න සහ කියවීමට ස්තූතියි!

බාගැනීම සඳහා වැඩපොත පුහුණු වන්න

සතියේ දින සූත්‍රය Excel - උදාහරණ (.xlsxගොනුව)