Šajā pamācībā ir sniegti vairāki "Excel if contains" formulas piemēri, kuros parādīts, kā atgriezt kaut ko citā slejā, ja mērķa šūnā ir vajadzīgā vērtība, kā meklēt ar daļēju atbilstību un pārbaudīt vairākus kritērijus, izmantojot OR, kā arī AND loģiku.

Viens no visbiežāk sastopamajiem uzdevumiem programmā Excel ir pārbaudīt, vai šūnā ir kāda vērtība. Kāda veida vērtība tā var būt? Vienkārši jebkurš teksts vai skaitlis, konkrēts teksts vai jebkura vērtība vispār (nevis tukša šūna).

Excel programmā ir vairāki formulas "Ja šūna satur" varianti atkarībā no tā, kādas tieši vērtības vēlaties atrast. Parasti jūs izmantosiet IF funkciju, lai veiktu loģisku pārbaudi un atgrieztu vienu vērtību, ja nosacījums ir izpildīts (šūna satur), un/vai citu vērtību, ja nosacījums nav izpildīts (šūna nesatur). Tālāk sniegtajos piemēros ir aprakstīti visbiežāk sastopamie scenāriji.

Ja šūnā ir kāda vērtība, tad

Sākumā apskatīsim, kā atrast šūnas, kurās ir jebkas: jebkurš teksts, skaitlis vai datums. Šim nolūkam izmantosim vienkāršu IF formulu, kas pārbauda, vai šūnās nav tukšu vietu.

Piemēram, lai B slejā atgrieztu "Nav tukšs", ja A slejas šūnā tajā pašā rindā ir kāda vērtība, B2 slejā ievadiet šādu formulu un pēc tam divreiz noklikšķiniet uz mazā zaļā kvadrātiņa labajā apakšējā stūrī, lai kopētu formulu uz leju slejā:

=IF(A2"", "Nav tukšs", "")

Rezultāts būs līdzīgs šim:

Ja šūnā ir teksts, tad

Ja vēlaties atrast tikai šūnas ar teksta vērtībām, ignorējot skaitļus un datumus, izmantojiet IF kopā ar funkciju ISTEXT. Šeit ir vispārīgā formula, lai atgrieztu kādu vērtību citā šūnā, ja mērķa šūnā ir šāda vērtība. jebkurš teksts :

Pieņemsim, ka vēlaties B slejā ievietot vārdu "jā", ja A slejas šūnā ir teksts. Lai to izdarītu, B2 ievietojiet šādu formulu:

=IF(ISTEXT(A2), "Jā", "")

Ja šūnā ir numurs, tad

Līdzīgā veidā varat identificēt šūnas ar skaitliskām vērtībām (skaitļiem un datumiem). Šim nolūkam izmantojiet funkciju IF kopā ar ISNUMBER:

Pēc šādas formulas B slejā tiek atgriezts "jā", ja atbilstošajā A slejas šūnā ir kāds skaitlis:

=IF(ISNUMBER(A2), "Jā", "")

Ja šūnā ir konkrēts teksts

Atrast šūnas, kurās ir noteikts teksts (vai skaitļi, vai datumi), ir vienkārši. Uzrakstiet regulāru IF formulu, kas pārbauda, vai mērķa šūnā ir vajadzīgais teksts, un ierakstiet tekstu, kas jāatgriež šūnā value_if_true arguments.

Piemēram, lai noskaidrotu, vai šūnā A2 ir "āboli", izmantojiet šo formulu:

=IF(A2="āboli", "Jā", "")

Ja šūnā nav konkrēta teksta

Ja meklējat pretēju rezultātu, t. i., atgriezt kādu vērtību citai kolonnai, ja mērķa šūnā nav norādītā teksta ("āboli"), tad veiciet vienu no šīm darbībām.

Ierakstiet tukšu virkni ("") laukā value_if_true argumentu un tekstu, kas jāatgriež value_if_false arguments:

=IF(A2="āboli", "", "Ne āboli")

Vai arī ievietojiet operatoru "nav vienāds ar", lai logical_test un tekstu, kas jāatgriež value_if_true:

=IF(A2 "āboli", "Ne āboli", "")

Jebkurā gadījumā formula dos šādu rezultātu:

Ja šūnā ir teksts: burtu un lielo un mazo burtu sensitīva formula

Lai piespiestu formulu atšķirt lielos un mazos burtus, izmantojiet funkciju EXACT, kas pārbauda, vai divas teksta virknes ir precīzi vienādas, ieskaitot burtu lielumu:

=IF(EXACT(A2, "APPLES"), "Jā", "")

Varat arī ievadīt modeļa teksta virkni kādā šūnā (piemēram, C1), noteikt šūnas atsauci ar $ zīmi ($C$1) un salīdzināt mērķa šūnu ar šo šūnu:

=IF(EXACT(A2,$C$1), "Jā", "")

Ja šūnā ir noteikta teksta virkne (daļēja atbilstība)

Mēs esam pabeiguši triviālus uzdevumus un pāriet pie sarežģītākiem un interesantākiem :) Šajā piemērā ir nepieciešamas trīs dažādas funkcijas, lai noskaidrotu, vai dotais simbols vai apakšvirkne ir šūnas satura daļa:

Formula darbojas no iekšpuses uz āru, un šeit ir aprakstīts, kā to dara:

• SEARCH funkcija meklē teksta virkni, un, ja virkne ir atrasta, atgriež pirmās rakstzīmes pozīciju, pretējā gadījumā atgriež #VALUE! kļūdu.
• Ar funkciju ISNUMBER tiek pārbaudīts, vai meklēšana SEARCH ir bijusi veiksmīga vai neveiksmīga. Ja SEARCH ir atgriezis jebkuru skaitli, ISNUMBER atgriež TRUE. Ja SEARCH ir radījusi kļūdu, ISNUMBER atgriež FALSE.
• Visbeidzot, funkcija IF atdod norādīto vērtību šūnām, kurām loģiskajā testā ir TRUE, pretējā gadījumā - tukšu virkni ("").

Un tagad aplūkosim, kā šī vispārīgā formula darbojas reālās darblapās.

Ja šūnā ir noteikts teksts, ievietojiet vērtību citā šūnā

Pieņemsim, ka A slejā ir saraksts ar pasūtījumiem, un jūs vēlaties atrast pasūtījumus ar konkrētu identifikatoru, piemēram, "A-". Šo uzdevumu var izpildīt, izmantojot šādu formulu:

=IF(ISNUMBER(SEARCH("A-",A2)), "Derīgs","")

Tā vietā, lai virkni stingri kodētu formulā, varat to ievadīt atsevišķā šūnā (E1) un atsauci uz šo šūnu iekļaut formulā:

=IF(ISNUMBER(SEARCH($E$1,A2)), "Derīgs","")

Lai formula darbotos pareizi, pārliecinieties, ka tās šūnas adrese, kurā atrodas virkne, ir bloķēta ar zīmi $ (absolūtā šūnas atsauce).

Ja šūnā ir konkrēts teksts, kopējiet to uz citu kolonnu

Ja derīgo šūnu saturu vēlaties kopēt citur, vienkārši norādiet novērtētās šūnas (A2) adresi vienumā value_if_true arguments:

=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")

Zemāk redzamajā ekrāna attēlā parādīti rezultāti:

Ja šūnā ir konkrēts teksts: burtu un lielo un mazo burtu sensitīva formula

Abos iepriekš minētajos piemēros formulās nav izšķirti burtu un ciparu lieli un mazie burti. Ja strādājat ar datiem, kuros ir izšķirti burtu un ciparu lieli un mazie burti, izmantojiet funkciju FIND, nevis SEARCH, lai izšķirtu rakstzīmju lielumu.

Piemēram, pēc šādas formulas tiks identificēti tikai pasūtījumi ar lielo burtu "A-", ignorējot mazo burtu "a-".

=IF(ISNUMBER(FIND("A-",A2)), "Derīgs","")

Ja šūnā ir viena no daudzām teksta virknēm (OR loģika)

Lai identificētu šūnas, kurās ir vismaz viena no daudzām meklējamām lietām, izmantojiet kādu no šādām formulām.

IF VAI ISNUMBER Meklēšanas formula

Acīmredzamākā pieeja būtu pārbaudīt katru apakšvirzienu atsevišķi, un, ja ir atrasts vismaz viens apakšvirziens, tad, veicot IF formulas loģisko pārbaudi, OR funkcija atgriež TRUE:

Pieņemsim, ka A slejā ir SKU saraksts un jūs vēlaties atrast tos, kuros ir vārds "kleita" vai "svārki". To var izdarīt, izmantojot šo formulu:

=IF(OR(ISNUMBER(SEARCH("kleita",A2)),ISNUMBER(SEARCH("svārki",A2))), "Derīgs ","")

Šī formula diezgan labi darbojas pāris vienībām, taču tas noteikti nav pareizais risinājums, ja vēlaties pārbaudīt daudzus elementus. Šajā gadījumā labāka pieeja būtu izmantot SUMPRODUCT funkciju, kā parādīts nākamajā piemērā.

SUMPRODUCT ISNUMBER SEARCH formula

Ja jums ir darīšana ar vairākām teksta virknēm, katras virknes meklēšana atsevišķi padarītu formulu pārāk garu un grūti lasāmu. Elegantāks risinājums būtu iestrādāt ISNUMBER SEARCH kombināciju funkcijā SUMPRODUCT un pārbaudīt, vai rezultāts ir lielāks par nulli:

Piemēram, lai noskaidrotu, vai A2 ir kāds no šūnās D2:D4 ievadītajiem vārdiem, izmantojiet šo formulu:

=SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0

Varat arī izveidot nosauktu diapazonu, kurā ir meklējamās virknes, vai ievadīt vārdus tieši formulā:

=SUMPRODUCT(--ISNUMBER(SEARCH({"kleita", "svārki", "džinsi"},A2)))>0

Jebkurā gadījumā rezultāts būs līdzīgs šim:

Lai izvades rezultātu padarītu lietotājam draudzīgāku, iepriekš minēto formulu var ievietot IF funkcijā un TRUE/FALSE vērtību vietā atgriezt savu tekstu:

=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Derīgs", "")

Kā darbojas šī formula

Pamatā jūs izmantojat ISNUMBER kopā ar SEARCH, kā paskaidrots iepriekšējā piemērā. Šajā gadījumā meklēšanas rezultāti tiek attēloti masīva formā, piemēram, {TRUE;FALSE;FALSE}. Ja šūnā ir vismaz viena no norādītajām apakšrindām, masīvā būs TRUE. Dubultais vienrindas operators (--) piespiež TRUE / FALSE vērtības attiecīgi 1 un 0, un iegūst masīvu, piemēram.{1;0;0}. Visbeidzot funkcija SUMPRODUCT saskaita skaitļus un atlasa šūnas, kurās rezultāts ir lielāks par nulli.

Ja šūnā ir vairākas virknes (AND loģika)

Situācijās, kad vēlaties atrast šūnas, kurās ir visas norādītās teksta virknes, izmantojiet jau pazīstamo kombināciju ISNUMBER SEARCH kopā ar IF AND:

Piemēram, ar šo formulu varat atrast SKU, kas satur gan "dress", gan "blue":

=IF(AND(ISNUMBER(SEARCH("kleita",A2)),ISNUMBER(SEARCH("zils",A2))), "Derīgs ","")

Varat arī ievadīt virknes atsevišķās šūnās un atsaukties uz šīm šūnām formulā:

=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2)), "Derīgs",""))

Alternatīvs risinājums ir saskaitīt katras virknes atkārtojumus un pārbaudīt, vai katrs atkārtojums ir lielāks par nulli:

=IF(AND(COUNTIF(A2, "*dress*")>0,COUNTIF(A2, "*blue*")>0), "Valid","")

Rezultāts būs tieši tāds, kā parādīts ekrānšā attēlā.

Kā atgriezt dažādus rezultātus, pamatojoties uz šūnas vērtību

Ja vēlaties salīdzināt katru mērķa kolonnas šūnu ar citu elementu sarakstu un katrai atbilstībai atgriezt atšķirīgu vērtību, izmantojiet vienu no šādām pieejām.

Iestrādāti IF

Ievietotās IF formulas loģika ir ļoti vienkārša: katra nosacījuma pārbaudei tiek izmantota atsevišķa IF funkcija, un atkarībā no šo pārbaužu rezultātiem tiek atgrieztas dažādas vērtības.

Pieņemsim, ka A slejā ir saraksts ar vienībām, un jūs vēlaties, lai to saīsinājumi būtu B slejā.Lai to izdarītu, izmantojiet šādu formulu:

=IF(A2="ābols", "Ap", IF(A2="avokado", "Av", IF(A2="banāns", "B", IF(A2="citrons", "L", ""))))

Lai iegūtu sīkāku informāciju par ligzdoto IF sintaksi un loģiku, skatiet sadaļu Excel ligzdotais IF - vairāki nosacījumi vienā formulā.

Pārlūkošanas formula

Ja meklējat kompaktāku un labāk saprotamu formulu, izmantojiet LOOKUP funkciju, kurā meklēšanas un atgriešanas vērtības tiek piegādātas kā vertikālas masīva konstantes:

Lai iegūtu precīzus rezultātus, pārliecinieties, ka meklēšanas vērtības ir norādītas alfabētiskā secībā , no A līdz Z.

=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})

Salīdzinot ar ieliktajiem IF, Lookup formulai ir vēl viena priekšrocība - tā saprot, ka aizstājējzīmju rakstzīmes un tādējādi var identificēt daļējas sakritības.

Piemēram, ja A slejā ir dažas banānu šķirnes, varat meklēt "*banāns*", un visām šādām šūnām tiks atgriezts tas pats saīsinājums ("B"):

=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})

Papildinformāciju skatiet sadaļā Lookup formula kā alternatīva ievietotajiem IF.

Vlookup formula

Strādājot ar mainīgu datu kopu, var būt ērtāk ievadīt atbilstības sarakstu atsevišķās šūnās un iegūt tās, izmantojot Vlookup formulu, piemēram:

=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )

Lai iegūtu vairāk informācijas, skatiet Excel VLOOKUP pamācību iesācējiem.

Šādā veidā Excel programmā tiek pārbaudīts, vai šūnā ir kāda vērtība vai konkrēts teksts. Nākamnedēļ mēs turpināsim aplūkot Excel formulas Ja šūna satur un uzzināsim, kā saskaitīt vai summēt attiecīgās šūnas, kopēt vai dzēst veselas rindas, kurās ir šīs šūnas, un daudz ko citu. Lūdzu, sekojiet līdzi!

Prakses darba burtnīca

Excel Ja šūna satur - formulas piemēri (.xlsx fails)