द्वि-आयामी लुकअप के लिए एक्सेल में INDEX MATCH MATCH

Michael Brown

03-06-2023 एक्सेल
  • इसे साझा करें
Michael Brown

ट्यूटोरियल एक्सेल में दो आयामी लुकअप करने के लिए कुछ अलग सूत्र दिखाता है। बस विकल्पों को देखें और अपना पसंदीदा चुनें:)

अपनी एक्सेल स्प्रेडशीट में कुछ खोजते समय, अधिकांश समय आप लंबवत रूप से स्तंभों में या क्षैतिज रूप से पंक्तियों में देखेंगे। लेकिन कभी-कभी आपको पंक्तियों और स्तंभों दोनों में देखने की आवश्यकता होती है। दूसरे शब्दों में, आपका लक्ष्य एक निश्चित पंक्ति और स्तंभ के चौराहे पर एक मान खोजना है। इसे मैट्रिक्स लुकअप (उर्फ 2-डायमेंशनल या 2-वे लुकअप ) कहा जाता है, और यह ट्यूटोरियल दिखाता है कि इसे 4 अलग-अलग तरीकों से कैसे किया जाए।<3

Excel INDEX MATCH MATCH फ़ॉर्मूला

Excel में टू-वे लुकअप करने का सबसे लोकप्रिय तरीका INDEX MATCH MATCH का उपयोग करना है। यह क्लासिक INDEX MATCH सूत्र का एक रूपांतर है जिसमें आप पंक्ति और स्तंभ दोनों संख्याएँ प्राप्त करने के लिए एक और MATCH फ़ंक्शन जोड़ते हैं:

INDEX ( data_array , MATCH ( vlookup_value<2)>, lookup_column_range , 0), MATCH ( hlookup value , lookup_row_range , 0))

उदाहरण के तौर पर, आबादी को खींचने के लिए एक सूत्र बनाते हैं नीचे दी गई तालिका से किसी दिए गए वर्ष में एक निश्चित जानवर की। शुरुआत के लिए, हम सभी तर्कों को परिभाषित करते हैं:

  • Data_array - B2:E4 (डेटा सेल, जिसमें पंक्ति और कॉलम हेडर शामिल नहीं हैं)
  • Vlookup_value - H1 (लक्षित पशु)
  • Lookup_column_range - A2:A4 (पंक्ति शीर्षलेख: पशु नाम) -A3:A4
  • Hlookup_value - H2 (लक्ष्य वर्ष)
  • Lookup_row_range - B1:E1 (कॉलम हेडर: वर्ष)
    • <7

    सभी तर्कों को एक साथ रखें और आपको टू-वे लुकअप के लिए यह फॉर्मूला मिलेगा:

    =INDEX(B2:E4, MATCH(H1, A2:A4, 0), MATCH(H2, B1:E1, 0))

    यह फॉर्मूला कैसे काम करता है

    हालांकि यह थोड़ा सा दिख सकता है पहली नज़र में जटिल, सूत्र का तर्क वास्तव में सीधा और समझने में आसान है। INDEX फ़ंक्शन पंक्ति और स्तंभ संख्याओं के आधार पर डेटा सरणी से एक मान प्राप्त करता है, और दो MATCH फ़ंक्शन उन संख्याओं की आपूर्ति करते हैं:

    INDEX(B2:E4, row_num, column_num)

    यहां, हम MATCH(lookup_value, lookup_array, [match_type]) lookup_array में lookup_value की सापेक्ष स्थिति लौटाने के लिए।

    इसलिए, पंक्ति संख्या प्राप्त करने के लिए, हम खोज करते हैं पंक्ति शीर्षकों (A2:A4) में रुचि के पशु (H1) के लिए:

    MATCH(H1, A2:A4, 0)

    स्तंभ संख्या प्राप्त करने के लिए, हम स्तंभ शीर्षकों में लक्ष्य वर्ष (H2) की खोज करते हैं (B1:E1):

    MATCH(H2, B1:E1, 0)

    दोनों मामलों में, हम तीसरे तर्क को 0 पर सेट करके सटीक मिलान की तलाश करते हैं।

    इस उदाहरण में, पहला MATCH रिटर्न देता है 2 क्योंकि हमारा vlookup value (ध्रुवीय भालू) A3 में पाया जाता है, जो A2:A4 में दूसरा सेल है। दूसरा MATCH 3 लौटाता है क्योंकि hlookup मान (2000) D1 में पाया जाता है, जो कि B1:E1 में तीसरा सेल है।

    उपर्युक्त को देखते हुए, सूत्र कम होकर:

    INDEX(B2:E4, 2, 3)

    और डेटा सरणी B2:E4 में दूसरी पंक्ति और तीसरे कॉलम के चौराहे पर एक मान वापस करें, जो एक हैसेल D3 में मान।

    2-तरफ़ा लुकअप के लिए VLOOKUP और MATCH फ़ॉर्मूला

    Excel में द्वि-आयामी लुकअप करने का दूसरा तरीका VLOOKUP और MATCH फ़ंक्शन के संयोजन का उपयोग करना है:

    VLOOKUP( vlookup_value , table_array , MATCH( hlookup_value , lookup_row_range , 0), FALSE)

    हमारी नमूना तालिका के लिए , सूत्र निम्न आकार लेता है:

    =VLOOKUP(H1, A2:E4, MATCH(H2, A1:E1, 0), FALSE)

    कहाँ:

    • Table_array - A2:E4 (पंक्ति शीर्षलेख सहित डेटा सेल)
    • Vlookup_value - H1 (टारगेट एनिमल)
    • Hlookup_value - H2 (टारगेट ईयर)
    • Lookup_row_range - A1:E1 (कॉलम हेडर: वर्ष)

    यह सूत्र कैसे काम करता है

    सूत्र का मूल VLOOKUP फ़ंक्शन सटीक मिलान के लिए कॉन्फ़िगर किया गया है (अंतिम तर्क FALSE पर सेट), जो तालिका सरणी (A2:E4) के पहले कॉलम में लुकअप मान (H1) की खोज करता है और उसी पंक्ति में दूसरे कॉलम से मान लौटाता है। यह निर्धारित करने के लिए कि किस कॉलम से मान लौटाना है, आप MATCH फ़ंक्शन का उपयोग करते हैं जो सटीक मिलान के लिए भी कॉन्फ़िगर किया गया है (अंतिम तर्क 0 पर सेट है):

    MATCH(H2, A1:E1, 0)

    MATCH इसमें मान की खोज करता है कॉलम हेडर (A1:E1) पर H2 और पाए गए सेल की सापेक्ष स्थिति लौटाता है। हमारे मामले में, लक्ष्य वर्ष (2010) ई1 में पाया जाता है, जो लुकअप ऐरे में 5वां है। इसलिए, नंबर 5 VLOOKUP के col_index_num तर्क पर जाता है:

    VLOOKUP(H1, A2:E4, 5, FALSE)

    VLOOKUP इसे वहां से लेता है, एक पाता हैA2 में इसके लुकअप मान के लिए सटीक मिलान करता है और उसी पंक्ति में 5वें कॉलम से मान लौटाता है, जो कि सेल E2 है।

    महत्वपूर्ण नोट! सूत्र के ठीक से काम करने के लिए, VLOOKUP के table_array (A2:E4) और MATCH (A1:E1) के lookup_array में स्तंभों की संख्या समान होनी चाहिए, अन्यथा MATCH द्वारा पास की गई संख्या से col_index_num गलत होगा ( table_array में कॉलम की स्थिति के अनुरूप नहीं होगा)।

    पंक्तियों और कॉलम में देखने के लिए XLOOKUP फ़ंक्शन

    हाल ही में माइक्रोसॉफ्ट ने एक्सेल में एक और फ़ंक्शन पेश किया है जो सभी मौजूदा लुकअप फ़ंक्शंस जैसे VLOOKUP, HLOOKUP और INDEX MATCH को बदलने के लिए है। अन्य बातों के अलावा, XLOOKUP एक ​​विशिष्ट पंक्ति और स्तंभ के प्रतिच्छेदन को देख सकता है:

    XLOOKUP( vlookup_value , vlookup_column_range , XLOOKUP( hlookup_value , <1)>hlookup_row_range
, data_array ))

हमारे नमूना डेटा सेट के लिए, सूत्र इस प्रकार है:

=XLOOKUP(H1, A2:A4, XLOOKUP(H2, B1:E1, B2:E4))

नोट। वर्तमान में XLOOKUP एक ​​बीटा फ़ंक्शन है, जो केवल Office 365 सदस्यों के लिए उपलब्ध है जो Office Insiders प्रोग्राम का हिस्सा हैं। पूरी पंक्ति या स्तंभ। आंतरिक फ़ंक्शन हेडर पंक्ति में लक्ष्य वर्ष की खोज करता है और उस वर्ष के लिए सभी मान लौटाता है (इस उदाहरण में, वर्ष 1980 के लिए)। वे मान बाहरी के return_array तर्क पर जाते हैंXLOOKUP:

XLOOKUP(H1, A2:A4, {22000;25000;700}))

बाहरी XLOOKUP फ़ंक्शन कॉलम हेडर में लक्षित जानवर की खोज करता है और रिटर्न_अरे से उसी स्थिति में मान लौटाता है।

दो के लिए SUMPRODUCT सूत्र -वे लुकअप

SUMPRODUCT फ़ंक्शन एक्सेल में एक स्विस चाकू की तरह है - यह अपने निर्धारित उद्देश्य से परे बहुत कुछ कर सकता है, खासकर जब कई मानदंडों का मूल्यांकन करने की बात आती है।

दो को देखने के लिए मानदंड, पंक्तियों और स्तंभों में, इस सामान्य सूत्र का उपयोग करें:

SUMPRODUCT( vlookup_column_range = vlookup_value ) * ( hlookup_row_range = hlookup_value ), data_array )

हमारे डेटासेट में 2-तरफ़ा लुकअप करने के लिए, फ़ॉर्मूला इस प्रकार है:

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2), B2:E4)

नीचे दिया गया सिंटैक्स भी काम करेगा:

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2) * B2:E4)

यह सूत्र कैसे काम करता है

सूत्र के मूल में, हम दो लुकअप मानों की तुलना पंक्ति और स्तंभ शीर्षकों से करते हैं (H1 में लक्षित जानवर सभी जानवरों से A2:A4 में नाम और B1:E1 में सभी वर्षों की तुलना में H2 में लक्ष्य वर्ष):

(A2:A4=H1) * (B1:E1=H2)

यह परिणाम TRUE और FALSE मानों की 2 सरणियों में ults, जहाँ TRUE का प्रतिनिधित्व मेल खाता है:

{FALSE;FALSE;TRUE} * {FALSE,TRUE,FALSE,FALSE}

गुणन ऑपरेशन TRUE और FALSE मानों को 1 और 0 में जोड़ता है और 4 का द्वि-आयामी सरणी बनाता है कॉलम और 3 पंक्तियाँ (पंक्तियों को अर्धविराम से अलग किया जाता है और डेटा के प्रत्येक कॉलम को अल्पविराम से अलग किया जाता है):

{0,0,0,0;0,0,0,0;0,1,0,0}

SUMPRODUCT फ़ंक्शन उपरोक्त सरणी के तत्वों को निम्न के आइटम से गुणा करता हैB2:E4 एक ही स्थिति में:

{0,0,0,0;0,0,0,0;0,1,0,0} * {22000,13800,8500,3500;25000,23000,22000,20000;700,2000,2300,2500}

और क्योंकि शून्य से गुणा करने पर शून्य मिलता है, केवल पहली सरणी में 1 से संबंधित आइटम बचता है:

SUMPRODUCT({0,0,0,0;0,0,0,0;0,2000,0,0}) <3

अंत में, SUMPRODUCT परिणामी सरणी के तत्वों को जोड़ता है और 2000 का मान लौटाता है।

ध्यान दें। यदि आपकी तालिका में एक ही नाम वाली एक से अधिक पंक्तियाँ या/और कॉलम हेडर हैं, तो अंतिम सरणी में शून्य के अलावा एक से अधिक संख्याएँ होंगी, और उन सभी संख्याओं को जोड़ दिया जाएगा। परिणामस्वरूप, आपको उन मानों का योग प्राप्त होगा जो दोनों मानदंडों को पूरा करते हैं। यह वह है जो SUMPRODUCT सूत्र को INDEX MATCH MATCH और VLOOKUP से अलग बनाता है, जो पहले पाए गए मिलान को लौटाता है।

नामित श्रेणियों के साथ मैट्रिक्स लुकअप (स्पष्ट चौराहा)

करने का एक और आश्चर्यजनक सरल तरीका एक्सेल में एक मैट्रिक्स लुकअप नामित श्रेणियों का उपयोग कर रहा है। ऐसे:

भाग 1: कॉलम और पंक्तियों को नाम दें

अपनी तालिका में प्रत्येक पंक्ति और प्रत्येक कॉलम को नाम देने का सबसे तेज़ तरीका यह है:

  1. संपूर्ण तालिका का चयन करें (हमारे मामले में A1:E4)।
  2. सूत्र टैब पर, परिभाषित नाम समूह में, बनाएं क्लिक करें चयन से या Ctrl + Shift + F3 शॉर्टकट दबाएं।
  3. चयन से नाम बनाएं संवाद बॉक्स में, शीर्ष पंक्ति और बाएं चुनें कॉलम, और ओके पर क्लिक करें।

यह स्वचालित रूप से पंक्ति और कॉलम हेडर के आधार पर नाम बनाता है। हालांकि, कुछ चेतावनी हैं:

  • यदि आपका कॉलम और/यापंक्ति शीर्षलेख संख्याएं हैं या विशिष्ट वर्ण हैं जिन्हें एक्सेल नामों में अनुमति नहीं है, ऐसे कॉलम और पंक्तियों के नाम नहीं बनाए जाएंगे। निर्मित नामों की सूची देखने के लिए, नाम प्रबंधक ( Ctrl + F3 ) खोलें। यदि कुछ नाम गायब हैं, तो उन्हें मैन्युअल रूप से परिभाषित करें जैसा कि एक्सेल में एक श्रेणी का नाम कैसे दें।
  • यदि आपकी कुछ पंक्ति या कॉलम हेडर में रिक्त स्थान हैं, तो रिक्त स्थान को अंडरस्कोर से बदल दिया जाएगा, उदाहरण के लिए, Polar_bear ।

हमारी नमूना तालिका के लिए, Excel स्वचालित रूप से केवल पंक्ति नाम बनाता है। कॉलम नाम मैन्युअल रूप से बनाए जाने चाहिए क्योंकि कॉलम हेडर नंबर होते हैं। इसे दूर करने के लिए, आप केवल अंडरस्कोर के साथ संख्याओं की शुरुआत कर सकते हैं, जैसे _1990 ।

परिणामस्वरूप, हमारे पास निम्नलिखित नामांकित श्रेणियां हैं:

भाग 2 : एक मैट्रिक्स लुकअप फॉर्मूला बनाएं

किसी दी गई पंक्ति और कॉलम के चौराहे पर एक मान खींचने के लिए, खाली सेल में केवल निम्न सामान्य सूत्रों में से एक टाइप करें:

= row_name column_name

या इसके विपरीत:

= column_name row_name

उदाहरण के लिए, 1990 में ब्लू व्हेल की आबादी प्राप्त करने के लिए , सूत्र उतना ही सरल है जितना:

=Blue_whale _1990

यदि किसी को अधिक विस्तृत निर्देशों की आवश्यकता है, तो निम्न चरण आपको प्रक्रिया के बारे में बताएंगे:

  1. एक सेल में जहां आप परिणाम दिखाना चाहते हैं, समानता चिह्न (=) टाइप करें। बाद मेंआपने कुछ अक्षर टाइप किए हैं, एक्सेल आपके इनपुट से मेल खाने वाले सभी मौजूदा नाम प्रदर्शित करेगा। वांछित नाम को अपने सूत्र में दर्ज करने के लिए उस पर डबल-क्लिक करें:
  2. पंक्ति नाम के बाद, स्पेस टाइप करें, जो चौराहे ऑपरेटर के रूप में काम करता है इस मामले में।
  3. लक्ष्य कॉलम नाम दर्ज करें ( _1990 हमारे मामले में)।
  4. जैसे ही पंक्ति और स्तंभ दोनों नाम दर्ज किए जाते हैं, एक्सेल आपकी तालिका में संबंधित पंक्ति और स्तंभ को हाइलाइट कर देगा, और आप सूत्र को पूरा करने के लिए Enter दबाएं:
    5. <20

    आपका मैट्रिक्स लुकअप पूरा हो गया है, और नीचे दिया गया स्क्रीनशॉट परिणाम दिखाता है:

    एक्सेल में पंक्तियों और स्तंभों को इस तरह देखें। पढ़ने के लिए मैं आपको धन्यवाद देता हूं और आशा करता हूं कि अगले सप्ताह आपसे हमारे ब्लॉग पर मुलाकात होगी!

    उपलब्ध डाउनलोड

    द्वि-आयामी लुकअप नमूना कार्यपुस्तिका

<3
पिछला पद सूत्र के साथ स्तंभ को पंक्ति में बदलने के लिए Excel में TRANSPOSE फ़ंक्शन
अगली पोस्ट Excel में पंक्तियों को शॉर्टकट और अन्य तरीकों से कैसे सम्मिलित करें

माइकल ब्राउन सॉफ्टवेयर टूल्स का उपयोग करके जटिल प्रक्रियाओं को सरल बनाने के जुनून के साथ एक समर्पित प्रौद्योगिकी उत्साही है। टेक उद्योग में एक दशक से अधिक के अनुभव के साथ, उन्होंने माइक्रोसॉफ्ट एक्सेल और आउटलुक के साथ-साथ गूगल शीट्स और डॉक्स में अपने कौशल को निखारा है। माइकल का ब्लॉग अपने ज्ञान और विशेषज्ञता को दूसरों के साथ साझा करने के लिए समर्पित है, उत्पादकता और दक्षता में सुधार के लिए आसान-से-अनुसरण युक्तियाँ और ट्यूटोरियल प्रदान करता है। चाहे आप एक अनुभवी पेशेवर हों या नौसिखिए, माइकल का ब्लॉग इन आवश्यक सॉफ़्टवेयर उपकरणों से अधिकाधिक लाभ उठाने के लिए मूल्यवान अंतर्दृष्टि और व्यावहारिक सलाह प्रदान करता है।