Upami anjeun milari pungsi Excel kanggo nampi dinten minggu ti tanggal, anjeun parantos sumping dina halaman anu leres. Tutorial ieu bakal ngajarkeun anjeun cara ngagunakeun rumus WEEKDAY dina Excel pikeun ngarobah tanggal jadi ngaran poé minggu, nyaring, nyorot jeung ngitung sabtu minggu atawa poé gawé, jeung sajabana.

Aya rupa-rupa fungsi pikeun dianggo sareng kaping dina Excel. Poé fungsi minggu (WEEKDAY) hususna kapaké pikeun perencanaan sarta scheduling, contona pikeun nangtukeun timeframe hiji proyék tur otomatis ngahapus weekends tina total. Janten, hayu urang tingali conto hiji-hiji sareng tingali kumaha aranjeunna tiasa ngabantosan anjeun ngarengsekeun sababaraha pancén anu aya hubunganana sareng tanggal dina Excel.

WEEKDAY - Fungsi Excel kanggo dinten minggu

Fungsi Excel WEEKDAY dipaké pikeun mulangkeun poé dina saminggu ti tanggal nu tangtu.

Hasilna mangrupa integer, mimitian ti 1 (Minggu) nepi ka 7 (Saptu) sacara standar. . Upami logika bisnis anjeun peryogi enumerasi anu béda, anjeun tiasa ngonpigurasikeun rumus pikeun ngamimitian ngitung sareng dinten minggu anu sanés.

Pungsi WEEKDAY sayogi dina sadaya vérsi Excel 365 dugi ka 2000.

Sintaksis fungsi WEEKDAY nyaéta kieu:

Dimana:

Serial_number (diperlukeun) - tanggal nu Anjeun hoyong konvérsi kana nomer minggu. Ieu bisa disadiakeun salaku angka serial ngalambangkeun tanggal, salaku string téks dina format nunu Excel kaharti, salaku rujukan ka sél nu ngandung tanggal, atawa ku cara maké pungsi DATE.

Return_type (opsional) - nangtukeun poé naon dina saminggu pikeun dipaké salaku poé kahiji. . Upami dileungitkeun, standar ka Minggu-Saptu.

Ieu daptar sadaya nilai return_type anu dirojong:

Catetan. Nilai return_type 11 nepi ka 17 diwanohkeun dina Excel 2010 sahingga teu bisa dipaké dina vérsi saméméhna.

Rumus WEEKDAY Dasar dina Excel

Pikeun ngamimitian, hayu urang tingali kumaha ngagunakeun rumus WEEKDAY dina wangun pangbasajanna pikeun meunangkeun nomer poé ti tanggal.

Contona, pikeun meunangkeun poé minggu ti tanggal dina C4 kalawan standar Minggu - Sabtu minggu, rumusna nyaéta:

=WEEKDAY(C4)

Upami anjeun gaduh nomer séringagambarkeun tanggal (misalna dibawa ku pungsi DATEVALUE), anjeun bisa ngasupkeun nomer eta langsung dina rumus:

=WEEKDAY(45658)

Oge, Anjeun bisa ngetik tanggal salaku string téks diapit ku tanda petik. langsung dina rumus. Pastikeun anjeun nganggo format tanggal anu dipiharep sareng tiasa diinterpretasi ku Excel:

=WEEKDAY("1/1/2025")

Atawa, asupkeun tanggal sumber dina cara anu dipercaya 100% nganggo fungsi DATE:

=WEEKDAY(DATE(2025, 1,1))

Pikeun ngagunakeun pemetaan dinten salain ti standar Sun-Sab, lebetkeun nomer anu pas dina argumen kadua. Contona, pikeun ngamimitian ngitung poé ti Senén, rumusna nyaéta:

=WEEKDAY(C4, 2)

Dina gambar di handap ieu, sakabéh rumus ngabalikeun poé dina saminggu luyu jeung 1 Januari 2025, nyaéta. disimpen salaku angka 45658 internal dina Excel. Gumantung kana nilai diatur dina argumen kadua, rumus kaluaran hasil béda.

Saheulaanan, sigana mah angka nu dipulangkeun ku fungsi WEEKDAY boga rasa praktis pisan. Tapi hayu urang tingali tina sudut anu béda sareng bahas sababaraha rumus anu ngarengsekeun tugas-tugas kahirupan nyata.

Kumaha cara ngarobah tanggal Excel kana nami dinten minggu

Dumasar desain, fungsi Excel WEEKDAY mulih dinten minggu salaku angka. Pikeun ngarobah angka poe minggu jadi ngaran poe, pake fungsi TEXT.

Pikeun meunangkeun ngaran sapoe , pake kode format "dddd":

Pikeun mulang disinggetngaran poé , kode formatna nyaéta "ddd":

Contona, pikeun ngarobah tanggal dina A3 kana ngaran weekday , rumusna nyaéta:

=TEXT(WEEKDAY(A3), "dddd")

Atawa

=TEXT(WEEKDAY(A3), "ddd")

Solusi séjén anu mungkin nyaéta ngagunakeun WEEKDAY sareng fungsi CHOOSE.

Contona, pikeun meunangkeun ngaran poé minggu anu disingkat ti tanggal dina A3, rumusna kieu:

=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")

Di dieu, WEEKDAY mulihkeun nomer séri ti 1 (Minggu) nepi ka 7 (Sabtu. ) sareng PILIH milih nilai anu saluyu tina daptar. Kusabab tanggal dina A3 (Rebo) pakait jeung 4, PILIH kaluaran "Rebo", nu mangrupa nilai 4 dina daptar.

Sanajan rumus PILIH rada leuwih pajeujeut pikeun dikonpigurasikeun, éta nyadiakeun leuwih kalenturan sangkan anjeun kaluaran ngaran poé dina format naon waé nu dipikahoyong. Dina conto di luhur, urang nunjukkeun nami dinten anu disingkat. Gantina, anjeun tiasa ngirimkeun nami lengkep, singketan khusus atanapi bahkan nami dinten dina basa anu sanés.

Tip. Cara panggampangna sanésna pikeun ngarobih tanggal kana nami dinten minggu nyaéta ku nerapkeun format tanggal khusus. Contona, format kode "dddd, mmmm d, yyyy" bakal boga tanggal dipintonkeun salaku " Jumaah, 3 Januari 2025 " sedengkeun "dddd" bakal nembongkeun ngan " Jumaah " .

Rumus Excel WEEKDAY pikeun milarian sareng nyaring dinten kerja sareng sabtu minggu

Nalika ngadamel daptar tanggal anu panjang, anjeun panginten hoyong terang mana anu dinten damel sareng anu mana sabtu minggu.

Pikeun ngidentipikasi sabtu minggu sareng dinten minggu dina Excel, jieun pernyataan IF sareng fungsi WEEKDAY nested. Contona:

=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")

Rumus ieu asup ka sél A3 sarta disalin ka handap saloba sél nu diperlukeun.

Dina rumus WEEKDAY, anjeun nyetel return_type nepi ka 2, nu pakait jeung minggu Mon-Sun dimana Senén nyaéta poé 1. Ku kituna, lamun jumlah weekday kirang ti 6 (Senén ngaliwatan Jumaah), rumus mulih "Workday", disebutkeun - "Weekend".

Pikeun nyaring sabtu minggu atawa poé gawé , larapkeun saringan Excel kana set data anjeun ( Data tab > Filter ) terus pilih "Saptu minggu" atawa "Poé Gawé".

Dina screenshot di handap, urang geus disaring poé minggu, jadi ukur sabtu minggu nu katingali:

Upami sababaraha kantor régional organisasi anjeun damel dina jadwal anu béda dimana dinten istirahat. lian ti Saptu jeung Minggu, anjeun bisa kalayan gampang nyaluyukeun rumus WEEKDAY ka kabutuhan Anjeun ku nangtukeun hiji béda return_type .

Contona, pikeun ngubaran Sabtu jeung Senen salaku sabtu minggu, setel return_type ka 12, jadi Anjeun bakal meunang tipe minggu "Salasa (1) nepi ka Senén (7)":

=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")

Kumaha cara nyorot dinten kerja sabtu minggu sareng dina Excel

Pikeun ningali sabtu minggu sareng dinten kerja dina lembar kerja anjeun sakedapan, anjeun tiasa otomatis ngiuhan dina warna anu béda. Jang ngalampahkeun ieu, make rumus weekday / sabtu minggu dibahas dina conto saméméhna kalawanpormat kondisional Excel. Salaku kondisi tersirat, urang ngan butuh fungsi inti WEEKDAY tanpa wrapper IF.

Pikeun nyorot sabtu minggu (Saptu jeung Minggu):

=WEEKDAY($A2, 2)<6

Pikeun nyorot poé gawé (Senén - Jumaah):

=WEEKDAY($A2, 2)>5

Dimana A2 nyaéta sél kénca luhur rentang nu dipilih.

Pikeun Nyetél aturan pormat kondisional, léngkah-léngkahna nyaéta:

1. Pilih daptar tanggal (A2:A15 dina kasus urang).
2. Dina tab Home , dina grup Styles , klik Format kondisional > Aturan Anyar .
3. Dina dialog Aturan Format Anyar kotak, pilih Paké rumus pikeun nangtukeun sél mana nu rék diformat .
4. Dina Format nilai dimana rumus ieu bener kotak, asupkeun rumus di luhur-disebutkeun pikeun sabtu minggu atawa poe minggu.
5. Klik tombol Format tur pilih format nu dipikahoyong.
6. Klik OK dua kali pikeun nyimpen parobahanana jeung nutup jandela dialog.

Kanggo inpo nu lengkep dina unggal léngkah, mangga tingali Kumaha nyetél pormat kondisional sareng rumus.

Hasilna katingali saé, sanés?

Kumaha cara ngitung poé minggu jeung sabtu minggu dina Excel

Pikeun meunangkeun jumlah poé minggu atawa sabtu minggu dina daptar tanggal, Anjeun bisa maké fungsi WEEKDAY dina kombinasi jeung SUM. Contona:

Pikeun ngitung sabtu minggu , rumus dina D3 nyaéta:

=SUM(--(WEEKDAY(A3:A20, 2)>5))

Pikeun ngitung poé minggu ,rumus dina D4 nyandak formulir kieu:

=SUM(--(WEEKDAY(A3:A20, 2)<6))

Dina Excel 365 jeung Excel 2021 nu ngatur arrays natively, ieu jalan salaku rumus biasa sakumaha ditémbongkeun dina screenshot handap. Dina Excel 2019 sareng sateuacana, pencét Ctrl + Shift + Enter pikeun ngajantenkeun rumus array.

Kumaha rumus ieu:

Pungsi WEEKDAY kalawan return_type disetel ka 2 mulihkeun jumlah poé ti 1 (Sen) nepi ka 7 (Minggu ) pikeun tiap tanggal dina rentang A3:A20. Ekspresi logis mariksa upami nomer anu dipulangkeun langkung ageung tibatan 5 (pikeun akhir minggu) atanapi kirang ti 6 (pikeun dinten minggu). Hasil tina operasi ieu mangrupa susunan nilai BENER jeung PALSU.

Negasi ganda (--) maksakeun nilai logis jadi 1 jeung 0. Sareng fungsi SUM nambihanana. Kumargi 1 (BENER) ngalambangkeun dinten anu kedah diitung sareng 0 (SALAH) dinten anu teu dipalire, anjeun nampi hasil anu dipikahoyong.

Tip. Pikeun ngitung weekdays antara dua tanggal , gunakeun fungsi NETWORKDAYS atawa NETWORKDAYS.INTL.

Lamun poe minggu teh, mun Saptu atawa Minggu tuluy

Tungtungna, hayu urang bahas deui. kasus husus nu nunjukeun kumaha nangtukeun poé dina saminggu, sarta lamun éta Saptu atawa Minggu lajeng ngalakukeun hiji hal, lamun weekday lajeng ngalakukeun hal sejenna.

Anggap anjeun ngitung pangmayaran kanggo karyawan anu parantos damel tambahan dina dinten liburna, janten anjeun peryogipikeun nerapkeun ongkos pangmayaran béda pikeun workdays na weekends. Ieu tiasa dilakukeun nganggo pernyataan IF di handap ieu:

• Dina argumen logical_test , sarang pungsi WEEKDAY anu mariksa naha dinten anu ditangtukeun nyaéta dinten damel atanapi sabtu minggu.
• Dina argumen value_if_true , kalikeun jumlah jam gawé ku laju sabtu minggu (G4).
• Dina argumen value_if_false , kalikeun jumlah jam gawé. ku laju poé gawé (G3).

Rumus lengkep dina D3 nyaéta kieu:

=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)

Pikeun rumus nyalin anu bener ka sél di handap, pastikeun pikeun ngonci alamat sél laju ku tanda $ (siga $G$4).

Pungsi WEEKDAY teu jalan

Sacara umum, aya dua kasalahan umum anu bisa dibalikkeun ku rumus WEEKDAY:

#VALUE! aya kasalahan lamun:

• Serial_number atawa return_type non-numeric.
• Serial_number kaluar tina rentang tanggal nu dirojong (1900 nepi ka 9999).

#NUM! kasalahan lumangsung nalika return_type kaluar tina rentang nu diidinan (1-3 atawa 11-17).

Ieu cara ngagunakeun pungsi WEEKDAY dina Excel pikeun ngamanipulasi poé minggu. Dina artikel salajengna, urang bakal ngajalajah fungsi Excel pikeun beroperasi dina unit waktos anu langkung ageung sapertos minggu, bulan sareng taun. Mangga teraskeun sareng hatur nuhun pikeun maca!

Buku kerja latihan pikeun diunduh

rumus WEEKDAY dina Excel - conto (.xlsxfile)