Tutorial ini menampilkan beberapa rumus berbeda untuk melakukan pencarian dua dimensi di Excel. Lihat saja alternatifnya dan pilih favorit Anda :)

Ketika mencari sesuatu di spreadsheet Excel Anda, sebagian besar waktu Anda akan mencari secara vertikal di kolom atau secara horizontal di baris. Tetapi kadang-kadang Anda perlu mencari di kedua baris dan kolom. Dengan kata lain, Anda bertujuan untuk menemukan nilai di persimpangan baris dan kolom tertentu. Ini disebut pencarian matriks (alias 2-dimensi atau Pencarian 2 arah ), dan tutorial ini menunjukkan cara melakukannya dengan 4 cara berbeda.

Rumus INDEX MATCH MATCH Excel

Cara paling populer untuk melakukan pencarian dua arah di Excel adalah dengan menggunakan INDEX MATCH MATCH. Ini adalah variasi dari rumus INDEX MATCH klasik yang Anda tambahkan satu lagi fungsi MATCH untuk mendapatkan nomor baris dan kolom:

Sebagai contoh, mari kita buat rumus untuk menarik populasi hewan tertentu pada tahun tertentu dari tabel di bawah ini. Sebagai permulaan, kita definisikan semua argumen:

• Data_array - B2:E4 (sel data, tidak termasuk header baris dan kolom)
• Vlookup_value - H1 (hewan target)
• Lookup_column_range - A2:A4 (tajuk baris: nama hewan) - A3:A4
• Hlookup_value - H2 (tahun target)
• Lookup_row_range - B1:E1 (judul kolom: tahun)

Gabungkan semua argumen dan Anda akan mendapatkan rumus ini untuk pencarian dua arah:

=INDEX(B2:E4, MATCH(H1, A2:A4, 0), MATCH(H2, B1:E1, 0))

Bagaimana formula ini bekerja

Meskipun sekilas terlihat agak rumit, logika rumus ini sangat mudah dan mudah dipahami. Fungsi INDEX mengambil nilai dari larik data berdasarkan nomor baris dan kolom, dan dua fungsi MATCH memasok angka-angka tersebut:

INDEX(B2:E4, row_num, column_num)

Di sini, kita memanfaatkan kemampuan MATCH(lookup_value, lookup_array, [match_type]) untuk mengembalikan sebuah posisi relatif dari lookup_value di lookup_array .

Jadi, untuk mendapatkan nomor baris, kita mencari hewan yang diminati (H1) di seluruh header baris (A2:A4):

COCOKKAN(H1, A2:A4, 0)

Untuk mendapatkan nomor kolom, kita mencari tahun target (H2) di seluruh tajuk kolom (B1:E1):

COCOKKAN(H2, B1:E1, 0)

Dalam kedua kasus tersebut, kita mencari kecocokan yang tepat dengan menetapkan argumen ke-3 ke 0.

Dalam contoh ini, MATCH pertama mengembalikan 2 karena nilai vlookup kami (Beruang kutub) ditemukan di A3, yang merupakan sel ke-2 di A2: A4. MATCH kedua mengembalikan 3 karena nilai hlookup (2000) ditemukan di D1, yang merupakan sel ke-3 di B1: E1.

Dengan mengingat hal di atas, rumusnya berkurang menjadi:

INDEKS(B2:E4, 2, 3)

Dan mengembalikan nilai di persimpangan baris ke-2 dan kolom ke-3 dalam larik data B2: E4, yang merupakan nilai dalam sel D3.

Rumus VLOOKUP dan MATCH untuk pencarian 2 arah

Cara lain untuk melakukan pencarian dua dimensi di Excel adalah dengan menggunakan kombinasi fungsi VLOOKUP dan MATCH:

Untuk tabel sampel kita, rumusnya mengambil bentuk berikut ini:

=VLOOKUP(H1, A2:E4, MATCH(H2, A1:E1, 0), FALSE)

Di mana:

• Table_array - A2:E4 (sel data termasuk tajuk baris)
• Vlookup_value - H1 (hewan target)
• Hlookup_value - H2 (tahun target)
• Lookup_row_range - A1:E1 (judul kolom: tahun)

Bagaimana formula ini bekerja

Inti rumusnya adalah fungsi VLOOKUP yang dikonfigurasi untuk pencocokan tepat (argumen terakhir disetel ke FALSE), yang mencari nilai pencarian (H1) di kolom pertama larik tabel (A2: E4) dan mengembalikan nilai dari kolom lain di baris yang sama. Untuk menentukan kolom mana yang akan mengembalikan nilai, Anda menggunakan fungsi MATCH yang juga dikonfigurasi untuk pencocokan tepat (argumen terakhir disetel ke 0):

COCOKKAN(H2, A1:E1, 0)

MATCH mencari nilai dalam H2 di seluruh tajuk kolom (A1: E1) dan mengembalikan posisi relatif dari sel yang ditemukan. Dalam kasus kami, tahun target (2010) ditemukan di E1, yang berada di urutan ke-5 dalam array pencarian. col_index_num argumen dari VLOOKUP:

VLOOKUP(H1, A2:E4, 5, FALSE)

VLOOKUP mengambilnya dari sana, menemukan kecocokan yang tepat untuk nilai pencariannya di A2 dan mengembalikan nilai dari kolom ke-5 di baris yang sama, yaitu sel E2.

Catatan penting! Agar formula bekerja dengan benar, table_array (A2:E4) dari VLOOKUP dan lookup_array dari MATCH (A1:E1) harus memiliki jumlah kolom yang sama, jika tidak, angka yang diteruskan oleh MATCH ke col_index_num akan salah (tidak akan sesuai dengan posisi kolom di dalam table_array ).

Fungsi XLOOKUP untuk melihat dalam baris dan kolom

Baru-baru ini Microsoft telah memperkenalkan satu fungsi lagi di Excel yang dimaksudkan untuk menggantikan semua fungsi pencarian yang ada seperti VLOOKUP, HLOOKUP, dan INDEX MATCH. Antara lain, XLOOKUP dapat melihat perpotongan baris dan kolom tertentu:

Untuk set data sampel kami, rumusnya adalah sebagai berikut:

=XLOOKUP(H1, A2:A4, XLOOKUP(H2, B1:E1, B2:E4))

Catatan Saat ini XLOOKUP adalah fungsi beta, yang hanya tersedia untuk pelanggan Office 365 yang merupakan bagian dari program Office Insiders.

Bagaimana formula ini bekerja

Rumus ini menggunakan kemampuan XLOOKUP untuk mengembalikan seluruh baris atau kolom. Fungsi bagian dalam mencari tahun target di baris tajuk dan mengembalikan semua nilai untuk tahun itu (dalam contoh ini, untuk tahun 1980). Nilai-nilai itu masuk ke return_array argumen dari XLOOKUP luar:

XLOOKUP(H1, A2:A4, {22000;25000;700}))

Fungsi XLOOKUP luar mencari hewan target di seluruh tajuk kolom dan mengembalikan nilai di posisi yang sama dari return_array.

Rumus SUMPRODUCT untuk pencarian dua arah

Fungsi SUMPRODUCT seperti pisau Swiss di Excel - ia dapat melakukan banyak hal di luar tujuan yang ditentukan, terutama dalam hal mengevaluasi beberapa kriteria.

Untuk mencari dua kriteria, dalam baris dan kolom, gunakan rumus umum ini:

Untuk melakukan pencarian 2 arah dalam dataset kami, rumusnya adalah sebagai berikut:

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2), B2:E4)

Sintaks di bawah ini juga bisa digunakan:

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2) * B2:E4)

Bagaimana formula ini bekerja

Di jantung rumus, kita membandingkan dua nilai pencarian terhadap tajuk baris dan kolom (hewan target di H1 terhadap semua nama hewan di A2:A4 dan tahun target di H2 terhadap semua tahun di B1:E1):

(A2:A4=H1) * (B1:E1=H2)

Ini menghasilkan 2 larik nilai TRUE dan FALSE, di mana TRUE mewakili kecocokan:

{FALSE;FALSE;TRUE} * {FALSE,TRUE,FALSE,FALSE}

Operasi perkalian memaksa nilai TRUE dan FALSE menjadi 1 dan 0 dan menghasilkan larik dua dimensi yang terdiri dari 4 kolom dan 3 baris (baris dipisahkan oleh titik koma dan setiap kolom data oleh koma):

{0,0,0,0;0,0,0,0;0,1,0,0}

Fungsi SUMPRODUCT mengalikan elemen-elemen larik di atas dengan item B2:E4 pada posisi yang sama:

{0,0,0,0;0,0,0,0;0,1,0,0} * {22000,13800,8500,3500;25000,23000,22000,20000;700,2000,2300,2500}

Dan karena mengalikan dengan nol menghasilkan nol, hanya item yang berhubungan dengan 1 dalam larik pertama yang bertahan:

SUMPRODUCT({0,0,0,0;0,0,0,0;0,2000,0,0})

Akhirnya, SUMPRODUCT menjumlahkan elemen-elemen dari larik yang dihasilkan dan mengembalikan nilai 2000.

Catatan. Jika tabelmu memiliki lebih dari satu baris atau/dan tajuk kolom dengan nama yang sama, maka array terakhirnya akan berisi lebih dari satu angka selain nol, dan semua angka tersebut akan dijumlahkan. Hasilnya, kamu akan mendapatkan jumlah nilai yang memenuhi kedua kriteria tersebut. Hal inilah yang membuat rumus SUMPRODUCT berbeda dengan INDEX MATCH MATCH dan VLOOKUP, yang mengembalikan kecocokan yang ditemukan pertama kali.

Pencarian matriks dengan rentang bernama (Persimpangan eksplisit)

Satu lagi cara yang luar biasa sederhana untuk melakukan pencarian matriks di Excel adalah dengan menggunakan rentang bernama. Begini caranya:

Bagian 1: Nama kolom dan baris

Cara tercepat untuk menamai setiap baris dan setiap kolom dalam tabel Anda adalah sebagai berikut:

1. Pilih seluruh tabel (A1:E4 dalam kasus kita).
2. Pada Rumus tab, di tab Nama yang Ditetapkan kelompok, klik Buat dari Seleksi atau tekan pintasan Ctrl + Shift + F3.
3. Dalam Membuat Nama dari Seleksi kotak dialog, pilih Baris atas dan Kolom kiri, dan klik OK.

Ini secara otomatis menciptakan nama berdasarkan judul baris dan kolom. Namun demikian, ada beberapa peringatan:

• Jika tajuk kolom dan/atau baris Anda berupa angka atau berisi karakter tertentu yang tidak diperbolehkan dalam nama Excel, nama untuk kolom dan baris tersebut tidak akan dibuat. Untuk melihat daftar nama yang dibuat, buka Name Manager ( Ctrl + F3 ). Jika beberapa nama tidak ada, tentukan secara manual seperti yang dijelaskan di Cara memberi nama rentang di Excel.
• Jika sebagian header baris atau kolom Anda berisi spasi, spasi akan diganti dengan garis bawah, misalnya, Polar_bear .

Untuk tabel contoh kita, Excel secara otomatis hanya membuat nama barisnya saja. Nama kolomnya harus dibuat secara manual karena judul kolomnya berupa angka. Untuk mengatasinya, Anda cukup mengawali angkanya dengan garis bawah, seperti _1990 .

Sebagai hasilnya, kita memiliki rentang nama berikut ini:

Bagian 2: Membuat rumus pencarian matriks

Untuk menarik nilai di persimpangan baris dan kolom tertentu, cukup ketik salah satu rumus umum berikut dalam sel kosong:

Atau sebaliknya:

Misalnya, untuk mendapatkan populasi paus biru pada tahun 1990, rumusnya sesederhana:

=Blue_whale_1990

Jika seseorang memerlukan instruksi yang lebih terperinci, langkah-langkah berikut ini akan memandu Anda melalui prosesnya:

1. Dalam sel di mana Anda ingin hasilnya muncul, ketik tanda kesetaraan (=).
2. Mulailah mengetikkan nama baris target, katakanlah, Blue_whale Setelah kamu mengetikkan beberapa karakter, Excel akan menampilkan semua nama yang cocok dengan inputmu. Klik dua kali nama yang diinginkan untuk memasukkannya ke dalam rumusmu:
3. Setelah nama baris, ketik a ruang yang berfungsi sebagai operator persimpangan dalam kasus ini.
4. Masukkan nama kolom target ( _1990 dalam kasus kami).
5. Segera setelah nama baris dan kolom dimasukkan, Excel akan menyorot baris dan kolom yang sesuai dalam tabel Anda, dan Anda menekan Enter untuk menyelesaikan rumus:

Pencarian matriks Anda sudah selesai, dan screenshot di bawah ini menunjukkan hasilnya:

Itulah cara mencari dalam baris dan kolom di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

Buku kerja sampel pencarian 2-dimensi