Ձեռնարկը ցուցադրում է մի քանի տարբեր բանաձեւեր Excel-ում երկչափ որոնում կատարելու համար: Պարզապես նայեք այլընտրանքներին և ընտրեք ձեր նախընտրածը :)

Երբ որոնում եք ինչ-որ բան ձեր Excel աղյուսակներում, ժամանակի մեծ մասը դուք նայում եք ուղղահայաց՝ սյունակներով կամ հորիզոնական՝ տողերով: Բայց երբեմն դուք պետք է նայեք թե՛ տողերին, թե՛ սյունակներին: Այլ կերպ ասած, դուք նպատակ ունեք որոշակի տողի և սյունակի հատման կետում արժեք գտնել: Սա կոչվում է մատրիցի որոնում (նույնը` երկչափ կամ երկկողմանի որոնում ), և այս ձեռնարկը ցույց է տալիս, թե ինչպես դա անել 4 տարբեր եղանակներով:

Excel INDEX MATCH MATCH բանաձև

Excel-ում երկկողմանի որոնում կատարելու ամենատարածված միջոցը INDEX MATCH MATCH-ի օգտագործումն է: Սա դասական INDEX MATCH բանաձևի տարբերակն է, որին ավելացնում եք ևս մեկ MATCH ֆունկցիա՝ և՛ տողերի, և՛ սյունակների համարները ստանալու համար՝

Որպես օրինակ, եկեք ստեղծենք բանաձև՝ պոպուլյացիա քաշելու համար որոշակի կենդանու տվյալ տարում ստորև բերված աղյուսակից: Սկզբի համար մենք սահմանում ենք բոլոր արգումենտները՝

• Տվյալների_զանգված - B2:E4 (տվյալների բջիջները, առանց տողերի և սյունակների վերնագրերի)
• Vlookup_value - H1 (թիրախային կենդանի)
• Որոնման_սյունակի_միջակայք - A2:A4 (տողերի վերնագրեր. կենդանիների անուններ) -A3:A4
• Hlookup_value - H2 (նպատակային տարի)
• Lookup_row_range - B1:E1 (սյունակների վերնագրեր. տարիներ)

Միավորեք բոլոր արգումենտները և կստանաք այս բանաձևը երկկողմանի որոնման համար.

=INDEX(B2:E4, MATCH(H1, A2:A4, 0), MATCH(H2, B1:E1, 0))

Ինչպես է աշխատում այս բանաձևը

Չնայած այն կարող է մի փոքր թվալ: առաջին հայացքից բարդ բանաձևի տրամաբանությունն իսկապես պարզ է և հեշտ հասկանալի: INDEX ֆունկցիան առբերում է արժեք տվյալների զանգվածից՝ հիմնված տողերի և սյունակների թվերի վրա, և երկու MATCH ֆունկցիաներ ապահովում են այդ թվերը.

INDEX(B2:E4, row_num, column_num)

Այստեղ մենք օգտագործում ենք MATCH(lookup_value, lookup_array, [match_type]) վերադարձնելու հարաբերական դիրք lookup_value lookup_array -ում:

Այսպիսով, տողի համարը ստանալու համար մենք որոնում ենք Հետաքրքիր կենդանու համար (H1) տողերի վերնագրերում (A2:A4):

MATCH(H1, A2:A4, 0)

Սյունակի համարը ստանալու համար մենք փնտրում ենք նպատակային տարին (H2) սյունակների վերնագրերում: (B1:E1):

MATCH(H2, B1:E1, 0)

Երկու դեպքում էլ մենք փնտրում ենք ճշգրիտ համընկնում` 3-րդ արգումենտը դնելով 0-ի վրա:

Այս օրինակում առաջին MATCH-ը վերադառնում է 2, քանի որ մեր vlookup արժեքը (Բևեռային արջ) գտնվում է A3-ում, որը A2:A4-ի 2-րդ բջիջն է: Երկրորդ MATCH-ը վերադարձնում է 3, քանի որ hlookup արժեքը (2000) գտնվում է D1-ում, որը B1:E1-ի 3-րդ բջիջն է:

Հաշվի առնելով վերը նշվածը, բանաձևը կրճատվում է մինչև՝

INDEX(B2:E4, 2, 3)

Եվ վերադարձրեք արժեք B2:E4 տվյալների զանգվածի 2-րդ տողի և 3-րդ սյունակի հատման կետում, որըարժեքը D3 բջիջում:

VLOOKUP և MATCH բանաձև երկկողմանի որոնման համար

Excel-ում երկչափ որոնում կատարելու մեկ այլ եղանակ է VLOOKUP և MATCH ֆունկցիաների համակցությունը օգտագործելը. 3> VLOOKUP( vlookup_value , table_array , MATCH( hlookup_value , lookup_row_range , 0), FALSE)

Մեր օրինակելի աղյուսակի համար , բանաձևը ստանում է հետևյալ ձևը.

=VLOOKUP(H1, A2:E4, MATCH(H2, A1:E1, 0), FALSE)

Որտեղ՝

• Աղյուսակի_զանգված - A2:E4 (տվյալների բջիջները, ներառյալ տողերի վերնագրերը)
• Vlookup_value - H1 (թիրախային կենդանի)
• Hlookup_value - H2 (նպատակային տարի)
• Տողի_որոնման_միջակայք - A1:E1 (սյունակների վերնագրեր. տարիներ)

Ինչպես է աշխատում այս բանաձևը

Բանաձևի առանցքը VLOOKUP ֆունկցիան է, որը կազմաձևված է ճշգրիտ համապատասխանության համար (վերջին արգումենտը սահմանված է FALSE), որը որոնում է որոնման արժեքը (H1) աղյուսակի զանգվածի առաջին սյունակում (A2:E4) և վերադարձնում արժեք նույն տողում գտնվող մեկ այլ սյունակից: Որոշելու համար, թե որ սյունակից վերադարձնել արժեքը, դուք օգտագործում եք MATCH ֆունկցիան, որը նույնպես կազմաձևված է ճշգրիտ համընկնման համար (վերջին արգումենտը սահմանվել է 0):

MATCH(H2, A1:E1, 0)

MATCH որոնում է արժեքը H2 սյունակների վերնագրերում (A1:E1) և վերադարձնում է գտնված բջիջի հարաբերական դիրքը: Մեր դեպքում թիրախային տարին (2010թ.) գտնվում է E1-ում, որը 5-րդն է որոնման զանգվածում: Այսպիսով, 5 թիվը գնում է VLOOKUP-ի col_index_num արգումենտին.

VLOOKUP(H1, A2:E4, 5, FALSE)

VLOOKUP-ը վերցնում է այն այնտեղից և գտնումճշգրիտ համընկնում է իր որոնման արժեքին A2-ում և վերադարձնում է արժեք նույն շարքի 5-րդ սյունակից, որը E2 բջիջն է:

Կարևոր նշում: Որպեսզի բանաձևը ճիշտ աշխատի, VLOOKUP-ի աղյուսակի_զանգվածը (A2:E4) և MATCH-ի որոնման_զանգվածը (A1:E1) պետք է ունենան նույն թվով սյունակներ, այլապես MATCH-ով փոխանցված թիվը: col_index_num -ը սխալ կլինի (չի համապատասխանի սյունակի դիրքին աղյուսակի_զանգվածում ):

XLOOKUP ֆունկցիան` տողերում և սյունակներում դիտելու համար

Վերջերս Microsoft-ը ներկայացրել է ևս մեկ գործառույթ Excel-ում, որը նախատեսված է փոխարինելու բոլոր առկա որոնման գործառույթները, ինչպիսիք են VLOOKUP, HLOOKUP և INDEX MATCH: Ի թիվս այլ բաների, XLOOKUP-ը կարող է դիտել որոշակի տողի և սյունակի հատման կետը՝

Մեր նմուշային տվյալների հավաքածուի համար բանաձևը հետևյալն է.

=XLOOKUP(H1, A2:A4, XLOOKUP(H2, B1:E1, B2:E4))

Նշում. Ներկայումս XLOOKUP-ը բետա ֆունկցիա է, որը հասանելի է միայն Office 365-ի բաժանորդներին, ովքեր Office Insiders ծրագրի մաս են կազմում:

Ինչպես է աշխատում այս բանաձևը

Բանաձևն օգտագործում է XLOOKUP-ի հնարավորությունը վերադարձնելու համար ամբողջ տող կամ սյունակ: Ներքին ֆունկցիան որոնում է նպատակային տարին վերնագրի տողում և վերադարձնում այդ տարվա բոլոր արժեքները (այս օրինակում՝ 1980 թվականի համար): Այդ արժեքները գնում են արտաքինի return_array արգումենտինXLOOKUP:

XLOOKUP(H1, A2:A4, {22000;25000;700}))

Արտաքին XLOOKUP ֆունկցիան որոնում է թիրախային կենդանուն սյունակների վերնագրերում և վերադարձնում է նույն դիրքում գտնվող արժեքը վերադարձի_զանգվածից:

SUMPRODUCT բանաձևը երկուսի համար: -way search

SUMPRODUCT ֆունկցիան նման է շվեյցարական դանակի Excel-ում. այն կարող է շատ բաներ անել իր նշանակված նպատակներից դուրս, հատկապես երբ խոսքը վերաբերում է բազմաթիվ չափանիշների գնահատմանը:

Որպեսզի փնտրել երկու չափանիշներ: չափանիշները տողերում և սյունակներում օգտագործեք այս ընդհանուր բանաձևը՝

Մեր տվյալների բազայում երկկողմանի որոնում կատարելու համար բանաձևը հետևյալն է.

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2), B2:E4)

Ստորև շարահյուսությունը նույնպես կաշխատի.

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2) * B2:E4) անունները A2:A4-ում և թիրախային տարին H2-ում բոլոր տարիների համեմատ B1:E1-ում):

(A2:A4=H1) * (B1:E1=H2)

Սա ults TRUE և FALSE արժեքների 2 զանգվածում, որտեղ TRUE-ները համընկնում են.

{FALSE;FALSE;TRUE} * {FALSE,TRUE,FALSE,FALSE}

Բազմապատկման գործողությունը ստիպում է TRUE և FALSE արժեքները վերածել 1-ի և 0-ի և արտադրել 4-ի երկչափ զանգված: սյունակներ և 3 տողեր (տողերը բաժանված են ստորակետերով, իսկ տվյալների յուրաքանչյուր սյունակ՝ ստորակետով):

{0,0,0,0;0,0,0,0;0,1,0,0}

SUMPRODUCT ֆունկցիան բազմապատկում է վերը նշված զանգվածի տարրերը հետևյալ կետերով.B2:E4 նույն դիրքերում՝

{0,0,0,0;0,0,0,0;0,1,0,0} * {22000,13800,8500,3500;25000,23000,22000,20000;700,2000,2300,2500}

Եվ քանի որ զրոյով բազմապատկելով զրո է ստացվում, առաջին զանգվածում պահպանվում է միայն 1-ին համապատասխանող տարրը՝

SUMPRODUCT({0,0,0,0;0,0,0,0;0,2000,0,0})

Վերջապես, SUMPRODUCT-ը գումարում է ստացված զանգվածի տարրերը և վերադարձնում 2000 արժեք:

Նշում. Եթե ​​ձեր աղյուսակը ունի նույն անունով մեկից ավելի տող կամ/կամ սյունակի վերնագիր, ապա վերջնական զանգվածը կպարունակի մեկից ավելի թվեր, բացի զրոյից, և այդ բոլոր թվերը կգումարվեն: Արդյունքում, դուք կստանաք արժեքների գումար, որոնք համապատասխանում են երկու չափանիշներին: Դա այն է, ինչը տարբերվում է SUMPRODUCT բանաձևից INDEX MATCH MATCH-ից և VLOOKUP-ից, որոնք վերադարձնում են առաջին հայտնաբերված համընկնումը:

Մատրիցային որոնում անվանված միջակայքերով (բացահայտ խաչմերուկ)

Կատարելու ևս մեկ զարմանալի պարզ միջոց Excel-ում մատրիցային որոնումն իրականացվում է անվանված տիրույթների օգտագործմամբ: Ահա թե ինչպես.

Մաս 1. Անվանեք սյունակներ և տողեր

Ձեր աղյուսակի յուրաքանչյուր տող և սյունակ անվանելու ամենաարագ ձևը հետևյալն է.

1. Ընտրեք ամբողջ աղյուսակը (մեր դեպքում A1:E4):
2. Բանաձևեր ներդիրում, Սահմանված անուններ խմբում սեղմեք Ստեղծել Selection կամ սեղմեք Ctrl + Shift + F3 դյուրանցումը:
3. Ստեղծել անուններ ընտրանքից երկխոսության դաշտում ընտրեք Վերին տող և Ձախ սյունակ, և սեղմեք OK:

Սա ինքնաբերաբար անուններ է ստեղծում տողերի և սյունակների վերնագրերի հիման վրա: Այնուամենայնիվ, կան մի քանի նախազգուշացումներ.

• Եթե ձեր սյունակը և/կամտողերի վերնագրերը թվեր են կամ պարունակում են հատուկ նիշեր, որոնք թույլատրված չեն Excel-ի անուններում, այդպիսի սյունակների և տողերի անունները չեն ստեղծվի: Ստեղծված անունների ցանկը տեսնելու համար բացեք Անունների կառավարիչը (Ctrl + F3): Եթե ​​որոշ անուններ բացակայում են, սահմանեք դրանք ձեռքով, ինչպես բացատրված է «Ինչպես անվանել միջակայք Excel-ում» բաժնում:
• Եթե ձեր տողերի կամ սյունակների վերնագրերից մի քանիսը բացատներ են պարունակում, բացատները կփոխարինվեն ընդգծումներով, օրինակ՝ <1:>Բևեռային_արջուկ ։

Մեր օրինակելի աղյուսակի համար Excel-ը ավտոմատ կերպով ստեղծել է միայն տողերի անունները: Սյունակների անունները պետք է ստեղծվեն ձեռքով, քանի որ սյունակների վերնագրերը թվեր են: Սա հաղթահարելու համար դուք կարող եք պարզապես թվերը նախաբանել ընդգծումներով, ինչպես օրինակ _1990 :

Արդյունքում մենք ունենք հետևյալ անվանվող միջակայքերը.

Մաս 2: Ստեղծեք մատրիցային որոնման բանաձև

Տրված տողի և սյունակի հատման կետում արժեք հանելու համար դատարկ բջիջում պարզապես մուտքագրեք հետևյալ ընդհանուր բանաձևերից մեկը.

Կամ հակառակը՝

Օրինակ՝ 1990 թվականին կապույտ կետերի պոպուլյացիան ստանալու համար , բանաձևը պարզ է.

=Blue_whale _1990

Եթե ինչ-որ մեկին ավելի մանրամասն հրահանգներ են պետք, հետևյալ քայլերը ձեզ կուղեկցեն այդ գործընթացում.

1. Բջջում որտեղ ցանկանում եք, որ արդյունքը հայտնվի, մուտքագրեք հավասարության նշանը (=):
2. Սկսեք մուտքագրել թիրախային շարքի անունը, ասենք, Կապույտ_կետ : հետոԴուք մուտքագրել եք մի քանի նիշ, Excel-ը կցուցադրի բոլոր առկա անունները, որոնք համապատասխանում են ձեր մուտքագրմանը: Կրկնակի սեղմեք ցանկալի անունը՝ այն ձեր բանաձևում մուտքագրելու համար.
3. Տողի անունից հետո մուտքագրեք բացատ , որը գործում է որպես հատման օպերատոր : այս դեպքում:
4. Մուտքագրեք թիրախային սյունակի անունը ( _1990 մեր դեպքում):
5. Հենց որ և՛ տողերի, և՛ սյունակների անունները մուտքագրվեն, Excel-ը ձեր աղյուսակում կնշի համապատասխան տողն ու սյունը, և դուք սեղմեք Enter՝ բանաձևը լրացնելու համար.

Ձեր մատրիցային որոնումն ավարտված է, և ստորև ներկայացված սքրինշոթը ցույց է տալիս արդյունքը. Շնորհակալ եմ կարդալու համար և հուսով եմ, որ հաջորդ շաբաթ կտեսնենք ձեզ մեր բլոգում:

Հասանելի ներբեռնումներ

2-չափ որոնում աշխատանքային գրքույկի օրինակ