Kennslan veitir fjölda "Excel ef inniheldur" formúludæmi sem sýna hvernig á að skila einhverju í öðrum dálki ef markreitur inniheldur tilskilið gildi, hvernig á að leita með hluta samsvörun og prófa mörg skilyrði með OR sem og OG rökfræði.

Eitt af algengustu verkefnum í Excel er að athuga hvort hólf innihaldi áhugaverð. Hvers konar verðmæti getur það verið? Bara hvaða texti eða númer sem er, sérstakur texti eða hvaða gildi sem er (ekki tómur reit).

Það eru til nokkur afbrigði af formúlunni „Ef reit inniheldur“ í Excel, eftir því nákvæmlega hvaða gildi þú vilt finna. Almennt muntu nota IF fallið til að gera rökrétt próf og skila einu gildi þegar skilyrðið er uppfyllt (reitur inniheldur) og/eða annað gildi þegar skilyrðið er ekki uppfyllt (reitur inniheldur ekki). Dæmin hér að neðan ná yfir algengustu aðstæður.

Ef hólf inniheldur eitthvert gildi, þá

Til að byrja með skulum við sjá hvernig á að finna hólf sem innihalda eitthvað: hvaða texta, númer eða dagsetningu. Til þess ætlum við að nota einfalda IF-formúlu sem athugar hvort hólf eru ekki auð.

Fyrir Til dæmis, til að skila „Ekki auð“ í dálki B ef reit í dálki A í sömu röð inniheldur eitthvert gildi, slærðu inn eftirfarandi formúlu í B2 og tvísmellir svo á litla græna ferninginn neðst í hægra horninu til að afrita formúluna niður thedálkur:

=IF(A2"", "Not blank", "")

Niðurstaðan mun líta svipað út:

Ef hólf inniheldur texta, þá

Ef þú vilt finna aðeins frumur með textagildum sem hunsa tölur og dagsetningar, notaðu þá IF ásamt ISTEXT aðgerðinni. Hér er almenna formúlan til að skila einhverju gildi í öðrum reit ef markreitur inniheldur allan texta :

Svo sem þú vilt setja orðið "já" í dálk B ef reit í dálki A inniheldur texta. Til að gera það skaltu setja eftirfarandi formúlu í B2:

=IF(ISTEXT(A2), "Yes", "")

Ef reit inniheldur tölu, þá

Á svipaðan hátt , þú getur auðkennt frumur með tölugildum (tölur og dagsetningar). Notaðu IF fallið ásamt ISNUMBER:

Eftirfarandi formúla skilar "já" í dálki B ef samsvarandi reit í dálki A inniheldur hvaða tölu sem er:

=IF(ISNUMBER(A2), "Yes", "")

Ef reit inniheldur ákveðinn texta

Finnur reiti sem innihalda ákveðinn texta (eða tölur eða dagsetningar) er auðvelt. Þú skrifar venjulega IF formúlu sem athugar hvort markreitur innihaldi þann texta sem óskað er eftir og slærð inn textann sem á að skila í gildi_ef_satt röksemdin.

Til dæmis, til að komast að því hvort hólf A2 inniheldur "epli", notaðu þessa formúlu:

=IF(A2="apples", "Yes", "")

Ef klefi inniheldur ekki sértækttexti

Ef þú ert að leita að gagnstæðri niðurstöðu, þ.e. skila einhverju gildi í annan dálk ef markreitur inniheldur ekki tilgreindan texta ("epli"), gerðu þá eitt af eftirfarandi.

Gefðu upp tóman streng ("") í value_if_true röksemdinni og texta til að skila í value_if_false röksemdinni:

=IF(A2="apples", "", "Not apples")

Eða , settu "ekki jafnt og" stjórnanda í logical_test og texta til að skila í value_if_true:

=IF(A2"apples", "Not apples", "")

Hvort sem er, formúlan mun framleiða þessi niðurstaða:

Ef hólf inniheldur texta: hástafanæm formúla

Til að þvinga formúluna þína til að greina á milli hástafa og lágstafa skaltu nota EXACT aðgerðina sem athugar hvort tveir textastrengir séu nákvæmlega jafnir, þ.m.t. hástafir:

=IF(EXACT(A2,"APPLES"), "Yes", "")

Þú getur líka sett inn fyrirmyndartextastrenginn í einhverjum reit (segðu í C1), lagfærðu frumutilvísunina með $ tákninu ($C$1) og berðu markreitinn saman við þann reit:

=IF(EXACT(A2,$C$1), "Yes", "")

Ef reit inniheldur sérstakan textastreng (hlutasamsvörun)

Við höfum lokið við léttvæg verkefni og förum yfir í krefjandi og áhugaverðari verkefni :) Í þessu dæmi þarf þrjár mismunandi aðgerðir til að finna út hvort tiltekinn karakter eða undirstrengur sé hluti af reitnum innihald:

Vinnur innan frá og út , hér er það sem formúlan gerir:

• TheSEARCH aðgerðin leitar að textastreng og ef strengurinn finnst skilar hann staðsetningu fyrsta stafsins, #VALUE! villa annars.
• ISNUMBER aðgerðin athugar hvort SEARCH heppnaðist eða mistókst. Ef SEARCH hefur skilað einhverju númeri skilar ISNUMBER TRUE. Ef SEARCH leiðir til villu skilar ISNUMBER FALSE.
• Að lokum skilar IF fallið tilgreindu gildi fyrir reiti sem hafa TRUE í rökrétta prófinu, tómum streng ("") annars.

Og nú skulum við sjá hvernig þessi almenna formúla virkar í raunverulegum vinnublöðum.

Ef reit inniheldur ákveðinn texta skaltu setja gildi í annan reit

Svo sem þú ert með lista yfir pantanir í dálki A og þú vilt finna pantanir með tilteknu auðkenni, segðu "A-". Verkefnið er hægt að framkvæma með þessari formúlu:

=IF(ISNUMBER(SEARCH("A-",A2)),"Valid","")

Í stað þess að harðkóða strenginn í formúlunni geturðu sett hann inn í sérstakan reit (E1), tilvísunina í reitinn í formúlunni þinni :

=IF(ISNUMBER(SEARCH($E$1,A2)),"Valid","")

Til þess að formúlan virki rétt, vertu viss um að læsa heimilisfangi reitsins sem inniheldur strenginn með $ tákninu (algjör hólfsvísun).

Ef reit inniheldur ákveðinn texta, afritaðu hann í annan dálk

Ef þú vilt afrita innihald gildandi refa einhvers staðar annars staðar skaltu einfaldlega gefa upp heimilisfang reitsins sem er metið (A2) í value_if_true rök:

=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")

Skjámyndin hér að neðan sýnir niðurstöðurnar:

Efklefi inniheldur sérstakan texta: hástafahámarksnæm formúla

Í báðum ofangreindum dæmum eru formúlurnar óháðar hástöfum. Í aðstæðum þegar þú vinnur með hástafanæm gögn, notaðu FIND aðgerðina í stað SEARCH til að greina á milli hástafa og hástafa.

Til dæmis mun eftirfarandi formúla aðeins auðkenna pantanir með hástöfum "A-" og hunsa lágstafi " a-".

=IF(ISNUMBER(FIND("A-",A2)),"Valid","")

Ef reit inniheldur einn af mörgum textastrengjum (OR rökfræði)

Til að bera kennsl á reiti sem innihalda a.m.k. eitt af mörgum hlutum sem þú ert að leita að, notaðu eina af eftirfarandi formúlum.

EF EÐA TALA LEIT formúla

Augljósasta aðferðin væri að athuga hvern undirstreng fyrir sig og hafa OR aðgerðina skilaðu TRUE í rökréttu prófi IF formúlunnar ef að minnsta kosti einn undirstrengur finnst:

Svo sem að þú sért með lista yfir SKU í dálki A og þú langar að finna þá sem innihalda annað hvort "kjól" eða "pils". Þú getur látið gera það með því að nota þessa formúlu:

=IF(OR(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("skirt",A2))),"Valid ","")

Formúlan virkar nokkuð vel fyrir nokkra hluti, en það er vissulega ekki leiðin til að farðu ef þú vilt athuga margt. Í þessu tilviki væri betri nálgun að nota SUMPRODUCT aðgerðina eins og sýnt er í næsta dæmi.

SUMPRODUCT ISNUMBER Leitarformúla

Ef þú ertað takast á við marga textastrengi, leit að hverjum streng fyrir sig myndi gera formúluna þína of langa og erfiða að lesa. Glæsilegri lausn væri að fella ISNUMBER SEARCH samsetninguna inn í SUMPRODUCT aðgerðina og athuga hvort niðurstaðan sé meiri en núll:

=SUMPRODUCT(--ISNUMBER(SEARCH({"dress","skirt","jeans"},A2)))>0

Hvort sem er, útkoman verður svipuð þessari:

Til að gera úttakið notendavænni geturðu hreiðrað ofangreinda formúlu inn í IF fallið og skilað þínum eigin texta í stað TRUE/FALSE gildin:

=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Valid", "")

Hvernig þessi formúla virkar

Í kjarnanum notarðu ISNUMBER ásamt SEARCH eins og útskýrt var í fyrra dæmi. Í þessu tilviki eru leitarniðurstöðurnar sýndar í formi fylkis eins og {TRUE;FALSE;FALSE}. Ef reit inniheldur að minnsta kosti einn af tilgreindum undirstrengjum verður TRUE í fylkinu. Tvöfaldur einingi (--) þvingar TRUE / FALSE gildin í 1 og 0, í sömu röð, og gefur fylki eins og {1;0;0}. Að lokum leggur SUMPRODUCT aðgerðin saman tölurnar og við veljum út reiti þar sem útkoman er meiri en núll.

Efreit inniheldur nokkra strengi (OG rökfræði)

Í aðstæðum þegar þú vilt finna reiti sem innihalda alla tilgreinda textastrengi, notaðu þá þegar þekktu ISNUMBER SEARCH samsetninguna ásamt IF AND:

Til dæmis geturðu fundið vörunúmer sem innihalda bæði "dress" og "blue" með þessari formúlu:

=IF(AND(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("blue",A2))),"Valid ","")

Eða þú getur slegið inn strengina í aðskildum hólfum og vísað til þeirra hólfa í formúlunni þinni:

=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2))),"Valid ","")

Sem önnur lausn geturðu talið tilvik hvers strengs og athugað ef hver tala er meiri en núll:

=IF(AND(COUNTIF(A2,"*dress*")>0,COUNTIF(A2,"*blue*")>0),"Valid","")

Niðurstaðan verður nákvæmlega eins og sýnt er á skjáskotinu hér að ofan.

Hvernig á að skila mismunandi niðurstöðum byggðar á reitgildi

Ef þú vilt bera saman hverja reit í markdálknum við annan lista yfir hluti og skila öðru gildi fyrir hverja samsvörun, notaðu eina af eftirfarandi aðferðum.

Hreiður IFs

Rökfræði hreiðruðu IF formúlunnar er eins einföld og þessi: þú notar sérstakt IF fall til að prófa hvert skilyrði og skilar mismunandi gildum eftir niðurstöðum þessara prófa.

Svo sem þú ert með lista yfir atriði í dálki A og þú vilt hafa skammstafanir þeirra í dálki B. Til að gera það skaltu nota eftirfarandi formúlu:

=IF(A2="apple", "Ap", IF(A2="avocado", "Av", IF(A2="banana", "B", IF(A2="lemon", "L", ""))))

Fyrir allar upplýsingar um setningafræði og rökfræði hreiðra IF, vinsamlegast sjáðu Excel hreiður IF - mörg skilyrði í einni formúlu.

Uppflettingarformúla

Ef þú ert að leita að meira fyrirferðarlítil og skiljanlegri formúlu, notaðu LOOKUP fallið með uppfletti- og skilagildum sem eru til staðar sem lóðréttir fylkisfastar:

Til að fá nákvæmar niðurstöður, vertu viss um að skrá uppleitargildin í stafrófsröð , frá A til Ö.

=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})

Í samanburði við hreiðra IF hefur leit uppskriftin enn einn kostinn - hún skilur algildisstafina og getur þess vegna auðkennt samsvörun að hluta.

Til dæmis ef dálkur A inniheldur nokkrar tegundir af bananum geturðu flett upp "*banani*" og fengið sömu skammstöfunina ("B") til baka fyrir allar slíkar frumur:

=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})

Fyrir frekari upplýsingar, vinsamlegast sjáðu upplitsformúlu sem valkost við hreiður IF.

Vlookup formúla

Þegar unnið er með breytu gagnasett gæti verið þægilegra að setja inn lista yfir samsvörun í aðskildum frumur og sæktu þær með því að nota Vlookup formúlu,t.d.:

=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )

Nánari upplýsingar er að finna í Excel VLOOKUP kennsluefni fyrir byrjendur.

Svona athugarðu hvort reit inniheldur hvaða gildi eða sérstakan texta í Excel. Í næstu viku ætlum við að halda áfram að skoða Ef reiturinn í Excel inniheldur formúlur og læra hvernig á að telja eða leggja saman viðeigandi reiti, afrita eða fjarlægja heilar línur sem innihalda þær reiti og fleira. Vinsamlega fylgist með!

Æfðu vinnubók

Excel ef klefi inniheldur - formúludæmi (.xlsx skrá)