Udžbenik pruža brojne primjere formula "Excel ako sadrži" koji pokazuju kako vratiti nešto u drugom stupcu ako ciljna ćelija sadrži traženu vrijednost, kako pretraživati ​​s djelomičnim podudaranjem i testirati više kriterija s OR kao kao i I logika.

Jedan od najčešćih zadataka u Excelu je provjera sadrži li ćelija vrijednost od interesa. Kakva to vrijednost može biti? Samo bilo koji tekst ili broj, određeni tekst ili bilo koja vrijednost uopće (ne prazna ćelija).

Postoji nekoliko varijacija formule "Ako ćelija sadrži" u Excelu, ovisno o tome koje točno vrijednosti želite pronaći. Općenito, koristit ćete funkciju IF za izvođenje logičkog testa i vraćanje jedne vrijednosti kada je uvjet ispunjen (ćelija sadrži) i/ili drugu vrijednost kada uvjet nije ispunjen (ćelija ne sadrži). Donji primjeri pokrivaju najčešće scenarije.

Ako ćelija sadrži bilo kakvu vrijednost, tada

Za početak, da vidimo kako pronaći ćelije koje sadrže bilo što: bilo koju tekst, broj ili datum. Za ovo ćemo upotrijebiti jednostavnu IF formulu koja provjerava ćelije koje nisu prazne.

Za Na primjer, da biste vratili "Nije prazno" u stupcu B ako ćelija stupca A u istom retku sadrži bilo koju vrijednost, unesite sljedeću formulu u B2, a zatim dvaput kliknite mali zeleni kvadratić u donjem desnom kutu da kopirate formulu prema dolje thestupac:

=IF(A2"", "Not blank", "")

Rezultat će izgledati slično ovome:

Ako ćelija sadrži tekst, tada

Ako želite pronaći samo ćelije s tekstualnim vrijednostima zanemarujući brojeve i datume, upotrijebite IF u kombinaciji s funkcijom ISTEXT. Evo generičke formule za vraćanje neke vrijednosti u drugoj ćeliji ako ciljna ćelija sadrži bilo koji tekst :

Pretpostavimo da želite umetnuti riječ "da" u stupac B ako ćelija u stupcu A sadrži tekst. Da biste to učinili, stavite sljedeću formulu u B2:

=IF(ISTEXT(A2), "Yes", "")

Ako ćelija sadrži broj, tada

Na sličan način , možete identificirati ćelije s numeričkim vrijednostima (brojevima i datumima). Za to upotrijebite funkciju IF zajedno s ISNUMBER:

Sljedeća formula vraća "yes" u stupcu B ako odgovarajuća ćelija u stupcu A sadrži bilo koji broj:

=IF(ISNUMBER(A2), "Yes", "")

Ako ćelija sadrži određeni tekst

Pronalaženje ćelija koje sadrže određeni tekst (ili brojeva ili datuma) je jednostavno. Napišete uobičajenu IF formulu koja provjerava sadrži li ciljna ćelija željeni tekst i upišete tekst koji želite vratiti u argument value_if_true .

Na primjer, da biste saznali sadrži li ćelija A2 "jabuke", koristite ovu formulu:

=IF(A2="apples", "Yes", "")

Ako ćelija ne sadrži specifičnetekst

Ako tražite suprotan rezultat, tj. vraćate neku vrijednost u drugi stupac ako ciljna ćelija ne sadrži navedeni tekst ("jabuke"), učinite jedno od sljedećeg.

Unesite prazan niz ("") u argument value_if_true i tekst za vraćanje u argument value_if_false :

=IF(A2="apples", "", "Not apples")

Ili , stavite operator "nije jednako" u logical_test i tekst za vraćanje u value_if_true:

=IF(A2"apples", "Not apples", "")

U svakom slučaju, formula će proizvesti ovaj rezultat:

Ako ćelija sadrži tekst: formula koja razlikuje velika i mala slova

Da biste prisilili svoju formulu da razlikuje velika i mala slova, upotrijebite funkciju EXACT koja provjerava jesu li dva tekstualna niza potpuno jednaka, uključujući velika i mala slova:

=IF(EXACT(A2,"APPLES"), "Yes", "")

Također možete unijeti tekstualni niz modela u neku ćeliju (recimo u C1), popravite referencu ćelije znakom $ ($C$1) i usporedite ciljnu ćeliju s tom ćelijom:

=IF(EXACT(A2,$C$1), "Yes", "")

If ćelija sadrži određeni tekstualni niz (djelomično podudaranje)

Završili smo s trivijalnim zadacima i prelazimo na one izazovnije i zanimljivije :) U ovom primjeru, potrebne su tri različite funkcije da se otkrije je li dati znak ili podniz dio ćelije contents:

Rad iznutra prema van , evo što formula radi:

• TheSEARCH funkcija traži tekstualni niz, a ako je niz pronađen, vraća položaj prvog znaka, #VALUE! greška inače.
• Funkcija ISNUMBER provjerava je li PRETRAGA uspjela ili nije uspjela. Ako je SEARCH vratio bilo koji broj, ISNUMBER vraća TRUE. Ako SEARCH rezultira pogreškom, ISNUMBER vraća FALSE.
• Konačno, funkcija IF vraća navedenu vrijednost za ćelije koje imaju TRUE u logičkom testu, au suprotnom prazan niz ("").

A sada, da vidimo kako ova generička formula radi u radnim listovima iz stvarnog života.

Ako ćelija sadrži određeni tekst, stavite vrijednost u drugu ćeliju

Pretpostavimo da imate popis naloge u stupcu A i želite pronaći naloge s određenim identifikatorom, recimo "A-". Zadatak se može izvršiti ovom formulom:

=IF(ISNUMBER(SEARCH("A-",A2)),"Valid","")

Umjesto tvrdog kodiranja niza u formuli, možete ga unijeti u zasebnu ćeliju (E1), referencu te ćelije u svojoj formuli :

=IF(ISNUMBER(SEARCH($E$1,A2)),"Valid","")

Da bi formula radila ispravno, obavezno zaključajte adresu ćelije koja sadrži niz sa znakom $ (apsolutna referenca ćelije).

Ako ćelija sadrži određeni tekst, kopirajte ga u drugi stupac

Ako želite kopirati sadržaj valjanih ćelija negdje drugdje, jednostavno unesite adresu procijenjene ćelije (A2) u value_if_true argumentu:

=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")

Snimak zaslona u nastavku prikazuje rezultate:

Akoćelija sadrži određeni tekst: formula koja razlikuje velika i mala slova

U oba gornja primjera, formule ne razlikuju velika i mala slova. U situacijama kada radite s podacima koji razlikuju velika i mala slova, upotrijebite funkciju FIND umjesto SEARCH da biste razlikovali velika i mala slova.

Na primjer, sljedeća formula će identificirati samo narudžbe s velikim slovima "A-" ignorirajući mala slova " a-".

=IF(ISNUMBER(FIND("A-",A2)),"Valid","")

Ako ćelija sadrži jedan od mnogih tekstualnih nizova (ILI logika)

Za prepoznavanje ćelija koje sadrže najmanje jednu od mnogih stvari koje tražite, upotrijebite jednu od sljedećih formula.

Formula PRETRAŽIVANJA AKO ILI JE BROJA

Najočitiji pristup bio bi provjeriti svaki podniz pojedinačno i imati funkciju ILI vrati TRUE u logičkom testu IF formule ako je pronađen barem jedan podniz:

Pretpostavimo da imate popis SKU-ova u stupcu A i vi želite pronaći one koje uključuju ili "haljinu" ili "suknju". Možete to učiniti pomoću ove formule:

=IF(OR(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("skirt",A2))),"Valid ","")

Formula prilično dobro funkcionira za nekoliko stavki, ali to sigurno nije način da idi ako želiš provjeriti mnoge stvari. U ovom bi slučaju bolji pristup bio korištenje funkcije SUMPROIZVOD kao što je prikazano u sljedećem primjeru.

FORMULA ZA PRETRAŽIVANJE BROJA SUMPROIZVODA

Ako steako radite s više tekstualnih nizova, traženje svakog niza pojedinačno učinilo bi vašu formulu predugom i teškom za čitanje. Elegantnije rješenje bilo bi ugraditi kombinaciju ISNUMBER SEARCH u funkciju SUMPRODUCT i vidjeti je li rezultat veći od nule:

Na primjer, da biste saznali sadrži li A2 bilo koju od riječi unesenih u ćelije D2:D4, upotrijebite ovu formulu:

=SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0

Alternativno, možete stvoriti imenovani raspon koji sadrži nizove za pretraživanje ili unijeti riječi izravno u formulu:

=SUMPRODUCT(--ISNUMBER(SEARCH({"dress","skirt","jeans"},A2)))>0

U svakom slučaju, rezultat će biti sličan ovome:

Kako bi izlaz bio lakši za korištenje, možete ugniježditi gornju formulu u funkciju IF i vratiti vlastiti tekst umjesto TRUE/FALSE vrijednosti:

=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Valid", "")

Kako ova formula funkcionira

U osnovi, koristite ISNUMBER zajedno s PRETRAŽIVANJEM kao što je objašnjeno u prethodnom primjeru. U ovom slučaju, rezultati pretraživanja predstavljeni su u obliku niza poput {TRUE;FALSE;FALSE}. Ako ćelija sadrži barem jedan od navedenih podnizova, u nizu će biti TRUE. Dvostruki unarni operator (--) prisiljava TRUE/FALSE vrijednosti na 1 odnosno 0 i isporučuje niz poput {1;0;0}. Konačno, funkcija SUMPRODUCT zbraja brojeve i odabiremo ćelije u kojima je rezultat veći od nule.

Akoćelija sadrži nekoliko nizova (I logika)

U situacijama kada želite pronaći ćelije koje sadrže sve navedene tekstualne nizove, koristite već poznatu kombinaciju ISBROJ PRETRAŽIVANJE zajedno s IF AND:

Na primjer, možete pronaći SKU-ove koji sadrže i "dress" i "blue" pomoću ove formule:

=IF(AND(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("blue",A2))),"Valid ","")

Ili možete upisati nizove u zasebnim ćelijama i referencirajte te ćelije u svojoj formuli:

=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2))),"Valid ","")

Kao alternativno rješenje, možete brojati pojavljivanja svakog niza i provjeriti ako je svaki broj veći od nule:

=IF(AND(COUNTIF(A2,"*dress*")>0,COUNTIF(A2,"*blue*")>0),"Valid","")

Rezultat će biti točno kao što je prikazano na gornjoj snimci zaslona.

Kako vratiti različite rezultate na temelju vrijednosti ćelije

U slučaju da želite usporediti svaku ćeliju u ciljnom stupcu s drugim popisom stavki i vratiti drugu vrijednost za svako podudaranje, koristite jedan od sljedećih pristupa.

Ugniježđeno IFs

Logika ugniježđene IF formule jednostavna je: koristite zasebnu IF funkciju za testiranje svakog uvjeta i vraćate različite vrijednosti ovisno o rezultatima tih testova.

Pretpostavimo da imate popis stavki u stupcu A i želite imati njihove kratice u stupcu B. Da biste to učinili, upotrijebite sljedeću formulu:

=IF(A2="apple", "Ap", IF(A2="avocado", "Av", IF(A2="banana", "B", IF(A2="lemon", "L", ""))))

Za sve detalje o sintaksi i logici ugniježđenog IF-a pogledajte Excel ugniježđeni IF - više uvjeta u jednoj formuli.

Formula traženja

Ako tražite više kompaktnu i bolje razumljivu formulu, upotrijebite funkciju LOOKUP s traženim i povratnim vrijednostima navedenim kao vertikalne konstante polja:

Za točne rezultate, obavezno navedite vrijednosti pretraživanja abecednim redom , od A do Z.

=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})

U usporedbi s ugniježđenim IF-ovima, formula Lookup ima još jednu prednost - razumije zamjenske znakove i stoga može identificirati djelomična podudaranja.

Na primjer, ako stupac A sadrži nekoliko sortiranja banana, možete potražiti "*banana*" i imati istu skraćenicu ("B") vraćenu za sve takve ćelije:

=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})

Za više informacija pogledajte Formulu pretraživanja kao alternativu ugniježđenim IF-ovima.

Formula Vlookupa

Kada radite s varijabilnim skupom podataka, možda bi bilo prikladnije unijeti popis podudaranja u zasebno ćelije i dohvatite ih pomoću Vlookup formule,npr.:

=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )

Za više informacija pogledajte vodič za Excel VLOOKUP za početnike.

Ovako možete provjeriti je li ćelija sadrži bilo koju vrijednost ili određeni tekst u Excelu. Sljedeći tjedan nastavit ćemo s pregledom Excelove ćelije Ako ćelija sadrži formule i naučiti kako brojati ili zbrajati relevantne ćelije, kopirati ili ukloniti cijele retke koji sadrže te ćelije i više. Pratite nas!

Radna bilježnica

Excel ako ćelija sadrži - primjeri formula (.xlsx datoteka)