Mafunzo hutoa idadi ya mifano ya fomula ya "Excel ikiwa ina" ambayo inaonyesha jinsi ya kurejesha kitu katika safu wima nyingine ikiwa kisanduku lengwa kina thamani inayohitajika, jinsi ya kutafuta kwa kutumia sehemu inayolingana na kujaribu vigezo vingi kwa AU kama. pamoja na NA mantiki.

Mojawapo ya kazi za kawaida katika Excel ni kuangalia kama kisanduku kina thamani ya riba. Hiyo inaweza kuwa thamani ya aina gani? Maandishi au nambari yoyote, maandishi mahususi, au thamani yoyote kabisa (si kisanduku tupu).

Kuna tofauti kadhaa za fomula ya "Ikiwa kisanduku kina" katika Excel, kulingana na ni thamani gani hasa unataka kupata. Kwa ujumla, utatumia chaguo la kukokotoa la IF kufanya jaribio la kimantiki, na kurudisha thamani moja hali inapofikiwa (kisanduku kina) na/au thamani nyingine wakati hali haijatimizwa (kisanduku hakina). Mifano iliyo hapa chini inashughulikia matukio ya mara kwa mara.

Ikiwa kisanduku kina thamani yoyote, basi

Kwa kuanzia, hebu tuone jinsi ya kupata visanduku vilivyo na chochote: yoyote. maandishi, nambari au tarehe. Kwa hili, tutatumia fomula rahisi ya IF ambayo hukagua visanduku visivyo tupu.

Kwa kwa mfano, kurudisha "Si tupu" katika safu wima B ikiwa kisanduku A katika safu mlalo sawa kina thamani yoyote, unaweka fomula ifuatayo katika B2, kisha ubofye mara mbili mraba mdogo wa kijani katika kona ya chini kulia ili kunakili fomula chini. yasafu:

=IF(A2"", "Not blank", "")

matokeo yatafanana na haya:

Ikiwa kisanduku kina maandishi, basi

Ikiwa ungependa kupata visanduku pekee vilivyo na thamani za maandishi zinazopuuza nambari na tarehe, basi tumia IF pamoja na chaguo za kukokotoa za ISTEXT. Hii ndio fomula ya jumla ya kurudisha thamani fulani katika kisanduku kingine ikiwa kisanduku lengwa kina maandishi yoyote :

Tuseme, unataka kuingiza neno "ndiyo" katika safu wima B ikiwa kisanduku katika safu wima A kina maandishi. Ili kuifanya, weka fomula ifuatayo katika B2:

=IF(ISTEXT(A2), "Yes", "")

Ikiwa kisanduku kina nambari, basi

Kwa mtindo sawa , unaweza kutambua visanduku vilivyo na nambari za nambari (nambari na tarehe). Kwa hili, tumia chaguo la kukokotoa la IF pamoja na ISNUMBER:

Mfumo ifuatayo inarejesha "ndiyo" katika safu wima. B ikiwa kisanduku sambamba katika safu wima A kina nambari yoyote:

=IF(ISNUMBER(A2), "Yes", "")

Ikiwa kisanduku kina maandishi maalum

Kutafuta visanduku vilivyo na maandishi fulani. (au nambari au tarehe) ni rahisi. Unaandika fomula ya kawaida ya IF ambayo hukagua ikiwa kisanduku lengwa kina maandishi unayotaka, na kuandika maandishi ili kurejesha katika hoja ya value_if_true .

Kwa mfano, ili kujua kama kisanduku A2 kina "tufaha", tumia fomula hii:

=IF(A2="apples", "Yes", "")

Ikiwa kisanduku hakina mahususimaandishi

Ikiwa unatafuta matokeo tofauti, yaani, rudisha thamani fulani kwenye safu wima nyingine ikiwa kisanduku lengwa hakina maandishi maalum ("apples"), basi fanya mojawapo ya yafuatayo.

Toa mfuatano tupu ("") katika hoja ya value_if_true , na maandishi ya kurejesha katika value_if_false hoja:

=IF(A2="apples", "", "Not apples")

Au , weka opereta "si sawa na" katika logical_test na maandishi ya kurejesha katika value_if_true:

=IF(A2"apples", "Not apples", "")

Kwa vyovyote vile, fomula itatoa tokeo hili:

Ikiwa kisanduku kina maandishi: fomula nyeti kwa kadiri

Ili kulazimisha fomula yako kutofautisha herufi kubwa na ndogo, tumia kitendakazi EXACT ambacho hukagua kama mifuatano miwili ya maandishi ni sawa kabisa, ikijumuisha herufi:

=IF(EXACT(A2,"APPLES"), "Yes", "")

Unaweza pia kuingiza mfuatano wa mfuatano wa maandishi katika kisanduku fulani (sema kwa ndani. C1), rekebisha rejeleo la kisanduku kwa ishara ya $ ($C$1), na ulinganishe kisanduku lengwa na kisanduku hicho:

=IF(EXACT(A2,$C$1), "Yes", "")

Ikiwa kisanduku ina mfuatano maalum wa maandishi (sehemu inayolingana)

Tumemaliza na majukumu madogo na kuendelea na yale magumu na ya kuvutia zaidi :) Katika mfano huu, inachukua vipengele vitatu tofauti ili kujua ikiwa herufi au kamba ndogo ni sehemu ya seli. yaliyomo:

Kufanya kazi kutoka ndani kwenda nje , hii ndio fomula hufanya:

• TheChaguo za kukokotoa za TAFUTA hutafuta mfuatano wa maandishi, na mfuatano ukipatikana, hurejesha nafasi ya herufi ya kwanza, #VALUE! hitilafu vinginevyo.
• Chaguo za kukokotoa za ISNUMBER hukagua kama SEARCH ilifaulu au imeshindwa. Ikiwa SEARCH imerudisha nambari yoyote, ISNUMBER itarejesha TRUE. Ikiwa SEARCH itasababisha hitilafu, ISNUMBER hurejesha FALSE.
• Mwishowe, chaguo za kukokotoa za IF hurejesha thamani iliyobainishwa kwa seli ambazo zina TRUE katika jaribio la kimantiki, mfuatano tupu ("") vinginevyo.

Na sasa, hebu tuone jinsi fomula hii ya jumla inavyofanya kazi katika laha-kazi halisi.

Ikiwa kisanduku kina maandishi fulani, weka thamani katika kisanduku kingine

Tuseme una orodha ya maagizo katika safu A na unataka kupata maagizo na kitambulisho maalum, sema "A-". Jukumu linaweza kukamilishwa kwa fomula hii:

=IF(ISNUMBER(SEARCH("A-",A2)),"Valid","")

Badala ya kuweka msimbo mgumu katika fomula, unaweza kuiingiza katika kisanduku tofauti (E1), marejeleo ya kisanduku hicho katika fomula yako. :

=IF(ISNUMBER(SEARCH($E$1,A2)),"Valid","")

Ili fomula ifanye kazi ipasavyo, hakikisha kuwa umefunga anwani ya kisanduku kilicho na mfuatano kwa ishara $ (marejeleo kamili ya seli).

Ikiwa kisanduku kina maandishi mahususi, nakili hadi safuwima nyingine

Ikiwa ungependa kunakili maudhui ya seli sahihi mahali pengine, toa tu anwani ya kisanduku kilichotathminiwa (A2) katika thamani_kama_kweli hoja:

=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")

Picha ya skrini iliyo hapa chini inaonyesha matokeo:

Ikiwakisanduku kina maandishi mahususi: fomula nyeti kulingana na kadhia

Katika mifano yote miwili iliyo hapo juu, fomula hazijali ukubwa wa kesi. Katika hali unapofanya kazi na data ambayo ni nyeti kwa herufi, tumia kipengele cha KUTAFUTA badala ya TAFUTA ili kutofautisha herufi.

Kwa mfano, fomula ifuatayo itatambua tu maagizo yenye herufi kubwa "A-" ikipuuza herufi ndogo " a-".

=IF(ISNUMBER(FIND("A-",A2)),"Valid","")

Ikiwa kisanduku kina mojawapo ya mifuatano mingi ya maandishi (AU mantiki)

Ili kutambua visanduku vilivyo na angalau mojawapo ya mambo mengi unayotafuta, tumia mojawapo ya fomula zifuatazo.

IF AU ISNUMBER SEARCH formula

Njia iliyo dhahiri zaidi itakuwa kuangalia kila mfuatano mdogo mmoja mmoja na kuwa na AU kitendakazi. rudisha TRUE katika jaribio la kimantiki la fomula ya IF ikiwa angalau mfuatano mmoja utapatikana:

Tuseme una orodha ya SKU kwenye safu wima A na wewe wanataka kupata zile zinazojumuisha ama "mavazi" au "sketi". Unaweza kuifanya kwa kutumia fomula hii:

=IF(OR(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("skirt",A2))),"Valid ","")

Mchanganyiko huo hufanya kazi vizuri kwa vipengee kadhaa, lakini kwa hakika si njia ya kufanya hivyo. nenda kama unataka kuangalia mambo mengi. Katika hali hii, mbinu bora itakuwa kutumia chaguo za kukokotoa za SUMPRODUCT kama inavyoonyeshwa katika mfano unaofuata.

fomula ya SUMPRODUCT ISNUMBER SEARCH

Ikiwa ukokushughulika na mifuatano mingi ya maandishi, kutafuta kila mfuatano mmoja mmoja kunaweza kufanya fomula yako kuwa ndefu na ngumu kusoma. Suluhisho maridadi zaidi litakuwa kupachika mchanganyiko wa ISNUMBER SEARCH kwenye kitendakazi cha SUMPRODUCT, na uone kama tokeo ni kubwa kuliko sufuri:

Kwa mfano, ili kujua kama A2 ina maneno yoyote ya ingizo katika seli D2:D4, tumia fomula hii:

=SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0

Mbadala, unaweza kuunda safu iliyotajwa iliyo na mifuatano ya kutafuta, au kutoa maneno moja kwa moja katika fomula:

=SUMPRODUCT(--ISNUMBER(SEARCH({"dress","skirt","jeans"},A2)))>0

Kwa vyovyote vile, matokeo yatakuwa sawa na haya:

Ili kufanya pato lifae mtumiaji zaidi, unaweza kuweka fomula iliyo hapo juu kwenye chaguo za kukokotoa za IF na urudishe maandishi yako badala ya thamani za TRUE/FALSE:

=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Valid", "")

Jinsi fomula hii inavyofanya kazi

Katika msingi, unatumia ISNUMBER pamoja na SEARCH kama ilivyoelezwa katika mfano uliopita. Katika hali hii, matokeo ya utafutaji yanawakilishwa katika mfumo wa mkusanyiko kama {TRUE;FALSE;FALSE}. Ikiwa kisanduku kina angalau kifungu kidogo kimoja kilichobainishwa, kutakuwa na TRUE katika safu. Opereta mara mbili isiyo ya kawaida (--) hulazimisha thamani za TRUE / FALSE hadi 1 na 0, mtawalia, na kutoa safu kama {1;0;0}. Hatimaye, chaguo la kukokotoa la SUMPRODUCT linaongeza nambari, na tunachagua seli ambapo matokeo ni makubwa kuliko sufuri.

Ikiwaseli ina mifuatano kadhaa (NA mantiki)

Katika hali unapotaka kupata visanduku vilivyo na mifuatano yote ya maandishi iliyobainishwa, tumia mseto unaojulikana tayari wa ISNUMBER SEARCH pamoja na IF AND:

Kwa mfano, unaweza kupata SKU zenye "dress" na "blue" kwa fomula hii:

=IF(AND(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("blue",A2))),"Valid ","")

Au, unaweza kuandika mifuatano katika seli tofauti na kurejelea visanduku hivyo katika fomula yako:

=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2))),"Valid ","")

Kama suluhu mbadala, unaweza kuhesabu matukio ya kila mfuatano na kuangalia ikiwa kila hesabu ni kubwa kuliko sifuri:

=IF(AND(COUNTIF(A2,"*dress*")>0,COUNTIF(A2,"*blue*")>0),"Valid","")

matokeo yatakuwa kama inavyoonyeshwa kwenye picha ya skrini hapo juu.

Jinsi ya kurejesha matokeo tofauti kulingana na thamani ya seli

Iwapo ungependa kulinganisha kila kisanduku kwenye safu wima lengwa dhidi ya orodha nyingine ya vipengee na kurudisha thamani tofauti kwa kila mechi, tumia mojawapo ya mbinu zifuatazo.

Nested IFs

mantiki ya fomula ya IF iliyoorodheshwa ni rahisi kama hii: unatumia chaguo tofauti za kukokotoa za IF kujaribu kila hali, na kurudisha thamani tofauti kulingana na matokeo ya majaribio hayo.

Tuseme una orodha ya vipengee kwenye safu wima A na unataka vifupisho vyake viwe kwenye safu wima B. Ili kufanya hivyo, tumia fomula ifuatayo:

=IF(A2="apple", "Ap", IF(A2="avocado", "Av", IF(A2="banana", "B", IF(A2="lemon", "L", ""))))

Kwa maelezo kamili kuhusu sintaksia na mantiki ya IF iliyowekewa kiota, tafadhali angalia Excel iliyoorodheshwa IF - hali nyingi katika fomula moja.

Mfumo wa kutafuta

Ikiwa unatafuta zaidi fomula iliyoshikana na inayoeleweka vyema zaidi, tumia kitendakazi cha LOOKUP pamoja na kuangalia na kurejesha thamani zinazotolewa kama safu wima za safu wima:

Kwa matokeo sahihi, hakikisha kuwa umeorodhesha thamani za utafutaji katika mfuatano wa alfabeti , kutoka A hadi Z.

=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})

Ikilinganishwa na IF zilizowekwa kiota, fomula ya Kutafuta ina faida moja zaidi - inaelewa herufi za mwitu na kwa hivyo inaweza kutambua sehemu zinazolingana.

Kwa mfano, ikiwa safu wima A ina aina chache ya ndizi, unaweza kutafuta "*ndizi*" na urejeshe ufupisho sawa ("B") kwa visanduku vyote kama hivyo:

=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})

Kwa maelezo zaidi, tafadhali angalia fomula ya Kutafuta kama njia mbadala ya IF zilizowekwa kwenye kiota.

Fomula ya Vlookup

Unapofanya kazi na seti tofauti ya data, inaweza kuwa rahisi zaidi kuweka orodha ya zinazolingana katika tofauti. seli na kuzipata kwa kutumia fomula ya Vlookup,k.m.:

=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )

Kwa maelezo zaidi, tafadhali angalia mafunzo ya Excel VLOOKUP kwa wanaoanza.

Hivi ndivyo unavyoangalia kama kisanduku kikiwa na seli. ina thamani yoyote au maandishi maalum katika Excel. Wiki ijayo, tutaendelea kuangalia kama kisanduku cha Excel kina fomula na tujifunze jinsi ya kuhesabu au kujumlisha visanduku vinavyofaa, kunakili au kuondoa safu mlalo zote zilizo na seli hizo, na zaidi. Tafadhali subiri!

Kitabu cha mazoezi

Excel Ikiwa Kiini Ina - mifano ya fomula (faili.xlsx)