Tutorialak "Excel badauka" formula-adibide batzuk eskaintzen ditu, xede-gelaxkak nahitaezko balio bat badu beste zutabe batean zerbait itzultzen erakusten dutenak, bat-etortze partzialarekin nola bilatu eta hainbat irizpide probatu EDO gisa. baita ETA logika ere.

Excel-en eginkizun ohikoenetako bat gelaxka batek balio interesgarri bat duen egiaztatzea da. Nolako balioa izan daiteke hori? Edozein testu edo zenbaki, testu zehatz edo edozein balio (ez gelaxka hutsik).

Excel-en "Gelak badu" formularen hainbat aldaera daude, aurkitu nahi dituzun balioen arabera. Orokorrean, IF funtzioa erabiliko duzu proba logiko bat egiteko, eta balio bat itzuliko duzu baldintza betetzen denean (gelaxkak dauka) eta/edo beste balio bat baldintza betetzen ez denean (gelaxkak ez dauka). Beheko adibideek agertokirik ohikoenak estaltzen dituzte.

Gelulak edozein balio badu,

Hasteko, ikus dezagun nola aurkitu ezer duten gelaxkak: edozein testua, zenbakia edo data. Horretarako, hutsik gabeko gelaxkak egiaztatzen dituen IF formula sinple bat erabiliko dugu.

For Adibidez, B zutabean "Ez hutsik" itzultzeko, errenkada bereko A zutabearen gelaxkak edozein balio badu, sartu hurrengo formula B2n, eta egin klik bikoitza beheko eskuineko izkinan dagoen karratu berde txikian formula behera kopiatzeko. duzutabea:

=IF(A2"", "Not blank", "")

Emaitza honen antzekoa izango da:

Gelulak testua badu, orduan

Zenbakiak eta datak alde batera utzita testu-balioak dituzten gelaxkak soilik aurkitu nahi badituzu, erabili IF ISTEXT funtzioarekin batera. Hona hemen beste gelaxka batean balioren bat itzultzeko formula generikoa xede-gelaxkak edozein testu badu:

Demagun, "bai" hitza B zutabean txertatu nahi duzula A zutabeko gelaxka batek testua badu. Hori egiteko, jarri formula hau B2-n:

=IF(ISTEXT(A2), "Yes", "")

Gelulak zenbakia badu,

Antzeko moduan. , zenbakizko balioekin (zenbakiak eta datak) dituzten gelaxkak identifikatu ditzakezu. Horretarako, erabili IF funtzioa ISNUMBER-rekin batera:

Ondoko formulak "bai" itzultzen du zutabean B A zutabeko dagokion gelaxkak edozein zenbaki badu:

=IF(ISNUMBER(A2), "Yes", "")

Gelulak testu zehatza badu

Testu jakin bat duten gelaxkak aurkitzea (edo zenbakiak edo datak) erraza da. Helburuko gelaxkak nahi duzun testua duen ala ez egiaztatzen duen IF formula arrunt bat idazten duzu, eta idatzi itzultzeko testua value_if_true argumentuan.

Adibidez, A2 gelaxkak "sagarrak" dituen jakiteko, erabili formula hau:

=IF(A2="apples", "Yes", "")

Gelulak zehatzik ez badutestua

Kontrako emaitza bilatzen ari bazara, hau da, beste zutabe bati balioren bat itzuli helburuko gelaxkak zehaztutako testua ("sagarrak") ez badu, egin hauetako bat.

Eman kate huts bat ("") value_if_true argumentuan eta itzultzeko testua value_if_false argumentuan:

=IF(A2="apples", "", "Not apples")

Edo , jarri "ez berdina" eragilea logical_test -n eta testua itzultzeko value_if_true:

=IF(A2"apples", "Not apples", "")

Edozein modura, formulak sortuko du. emaitza hau:

Gelhak testua badu: maiuskulak eta minuskulak bereizten dituen formula

Formula letra larriak eta minuskulak bereiztera behartzeko, erabili ZEHAZ funtzioa. bi testu-kateak guztiz berdinak diren egiaztatzen du, letra maiuskulak barne:

=IF(EXACT(A2,"APPLES"), "Yes", "")

Ereduzko testu-katea ere sar dezakezu gelaxka batean (esan C1), konpondu gelaxka-erreferentzia $ zeinuarekin ($C$1), eta alderatu xede-gelaxka gelaxka horrekin:

=IF(EXACT(A2,$C$1), "Yes", "")

Gelula bada testu-kate zehatza dauka (Parte-partziala)

Zeregin hutsalekin amaitu dugu eta erronka eta interesgarriagoetara pasa dugu :) Adibide honetan, hiru funtzio desberdin behar dira karaktere edo azpikate bat gelaxkako zati bat den jakiteko. edukia:

Barrutik lan egiten , hona hemen formulak zer egiten duen:

• TheBILATZAILEA funtzioak testu-kate bat bilatzen du, eta katea aurkitzen bada, lehenengo karakterearen posizioa itzultzen du, #BALIOA! errorea bestela.
• ISNUMBER funtzioak BILATZAILEAK arrakasta izan ala huts egin duen egiaztatzen du. SEARCH-ek edozein zenbaki itzuli badu, ISNUMBER EGIA ematen du. BILATZAILEAK errore bat sortzen badu, ISNUMERAK GEZURRA itzultzen du.
• Azkenik, IF funtzioak proba logikoan EGIA duten gelaxketarako zehaztutako balioa itzultzen du, kate huts bat ("") bestela.

Eta orain, ikus dezagun nola funtzionatzen duen formula generiko honek bizitza errealeko lan-orrietan.

Gelulak testu jakin bat badu, jarri balio bat beste gelaxka batean

Demagun zerrenda bat duzula. eskaerak A zutabean eta identifikatzaile zehatz batekin eskaerak aurkitu nahi dituzu, esan "A-". Egitekoa formula honekin bete daiteke:

=IF(ISNUMBER(SEARCH("A-",A2)),"Valid","")

Formulan katea gogor kodetu beharrean, beste gelaxka batean sar dezakezu (E1), zure formulako gelaxka horren erreferentzia. :

=IF(ISNUMBER(SEARCH($E$1,A2)),"Valid","")

Formulak behar bezala funtziona dezan, ziurtatu katea duen gelaxkaren helbidea $ zeinuarekin (zelula erreferentzia absolutua) blokeatu duzula.

Gelulak testu zehatza badu, kopiatu beste zutabe batera

Baliozko gelaxken edukia beste nonbait kopiatu nahi baduzu, eman ebaluatutako gelaxkaren helbidea (A2) value_if_true argumentuan:

=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")

Beheko pantaila-argazkiak emaitzak erakusten ditu:

Badagelaxkak testu zehatza dauka: maiuskulak eta minuskulak bereizten ditu formula

Aurreko bi adibideetan, formulek maiuskulak eta minuskulak bereizten dituzte. Maiuskulak eta minuskulak bereizten dituzten datuekin lan egiten duzun egoeretan, erabili BILATU funtzioa BILATU beharrean karaktereak bereizteko.

Adibidez, hurrengo formulak "A-" letra larria duten ordenak bakarrik identifikatuko ditu minuskulak alde batera utzita " a-".

=IF(ISNUMBER(FIND("A-",A2)),"Valid","")

Gelulak testu-kate askotako bat badu (EDO logika)

Gutxienez duten gelaxkak identifikatzeko bilatzen ari zaren gauza askotariko bat, erabili formula hauetako bat.

IF OR ZENBAKIAREN BILATZAILEA formula

Ikuspegirik nabarmenena azpikate bakoitza banan-banan egiaztatzea eta OR funtzioa izatea litzateke. itzul ezazu EGIA IF formularen proba logikoan gutxienez azpikate bat aurkitzen bada:

Demagun SKU zerrenda bat duzula A zutabean eta zuk "soinekoa" edo "gona" barne hartzen dutenak aurkitu nahi dituzu. Formula hau erabiliz egin dezakezu:

=IF(OR(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("skirt",A2))),"Valid ","")

Formulak nahiko ondo funtzionatzen du pare bat elementutarako, baina ez da modua. joan gauza asko egiaztatu nahi badituzu. Kasu honetan, hurbilketa hobe bat SUMPRODUCT funtzioa erabiltzea izango litzateke hurrengo adibidean erakusten den moduan.

SUMPRODUCT ISNUMBER IS BILAKETA formula

BadiraHainbat testu-kateei aurre eginez, kate bakoitza banan-banan bilatuz gero, formula luzeegia eta irakurtzeko zaila izango litzateke. Soluzio dotoreagoa izango litzateke ISNUMBER SEARCH konbinazioa SUMPRODUCT funtzioan txertatzea, eta ikusi emaitza zero baino handiagoa den:

Adibidez, A2-k D2:D4 gelaxketan sartutako hitzen bat duen jakiteko, erabili formula hau:

=SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0

Bestela, bilatu beharreko kateak dituen izen-barruti bat sor dezakezu, edo zuzenean eman hitzak formulan:

=SUMPRODUCT(--ISNUMBER(SEARCH({"dress","skirt","jeans"},A2)))>0

Edozein modura, emaitza honen antzekoa izango da:

Irteera erabilerrazagoa izan dadin, goiko formula IF funtzioan habia dezakezu eta zure testua itzul dezakezu EGIA/FALSE balioen ordez:

=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Valid", "")

Formula honek nola funtzionatzen duen

Muinean, ISNUMBER erabiltzen duzu BILATZAILEarekin batera, aurreko adibidean azaldu bezala. Kasu honetan, bilaketa-emaitzak {TRUE;FALSE;FALSE} bezalako array moduan irudikatzen dira. Gelaxka batek gutxienez zehaztutako azpikateetako bat badu, EGIA izango da matrizean. Eragile unario bikoitzak (--) TRUE / FALSE balioak 1 eta 0ra behartzen ditu, hurrenez hurren, eta {1;0;0} bezalako array bat ematen du. Azkenik, SUMPRODUCT funtzioak zenbakiak batzen ditu, eta emaitza zero baino handiagoa den gelaxkak hautatzen ditugu.

Bada.gelaxkak hainbat kate ditu (AND logika)

Zehaztutako testu-kate guztiak dituzten gelaxkak aurkitu nahi dituzun egoeretan, erabili dagoeneko ezaguna den ISNUMBER SEARCH konbinazioa IF AND:

Adibidez, "soinekoa" eta "urdina" duten SKUak aurki ditzakezu formula honekin:

=IF(AND(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("blue",A2))),"Valid ","")

Edo idatzi dezakezu kateak gelaxka bereizietan eta erreferentzia gelaxka horiek zure formulan:

=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2))),"Valid ","")

Konponbide alternatibo gisa, kate bakoitzaren agerraldiak zenbatu eta egiaztatu dezakezu. zenbaketa bakoitza zero baino handiagoa bada:

=IF(AND(COUNTIF(A2,"*dress*")>0,COUNTIF(A2,"*blue*")>0),"Valid","")

Emaitza goiko pantaila-argazkian erakusten den bezalakoa izango da.

Nola itzuli emaitza desberdinak gelaxka-balioan oinarrituta

Helburuko zutabeko gelaxka bakoitza beste elementu-zerrenda batekin alderatu eta bat-etortze bakoitzerako balio ezberdin bat itzuli nahi baduzu, erabili ikuspegi hauetako bat.

Habiratua. IFs

Habiaraturiko IF formularen logika hau bezain erraza da: IF funtzio bereizia erabiltzen duzu baldintza bakoitza probatzeko, eta balio desberdinak itzultzen ditu proba horien emaitzen arabera.

Demagun A zutabean elementuen zerrenda bat duzula eta haien laburdurak B zutabean eduki nahi dituzula. Hori egiteko, erabili formula hau:

=IF(A2="apple", "Ap", IF(A2="avocado", "Av", IF(A2="banana", "B", IF(A2="lemon", "L", ""))))

Habiaratutako IF-ren sintaxiari eta logikari buruzko xehetasun osoak lortzeko, ikus Excel habiaratutako IF - baldintza anitz formula bakarrean.

Bilaketa formula

Gehiago bat bilatzen ari bazara. formula trinkoa eta ulergarriagoa dena, erabili BILATU funtzioa matrize bertikaleko konstante gisa emandako bilaketa eta itzulera balioekin:

Emaitza zehatzak lortzeko, ziurtatu bilaketa-balioak ordena alfabetikoan zerrendatzen dituzula, A-tik Z-ra.

=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})

Habiaratutako IFekin alderatuta, Bilaketa formulak abantaila gehiago du: komodinak<10 ulertzen ditu> eta, beraz, parekatze partzialak identifikatu ditzake.

Adibidez, A zutabeak sorta batzuk baditu bananen, "*banana*" bila dezakezu eta laburdura bera ("B") itzul dezakezu zelula guztietarako:

=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})

Informazio gehiago lortzeko, ikusi Bilaketa-formula habiaratu diren IF-en alternatiba gisa.

Vlookup formula

Datu aldagai-multzo batekin lan egiten duzunean, erosoagoa izan daiteke bat-etorketen zerrenda bereizita sartzea. zelulak eta berreskuratu Vlookup formula bat erabiliz,adibidez:

=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )

Informazio gehiago lortzeko, ikusi Excel VLOOKUP tutoriala hasiberrientzako.

Horrela egiaztatzen duzu gelaxka bat. Excel-en edozein balio edo testu zehatz dauka. Datorren astean, Excel-en gelaxkak formulak baditu aztertzen jarraituko dugu eta gelaxka garrantzitsuak zenbatzen edo batutzen ikasiko dugu, kopiatu edo kendu gelaxka horiek dituzten errenkada osoak eta abar. Mesedez, egon adi!

Lan itzazu lan-koadernoa

Gelaxkak baditu Excel - formula adibideak (.xlsx fitxategia)