إذا كنت تبحث عن وظيفة Excel للحصول على يوم من أيام الأسبوع من تاريخه ، فقد وصلت إلى الصفحة الصحيحة. سيعلمك هذا البرنامج التعليمي كيفية استخدام صيغة WEEKDAY في Excel لتحويل تاريخ إلى اسم يوم من أيام الأسبوع ، وتصفية وتمييز وإحصاء عطلات نهاية الأسبوع أو أيام العمل ، والمزيد.

هناك مجموعة متنوعة من الوظائف لـ العمل مع التواريخ في Excel. تعتبر وظيفة يوم من الأسبوع (WEEKDAY) مفيدة بشكل خاص للتخطيط والجدولة ، على سبيل المثال لتحديد الإطار الزمني لمشروع وإزالة عطلات نهاية الأسبوع من الإجمالي تلقائيًا. لذلك ، دعنا نراجع الأمثلة في وقت واحد ونرى كيف يمكن أن تساعدك في التعامل مع المهام المختلفة المتعلقة بالتاريخ في Excel.

WEEKDAY - وظيفة Excel ليوم من الأسبوع

تُستخدم وظيفة Excel WEEKDAY لإرجاع يوم الأسبوع من تاريخ معين.

النتيجة هي عدد صحيح ، يتراوح من 1 (الأحد) إلى 7 (السبت) افتراضيًا . إذا كان منطق العمل الخاص بك يتطلب تعدادًا مختلفًا ، فيمكنك تكوين الصيغة لبدء العد مع أي يوم آخر من أيام الأسبوع.

تتوفر وظيفة WEEKDAY في كافة إصدارات Excel 365 حتى 2000.

صيغة الدالة WEEKDAY كما يلي:

WEEKDAY (serial_number، [return_type])

حيث:

Serial_number (مطلوب) - التاريخ الذي تريد تحويله إلى رقم أيام الأسبوع. يمكن توفيره كرقم تسلسلي يمثل التاريخ ، كسلسلة نصية في التنسيقالذي يفهمه Excel ، كمرجع إلى الخلية التي تحتوي على التاريخ ، أو باستخدام وظيفة DATE.

نوع الإرجاع (اختياري) - يحدد أي يوم من الأسبوع سيتم استخدامه باعتباره اليوم الأول . إذا تم حذفها ، يتم تعيينها افتراضيًا على الأسبوع من الأحد إلى السبت.

فيما يلي قائمة بجميع القيم المدعومة نوع الإرجاع :

<تم إرجاع 14> الرقم

نوع الإرجاع
1 أو حذفه	من 1 (الأحد) إلى 7 (السبت)
2	من 1 (الاثنين) إلى 7 (الأحد)
3	من 0 (الاثنين) إلى 6 (الأحد)
11	من 1 (الاثنين) إلى 7 (الأحد)
12	من 1 (الثلاثاء) إلى 7 (الاثنين)
13	من 1 (الأربعاء) إلى 7 (الثلاثاء)
14	من 1 (الخميس) إلى 7 (الأربعاء)
15	من 1 (الجمعة) إلى 7 (الخميس)
16	من 1 (السبت) إلى 7 (الجمعة)
17	من 1 (الأحد) إلى 7 (السبت)

ملاحظة. تم تقديم قيم return_type من 11 إلى 17 في Excel 2010 وبالتالي لا يمكن استخدامها في الإصدارات السابقة.

صيغة WEEKDAY الأساسية في Excel

بالنسبة للمبتدئين ، دعنا نرى كيف لاستخدام صيغة WEEKDAY في أبسط صورها للحصول على رقم اليوم من التاريخ.

على سبيل المثال ، للحصول على يوم من أيام الأسبوع من التاريخ في C4 مع الأسبوع الافتراضي من الأحد إلى السبت ، تكون الصيغة هي:

=WEEKDAY(C4)

إذا كان لديك رقم تسلسليتمثل التاريخ (على سبيل المثال ، الذي تم إحضاره بواسطة دالة DATEVALUE) ، يمكنك إدخال هذا الرقم مباشرةً في الصيغة:

=WEEKDAY(45658)

أيضًا ، يمكنك كتابة التاريخ كسلسلة نصية محاطة بعلامات اقتباس مباشرة في الصيغة. فقط تأكد من استخدام تنسيق التاريخ الذي يتوقعه Excel ويمكنه تفسيره:

=WEEKDAY("1/1/2025")

أو ، قم بتوفير تاريخ المصدر بطريقة موثوقة بنسبة 100٪ باستخدام الدالة DATE:

=WEEKDAY(DATE(2025, 1,1))

لاستخدام تعيين اليوم بخلاف Sun-Sat الافتراضي ، أدخل رقمًا مناسبًا في الوسيطة الثانية. على سبيل المثال ، لبدء حساب الأيام من يوم الاثنين ، تكون الصيغة:

=WEEKDAY(C4, 2)

في الصورة أدناه ، تُرجع جميع الصيغ يوم الأسبوع الموافق 1 يناير 2025 ، وهو تم تخزينها كرقم 45658 داخليا في Excel. اعتمادًا على القيمة المعينة في الوسيطة الثانية ، تُخرج الصيغ نتائج مختلفة.

للوهلة الأولى ، قد يبدو أن الأرقام التي تم إرجاعها بواسطة وظيفة WEEKDAY لها القليل من المعنى العملي. ولكن دعونا ننظر إليها من زاوية مختلفة ونناقش بعض الصيغ التي تحل مهام الحياة الواقعية.

كيفية تحويل تاريخ Excel إلى اسم أيام الأسبوع

حسب التصميم ، وظيفة Excel WEEKDAY إرجاع يوم الأسبوع كرقم. لتحويل رقم أيام الأسبوع إلى اسم اليوم ، استخدم وظيفة TEXT.

للحصول على أسماء يوم كامل ، استخدم رمز تنسيق "dddd":

TEXT (WEEKDAY (<10)> التاريخ ) ، "dddd")

لإرجاع مختصرأسماء الأيام ، رمز التنسيق هو "ddd":

TEXT (WEEKDAY ( التاريخ ) ، "ddd")

على سبيل المثال ، لتحويل التاريخ في A3 إلى اسم يوم من أيام الأسبوع ، الصيغة هي:

=TEXT(WEEKDAY(A3), "dddd")

أو

=TEXT(WEEKDAY(A3), "ddd")

هناك حل آخر ممكن وهو استخدام WEEKDAY مع وظيفة CHOOSE.

على سبيل المثال ، للحصول على اسم يوم من أيام الأسبوع مختصر من التاريخ الموجود في A3 ، فإن الصيغة تسير على النحو التالي:

=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")

هنا ، تُرجع WEEKDAY الرقم التسلسلي من 1 (الأحد) إلى 7 (السبت ) واختيار القيمة المقابلة من القائمة. نظرًا لأن التاريخ في A3 (الأربعاء) يتوافق مع 4 ، اختر إخراج "الأربعاء" ، وهي القيمة الرابعة في القائمة.

على الرغم من أن تكوين صيغة CHOOSE أكثر تعقيدًا إلى حد ما ، إلا أنه يوفر مزيدًا من المرونة مما يتيح لك إخراج أسماء اليوم بأي تنسيق تريده. في المثال أعلاه ، نعرض أسماء الأيام المختصرة. بدلاً من ذلك ، يمكنك تقديم أسماء كاملة أو اختصارات مخصصة أو حتى أسماء أيام بلغة مختلفة.

نصيحة. هناك طريقة أخرى سهلة لتحويل تاريخ إلى اسم يوم من أيام الأسبوع وهي تطبيق تنسيق تاريخ مخصص. على سبيل المثال ، تنسيق الرمز "dddd، mmmm d، yyyy" سيكون له التاريخ المعروض كـ " الجمعة ، 3 يناير 2025 " بينما "dddd" ستظهر فقط " الجمعة " .

صيغة Excel WEEKDAY للبحث عن أيام العمل وعطلات نهاية الأسبوع وتصفيتها

عند التعامل مع قائمة طويلة من التواريخ ، قد ترغب في معرفة أيام العمل وأيها أيام عطلات نهاية الأسبوع.

لتحديد عطلات نهاية الأسبوع وأيام الأسبوع في Excel ، أنشئ جملة IF باستخدام دالة WEEKDAY المتداخلة. على سبيل المثال:

=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")

تنتقل هذه الصيغة إلى الخلية A3 ويتم نسخها لأسفل عبر العديد من الخلايا حسب الحاجة.

في صيغة WEEKDAY ، تقوم بتعيين return_type إلى 2 ، والذي يتوافق مع أسبوع الإثنين إلى الأحد حيث يكون الاثنين هو اليوم الأول. لذلك ، إذا كان رقم يوم الأسبوع أقل من 6 (من الاثنين إلى الجمعة) ، فإن الصيغة ترجع "يوم العمل" ، وإلا - "عطلة نهاية الأسبوع".

لتصفية عطلات نهاية الأسبوع أو أيام العمل ، قم بتطبيق عامل تصفية Excel على مجموعة البيانات الخاصة بك (علامة التبويب البيانات علامة التبويب & gt؛ تصفية ) وحدد إما "عطلة نهاية الأسبوع" أو "يوم العمل".

في لقطة الشاشة أدناه ، تمت تصفية أيام الأسبوع ، بحيث تظهر عطلات نهاية الأسبوع فقط:

إذا كان هناك مكتب إقليمي لمؤسستك يعمل وفقًا لجدول زمني مختلف حيث تكون أيام الراحة بخلاف السبت والأحد ، يمكنك بسهولة ضبط صيغة WEEKDAY وفقًا لاحتياجاتك عن طريق تحديد نوع مختلف return_type .

على سبيل المثال ، للتعامل مع السبت و الإثنين كعطلات نهاية الأسبوع ، اضبط return_type على 12 ، لذلك ستحصل على نوع الأسبوع من "الثلاثاء (1) إلى الاثنين (7)":

=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")

كيفية تمييز أيام عطلة نهاية الأسبوع وفي Excel

لتحديد عطلات نهاية الأسبوع وأيام العمل في ورقة العمل الخاصة بك في لمحة ، يمكنك جعلها مظللة تلقائيًا بألوان مختلفة. لهذا ، استخدم صيغة أيام الأسبوع / نهاية الأسبوع التي تمت مناقشتها في المثال السابق معتنسيق Excel الشرطي. كما هو شرط ضمنيًا ، نحتاج فقط إلى وظيفة WEEKDAY الأساسية بدون غلاف IF.

إلى تمييز عطلات نهاية الأسبوع (السبت والأحد):

=WEEKDAY($A2, 2)<6

إلى تمييز أيام العمل (الاثنين - الجمعة):

=WEEKDAY($A2, 2)>5

حيث A2 هي الخلية العلوية اليسرى للنطاق المحدد.

إلى قم بإعداد قاعدة التنسيق الشرطي ، والخطوات هي:

1. حدد قائمة التواريخ (A2: A15 في حالتنا).
2. في علامة التبويب الصفحة الرئيسية ، في المجموعة أنماط ، انقر فوق تنسيق شرطي & gt؛ قاعدة جديدة .
3. في مربع الحوار قاعدة تنسيق جديدة في المربع ، حدد استخدم صيغة لتحديد الخلايا المراد تنسيقها .
4. في المربع تنسيق القيم حيث تكون هذه الصيغة صحيحة ، أدخل الصيغة المذكورة أعلاه لعطلات نهاية الأسبوع أو أيام الأسبوع.
5. انقر فوق الزر تنسيق وحدد التنسيق المطلوب.
6. انقر فوق موافق مرتين لحفظ التغييرات وإغلاق نوافذ الحوار.

للحصول على معلومات مفصلة حول كل خطوة ، يرجى الاطلاع على كيفية الإعداد التنسيق الشرطي بالصيغة.

النتيجة تبدو جميلة ، أليس كذلك؟

كيفية حساب أيام الأسبوع وعطلات نهاية الأسبوع في Excel

للحصول على عدد أيام الأسبوع أو عطلات نهاية الأسبوع في قائمة التواريخ ، يمكنك استخدام الدالة WEEKDAY جنبًا إلى جنب مع SUM. على سبيل المثال:

إلى عد عطلات نهاية الأسبوع ، الصيغة في D3 هي:

=SUM(--(WEEKDAY(A3:A20, 2)>5))

إلى عد أيام الأسبوع ،تأخذ الصيغة في D4 هذا النموذج:

=SUM(--(WEEKDAY(A3:A20, 2)<6))

في Excel 365 و Excel 2021 اللذان يتعاملان مع المصفوفات محليًا ، يعمل هذا كصيغة عادية كما هو موضح في لقطة الشاشة أدناه. في Excel 2019 والإصدارات الأقدم ، اضغط على Ctrl + Shift + Enter لجعلها صيغة صفيف.

كيف تعمل هذه الصيغ:

ترجع الدالة WEEKDAY مع تعيين return_type إلى 2 رقم يوم من 1 (Mon) إلى 7 (Sun) ) لكل تاريخ في النطاق A3: A20. يتحقق التعبير المنطقي مما إذا كانت الأرقام التي تم إرجاعها أكبر من 5 (لعطلات نهاية الأسبوع) أو أقل من 6 (لأيام الأسبوع). نتيجة هذه العملية هي مصفوفة من قيم TRUE و FALSE.

النفي المزدوج (-) يفرض القيم المنطقية على 1 و 0. وتجمعهم الدالة SUM. بالنظر إلى أن 1 (TRUE) يمثل الأيام التي يجب عدها و 0 (FALSE) الأيام التي يجب تجاهلها ، تحصل على النتيجة المرجوة.

نصيحة. لحساب أيام الأسبوع بين تاريخين ، استخدم الدالة NETWORKDAYS أو NETWORKDAYS.INTL.

إذا كان يوم الأسبوع إذن ، إذا كان يوم السبت أو الأحد ، ثم

أخيرًا ، دعنا نناقش أكثر قليلاً حالة معينة توضح كيفية تحديد يوم الأسبوع ، وإذا كان يوم السبت أو الأحد ، فافعل شيئًا ما ، وإذا كان يومًا من أيام الأسبوع ، فافعل شيئًا آخر.

IF (WEEKDAY ( خلية ، 2) & gt؛ 5، if_weekend_then ، if_weekday_then )

افترض أنك تحسب المدفوعات للموظفين الذين قاموا ببعض الأعمال الإضافية في أيام إجازتهم ، لذلك تحتاجلتطبيق معدلات مدفوعات مختلفة لأيام العمل وعطلات نهاية الأسبوع. يمكن القيام بذلك باستخدام عبارة IF التالية:

• في الوسيطة logical_test ، قم بتداخل دالة WEEKDAY التي تتحقق مما إذا كان يوم معين هو يوم عمل أو عطلة نهاية أسبوع. 28> في الوسيطة value_if_true ، اضرب عدد ساعات العمل في معدل نهاية الأسبوع (G4).
• في الوسيطة value_if_false ، اضرب عدد ساعات العمل حسب معدل يوم العمل (G3).

تأخذ الصيغة الكاملة في D3 هذا النموذج:

=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)

لكي تنسخ الصيغة بشكل صحيح إلى الخلايا أدناه ، تأكد من قفل عناوين خلايا المعدل بعلامة $ (مثل $ G $ 4).

دالة WEEKDAY لا تعمل

بشكل عام ، هناك خطأان شائعان قد ترجعهما صيغة WEEKDAY:

#VALUE! يحدث الخطأ إذا كان إما:

• Serial_number أو return_type غير رقمي.
• Serial_number خارج نطاق التواريخ المدعوم (1900 إلى 9999).

#NUM! يحدث الخطأ عندما يكون نوع الإرجاع خارج النطاق المسموح به (1-3 أو 11-17).

هذه هي كيفية استخدام وظيفة WEEKDAY في Excel لمعالجة أيام الأسبوع. في المقالة التالية ، سوف نستكشف وظائف Excel للعمل على وحدات زمنية أكبر مثل الأسابيع والأشهر والسنوات. يرجى البقاء على اتصال وشكرًا على القراءة!

تدرب على المصنف للتنزيل

صيغة WEEKDAY في Excel - أمثلة (.xlsxملف)