Энэ заавар нь Excel дээр хоёр хэмжээст хайлт хийх хэд хэдэн өөр томъёог харуулсан. Альтернатив хувилбаруудыг хараад дуртай зүйлээ сонгоорой :)

Excel хүснэгтээс ямар нэг зүйл хайхдаа ихэнхдээ босоогоор багана эсвэл хэвтээ байдлаар мөрөнд хайдаг. Гэхдээ заримдаа та мөр, баганын аль алиныг нь харах хэрэгтэй болдог. Өөрөөр хэлбэл, та тодорхой мөр, баганын огтлолцол дээр утгыг олохыг зорьдог. Үүнийг матриц хайх ( 2 хэмжээст эсвэл 2 талын хайлт ) гэж нэрлэдэг бөгөөд энэ заавар нь үүнийг 4 өөр аргаар хэрхэн хийхийг харуулсан.

Excel INDEX MATCH MATCH томъёо

Excel дээр хоёр талын хайлт хийх хамгийн түгээмэл арга бол INDEX MATCH MATCH ашиглах явдал юм. Энэ бол мөр болон баганын дугаарыг хоёуланг нь авахын тулд та нэг MATCH функцийг нэмж өгөх сонгодог INDEX TATCH томьёоны хувилбар юм:

vlookup_value<2)>, баганын_муж , 0), MATCH ( hlookup утга , харах_мөрийн_муж , 0))

Жишээ нь, хүн амын тоог татах томьёог гаргая. тухайн жилийн тодорхой амьтныг доорх хүснэгтээс . Эхлэгчдэд бид бүх аргументуудыг тодорхойлно:

• Data_array - B2:E4 (мөр ба баганын толгойг оруулаагүй мэдээллийн нүднүүд)
• Vlookup_value - H1 (зорилтот амьтан)
• Баганын_мужийг хайх - A2:A4 (мөрийн толгой: амьтны нэр) -A3:A4
• Hlookup_value - H2 (зорилтот жил)
• Харах_мөрийн_муж - B1:E1 (баганын толгой: жил)

Бүх аргументуудыг нийлүүлбэл та хоёр талын хайлт хийх томъёог авах болно:

=INDEX(B2:E4, MATCH(H1, A2:A4, 0), MATCH(H2, B1:E1, 0))

Энэ томъёо хэрхэн ажилладаг вэ

Хэдийгээр энэ нь бага зэрэг харагдаж магадгүй юм. Эхлээд харахад нарийн төвөгтэй, томьёоны логик нь үнэхээр энгийн бөгөөд ойлгоход хялбар юм. INDEX функц нь мөр, баганын дугаар дээр тулгуурлан өгөгдлийн массиваас утгыг гаргаж авдаг бөгөөд хоёр MATCH функц нь эдгээр тоонуудыг нийлүүлдэг:

INDEX(B2:E4, row_num, column_num)

Энд бид MATCH(хайлтын_утга, хайлтын_массив, [тохируулах_төрөл]) харьцах_массив доторх харьцах_утга -ын харьцангуй байрлал -ыг буцаана.

Тиймээс мөрийн дугаарыг авахын тулд хайлт хийнэ. Мөрний толгойн (A2:A4) дээрх сонирхсон амьтны хувьд (H1):

MATCH(H1, A2:A4, 0)

Баганын дугаарыг авахын тулд бид баганын толгой хэсэгт зорилтот жилийг (H2) хайдаг. (B1:E1):

MATCH(H2, B1:E1, 0)

Хоёр тохиолдолд бид 3-р аргументыг 0 болгож яг тохирохыг хайдаг.

Энэ жишээнд эхний MATCH буцаана. 2 учир нь бидний vlookup утга (цагаан баавгай) нь A2:A4-ийн 2-р нүд болох A3-д байдаг. Хоёрдахь MATCH нь 3-ыг буцаана, учир нь hlookup утга (2000) нь B1:E1-ийн 3-р нүд болох D1-д олддог.

Дээр дурдсаныг харгалзан томъёо нь:

INDEX(B2:E4, 2, 3) <болж буурна. 3>

Мөн B2:E4 өгөгдлийн массивын 2-р мөр ба 3-р баганын огтлолцол дээрх утгыг буцаана.D3 нүдэн дэх утга.

2 талын хайлт хийх VLOOKUP болон TATCH томьёо

Excel дээр хоёр хэмжээст хайлт хийх өөр нэг арга бол VLOOKUP болон MATCH функцуудын хослолыг ашиглах явдал юм:

VLOOKUP( vlookup_value , хүснэгтийн_массив , MATCH( hlookup_value , харах_мөрийн_муж , 0), FALSE)

Манай жишээ хүснэгтийн хувьд , томъёо нь дараах хэлбэртэй байна:

=VLOOKUP(H1, A2:E4, MATCH(H2, A1:E1, 0), FALSE)

Үүнд:

• Хүснэгтийн_массив - A2:E4 (мөрний толгойг оруулаад өгөгдлийн нүднүүд)
• Vlookup_утга - H1 (зорилтот амьтан)
• Hlookup_value - H2 (зорилтот жил)
• Харах_мөрийн_муж - A1:E1 (баганын толгой: жил)

Энэ томьёо хэрхэн ажилладаг вэ

Томьёоны цөм нь яг тааруулахаар тохируулсан VLOOKUP функц юм (сүүлийн аргумент FALSE болгож тохируулна), энэ нь хүснэгтийн массивын эхний баганад (A2:E4) хайлтын утгыг (H1) хайж, ижил мөрийн өөр баганаас утгыг буцаана. Аль баганаас утгыг буцаахыг тодорхойлохын тулд та яг тааруулахаар тохируулсан MATCH функцийг ашигладаг (сүүлийн аргументыг 0 болгож тохируулсан):

MATCH(H2, A1:E1, 0)

MATCH дараах утгыг хайдаг. Баганын толгой дээрх H2 (A1:E1) ба олсон нүдний харьцангуй байрлалыг буцаана. Манай тохиолдолд зорилтот жил (2010) нь хайлтын массивын 5-р байранд байгаа E1-ээс олддог. Тэгэхээр 5-ын тоо VLOOKUP-ийн col_index_num аргумент руу очно:

VLOOKUP(H1, A2:E4, 5, FALSE)

VLOOKUP үүнийг тэндээс авч, олно.A2 дахь хайлтын утгатай яг таарч, ижил мөрийн 5-р баганаас E2 нүд болох утгыг буцаана.

Анхаарах зүйл! Томьёог зөв ажиллуулахын тулд VLOOKUP-н хүснэгтийн_массив (A2:E4) болон MATCH (A1:E1)-ийн харах_массив ижил тооны баганатай байх ёстой, эс тэгвээс тоо нь MATCH-р дамжсан байх ёстой. col_index_num -д оруулах нь буруу байх болно ( хүснэгтийн_массив дахь баганын байрлалд тохирохгүй).

Мөр болон багануудыг харах XLOOKUP функц

Саяхан Майкрософт Excel-д VLOOKUP, HLOOKUP, INDEX MATCH гэх мэт одоо байгаа бүх хайлтын функцийг орлуулах зорилготой дахин нэг функцийг нэвтрүүлсэн. Бусад зүйлсийн дотор XLOOKUP нь тодорхой мөр, баганын огтлолцлыг харж болно:

XLOOKUP( vlookup_value , vlookup_баганын_муж , XLOOKUP( hlookup_value , <1)>hlookup_row_range

Манай түүвэр өгөгдлийн багцын хувьд томъёо дараах байдалтай байна:

=XLOOKUP(H1, A2:A4, XLOOKUP(H2, B1:E1, B2:E4))

Тайлбар. Одоогоор XLOOKUP нь бета функц бөгөөд үүнийг зөвхөн Office Insider програмын нэг хэсэг болох Office 365-ийн захиалагчдад ашиглах боломжтой.

Энэ томьёо хэрхэн ажилладаг вэ

Томьёо нь XLOOKUP-ийн өгөгдлийг буцаах чадварыг ашигладаг. бүх мөр эсвэл багана. Дотоод функц нь толгойн мөрөнд зорилтот жилийг хайж, тухайн жилийн бүх утгыг буцаана (энэ жишээнд 1980 оны). Эдгээр утгууд нь гадна талын буцах_массив аргумент руу очноXLOOKUP:

XLOOKUP(H1, A2:A4, {22000;25000;700}))

Гадна XLOOKUP функц нь баганын толгой хэсэгт зорилтот амьтныг хайж, буцах_массивээс ижил байрлалд байгаа утгыг буцаана.

Хоёр дахь SUMPRODUCT томъёо -Ware search

SUMPRODUCT функц нь Excel-ийн Швейцарийн хутгатай адил бөгөөд энэ нь зориулалтын зорилгоосоо илүү олон зүйлийг хийж чадна, ялангуяа олон шалгуурыг үнэлэх үед.

Хоёрыг хайх мөр, баганын шалгуурт дараах ерөнхий томьёог ашиглана уу:

Өгөгдлийн багцад 2 чиглэлтэй хайлт хийхийн тулд томъёо дараах байдалтай байна:

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2), B2:E4)

Доорх синтакс мөн ажиллах болно:

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2) * B2:E4)

Энэ томьёо хэрхэн ажилладаг вэ

Томьёоны гол хэсэгт бид хайлтын хоёр утгыг мөр, баганын толгойн (H1 дэх зорилтот амьтныг бүх амьтдын эсрэг) харьцуулдаг. A2:A4 дахь нэрс ба Н2 дахь зорилтот жилийг B1:E1 дэх бүх жилүүдийн эсрэг):

(A2:A4=H1) * (B1:E1=H2)

Энэ res ҮНЭН ба ХУДАЛ утгуудын 2 массив дахь ults ба ҮНЭН нь таарч байна:

{FALSE;FALSE;TRUE} * {FALSE,TRUE,FALSE,FALSE}

Үржүүлэх үйлдэл нь ҮНЭН ба ХУДАЛ утгыг 1 ба 0 болгон шахаж, 4-ийн хоёр хэмжээст массив үүсгэдэг. багана ба 3 мөр (мөрүүдийг цэг таслалаар, өгөгдлийн багана бүрийг таслалаар тусгаарлана):

{0,0,0,0;0,0,0,0;0,1,0,0}

SUMPRODUCT функц нь дээрх массивын элементүүдийг дараах зүйлсээр үржүүлдэг.B2:E4 ижил байрлалд:

{0,0,0,0;0,0,0,0;0,1,0,0} * {22000,13800,8500,3500;25000,23000,22000,20000;700,2000,2300,2500}

Тэгээр үржүүлэхэд тэг гарах тул эхний массивын 1-д харгалзах зүйл л үлдэнэ:

SUMPRODUCT({0,0,0,0;0,0,0,0;0,2000,0,0})

Эцэст нь SUMPRODUCT нь үүссэн массивын элементүүдийг нэмж, 2000 утгыг буцаана.

Тэмдэглэл. Хэрэв таны хүснэгт ижил нэртэй нэгээс олон мөр эсвэл баганын толгойтой бол эцсийн массив нь тэгээс өөр нэгээс олон тоог агуулсан байх бөгөөд эдгээр бүх тоонууд нэмэгдэх болно. Үүний үр дүнд та хоёр шалгуурыг хангасан утгуудын нийлбэрийг авах болно. Энэ нь SUMPRODUCT томьёог эхний олдсон тааралтыг буцаадаг INDEX MATCH MATCH болон VLOOKUP-аас ялгаатай болгодог зүйл юм.

Нэрлэсэн муж бүхий матриц хайх (тодорхой огтлолцол)

Хийх өөр нэг гайхалтай энгийн арга. Excel дээрх матриц хайх нь нэрлэсэн мужуудыг ашиглан хийгддэг. Үүнд:

1-р хэсэг: Багана болон мөрүүдийг нэрлэх

Хүснэгт дээрх мөр, багана бүрийг нэрлэх хамгийн хурдан арга бол:

1. Хүснэгтийг бүхэлд нь сонгоно уу (манай тохиолдолд A1:E4).
2. Томъёо табын Тодорхой нэрс бүлгийн Үүсгэх товчийг дарна уу. Сонголт хэсгээс эсвэл Ctrl + Shift + F3 товчлолыг дарна уу.
3. Сонголтоос нэр үүсгэх харилцах цонхноос Дээд мөр ба Зүүн хэсгийг сонгоно уу. багана, ба OK дээр дарна уу.

Энэ нь мөр, баганын толгой хэсэгт тулгуурлан автоматаар нэр үүсгэдэг. Гэсэн хэдий ч, хэд хэдэн анхааруулга байна:

• Хэрэв таны багана болон/эсвэлмөрийн толгой хэсэг нь Excel-ийн нэрэнд зөвшөөрөгдөөгүй тоо эсвэл тодорхой тэмдэгт агуулсан байвал ийм багана, мөрийн нэрийг үүсгэхгүй. Үүсгэсэн нэрсийн жагсаалтыг харахын тулд Нэрийн менежерийг нээнэ үү ( Ctrl + F3 ). Хэрэв зарим нэр байхгүй бол тэдгээрийг Excel-ийн мужийг хэрхэн нэрлэх талаар тайлбарласны дагуу гараар тодорхойлно уу.
• Хэрэв таны зарим мөр эсвэл баганын толгой хэсэгт хоосон зай байгаа бол зайг доогуур зураасаар солино, жишээлбэл, Алтан гадас_баавгай .

Манай жишээ хүснэгтийн хувьд Excel автоматаар зөвхөн мөрийн нэрийг үүсгэсэн. Баганын толгой хэсэг нь тоо учраас баганын нэрийг гараар үүсгэх шаардлагатай. Үүнийг даван туулахын тулд та тоонуудын өмнө _1990 гэх мэт доогуур зураастай байхад л болно.

Үүний үр дүнд бид дараах нэрлэсэн мужууд байна:

2-р хэсэг : Матриц хайх томьёо хийх

Өгөгдсөн мөр, баганын огтлолцол дээр утгыг татахын тулд хоосон нүдэнд дараах ерөнхий томьёоны аль нэгийг бичнэ үү:

Эсвэл эсрэгээр:

Жишээ нь, 1990 онд хөх халимны тоо толгойг авахын тулд , томъёо нь маш энгийн:

=Blue_whale _1990

Хэрэв хэн нэгэнд илүү нарийвчилсан заавар хэрэгтэй бол дараах алхмууд нь танд үйл явцыг удирдан чиглүүлэх болно:

1. Нүүрэнд Үр дүнг харуулахыг хүсэж байгаа газар тэгш байдлын тэмдгийг (=) бичнэ үү.
2. Зорилтот мөрийн нэрийг бичиж эхлээрэй, Цэнхэр_халим гэж хэлээрэй. Дараа ньХэрэв та хэд хэдэн тэмдэгт бичсэн бол Excel таны оруулсан бүх нэрсийг харуулах болно. Хүссэн нэр дээрээ давхар товшоод томьёодоо оруулна уу:
3. Мөрийн нэрний ард зай бичнэ үү. энэ тохиолдол.
4. Зорилтот баганын нэрийг оруулна уу (манай тохиолдолд _1990 ).
5. Мөр болон баганын нэрийг хоёуланг нь оруулмагц Excel таны хүснэгтийн харгалзах мөр, баганыг тодруулах ба Enter дарж томьёог бөглөнө:

Таны матриц хайлт хийгдсэн бөгөөд доорх дэлгэцийн агшинд үр дүн гарч байна:

Excel дээр мөр, баганаас ингэж хайх боломжтой. Уншсан танд баярлалаа, дараа долоо хоногт манай блог дээр уулзана гэж найдаж байна!

Татаж авах боломжтой

2 хэмжээст хайлтын загвар ажлын ном