Kwa mfano, tutengeneze fomula ya kuvuta idadi ya watu ya mnyama fulani katika mwaka fulani kutoka kwenye jedwali lililo hapa chini. Kwa wanaoanza, tunafafanua hoja zote:

• Data_array - B2:E4 (seli za data, bila kujumuisha vichwa vya safu mlalo na safu wima)
• Vlookup_value - H1 (mnyama lengwa)
• Masafa_ya_safu_ya_Tazama - A2:A4 (vichwa vya safu mlalo: majina ya wanyama) -A3:A4
• Thamani_ya_Hlookup - H2 (mwaka lengwa)
• Masafa_safu_ya_safu - B1:E1 (vichwa vya safu wima: miaka)

Weka hoja zote pamoja na utapata fomula hii ya utafutaji wa njia mbili:

=INDEX(B2:E4, MATCH(H1, A2:A4, 0), MATCH(H2, B1:E1, 0))

Jinsi fomula hii inavyofanya kazi

Ijapokuwa inaweza kuonekana kidogo. tata kwa mtazamo wa kwanza, mantiki ya fomula ni ya moja kwa moja na rahisi kuelewa. Chaguo za kukokotoa za INDEX hurejesha thamani kutoka kwa safu ya data kulingana na nambari za safu mlalo na safu wima, na vitendakazi viwili vya MATCH hutoa nambari hizo:

INDEX(B2:E4, row_num, column_num)

Hapa, tunaboresha uwezo wa MATCH(lookup_value, lookup_array, [match_type]) ili kurudisha nafasi jamaa ya lookup_value katika lookup_array .

Kwa hivyo, ili kupata nambari ya safu mlalo, tunatafuta kwa mnyama wa kupendeza (H1) kwenye vichwa vya safu mlalo (A2:A4):

MATCH(H1, A2:A4, 0)

Ili kupata nambari ya safu wima, tunatafuta mwaka lengwa (H2) kwenye vichwa vya safu wima. (B1:E1):

MATCH(H2, B1:E1, 0)

Katika hali zote mbili, tunatafuta inayolingana kabisa kwa kuweka hoja ya 3 kuwa 0.

Katika mfano huu, MATCH ya kwanza inarudi. 2 kwa sababu thamani yetu ya vlookup (Polar dubu) inapatikana katika A3, ambayo ni seli ya 2 katika A2:A4. MATCH ya pili inarejesha 3 kwa sababu thamani ya hlookup (2000) inapatikana katika D1, ambayo ni seli ya 3 katika B1:E1.

Kwa kuzingatia yaliyo hapo juu, fomula inapungua hadi:

INDEX(B2:E4, 2, 3)

Na urudishe thamani katika makutano ya safu mlalo ya 2 na safu wima ya 3 katika safu ya data B2:E4, ambayo nithamani katika kisanduku cha D3.

VLOOKUP na fomula ya MATCH ya kuangalia kwa njia 2

Njia nyingine ya kuangalia pande mbili katika Excel ni kwa kutumia mchanganyiko wa vitendaji vya VLOOKUP na MATCH:

Kwa sampuli ya jedwali letu , fomula inachukua umbo lifuatalo:

=VLOOKUP(H1, A2:E4, MATCH(H2, A1:E1, 0), FALSE)

Wapi:

• Table_array - A2:E4 (visanduku vya data ikijumuisha vichwa vya safu mlalo)
• Vlookup_value - H1 (mnyama lengwa)
• Hlookup_value - H2 (mwaka lengwa)
• Lookup_row_range - A1:E1 (vichwa vya safu wima: miaka)

Jinsi fomula hii inavyofanya kazi

Kiini cha fomula ni chaguo za kukokotoa za VLOOKUP zilizosanidiwa kwa ulinganifu kamili (hoja ya mwisho seti kuwa FALSE), ambayo hutafuta thamani ya utafutaji (H1) katika safu wima ya kwanza ya safu ya jedwali (A2:E4) na kurudisha thamani kutoka safu nyingine katika safu mlalo sawa. Kuamua ni safu ipi ya kurejesha thamani, unatumia chaguo la kukokotoa MATCH ambalo pia limesanidiwa kwa ulinganifu kamili (hoja ya mwisho imewekwa kuwa 0):

MATCH(H2, A1:E1, 0)

MATCH hutafuta thamani iliyo katika H2 kwenye vichwa vya safu wima (A1:E1) na hurejesha nafasi inayolingana ya kisanduku kilichopatikana. Kwa upande wetu, mwaka unaolengwa (2010) unapatikana katika E1, ambayo ni ya 5 katika safu ya utafutaji. Kwa hivyo, nambari 5 inakwenda kwa col_index_num hoja ya VLOOKUP:

VLOOKUP(H1, A2:E4, 5, FALSE)

VLOOKUP inaichukua kutoka hapo, inapatainayolingana kabisa na thamani yake ya kuangalia katika A2 na hurejesha thamani kutoka safu wima ya 5 katika safu mlalo sawa, ambayo ni kisanduku E2.

Dokezo muhimu! Ili fomula ifanye kazi kwa usahihi, jedwali_safu (A2:E4) ya VLOOKUP na lookup_array ya MATCH (A1:E1) lazima ziwe na idadi sawa ya safu wima, vinginevyo nambari itapitishwa na MATCH. hadi col_index_num itakuwa si sahihi (haitalingana na nafasi ya safu wima katika jedwali_array ).

Kitendakazi cha XLOOKUP ili kuangalia katika safu mlalo na safuwima

Hivi majuzi Microsoft imeanzisha chaguo jingine la kukokotoa katika Excel ambalo linakusudiwa kuchukua nafasi ya vitendakazi vyote vilivyopo kama vile VLOOKUP, HLOOKUP na INDEX MATCH. Miongoni mwa mambo mengine, XLOOKUP inaweza kuangalia makutano ya safu mlalo na safu mahususi:

Kwa sampuli ya seti yetu ya data, fomula huenda kama ifuatavyo:

=XLOOKUP(H1, A2:A4, XLOOKUP(H2, B1:E1, B2:E4))

Kumbuka. Kwa sasa XLOOKUP ni chaguo la kukokotoa la beta, ambalo linapatikana tu kwa watumiaji waliojisajili wa Office 365 ambao ni sehemu ya mpango wa Office Insiders.

Jinsi fomula hii inavyofanya kazi

Mfumo huu hutumia uwezo wa XLOOKUP kurejesha safu mlalo au safu nzima. Chaguo za kukokotoa za ndani hutafuta mwaka lengwa katika safu mlalo ya kichwa na kurejesha thamani zote za mwaka huo (katika mfano huu, kwa mwaka wa 1980). Thamani hizo huenda kwa return_array hoja ya njeXLOOKUP:

XLOOKUP(H1, A2:A4, {22000;25000;700}))

Kitendakazi cha nje cha XLOOKUP hutafuta mnyama lengwa kwenye vichwa vya safu wima na kurudisha thamani katika nafasi sawa kutoka kwa mkusanyiko_wa_rejesho.

fomula ya SUMPRODUCT ya mbili. -tafuta njia

Kitendaji cha SUMPRODUCT ni kama kisu cha Uswizi katika Excel - kinaweza kufanya mambo mengi zaidi ya madhumuni yake yaliyoainishwa, hasa inapokuja katika kutathmini vigezo vingi.

Kutafuta mbili. vigezo, katika safu mlalo na safu wima, tumia fomula hii ya jumla:

Ili kufanya uchunguzi wa njia 2 katika mkusanyiko wetu wa data, fomula huenda kama ifuatavyo:

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2), B2:E4)

Sintaksia iliyo hapa chini itafanya kazi pia:

=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2) * B2:E4)

Jinsi fomula hii inavyofanya kazi

Katika kiini cha fomula, tunalinganisha thamani mbili za utafutaji dhidi ya vichwa vya safu mlalo na safu wima (mnyama anayelengwa katika H1 dhidi ya wanyama wote. majina katika A2:A4 na mwaka unaolengwa katika H2 dhidi ya miaka yote katika B1:E1):

(A2:A4=H1) * (B1:E1=H2)

Hii res iko katika safu 2 za thamani za TRUE na FALSE, ambapo TRUE inawakilisha inalingana:

{FALSE;FALSE;TRUE} * {FALSE,TRUE,FALSE,FALSE}

Operesheni ya kuzidisha inalazimisha thamani za TRUE na FALSE kuwa 1 na 0 na kutoa safu ya miraba miwili ya 4. safu wima na safu mlalo 3 (safu hutenganishwa kwa nusukoloni na kila safu wima ya data kwa koma):

{0,0,0,0;0,0,0,0;0,1,0,0}

Utendaji wa SUMPRODUCT huzidisha vipengele vya safu iliyo hapo juu kwa vipengee vyaB2:E4 katika nafasi sawa:

{0,0,0,0;0,0,0,0;0,1,0,0} * {22000,13800,8500,3500;25000,23000,22000,20000;700,2000,2300,2500}

Na kwa sababu kuzidisha kwa sufuri kunatoa sifuri, ni kipengee kinacholingana na 1 pekee katika safu ya kwanza ndicho kitakachosalia:

SUMPRODUCT({0,0,0,0;0,0,0,0;0,2000,0,0})

Mwishowe, SUMPRODUCT huongeza vipengele vya safu inayotokana na kurejesha thamani ya 2000.

Kumbuka. Ikiwa jedwali lako lina zaidi ya safu mlalo moja au/na vichwa vya safu wima vyenye jina moja, safu ya mwisho itakuwa na zaidi ya nambari moja isipokuwa sifuri, na nambari hizo zote zitaongezwa. Kama matokeo, utapata jumla ya maadili ambayo yanakidhi vigezo vyote viwili. Ndiyo inayofanya fomula ya SUMPRODUCT kuwa tofauti na INDEX MATCH MATCH na VLOOKUP, ambayo hurejesha mechi ya kwanza iliyopatikana.

Utafutaji wa Matrix ulio na safu zilizotajwa (Mkutano ulio wazi)

Njia moja rahisi ajabu ya kufanya. uchunguzi wa matrix katika Excel ni kwa kutumia safu zilizotajwa. Hivi ndivyo unavyofanya:

Sehemu ya 1: Taja safu na safu mlalo

Njia ya haraka zaidi ya kutaja kila safu na kila safu katika jedwali lako ni hii:

1. Chagua jedwali zima (A1:E4 kwa upande wetu).
2. Kwenye kichupo cha Mfumo , katika kikundi cha Majina Yaliyoainishwa , bofya Unda kutoka kwa Uteuzi au bonyeza Ctrl + Shift + F3 njia ya mkato.
3. Katika Unda Majina kutoka kwa Uteuzi kisanduku cha mazungumzo, chagua Safu mlalo ya Juu na Kushoto. safu, na ubofye Sawa.

Hii huunda majina kiotomatiki kulingana na vichwa vya safu mlalo na safu wima. Hata hivyo, kuna tahadhari kadhaa:

• Ikiwa safu yako na/auVijajuu vya safu mlalo ni nambari au vina vibambo maalum ambavyo haviruhusiwi katika majina ya Excel, majina ya safuwima na safu mlalo kama hizo hayataundwa. Ili kuona orodha ya majina yaliyoundwa, fungua Kidhibiti cha Jina ( Ctrl + F3 ). Ikiwa baadhi ya majina hayapo, yabainishe wewe mwenyewe kama ilivyoelezwa katika Jinsi ya kutaja safu katika Excel.
• Ikiwa baadhi ya vichwa vya safu mlalo au safu wima yako vina nafasi, nafasi zitabadilishwa na mistari chini, kwa mfano, Polar_bear .

Kwa sampuli ya jedwali letu, Excel iliunda kiotomatiki majina ya safu mlalo pekee. Majina ya safu wima lazima yaundwe mwenyewe kwa sababu vichwa vya safu wima ni nambari. Ili kuondokana na hili, unaweza kutanguliza nambari kwa mistari chini, kama _1990 .

Kwa hivyo, tuna safu zifuatazo zilizopewa majina:

Sehemu ya 2 : Tengeneza fomula ya kuangalia matrix

Ili kuvuta thamani kwenye makutano ya safu mlalo na safu wima fulani, charaza tu mojawapo ya fomula zifuatazo za jumla katika kisanduku tupu:

Au kinyume chake:

Kwa mfano, kupata idadi ya nyangumi bluu mwaka wa 1990 , fomula ni rahisi kama:

=Blue_whale _1990

Iwapo mtu anahitaji maelekezo ya kina zaidi, hatua zifuatazo zitakusaidia katika mchakato:

1. Katika kisanduku ambapo unataka matokeo yaonekane, andika ishara ya usawa (=).
2. Anza kuandika jina la safu mlalo lengwa, sema, Blue_whale . Baada yaumeandika herufi kadhaa, Excel itaonyesha majina yote yaliyopo yanayolingana na ingizo lako. Bofya mara mbili jina unalotaka ili kuliweka katika fomula yako:
3. Baada ya jina la safu mlalo, andika nafasi , ambayo inafanya kazi kama opereta wa makutano katika kesi hii.
4. Ingiza jina la safu wima lengwa ( _1990 kwa upande wetu).
5. Mara tu majina ya safu mlalo na safu yanapoingizwa, Excel itaangazia safu mlalo na safu wima inayolingana katika jedwali lako, na ubonyeze Enter ili kukamilisha fomula:

Utafutaji wa tumbo lako umekamilika, na picha ya skrini iliyo hapa chini inaonyesha matokeo:

Hiyo ndiyo jinsi ya kuangalia katika safu mlalo na safu katika Excel. Ninakushukuru kwa kusoma na natumai kukuona kwenye blogu yetu wiki ijayo!

Vipakuliwa vinavyopatikana

kitabu cha sampuli ya utafutaji wa sura-2