გაკვეთილი შეიცავს უამრავ ფორმულას "Excel if შეიცავს" მაგალითებს, რომლებიც გვიჩვენებს, თუ როგორ უნდა დააბრუნოთ რაღაც სხვა სვეტში, თუ სამიზნე უჯრედი შეიცავს საჭირო მნიშვნელობას, როგორ მოძებნოთ ნაწილობრივი შესატყვისი და შეამოწმოთ მრავალი კრიტერიუმი OR როგორც ასევე AND ლოგიკა.

Excel-ში ერთ-ერთი ყველაზე გავრცელებული დავალება არის იმის შემოწმება, შეიცავს თუ არა უჯრედი ინტერესის მნიშვნელობას. რა სახის ღირებულება შეიძლება იყოს ეს? უბრალოდ ნებისმიერი ტექსტი ან რიცხვი, კონკრეტული ტექსტი ან საერთოდ რაიმე მნიშვნელობა (ცარიელი უჯრედი არ არის).

არსებობს Excel-ში "თუ უჯრედი შეიცავს" ფორმულის რამდენიმე ვარიაცია, რაც დამოკიდებულია ზუსტად იმაზე, თუ რა მნიშვნელობების პოვნა გსურთ. ზოგადად, თქვენ გამოიყენებთ IF ფუნქციას ლოგიკური ტესტის გასაკეთებლად და დააბრუნებთ ერთ მნიშვნელობას, როდესაც პირობა დაკმაყოფილებულია (უჯრედი შეიცავს) და/ან სხვა მნიშვნელობას, როდესაც პირობა არ არის დაკმაყოფილებული (უჯრედი არ შეიცავს). ქვემოთ მოყვანილი მაგალითები მოიცავს ყველაზე გავრცელებულ სცენარებს.

თუ უჯრედი შეიცავს რაიმე მნიშვნელობას, მაშინ

დაწყებისთვის, მოდით ვნახოთ, როგორ მოვძებნოთ უჯრედები, რომლებიც შეიცავს რაიმეს: ნებისმიერი ტექსტი, ნომერი ან თარიღი. ამისთვის ჩვენ ვაპირებთ გამოვიყენოთ მარტივი IF ფორმულა, რომელიც ამოწმებს არაცარიელ უჯრედებს.

ამისთვის მაგალითად, B სვეტში "არა ცარიელი" დასაბრუნებლად, თუ A სვეტის უჯრედი იმავე მწკრივში შეიცავს რაიმე მნიშვნელობას, შეიყვანეთ შემდეგი ფორმულა B2-ში და შემდეგ ორჯერ დააწკაპუნეთ პატარა მწვანე კვადრატზე ქვედა მარჯვენა კუთხეში, რომ დააკოპიროთ ფორმულა. Theსვეტი:

=IF(A2"", "Not blank", "")

შედეგი ასე გამოიყურება:

თუ უჯრედი შეიცავს ტექსტს, მაშინ

თუ გსურთ იპოვოთ მხოლოდ უჯრედები ტექსტური მნიშვნელობებით, რომლებიც უგულებელყოფენ რიცხვებს და თარიღებს, გამოიყენეთ IF ISTEXT ფუნქციის კომბინაციაში. აქ არის ზოგადი ფორმულა სხვა უჯრედში გარკვეული მნიშვნელობის დასაბრუნებლად, თუ სამიზნე უჯრედი შეიცავს ნებისმიერ ტექსტს :

ვთქვათ, გსურთ ჩასვათ სიტყვა "დიახ" სვეტში B, თუ A სვეტის უჯრედი შეიცავს ტექსტს. ამის შესასრულებლად ჩასვით შემდეგი ფორმულა B2-ში:

=IF(ISTEXT(A2), "Yes", "")

თუ უჯრედი შეიცავს რიცხვს, მაშინ

მსგავსი ფორმით , შეგიძლიათ ამოიცნოთ უჯრედები რიცხვითი მნიშვნელობებით (ნომრები და თარიღები). ამისათვის გამოიყენეთ IF ფუნქცია ISNUMBER-თან ერთად:

შემდეგი ფორმულა აბრუნებს "დიახ" სვეტში B თუ A სვეტის შესაბამისი უჯრედი შეიცავს ნებისმიერ რიცხვს:

=IF(ISNUMBER(A2), "Yes", "")

თუ უჯრედი შეიცავს კონკრეტულ ტექსტს

უჯრედების პოვნა გარკვეული ტექსტის შემცველი (ან რიცხვები ან თარიღები) მარტივია. თქვენ წერთ ჩვეულებრივ IF ფორმულას, რომელიც ამოწმებს შეიცავს თუ არა სამიზნე უჯრედი სასურველ ტექსტს და აკრიფეთ ტექსტი, რომელიც უნდა დააბრუნოთ არგუმენტში value_if_true .

მაგალითად, იმის გასარკვევად, შეიცავს თუ არა უჯრედი A2 "apples", გამოიყენეთ ეს ფორმულა:

=IF(A2="apples", "Yes", "")

თუ უჯრედი არ შეიცავს სპეციფიკურსtext

თუ თქვენ ეძებთ საპირისპირო შედეგს, ანუ დააბრუნეთ გარკვეული მნიშვნელობა სხვა სვეტში, თუ სამიზნე უჯრედი არ შეიცავს მითითებულ ტექსტს ("apples"), მაშინ გააკეთეთ ერთ-ერთი შემდეგი.

მიიტანეთ ცარიელი სტრიქონი ("") value_if_true არგუმენტში და ტექსტი დასაბრუნებლად value_if_false არგუმენტში:

=IF(A2="apples", "", "Not apples")

ან , ჩადეთ ოპერატორი "არა ტოლი" ლოგიკურ_ტესტში და ტექსტი დასაბრუნებლად value_if_true:

=IF(A2"apples", "Not apples", "")

ნებისმიერ შემთხვევაში, ფორმულა გამოიმუშავებს ეს შედეგი:

თუ უჯრედი შეიცავს ტექსტს: რეგისტრირებული ფორმულა

იმისთვის რომ აიძულოთ თქვენი ფორმულა განასხვავოს დიდი და პატარა ასოები, გამოიყენეთ EXACT ფუნქცია, რომელიც ამოწმებს არის თუ არა ორი ტექსტის სტრიქონი ზუსტად ტოლი, მათ შორის ასოს:

=IF(EXACT(A2,"APPLES"), "Yes", "")

თქვენ ასევე შეგიძლიათ შეიყვანოთ მოდელის ტექსტის სტრიქონი ზოგიერთ უჯრედში (ვთქვათ C1), დააფიქსირეთ უჯრედის მითითება $ ნიშნით ($C$1) და შეადარეთ სამიზნე უჯრედი ამ უჯრედთან:

=IF(EXACT(A2,$C$1), "Yes", "")

თუ უჯრედი შეიცავს კონკრეტულ ტექსტურ სტრიქონს (ნაწილობრივი დამთხვევა)

ჩვენ დავასრულეთ ტრივიალური ამოცანები და გადავედით უფრო რთულ და საინტერესოზე :) ამ მაგალითში სამი განსხვავებული ფუნქციაა საჭირო იმის გასარკვევად, არის თუ არა მოცემული სიმბოლო ან ქვესტრიქონი უჯრედის ნაწილი შინაარსი:

მუშაობს შიგნიდან გარეთ , აი რას აკეთებს ფორმულა:

• TheSEARCH ფუნქცია ეძებს ტექსტის სტრიქონს და თუ სტრიქონი იპოვეს, აბრუნებს პირველი სიმბოლოს პოზიციას, #VALUE! შეცდომის სხვაგვარად.
• ISNUMBER ფუნქცია ამოწმებს SEARCH წარმატებული იყო თუ ვერ. თუ SEARCH-მა დააბრუნა ნებისმიერი ნომერი, ISNUMBER აბრუნებს TRUE-ს. თუ SEARCH გამოიწვევს შეცდომას, ISNUMBER აბრუნებს FALSE-ს.
• საბოლოოდ, IF ფუნქცია აბრუნებს მითითებულ მნიშვნელობას უჯრედებისთვის, რომლებსაც აქვთ TRUE ლოგიკურ ტესტში, წინააღმდეგ შემთხვევაში ცარიელ სტრიქონს ("").

და ახლა, ვნახოთ, როგორ მუშაობს ეს ზოგადი ფორმულა რეალურ სამუშაო ფურცლებზე.

თუ უჯრედი შეიცავს გარკვეულ ტექსტს, ჩადეთ მნიშვნელობა სხვა უჯრედში

დავუშვათ, რომ გაქვთ სია შეკვეთები A სვეტში და გსურთ იპოვოთ შეკვეთები კონკრეტული იდენტიფიკატორით, თქვით "A-". დავალების შესრულება შესაძლებელია ამ ფორმულით:

=IF(ISNUMBER(SEARCH("A-",A2)),"Valid","")

ფორმულაში სტრიქონის მყარი კოდირების ნაცვლად, შეგიძლიათ შეიყვანოთ იგი ცალკე უჯრედში (E1), რომელიც მიუთითებს თქვენს ფორმულაში არსებულ უჯრედში. :

=IF(ISNUMBER(SEARCH($E$1,A2)),"Valid","")

ფორმულის სწორად მუშაობისთვის, დარწმუნდით, რომ დაბლოკეთ სტრიქონის შემცველი უჯრედის მისამართი $ ნიშნით (უჯრედის აბსოლუტური მითითება).

თუ უჯრედი შეიცავს კონკრეტულ ტექსტს, დააკოპირეთ იგი სხვა სვეტში

თუ გსურთ სწორი უჯრედების შიგთავსის სხვაგან კოპირება, უბრალოდ მიუთითეთ შეფასებული უჯრედის მისამართი (A2) value_if_true არგუმენტში:

=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")

ქვემოთ სკრინშოტი აჩვენებს შედეგებს:

თუუჯრედი შეიცავს სპეციფიკურ ტექსტს: რეგისტრის მგრძნობიარე ფორმულა

ორივე ზემოთ მოყვანილ მაგალითში, ფორმულები არის რეგისტრის მგრძნობიარე ფორმულა. სიტუაციებში, როდესაც მუშაობთ რეგისტრის მგრძნობიარე მონაცემებთან, გამოიყენეთ FIND ფუნქცია SEARCH-ის ნაცვლად სიმბოლოების რეგისტრის გასარჩევად.

მაგალითად, შემდეგი ფორმულა ამოიცნობს მხოლოდ ბრძანებებს დიდი „A-“ მცირე რეგისტრის უგულებელყოფით. a-".

=IF(ISNUMBER(FIND("A-",A2)),"Valid","")

თუ უჯრედი შეიცავს ტექსტის მრავალი სტრიქონიდან ერთს (ან ლოგიკა)

უჯრედების იდენტიფიცირება, რომლებიც შეიცავს მინიმუმ ბევრი რამ, რასაც ეძებთ, გამოიყენეთ შემდეგი ფორმულებიდან ერთ-ერთი.

IF OR ISNUMBER SEARCH ფორმულა

ყველაზე აშკარა მიდგომა იქნება თითოეული ქვესტრიქონის ცალ-ცალკე შემოწმება და OR ფუნქცია. დააბრუნეთ TRUE IF ფორმულის ლოგიკურ ტესტში, თუ მოიძებნება მინიმუმ ერთი ქვესტრიქონი:

დაუშვათ, რომ თქვენ გაქვთ SKU-ების სია A სვეტში და თქვენ მინდა ვიპოვო ის, რაც მოიცავს ან "კაბას" ან "კალთას". ამის გაკეთება შეგიძლიათ ამ ფორმულის გამოყენებით:

=IF(OR(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("skirt",A2))),"Valid ","")

ფორმულა საკმაოდ კარგად მუშაობს რამდენიმე ელემენტისთვის, მაგრამ ეს ნამდვილად არ არის გზა წადი თუ გინდა ბევრი რამის შემოწმება. ამ შემთხვევაში უკეთესი მიდგომა იქნება SUMPRODUCT ფუნქციის გამოყენება, როგორც ეს ნაჩვენებია შემდეგ მაგალითში.

SUMPRODUCT ISNUMBER SEARCH ფორმულა

თუ თქვენ ხართმრავალ ტექსტურ სტრიქონთან ურთიერთობისას, თითოეული სტრიქონის ინდივიდუალურად მოძიება თქვენს ფორმულას ზედმეტად გრძელს და წასაკითხად გახდის. უფრო ელეგანტური გამოსავალი იქნება ISNUMBER SEARCH კომბინაციის ჩასმა SUMPRODUCT ფუნქციაში და ვნახოთ, არის თუ არა შედეგი ნულზე მეტი:

მაგალითად, იმის გასარკვევად, შეიცავს თუ არა A2 შეყვანილ რომელიმე სიტყვას D2:D4 უჯრედებში, გამოიყენეთ ეს ფორმულა:

=SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0

ალტერნატიულად, შეგიძლიათ შექმნათ დასახელებული დიაპაზონი, რომელიც შეიცავს საძიებლად სტრიქონებს, ან მიაწოდოთ სიტყვები პირდაპირ ფორმულაში:

=SUMPRODUCT(--ISNUMBER(SEARCH({"dress","skirt","jeans"},A2)))>0

ნებისმიერ შემთხვევაში, შედეგი იქნება მსგავსი:

გამომავალი უფრო მოსახერხებელი რომ გახადოთ, შეგიძლიათ ზემოთ ჩამოთვლილი ფორმულა ჩასვათ IF ფუნქციაში და დააბრუნოთ თქვენი ტექსტი TRUE/FALSE მნიშვნელობების ნაცვლად:

=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Valid", "")

როგორ მუშაობს ეს ფორმულა

ძირითადად, თქვენ იყენებთ ISNUMBER-ს SEARCH-თან ერთად, როგორც ეს წინა მაგალითში იყო ახსნილი. ამ შემთხვევაში, ძიების შედეგები წარმოდგენილია მასივის სახით, როგორიცაა {TRUE;FALSE;FALSE}. თუ უჯრედი შეიცავს მითითებულ ქვესტრინგებიდან ერთს მაინც, მასივში იქნება TRUE. ორმაგი უნიალური ოპერატორი (--) აიძულებს TRUE / FALSE მნიშვნელობებს 1-ზე და 0-ზე, შესაბამისად, და აწვდის მასივს, როგორიცაა {1;0;0}. საბოლოოდ, SUMPRODUCT ფუნქცია აგროვებს რიცხვებს და ჩვენ ვირჩევთ უჯრედებს, სადაც შედეგი არის ნულზე მეტი.

თუუჯრედი შეიცავს რამდენიმე სტრიქონს (AND ლოგიკა)

სიტუაციებში, როდესაც გსურთ იპოვოთ უჯრედები, რომლებიც შეიცავს ყველა მითითებულ ტექსტურ სტრიქონს, გამოიყენეთ უკვე ნაცნობი ISNUMBER SEARCH კომბინაცია IF AND:

მაგალითად, შეგიძლიათ იპოვოთ SKU-ები, რომლებიც შეიცავს როგორც „dress“-ს და „ლურჯს“ ამ ფორმულით:

=IF(AND(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("blue",A2))),"Valid ","")

ან, შეგიძლიათ აკრიფოთ სტრიქონები ცალკეულ უჯრედებში და მიუთითეთ ეს უჯრედები თქვენს ფორმულაში:

=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2))),"Valid ","")

როგორც ალტერნატიული გადაწყვეტა, შეგიძლიათ დათვალოთ თითოეული სტრიქონის შემთხვევები და შეამოწმოთ თუ თითოეული რაოდენობა ნულზე მეტია:

=IF(AND(COUNTIF(A2,"*dress*")>0,COUNTIF(A2,"*blue*")>0),"Valid","")

შედეგი იქნება ზუსტად ისე, როგორც ნაჩვენებია ზემოთ მოცემულ ეკრანის სურათზე.

როგორ დავაბრუნოთ სხვადასხვა შედეგები უჯრედის მნიშვნელობის მიხედვით

თუ გსურთ შეადაროთ სამიზნე სვეტის თითოეული უჯრედი ერთეულების სხვა სიასთან და დააბრუნოთ განსხვავებული მნიშვნელობა თითოეული შესატყვისისთვის, გამოიყენეთ შემდეგი მიდგომებიდან ერთ-ერთი.

ჩადგმული IFs

ჩადგმული IF ფორმულის ლოგიკა ასეთი მარტივია: თქვენ იყენებთ ცალკე IF ფუნქციას თითოეული პირობის შესამოწმებლად და აბრუნებთ სხვადასხვა მნიშვნელობებს ამ ტესტების შედეგების მიხედვით.

დავუშვათ, რომ თქვენ გაქვთ A სვეტის ელემენტების სია და გსურთ გქონდეთ მათი შემოკლებები სვეტში B. ამის გასაკეთებლად გამოიყენეთ შემდეგი ფორმულა:

=IF(A2="apple", "Ap", IF(A2="avocado", "Av", IF(A2="banana", "B", IF(A2="lemon", "L", ""))))

სრული დეტალებისთვის ჩადგმული IF-ის სინტაქსისა და ლოგიკის შესახებ, გთხოვთ, იხილოთ Excel-ში ჩასმული IF - მრავალი პირობა ერთ ფორმულაში.

ძიების ფორმულა

თუ თქვენ ეძებთ მეტს კომპაქტური და უკეთ გასაგები ფორმულა, გამოიყენეთ LOOKUP ფუნქცია საძიებელი და დაბრუნების მნიშვნელობებით მოწოდებული, როგორც ვერტიკალური მასივის მუდმივები:

ზუსტი შედეგებისთვის, დარწმუნდით, რომ ჩამოთვალეთ საძიებო მნიშვნელობები ანბანური თანმიმდევრობით , A-დან Z-მდე.

=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})

ჩადგმულ IF-ებთან შედარებით, Lookup ფორმულას კიდევ ერთი უპირატესობა აქვს - მას ესმის გადამცემი სიმბოლოები და, შესაბამისად, შეუძლია ნაწილობრივი შესატყვისების იდენტიფიცირება.

მაგალითად, თუ სვეტი A შეიცავს რამდენიმე დალაგებას ბანანებიდან შეგიძლიათ მოძებნოთ "*banana*" და დაბრუნდეთ იგივე აბრევიატურა ("B") ყველა ასეთი უჯრედისთვის:

=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})

დამატებითი ინფორმაციისთვის, გთხოვთ, იხილოთ Lookup ფორმულა, როგორც ჩადგმული IF-ების ალტერნატივა.

Vlookup ფორმულა

ცვლად მონაცემთა ნაკრებთან მუშაობისას, შესაძლოა უფრო მოსახერხებელი იყოს შესატყვისობების სიის ცალკე შეყვანა. უჯრედები და ამოიღეთ ისინი Vlookup ფორმულის გამოყენებით,მაგ.:

=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )

დამატებითი ინფორმაციისთვის იხილეთ Excel VLOOKUP-ის გაკვეთილი დამწყებთათვის.

ასე ამოწმებთ, არის თუ არა უჯრედი შეიცავს ნებისმიერ მნიშვნელობას ან კონკრეტულ ტექსტს Excel-ში. მომავალ კვირას ჩვენ ვაპირებთ გავაგრძელოთ Excel-ის If უჯრედის ყურება და ვისწავლოთ როგორ დათვალოთ ან შეაჯამოთ შესაბამისი უჯრედები, დააკოპიროთ ან წაშალოთ ამ უჯრედების შემცველი მთელი რიგები და სხვა. გთხოვთ, თვალყური ადევნოთ!

სავარჯიშო სამუშაო წიგნი

Excel თუ უჯრედი შეიცავს - ფორმულის მაგალითები (ფაილი .xlsx)