সুচিপত্র
যদি আপনি তারিখ থেকে সপ্তাহের দিন পেতে এক্সেল ফাংশন খুঁজছেন, আপনি সঠিক পৃষ্ঠায় এসেছেন। এই টিউটোরিয়ালটি আপনাকে শেখাবে কিভাবে Excel-এ WEEKDAY সূত্র ব্যবহার করে একটি তারিখকে সপ্তাহের দিনের নামে রূপান্তর করতে হয়, ফিল্টার করতে হয়, হাইলাইট করতে হয় এবং উইকএন্ড বা কর্মদিবস গণনা করতে হয় এবং আরও অনেক কিছু। এক্সেলে তারিখ নিয়ে কাজ করুন। সপ্তাহের দিন ফাংশন (WEEKDAY) পরিকল্পনা এবং সময়সূচীর জন্য বিশেষভাবে উপযোগী, উদাহরণস্বরূপ একটি প্রকল্পের সময়সীমা নির্ধারণ করা এবং স্বয়ংক্রিয়ভাবে মোট থেকে সপ্তাহান্ত সরিয়ে ফেলা। সুতরাং, আসুন এক-একবার উদাহরণগুলি দিয়ে দেখি এবং এক্সেলের বিভিন্ন তারিখ-সম্পর্কিত কাজগুলি মোকাবেলায় কীভাবে তারা আপনাকে সাহায্য করতে পারে তা দেখুন৷
সপ্তাহ - দিনের জন্য এক্সেল ফাংশন সপ্তাহ
এক্সেল WEEKDAY ফাংশনটি একটি নির্দিষ্ট তারিখ থেকে সপ্তাহের দিন ফেরত দিতে ব্যবহৃত হয়।
ফলাফলটি একটি পূর্ণসংখ্যা, ডিফল্টরূপে 1 (রবিবার) থেকে 7 (শনিবার) পর্যন্ত . যদি আপনার ব্যবসায়িক যুক্তির জন্য একটি ভিন্ন গণনার প্রয়োজন হয়, তাহলে আপনি সপ্তাহের অন্য যেকোনো দিন গণনা শুরু করার জন্য সূত্রটি কনফিগার করতে পারেন।
WEEKDAY ফাংশনটি Excel 365 থেকে 2000 পর্যন্ত সমস্ত সংস্করণে উপলব্ধ।
WEEKDAY ফাংশনের সিনট্যাক্স নিম্নরূপ:
WEEKDAY(serial_number, [return_type])কোথায়:
Serial_number (প্রয়োজনীয়) - যে তারিখটি আপনি রূপান্তর করতে চান সপ্তাহের দিনের সংখ্যা পর্যন্ত। ফরম্যাটে টেক্সট স্ট্রিং হিসাবে এটি তারিখের প্রতিনিধিত্বকারী সিরিয়াল নম্বর হিসাবে সরবরাহ করা যেতে পারেযে এক্সেল বুঝতে পারে, তারিখ সম্বলিত কক্ষের রেফারেন্স হিসাবে, অথবা DATE ফাংশন ব্যবহার করে।
Return_type (ঐচ্ছিক) - প্রথম দিন হিসাবে সপ্তাহের কোন দিনটি ব্যবহার করতে হবে তা নির্ধারণ করে . যদি বাদ দেওয়া হয়, সূর্য-শনি সপ্তাহে ডিফল্ট।
এখানে সমস্ত সমর্থিত রিটার্ন_টাইপ মানগুলির একটি তালিকা রয়েছে:
| রিটার্ন_টাইপ | নম্বর ফেরত দেওয়া হয়েছে |
|---|---|
| 1 বা বাদ দেওয়া হয়েছে | 1 (রবিবার) থেকে 7 (শনিবার) |
| 2 | 1 (সোমবার) থেকে 7 (রবিবার) |
| 3 | 0 (সোমবার) থেকে 6 (রবিবার) |
| 11 | 1 (সোমবার) থেকে 7 (রবিবার) |
| 12 | 1 (মঙ্গলবার) থেকে 7 (সোমবার) |
| 13 | 1 (বুধবার) থেকে 7 (মঙ্গলবার) |
| 14 | 1 (বৃহস্পতিবার) থেকে 7 (বুধবার) |
| 15 | 1 (শুক্রবার) থেকে 7 (বৃহস্পতিবার) |
| 16 | 1 (শনিবার) থেকে 7 (শুক্রবার) |
| 17 | 1 (রবিবার) থেকে 7 (শনিবার) |
নোট। রিটার্ন_টাইপ মান 11 থেকে 17 এক্সেল 2010 এ চালু করা হয়েছিল এবং তাই সেগুলি আগের সংস্করণগুলিতে ব্যবহার করা যাবে না।
এক্সেলের বেসিক উইকেডে সূত্র
শুরুর জন্য, আসুন দেখি কিভাবে তারিখ থেকে দিনের সংখ্যা পেতে WEEKDAY সূত্রটিকে সবচেয়ে সহজ আকারে ব্যবহার করতে।
উদাহরণস্বরূপ, C4-তে তারিখ থেকে সপ্তাহের দিন ডিফল্ট রবিবার - শনিবার সপ্তাহে পেতে, সূত্রটি হল:
=WEEKDAY(C4)
আপনার যদি সিরিয়াল নম্বর থাকেতারিখের প্রতিনিধিত্ব করে (যেমন DATEVALUE ফাংশন দ্বারা আনা), আপনি সেই সংখ্যাটি সরাসরি সূত্রে লিখতে পারেন:
=WEEKDAY(45658)
এছাড়াও, আপনি তারিখটিকে উদ্ধৃতি চিহ্নের মধ্যে একটি পাঠ্য স্ট্রিং হিসাবে টাইপ করতে পারেন সরাসরি সূত্রে। এক্সেল যে তারিখের বিন্যাসটি আশা করে এবং ব্যাখ্যা করতে পারে তা ব্যবহার করতে ভুলবেন না:
=WEEKDAY("1/1/2025")
অথবা, DATE ফাংশন ব্যবহার করে 100% নির্ভরযোগ্য উপায়ে উত্স তারিখ সরবরাহ করুন:
=WEEKDAY(DATE(2025, 1,1))
ডিফল্ট সূর্য-শনি ব্যতীত দিনের ম্যাপিং ব্যবহার করতে, দ্বিতীয় আর্গুমেন্টে একটি উপযুক্ত সংখ্যা লিখুন। উদাহরণস্বরূপ, সোমবার থেকে দিন গণনা শুরু করার জন্য, সূত্রটি হল:
=WEEKDAY(C4, 2)
নীচের ছবিতে, সমস্ত সূত্রগুলি 1 জানুয়ারী, 2025 এর সাথে সম্পর্কিত সপ্তাহের দিনটি ফেরত দেয়, যা হল এক্সেলের অভ্যন্তরীণভাবে 45658 নম্বর হিসাবে সংরক্ষিত। দ্বিতীয় যুক্তিতে সেট করা মানের উপর নির্ভর করে, সূত্রগুলি বিভিন্ন ফলাফল দেয়। 
প্রথম দর্শনে, এটা মনে হতে পারে যে WEEKDAY ফাংশন দ্বারা প্রত্যাবর্তিত সংখ্যাগুলির ব্যবহারিক জ্ঞান খুব কম। তবে আসুন এটিকে একটি ভিন্ন কোণ থেকে দেখি এবং কিছু সূত্র নিয়ে আলোচনা করি যা বাস্তব জীবনের কাজগুলি সমাধান করে৷
কিভাবে এক্সেল তারিখকে সাপ্তাহিক দিনের নামে রূপান্তর করা যায়
ডিজাইন অনুসারে, এক্সেল উইকেডে ফাংশন একটি সংখ্যা হিসাবে সপ্তাহের দিন প্রদান করে। সপ্তাহের দিন নম্বরটিকে দিনের নামে পরিণত করতে, TEXT ফাংশনটি নিয়োগ করুন৷
পুরো দিনের নাম পেতে, "dddd" ফরম্যাট কোড ব্যবহার করুন:
TEXT(WEEKDAY(<10)>তারিখ ), "dddd")ফিরতে সংক্ষিপ্তদিনের নাম , ফরম্যাট কোড হল "ddd":
TEXT(WEEKDAY( date ), "ddd")উদাহরণস্বরূপ, A3-এ তারিখটিকে সাপ্তাহিক দিনের নামে রূপান্তর করতে , সূত্রটি হল:
=TEXT(WEEKDAY(A3), "dddd")
অথবা
=TEXT(WEEKDAY(A3), "ddd") 
আরেকটি সম্ভাব্য সমাধান হল WEEKDAY একত্রে CHOOSE ফাংশন ব্যবহার করা।
উদাহরণস্বরূপ, A3 তারিখ থেকে একটি সংক্ষিপ্ত সপ্তাহের দিন নাম পেতে, সূত্রটি নিম্নরূপ:
=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")
এখানে, WEEKDAY 1 (রবি) থেকে 7 (শনি) থেকে একটি ক্রমিক নম্বর প্রদান করে ) এবং CHOOSE তালিকা থেকে সংশ্লিষ্ট মান নির্বাচন করে। যেহেতু A3 (বুধবার) তারিখটি 4 এর সাথে মিলে যায়, তাই "বুধ" আউটপুট বেছে নিন, যা তালিকার ৪র্থ মান। 
যদিও CHOOSE সূত্রটি কনফিগার করার জন্য একটু বেশি কষ্টকর, এটি আপনাকে যে কোনো ফরম্যাটে দিনের নাম আউটপুট করতে আরও নমনীয়তা প্রদান করে। উপরের উদাহরণে, আমরা সংক্ষিপ্ত দিনের নামগুলি দেখাই। পরিবর্তে, আপনি একটি ভিন্ন ভাষায় সম্পূর্ণ নাম, কাস্টম সংক্ষিপ্ত রূপ বা এমনকি দিনের নাম প্রদান করতে পারেন৷
টিপ৷ একটি তারিখকে সপ্তাহের দিনের নামে রূপান্তর করার আরেকটি সহজ উপায় হল একটি কাস্টম তারিখ বিন্যাস প্রয়োগ করা। উদাহরণস্বরূপ, কোড ফর্ম্যাট "dddd, mmmm d, yyyy" তারিখটি " শুক্রবার, জানুয়ারী 3, 2025 " হিসাবে প্রদর্শিত হবে যখন "dddd" শুধুমাত্র " শুক্রবার " দেখাবে। .
>এক্সেলে সাপ্তাহিক ছুটির দিন এবং সপ্তাহের দিনগুলি সনাক্ত করতে নেস্টেড WEEKDAY ফাংশন সহ একটি IF স্টেটমেন্ট তৈরি করুন। উদাহরণ স্বরূপ:
=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")
এই সূত্রটি A3 কক্ষে যায় এবং প্রয়োজনমতো কপি করা হয়।
WEEKDAY সূত্রে, আপনি return_type সেট করেন থেকে 2, যা সোম-রবি সপ্তাহের সাথে মিলে যায় যেখানে সোমবার দিন 1। সুতরাং, যদি সপ্তাহের দিন সংখ্যা 6 এর কম হয় (সোম থেকে শুক্রবার), সূত্রটি "কাজের দিন", অন্যথায় - "উইকএন্ড" প্রদান করে। 
সপ্তাহান্ত বা কর্মদিবস ফিল্টার করতে , আপনার ডেটাসেটে এক্সেল ফিল্টার প্রয়োগ করুন ( ডেটা ট্যাব > ফিল্টার ) এবং "উইকএন্ড" বা নির্বাচন করুন "কর্মদিবস"।
নীচের স্ক্রিনশটে, আমরা সপ্তাহের দিনগুলি ফিল্টার আউট করেছি, তাই শুধুমাত্র সপ্তাহান্তে দৃশ্যমান: 
যদি আপনার সংস্থার কিছু আঞ্চলিক অফিস একটি ভিন্ন সময়সূচীতে কাজ করে যেখানে বিশ্রামের দিনগুলি শনিবার এবং রবিবার ছাড়া অন্য সময়, আপনি একটি ভিন্ন রিটার্ন_টাইপ নির্দিষ্ট করে আপনার প্রয়োজনের সাথে WEEKDAY সূত্র সহজেই সামঞ্জস্য করতে পারেন।
উদাহরণস্বরূপ, শনিবার এবং <10 এর সাথে আচরণ করতে>সোমবার উইকএন্ড হিসাবে, রিটার্ন_টাইপ 12 এ সেট করুন, যাতে আপনি "মঙ্গলবার (1) থেকে সোমবার (7)" সপ্তাহের ধরন পাবেন:
=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")
সাপ্তাহিক ছুটির কর্মদিবস এবং এক্সেলে কীভাবে হাইলাইট করবেন
আপনার ওয়ার্কশীটে এক নজরে সাপ্তাহিক ছুটির দিন এবং কর্মদিবসগুলিকে চিহ্নিত করতে, আপনি সেগুলিকে স্বয়ংক্রিয়ভাবে বিভিন্ন রঙে ছায়া পেতে পারেন৷ এর জন্য, আগের উদাহরণে আলোচনা করা সপ্তাহের দিন/সাপ্তাহিক ছুটির সূত্রটি ব্যবহার করুনএক্সেল শর্তসাপেক্ষ বিন্যাস. যেহেতু শর্তটি বোঝানো হয়েছে, আমাদের শুধুমাত্র IF র্যাপার ছাড়াই WEEKDAY ফাংশনটি প্রয়োজন৷
উইকএন্ড হাইলাইট করতে (শনিবার এবং রবিবার):
=WEEKDAY($A2, 2)<6
কাজের দিনগুলিকে হাইলাইট করতে (সোমবার - শুক্রবার):
=WEEKDAY($A2, 2)>5
যেখানে A2 হল নির্বাচিত পরিসরের উপরের-বাম ঘর৷
প্রতি শর্তসাপেক্ষ ফর্ম্যাটিং নিয়ম সেট আপ করুন, ধাপগুলি হল:
- তারিখের তালিকা নির্বাচন করুন (আমাদের ক্ষেত্রে A2:A15)।
- হোম ট্যাবে। , শৈলী গ্রুপে, শর্তগত বিন্যাস > নতুন নিয়ম ক্লিক করুন।
- নতুন বিন্যাস নিয়ম ডায়ালগে বক্সে, কোন কক্ষকে ফর্ম্যাট করতে হবে তা নির্ধারণ করতে একটি সূত্র ব্যবহার করুন নির্বাচন করুন।
- ফরম্যাট মান যেখানে এই সূত্রটি সত্য বক্সে, উইকএন্ডের জন্য উপরে উল্লিখিত সূত্রটি প্রবেশ করান অথবা সপ্তাহের দিন।
- ফরম্যাট বোতামে ক্লিক করুন এবং পছন্দসই ফর্ম্যাটটি নির্বাচন করুন।
- পরিবর্তনগুলি সংরক্ষণ করতে এবং ডায়ালগ উইন্ডো বন্ধ করতে দুবার ঠিক আছে ক্লিক করুন।
প্রতিটি ধাপে বিস্তারিত তথ্যের জন্য, অনুগ্রহ করে দেখুন কিভাবে সেট আপ করবেন ফর্মুলার সাথে শর্তসাপেক্ষ বিন্যাস।
ফলাফলটি বেশ সুন্দর দেখাচ্ছে, তাই না? 
এক্সেল-এ সপ্তাহের দিন এবং সাপ্তাহিক ছুটির দিনগুলি কীভাবে গণনা করবেন
তারিখগুলির তালিকায় সপ্তাহের দিন বা সপ্তাহান্তের সংখ্যা পেতে, আপনি SUM এর সাথে WEEKDAY ফাংশনটি ব্যবহার করতে পারেন। যেমন:
সাপ্তাহিক ছুটি গণনা করার জন্য, D3 এর সূত্রটি হল:
=SUM(--(WEEKDAY(A3:A20, 2)>5))
থেকে সাপ্তাহিক দিন গণনা ,D4-এর সূত্রটি এই ফর্মটি নেয়:
=SUM(--(WEEKDAY(A3:A20, 2)<6))
Excel 365 এবং Excel 2021-এ যা অ্যারেগুলিকে নেটিভভাবে পরিচালনা করে, এটি নীচের স্ক্রিনশটে দেখানো হিসাবে একটি নিয়মিত সূত্র হিসাবে কাজ করে। এক্সেল 2019 এবং তার আগে, এটিকে একটি অ্যারে সূত্র তৈরি করতে Ctrl + Shift + Enter টিপুন। 
এই সূত্রগুলি কীভাবে কাজ করে:
রিটার্ন_টাইপ 2 তে সেট করা উইকডে ফাংশনটি 1 (সোম) থেকে 7 (রবি) পর্যন্ত দিনের সংখ্যা প্রদান করে ) A3:A20 রেঞ্জের প্রতিটি তারিখের জন্য। লজিক্যাল এক্সপ্রেশন চেক করে যে প্রত্যাবর্তিত সংখ্যাগুলি 5 এর বেশি (সপ্তাহান্তের জন্য) বা 6 এর কম (সাপ্তাহিক দিনের জন্য)। এই অপারেশনের ফলাফল হল TRUE এবং FALSE মানের একটি অ্যারে৷
ডাবল নেগেশান (--) যৌক্তিক মানগুলিকে 1 এবং 0 এর জন্য বাধ্য করে৷ এবং SUM ফাংশন তাদের যোগ করে। প্রদত্ত যে 1 (TRUE) গণনা করার দিনগুলি এবং 0 (FALSE) দিনগুলি উপেক্ষা করার জন্য প্রতিনিধিত্ব করে, আপনি পছন্দসই ফলাফল পাবেন৷
টিপ৷ দুই তারিখের মধ্যে সপ্তাহের দিনগুলি গণনা করতে, NETWORKDAYS বা NETWORKDAYS.INTL ফাংশনটি ব্যবহার করুন৷
যদি সপ্তাহের দিন হয়, যদি শনিবার বা রবিবার হয় তাহলে
অবশেষে, আসুন আরও কিছু আলোচনা করা যাক নির্দিষ্ট ক্ষেত্রে যা দেখায় কিভাবে সপ্তাহের দিন নির্ধারণ করতে হয়, এবং যদি শনিবার বা রবিবার হয় তবে কিছু করুন, যদি সপ্তাহের দিন হয় তবে অন্য কিছু করুন৷
IF(WEEKDAY( cell , 2)> 5, if_weekend_then , if_weekday_then )ধরুন আপনি কর্মচারীদের জন্য অর্থপ্রদান গণনা করছেন যারা তাদের ছুটির দিনে কিছু অতিরিক্ত কাজ করেছেন, তাই আপনার প্রয়োজনকর্মদিবস এবং সাপ্তাহিক ছুটির জন্য বিভিন্ন পেমেন্ট রেট প্রয়োগ করতে। এটি নিম্নলিখিত IF স্টেটমেন্ট ব্যবহার করে করা যেতে পারে:
- logical_test আর্গুমেন্টে, WEEKDAY ফাংশনটি নেস্ট করুন যা একটি নির্দিষ্ট দিন কর্মদিবস নাকি সপ্তাহান্তে পরীক্ষা করে।
- value_if_true আর্গুমেন্টে, কাজের ঘন্টার সংখ্যাকে সপ্তাহান্তের হার (G4) দিয়ে গুণ করুন।
- value_if_false যুক্তিতে, কাজের ঘন্টার সংখ্যা গুণ করুন কার্যদিবসের হার (G3) দ্বারা।
D3-এর সম্পূর্ণ সূত্রটি এই ফর্মটি নেয়:
=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)
নীচের ঘরে সঠিকভাবে অনুলিপি করার জন্য, $ চিহ্ন (যেমন $G$4) দিয়ে রেট সেল ঠিকানা লক করতে ভুলবেন না। 
WEEKDAY ফাংশন কাজ করছে না
সাধারণত, দুটি সাধারণ ত্রুটি আছে যা একটি সপ্তাহের সূত্রে ফিরে আসতে পারে:
#VALUE! ত্রুটি দেখা দেয় যদি হয়:
- Serial_number অথবা return_type অ-সংখ্যাসূচক হয়।
- Serial_number এর বাইরে থাকে সমর্থিত তারিখ পরিসর (1900 থেকে 9999)।
#NUM! ত্রুটি দেখা দেয় যখন রিটার্ন_টাইপ অনুমোদিত সীমার বাইরে থাকে (1-3 বা 11-17)।
এভাবে সপ্তাহের দিনগুলিকে ম্যানিপুলেট করার জন্য এক্সেলে উইকেডে ফাংশন ব্যবহার করতে হয়। পরের প্রবন্ধে, আমরা এক্সেল ফাংশনগুলি অন্বেষণ করব যাতে সপ্তাহ, মাস এবং বছরের মতো বড় সময়ের ইউনিটগুলিতে কাজ করা যায়। অনুগ্রহ করে সাথে থাকুন এবং পড়ার জন্য আপনাকে ধন্যবাদ!
ডাউনলোডের জন্য ওয়ার্কবুক অনুশীলন করুন
এক্সেলের উইকেডে সূত্র - উদাহরণ (.xlsxফাইল)
