INDEX MATCH MATCH li Excel ji bo lêgerîna du-alî

Michael Brown

03-06-2023 Excel
  • Vê Parve Bikin
Michael Brown

Dersdar çend formulên cihêreng destnîşan dike da ku li Excel lêgerîna du-alî bikin. Tenê li alternatîfan mêze bikin û bijareya xwe hilbijêrin :)

Dema ku hûn li tiştek di pelgeyên xweya Excel-ê de digerin, pir caran hûn ê di stûnan de vertîkal an jî di rêzan de bi rengek horizontî bigerin. Lê carinan hûn hewce ne ku li her du rêz û stûnan binêrin. Bi gotinek din, hûn armanc dikin ku nirxek li hevberdana rêzek û stûnek diyar bibînin. Ji vê re tê gotin lêgerîna matrixê (ango 2-alî an lêgerîna 2-alî ), û ev tutorial nîşan dide ku meriv wê çawa bi 4 awayên cihêreng bike.

    Formula Excel INDEX MATCH MATCH

    Rêya herî populer a lêgerîna du-alî li Excel bi karanîna INDEX MATCH MATCH e. Ev guhertoyek ji formula klasîk a INDEX MATCH e ku hûn fonksiyonek MATCH lê zêde dikin da ku hûn hem jimareyên rêz û stûnan bistînin:

    INDEX ( data_array, MATCH ( vlookup_value, range_lookup_column, 0), MATCH ( nirxa hlookup, lookup_row_range, 0))

    Wek nimûne, ka em formulek çêbikin ku nifûsek bikişîne ji tabloya jêrîn di salek diyarî de heywanek diyar. Ji bo destpêkê, em hemî argumanan diyar dikin:

    • Data_array - B2:E4 (hucreyên daneyê, sernavên rêz û stûnan nagirin)
    • Vlookup_value - H1 (heywanê armanc)
    • Rêzika_stûna_lêgerînê - A2:A4 (sernivîsên rêzê: navên heywanan) -A3:A4
    • Hlookup_value - H2 (sala armanc)
    • Lêgerîn_row_range - B1:E1 (sernivîsên stûnê: sal)

    Hemû argumanan bidin hev û hûn ê vê formulê ji bo lêgerîna du-alî bistînin:

    =INDEX(B2:E4, MATCH(H1, A2:A4, 0), MATCH(H2, B1:E1, 0))

    Ev formula çawa dixebite

    Her çend dibe ku hinekî xuya bike di nihêrîna pêşîn de tevlihev e, mantiqa formula bi rastî rast û hêsan e ku tê fam kirin. Fonksiyona INDEX nirxek ji rêzika daneyê li ser bingeha hejmarên rêz û stûnê distîne, û du fonksiyonên MATCH van hejmaran peyda dikin:

    INDEX(B2:E4, row_num, column_num)

    Li vir, em şiyana MATCH(lookup_value,lookup_value) search_array, [match_type]) ji bo vegerandina pozîsyona têkildar ya lookup_value di lookup_array de.

    Ji ber vê yekê, ji bo bidestxistina hejmara rêzê, em lê digerin ji bo heywanê eleqedar (H1) li seranserê sernavên rêzê (A2:A4):

    MATCH(H1, A2:A4, 0)

    Ji bo ku hejmara stûnê bi dest bixin, em li sala armancê (H2) di sernavên stûnê de digerin. (B1:E1):

    MATCH(H2, B1:E1, 0)

    Di her du rewşan de, em bi danîna argumana sêyem li ser 0-yê li hevahengiya tam digerin.

    Di vê nimûneyê de, MATCHa yekem vedigere. 2 ji ber ku nirxa meya vlookupê (hirçê Polar) di A3 de tê dîtin, ku di A2 de şaneya 2yemîn e: A4. MATCHa duyemîn 3 vedigere ji ber ku nirxa hlookup (2000) di D1 de tê dîtin, ku hucreya 3mîn e di B1:E1 de.

    Li jor hatî dayîn, formula kêm dike:

    INDEX(B2:E4, 2, 3)

    Û nirxek li hevberdana rêza 2mîn û stûna 3yemîn a rêzika daneyê B2:E4 vegerîne, ku ev enirxa di şaneya D3 de.

    Formula VLOOKUP û MATCH ji bo lêgerîna 2-alî

    Rêyek din a lêgerîna du-alî ya li Excel bi karanîna tevhevkirina fonksiyonên VLOOKUP û MATCH e:

    VLOOKUP( vlookup_value , table_array , MATCH( hlookup_value , lookup_row_range , 0), FALSE)

    Ji bo tabloya nimûneya me , formula şeklê jêrîn digire:

    =VLOOKUP(H1, A2:E4, MATCH(H2, A1:E1, 0), FALSE)

    Li ku:

    • Table_array - A2:E4 (şaneyên daneyê tevî sernavên rêzê)
    • Vlookup_nirxa - H1 (heywanê_target)
    • Hlookup_nirxa - H2 (sala armanc)
    • Lookup_row_range - A1:E1 (sernivîsên stûnê: sal)

    Ev formula çawa dixebite

    Bêjeya formulê fonksiyona VLOOKUP e ku ji bo lihevhatina tam hatî mîheng kirin (argumana dawîn li ser FALSE hatî danîn), ku li nirxa lêgerînê (H1) di stûna yekem a rêzika tabloyê de (A2:E4) digere û nirxek ji stûnek din a di heman rêzê de vedigerîne. Ji bo ku diyar bikin ku meriv ji kîjan stûnê nirxek vegerîne, hûn fonksiyona MATCH-ê bikar tînin ku ew jî ji bo berhevdana tam hatî mîheng kirin (argumana paşîn li ser 0 hatî danîn):

    MATCH(H2, A1:E1, 0)

    MATCH li nirxê digere H2 li seranserê sernavên stûnê (A1: E1) û pozîsyona têkildar a şaneya hatî dîtin vedigerîne. Di doza me de, sala armanc (2010) di E1 de, ku di rêza lêgerînê de 5emîn e, tê dîtin. Ji ber vê yekê, hejmara 5 diçe argumana col_index_num ya VLOOKUP:

    VLOOKUP(H1, A2:E4, 5, FALSE)

    VLOOKUP wê ji wir digire, an jîJi bo nirxa lêgerîna wê ya di A2-ê de rast lihevhatî ye û nirxek ji stûna 5emîn a heman rêzê vedigerîne, ku ew şaneya E2 ye.

    Nîşeya girîng! Ji bo ku formula rast bixebite, divê tabloya_array (A2:E4) ya VLOOKUP û lookup_array ya MATCH (A1:E1) heman hejmara stûnan hebe, wekî din hejmara ku ji hêla MATCH ve derbas dibe. ji bo col_index_num dê xelet be (dê bi pozîsyona stûnê ya di tablo_array de negunca be).

    Fonksiyon XLOOKUP ku li rêz û stûnan binêre

    Di van demên dawî de Microsoft fonksiyonek din li Excel destnîşan kir ku tê vê wateyê ku hemî fonksiyonên lêgerînê yên heyî yên wekî VLOOKUP, HLOOKUP û INDEX MATCH veguherîne. Di nav tiştên din de, XLOOKUP dikare li hevberdana rêzek û stûnek taybetî binêre:

    XLOOKUP( value_vlookup_2>, vlookup_column_range , XLOOKUP( hlookup_value , hlookup_row_range , data_array ))

    Ji bo berhevoka daneyên nimûneya me, formula weha diçe:

    =XLOOKUP(H1, A2:A4, XLOOKUP(H2, B1:E1, B2:E4))

    Nîşe. Heya nuha XLOOKUP fonksiyonek beta ye, ku tenê ji bo aboneyên Office 365 yên ku beşek ji bernameya Office Insiders in, heye.

    Ev formula çawa dixebite

    Formula şiyana XLOOKUP-ê ji bo vegerandina an tevahiya rêz an stûn. Fonksiyona hundurîn di rêza sernavê de li sala armancê digere û hemî nirxên wê salê vedigerîne (di vê nimûneyê de, ji bo sala 1980). Ew nirx diçin argumana return_array ya derveXLOOKUP:

    XLOOKUP(H1, A2:A4, {22000;25000;700}))

    Fonksiyona XLOOKUP ya derve li ser sernivîsên stûnê li heywanê armanc digere û nirxê di heman pozîsyonê de ji rêzika vegera_vegerê vedigerîne.

    Formula SUMPRODUCT ji bo du -rêya lêgerînê

    Fonksiyon SUMPRODUCT di Excel de mîna kêrek Swîsreyî ye - ew dikare gelek tiştan ji armanca xwe ya destnîşankirî wêdetir bike, nemaze dema ku ew tê ser nirxandina pir pîvanan.

    Ji bo dîtina du pîvan, di rêz û stûnan de, vê formula giştî bikar bînin:

    SUMPRODUCT( vlookup_column_range = vlookup_value ) * ( hlookup_row_range = hlookup_value ), data_array )

    Ji bo ku di databasa me de lêgerînek 2-alî pêk bînin, formula weha diçe:

    =SUMPRODUCT((A2:A4=H1) * (B1:E1=H2), B2:E4)

    Sîntaksa jêrîn jî dê bixebite:

    =SUMPRODUCT((A2:A4=H1) * (B1:E1=H2) * B2:E4)

    Ev formula çawa dixebite

    Di bingeha formulê de, em du nirxên lêgerînê li hember sernavên rêz û stûnê (heywanê armanc di H1 de li hember hemî heywanan berhev dikin navên di A2:A4 de û sala armanc di H2 de li hember hemî salên B1:E1):

    (A2:A4=H1) * (B1:E1=H2)

    Ev res di 2 rêzikên nirxên TRUE û FALSE de cih digire, ku TRUE lihevhatinan nîşan dide:

    {FALSE;FALSE;TRUE} * {FALSE,TRUE,FALSE,FALSE}

    Operasyona pirjimariyê nirxên TRUE û FALSE di nav 1 û 0-an de dihêle û rêzek du-alî ya 4-an çêdike. stûn û 3 rêz (rêzik bi nîvkolonan û her stûna daneyan jî bi qertafekê têne veqetandin):

    {0,0,0,0;0,0,0,0;0,1,0,0}

    Fonksiyon SUMPRODUCT hêmanên rêzika jorîn bi hêmanênB2:E4 di heman cihan de:

    {0,0,0,0;0,0,0,0;0,1,0,0} * {22000,13800,8500,3500;25000,23000,22000,20000;700,2000,2300,2500}

    Û ji ber ku pirkirina bi sifirê sifir dide, di rêza yekem de tenê tişta ku bi 1-ê re têkildar e dijî:

    SUMPRODUCT({0,0,0,0;0,0,0,0;0,2000,0,0})

    Di dawiyê de, SUMPRODUCT hêmanên rêzika encamî zêde dike û nirxek 2000 vedigerîne.

    Nîşe. Ger tabloya we ji rêzek an/û sernivîsên stûnên bi heman navî zêdetir bin, rêzika paşîn dê ji jimarek ji bilî sifirê zêdetir hebin, û ew jimar dê tev werin zêdekirin. Wekî encamek, hûn ê komek nirxan bistînin ku her du pîvanan pêk tînin. Tiştê ku formula SUMPRODUCT ji INDEX MATCH MATCH û VLOOKUP-ê cuda dike, yên ku hevbera yekem hatî dîtin vedigerînin.

    Lêgerîna matrixê bi rêzikên binavkirî (Xeberdana eşkere)

    Rêyek din a ecêb hêsan lêgerîna matrixê ya li Excel bi karanîna rêzikên binavkirî ye. Bi vî awayî ye:

    Beş 1: Navê stûn û rêzan

    Rêya herî bilez a navkirina her rêz û stûnek di tabloya we de ev e:

    1. Tevahiya tabloyê hilbijêre (di rewşa me de A1:E4).
    2. Li ser tabloya Formulan , di koma Navên Diyarkirî de, bikirtînin Afirandin. ji Hilbijartinê an jî kurtebirra Ctrl + Shift + F3 bikirtînin.
    3. Di qutiya diyalogê de Navên ji Hilbijartinê biafirînin , Rêza jorîn û Çep hilbijêrin. stûn, û OK bikirtînin.

    Ev bixweber navan li gorî sernavên rêz û stûnan diafirîne. Lêbelê, çend hişyarî hene:

    • Heke stûna we û/anSernavên rêzan jimar in an jî tîpên taybetî hene ku di navên Excel de destûr nayê dayîn, navên stûn û rêzên weha nayên afirandin. Ji bo dîtina navnîşek navên çêkirî, Rêvebirê Navê vekin (Ctrl + F3). Ger hin nav winda nebin, wan bi destan diyar bikin wekî ku di Excel-ê de Navê rêzek çawa tê ravekirin.
    • Heke hin sernavên rêz an stûnên we valahiyan hebin, ew valahî dê bi xêzên jêrîn werin guheztin, mînakî, Polar_bear .

    Ji bo tabloya nimûneya me, Excel bixweber tenê navên rêzan afirandin. Navên stûnan divê bi destan bêne afirandin ji ber ku sernavên stûnan jimar in. Ji bo ku hûn vê yekê derbas bikin, hûn dikarin bi tenê jimareyan bi xêzên jêrîn bidin pêş, wek _1990 .

    Di encamê de, me rêzikên bi navên jêrîn hene:

    Beş 2 : Formulek lêgerîna matrixê çêbike

    Ji bo kişandina nirxek li hevberdana rêzek û stûnek diyarkirî, tenê yek ji formûlên gelemperî yên jêrîn di şaneyek vala de binivîsîne:

    = row_name navê_stûnê

    An jî berevajî:

    = navê_stûnê nav_row

    Mînakî, ji bo bidestxistina nifûsa kewarên şîn di sala 1990 de. , formula weha hêsan e:

    =Blue_whale _1990

    Heke kesek hewceyê rêwerzên berfirehtir be, gavên jêrîn dê we di pêvajoyê de rêve bibin:

    1. Di şaneyek de li cihê ku hûn dixwazin encam xuya bibe, nîşana wekheviyê binivîsin (=).
    2. Destpêkirina navê rêza mebestê binivîsin, bêje, Blue_whale . Piştîwe çend tîp nivîsandine, Excel dê hemî navên heyî yên ku têketina we li hev dikin nîşan bide. Navê ku tê xwestin du caran bikirtînin da ku wî têkevin formula xwe:
    3. Piştî navê rêzê, valahiyek binivîsin, ku wekî operatora hevberdanê di nav de kar dike. ev rewş.
    4. Navê stûna mebestê binivîse ( _1990 di rewşa me de).
    5. Gava ku navên rêz û stûnê her du têkevin, Excel dê rêz û stûna têkildar di tabloya we de ronî bike, û hûn Enter bişkînin da ku formula temam bikin:

    Lêgerîna matrixê ya we qediya, û dîmena jêrîn encamê nîşan dide:

    Bi vî rengî meriv di Excel de di rêz û stûnan de digerin. Ji bo xwendinê ez spasiya te dikim û hêvî dikim ku hefteya bê we li ser bloga xwe bibînim!

    Daxistinên berdest

    pirtûka xebatê ya nimûneya lêgerîna 2-alî

    Posta berê Fonksiyona TRANSPOSE-ê li Excel-ê ji bo guheztina stûnê li rêzê bi formula
    Posta paşîn Meriv çawa rêzan li Excel bi kurtebir û awayên din têxe

    Michael Brown dilxwazek teknolojiyê ya dilsoz e ku bi hewesek hêsankirina pêvajoyên tevlihev bi karanîna amûrên nermalavê ye. Bi zêdetirî deh salan ezmûnek di pîşesaziya teknolojiyê de, wî jêhatîbûna xwe di Microsoft Excel û Outlook, û her weha Google Sheets û Docs de pêş xist. Bloga Michael ji bo parvekirina zanyarî û pisporiya xwe bi kesên din re veqetandî ye, ji bo baştirkirina hilberî û karîgeriyê serişte û dersên hêsan-şopandinê peyda dike. Çi hûn pisporek demsalî ne an jî destpêkek in, bloga Michael ji bo ku hûn herî zêde ji van amûrên nermalava bingehîn sûd werbigirin, têgihiştinên hêja û şîretên pratîkî pêşkêşî dike.