સામગ્રીઓનું કોષ્ટક
ટ્યુટોરીયલ સંખ્યાબંધ "એક્સેલ જો સમાવિષ્ટ હોય તો" ફોર્મ્યુલા ઉદાહરણો પૂરા પાડે છે જે દર્શાવે છે કે જો લક્ષ્ય કોષમાં આવશ્યક મૂલ્ય હોય તો બીજી કૉલમમાં કંઈક કેવી રીતે પરત કરવું, આંશિક મેચ સાથે કેવી રીતે શોધવું અને OR તરીકે બહુવિધ માપદંડોનું પરીક્ષણ કરવું તેમજ AND લોજિક.
એક્સેલમાં સૌથી સામાન્ય કાર્યોમાંનું એક એ તપાસવાનું છે કે કોષમાં રસનું મૂલ્ય છે કે નહીં. તે કયા પ્રકારનું મૂલ્ય હોઈ શકે? ફક્ત કોઈપણ ટેક્સ્ટ અથવા નંબર, ચોક્કસ ટેક્સ્ટ, અથવા કોઈપણ મૂલ્ય (ખાલી કોષ નથી).
એક્સેલમાં "જો સેલ સમાવે છે" ફોર્મ્યુલાની ઘણી વિવિધતાઓ અસ્તિત્વમાં છે, તમે જે મૂલ્યો શોધવા માંગો છો તેના આધારે. સામાન્ય રીતે, તમે લોજિકલ ટેસ્ટ કરવા માટે IF ફંક્શનનો ઉપયોગ કરશો અને જ્યારે શરત પૂરી થાય ત્યારે એક મૂલ્ય (સેલ સમાવે છે) અને/અથવા જ્યારે શરત પૂરી ન થાય ત્યારે (કોષ સમાવિષ્ટ નથી) એક મૂલ્ય પરત કરશો. નીચેના ઉદાહરણો સૌથી વધુ વારંવાર આવતા દૃશ્યોને આવરી લે છે.
જો કોષમાં કોઈ મૂલ્ય હોય, તો પછી
શરૂઆત માટે, ચાલો જોઈએ કે કોઈ પણ વસ્તુ ધરાવતા કોષોને કેવી રીતે શોધી શકાય: કોઈપણ ટેક્સ્ટ, નંબર અથવા તારીખ. આ માટે, અમે એક સરળ IF ફોર્મ્યુલાનો ઉપયોગ કરવા જઈ રહ્યા છીએ જે બિન-ખાલી કોષોની તપાસ કરે છે.
IF( cell"", value_to_return, "")માટે ઉદાહરણ તરીકે, જો સમાન પંક્તિમાં કૉલમ A ના કોષમાં કોઈપણ મૂલ્ય હોય તો કૉલમ B માં "ખાલી નથી" પરત કરવા માટે, તમે B2 માં નીચેનું સૂત્ર દાખલ કરો, અને પછી સૂત્રને નીચે કૉપિ કરવા માટે નીચેના-જમણા ખૂણામાં નાના લીલા ચોરસ પર ડબલ ક્લિક કરો. આકૉલમ:
=IF(A2"", "Not blank", "")
પરિણામ આના જેવું જ દેખાશે:
જો સેલમાં ટેક્સ્ટ હશે, તો પછી
જો તમે સંખ્યાઓ અને તારીખોને અવગણીને ફક્ત ટેક્સ્ટ મૂલ્યો ધરાવતા કોષો શોધવા માંગતા હો, તો ISTEXT ફંક્શન સાથે સંયોજનમાં IF નો ઉપયોગ કરો. જો લક્ષ્ય કોષમાં કોઈપણ ટેક્સ્ટ :
IF(ISTEXT( cell), value_to_returnહોય તો બીજા કોષમાં અમુક મૂલ્ય પરત કરવા માટે અહીં સામાન્ય સૂત્ર છે. ")ધારો કે, તમે કૉલમ B માં "હા" શબ્દ દાખલ કરવા માગો છો જો કૉલમ A ના કોષમાં ટેક્સ્ટ હોય. તે પૂર્ણ કરવા માટે, નીચેના સૂત્રને B2 માં મૂકો:
=IF(ISTEXT(A2), "Yes", "")
જો કોષમાં સંખ્યા હોય, તો પછી
તે જ રીતે , તમે આંકડાકીય મૂલ્યો (સંખ્યાઓ અને તારીખો) સાથે કોષોને ઓળખી શકો છો. આ માટે, ISNUMBER સાથે IF ફંક્શનનો ઉપયોગ કરો:
IF(ISNUMBER( cell), value_to_return, "")નીચેનું સૂત્ર કૉલમમાં "હા" આપે છે B જો કૉલમ A માં અનુરૂપ કોષમાં કોઈપણ સંખ્યા હોય તો:
=IF(ISNUMBER(A2), "Yes", "")
જો કોષમાં ચોક્કસ ટેક્સ્ટ હોય તો
ચોક્કસ ટેક્સ્ટ ધરાવતા કોષો શોધો (અથવા સંખ્યાઓ અથવા તારીખો) સરળ છે. તમે નિયમિત IF ફોર્મ્યુલા લખો છો જે તપાસે છે કે લક્ષ્ય કોષમાં ઇચ્છિત ટેક્સ્ટ છે કે કેમ, અને value_if_true દલીલમાં પાછા ફરવા માટે ટેક્સ્ટ ટાઇપ કરો.
IF( cell=" ટેક્સ્ટ", વેલ્યુ_ટુ_રીટર્ન, "")ઉદાહરણ તરીકે, સેલ A2 માં "સફરજન" છે કે કેમ તે શોધવા માટે, આ ફોર્મ્યુલાનો ઉપયોગ કરો:
=IF(A2="apples", "Yes", "")
જો કોષમાં ચોક્કસ ન હોયટેક્સ્ટ
જો તમે વિપરીત પરિણામ શોધી રહ્યા છો, એટલે કે જો લક્ષ્ય કોષમાં ઉલ્લેખિત ટેક્સ્ટ ("સફરજન") ન હોય તો બીજી કૉલમમાં અમુક મૂલ્ય પરત કરો, પછી નીચેનામાંથી એક કરો.
value_if_true દલીલમાં ખાલી સ્ટ્રિંગ ("") અને value_if_false વાદ:
=IF(A2="apples", "", "Not apples")
અથવા પરત કરવા માટે ટેક્સ્ટ આપો , logical_test માં "not equal to" ઓપરેટર મૂકો અને value_if_true:
=IF(A2"apples", "Not apples", "")
કોઈપણ રીતે, ફોર્મ્યુલા ઉત્પન્ન કરશે. આ પરિણામ:
જો કોષમાં ટેક્સ્ટ છે: કેસ-સંવેદનશીલ ફોર્મ્યુલા
તમારા ફોર્મ્યુલાને અપરકેસ અને લોઅરકેસ અક્ષરો વચ્ચે તફાવત કરવા દબાણ કરવા માટે, EXACT ફંક્શનનો ઉપયોગ કરો જે લેટર કેસ સહિત બે ટેક્સ્ટ સ્ટ્રિંગ બરાબર સમાન છે કે કેમ તે ચકાસે છે:
=IF(EXACT(A2,"APPLES"), "Yes", "")
તમે અમુક સેલમાં મોડેલ ટેક્સ્ટ સ્ટ્રિંગ પણ ઇનપુટ કરી શકો છો (કહો C1), સેલ સંદર્ભને $ ચિહ્ન ($C$1) સાથે ઠીક કરો, અને તે સેલ સાથે લક્ષ્ય કોષની તુલના કરો:
=IF(EXACT(A2,$C$1), "Yes", "")
જો સેલ ચોક્કસ ટેક્સ્ટ સ્ટ્રિંગ સમાવે છે (આંશિક મેળ)
અમે નજીવા કાર્યો સાથે પૂર્ણ કર્યા છે અને વધુ પડકારરૂપ અને રસપ્રદ કાર્યો તરફ આગળ વધીએ છીએ :) આ ઉદાહરણમાં, આપેલ અક્ષર અથવા સબસ્ટ્રિંગ કોષનો ભાગ છે કે કેમ તે શોધવા માટે તે ત્રણ અલગ-અલગ કાર્યો લે છે. સામગ્રીઓ:
IF(ISNUMBER(SEARCH(" text", cell)), value_to_return,"")અંદરથી કામ કરવું , અહીં સૂત્ર શું કરે છે તે છે:
- TheSEARCH ફંક્શન ટેક્સ્ટ સ્ટ્રિંગ માટે શોધ કરે છે, અને જો સ્ટ્રિંગ મળે છે, તો પ્રથમ અક્ષરની સ્થિતિ, #VALUE! અન્યથા ભૂલ.
- ISNUMBER ફંક્શન તપાસે છે કે SEARCH સફળ થયું કે નિષ્ફળ. જો SEARCH એ કોઈપણ નંબર પરત કર્યો હોય, તો ISNUMBER TRUE પરત કરે છે. જો SEARCH ભૂલમાં પરિણમે છે, તો ISNUMBER FALSE પરત કરે છે.
- અંતઃ, IF ફંક્શન તાર્કિક પરીક્ષણમાં TRUE ધરાવતા કોષો માટે નિર્દિષ્ટ મૂલ્ય આપે છે, અન્યથા ખાલી સ્ટ્રિંગ ("").
અને હવે, ચાલો જોઈએ કે આ સામાન્ય સૂત્ર વાસ્તવિક જીવનની વર્કશીટ્સમાં કેવી રીતે કામ કરે છે.
જો કોષમાં ચોક્કસ ટેક્સ્ટ હોય, તો બીજા કોષમાં મૂલ્ય મૂકો
ધારો કે તમારી પાસે સૂચિ છે કૉલમ A માં ઓર્ડર અને તમે ચોક્કસ ઓળખકર્તા સાથે ઓર્ડર શોધવા માંગો છો, "A-" કહો. આ કાર્ય આ સૂત્ર વડે પૂર્ણ કરી શકાય છે:
=IF(ISNUMBER(SEARCH("A-",A2)),"Valid","")
સૂત્રમાં સ્ટ્રિંગને હાર્ડકોડ કરવાને બદલે, તમે તેને એક અલગ કોષ (E1) માં ઇનપુટ કરી શકો છો, જે તમારા સૂત્રમાં તે કોષનો સંદર્ભ છે. :
=IF(ISNUMBER(SEARCH($E$1,A2)),"Valid","")
સૂત્ર યોગ્ય રીતે કાર્ય કરવા માટે, $ ચિહ્ન (સંપૂર્ણ સેલ સંદર્ભ) સાથે સ્ટ્રિંગ ધરાવતા સેલના સરનામાને લૉક કરવાની ખાતરી કરો.
જો સેલમાં ચોક્કસ ટેક્સ્ટ હોય, તો તેને બીજા કૉલમમાં કૉપિ કરો
જો તમે માન્ય કોષોની સામગ્રીને બીજે ક્યાંક કૉપિ કરવા માંગતા હો, તો ફક્ત મૂલ્યાંકન કરેલ સેલનું સરનામું આપો (A2) value_if_true વાદમાં:
=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")
નીચેનો સ્ક્રીનશોટ પરિણામો બતાવે છે:
જોકોષમાં ચોક્કસ ટેક્સ્ટ છે: કેસ-સંવેદનશીલ સૂત્ર
ઉપરના બંને ઉદાહરણોમાં, સૂત્રો કેસ-સંવેદનશીલ છે. પરિસ્થિતિઓમાં જ્યારે તમે કેસ-સંવેદનશીલ ડેટા સાથે કામ કરો છો, ત્યારે કેરેક્ટર કેસને અલગ પાડવા માટે SEARCH ને બદલે FIND ફંક્શનનો ઉપયોગ કરો.
ઉદાહરણ તરીકે, નીચેનું સૂત્ર ફક્ત અપરકેસ "A-" લોઅરકેસને અવગણીને ઓર્ડરને ઓળખશે. a-."
=IF(ISNUMBER(FIND("A-",A2)),"Valid","")
જો કોષમાં ઘણી ટેક્સ્ટ સ્ટ્રીંગ્સમાંથી એક હોય (અથવા તર્ક)
ઓછામાં ઓછા સમાવતા કોષોને ઓળખવા માટે તમે જે ઘણી વસ્તુઓ શોધી રહ્યા છો તેમાંથી એક, નીચેના ફોર્મ્યુલામાંથી એકનો ઉપયોગ કરો.
IF OR ISNUMBER SEARCH ફોર્મ્યુલા
સૌથી સ્પષ્ટ અભિગમ એ છે કે દરેક સબસ્ટ્રિંગને વ્યક્તિગત રીતે તપાસવું અને OR ફંક્શન ધરાવવું જો ઓછામાં ઓછી એક સબસ્ટ્રિંગ મળી આવે તો IF ફોર્મ્યુલાના લોજિકલ ટેસ્ટમાં TRUE પરત કરો:
IF(OR(ISNUMBER(SEARCH(" string1), cell)), ISNUMBER (SEARCH(" string2", cell))), value_to_return, "")ધારો કે તમારી પાસે કૉલમ A માં SKU ની સૂચિ છે અને તમે "ડ્રેસ" અથવા "સ્કર્ટ" શામેલ હોય તે શોધવા માંગો છો. તમે આ ફોર્મ્યુલાનો ઉપયોગ કરીને તે કરી શકો છો:
=IF(OR(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("skirt",A2))),"Valid ","")
ફોર્મ્યુલા કેટલીક વસ્તુઓ માટે ખૂબ સારી રીતે કાર્ય કરે છે, પરંતુ તે ચોક્કસપણે આ રીત નથી જો તમારે ઘણી વસ્તુઓ તપાસવી હોય તો જાઓ. આ કિસ્સામાં, આગલા ઉદાહરણમાં બતાવ્યા પ્રમાણે SUMPRODUCT ફંક્શનનો ઉપયોગ કરવાનો વધુ સારો અભિગમ હશે.
SUMPRODUCT ISNUMBER શોધ સૂત્ર
જો તમેબહુવિધ ટેક્સ્ટ સ્ટ્રીંગ્સ સાથે કામ કરવું, દરેક સ્ટ્રિંગને વ્યક્તિગત રીતે શોધવાથી તમારું સૂત્ર ખૂબ લાંબુ અને વાંચવું મુશ્કેલ બનશે. વધુ ભવ્ય ઉકેલ એ SUMPRODUCT ફંક્શનમાં ISNUMBER શોધ સંયોજનને એમ્બેડ કરવાનું હશે, અને જુઓ કે શું પરિણામ શૂન્ય કરતા વધારે છે:
SUMPRODUCT(--ISNUMBER(SEARCH( strings, cell))))>0ઉદાહરણ તરીકે, A2 કોષો D2:D4 માં કોઈપણ શબ્દોનો ઇનપુટ ધરાવે છે કે કેમ તે શોધવા માટે, આ સૂત્રનો ઉપયોગ કરો:
=SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0
વૈકલ્પિક રીતે, તમે શોધવા માટે શબ્દમાળાઓ ધરાવતી નામવાળી શ્રેણી બનાવી શકો છો અથવા સીધા જ સૂત્રમાં શબ્દો આપી શકો છો:
=SUMPRODUCT(--ISNUMBER(SEARCH({"dress","skirt","jeans"},A2)))>0
કોઈપણ રીતે, પરિણામ આના જેવું જ હશે:
આઉટપુટને વધુ યુઝર-ફ્રેન્ડલી બનાવવા માટે, તમે ઉપરોક્ત ફોર્મ્યુલાને IF ફંક્શનમાં નેસ્ટ કરી શકો છો અને TRUE/FALSE મૂલ્યોને બદલે તમારું પોતાનું લખાણ પરત કરી શકો છો:
=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Valid", "")
આ ફોર્મ્યુલા કેવી રીતે કાર્ય કરે છે
મુખ્ય સ્થાને, તમે અગાઉના ઉદાહરણમાં સમજાવ્યા મુજબ SEARCH સાથે ISNUMBER નો ઉપયોગ કરો છો. આ કિસ્સામાં, શોધ પરિણામો એરેના સ્વરૂપમાં રજૂ થાય છે જેમ કે {TRUE;FALSE;FALSE}. જો કોષમાં ઉલ્લેખિત સબસ્ટ્રિંગમાંથી ઓછામાં ઓછું એક હોય, તો એરેમાં TRUE હશે. ડબલ યુનરી ઓપરેટર (--) TRUE/FALSE મૂલ્યોને અનુક્રમે 1 અને 0 પર દબાણ કરે છે અને {1;0;0} જેવી એરે પહોંચાડે છે. છેલ્લે, SUMPRODUCT ફંક્શન સંખ્યાઓ ઉમેરે છે, અને જ્યાં પરિણામ શૂન્ય કરતા વધારે હોય ત્યાં અમે કોષો પસંદ કરીએ છીએ.
જોકોષમાં અનેક શબ્દમાળાઓ છે (અને તર્ક)
પરિસ્થિતિઓમાં જ્યારે તમે સ્પષ્ટ કરેલ તમામ ટેક્સ્ટ સ્ટ્રીંગ્સ ધરાવતા કોષો શોધવા માંગતા હો, તો IF AND:
IF(AND(ISNUMBER) સાથે પહેલેથી જ પરિચિત ISNUMBER શોધ સંયોજનનો ઉપયોગ કરો (SEARCH(" string1", cell)), ISNUMBER(SEARCH(" string2", cell))), value_to_return,"")ઉદાહરણ તરીકે, તમે આ ફોર્મ્યુલા સાથે "ડ્રેસ" અને "બ્લુ" બંને ધરાવતા SKU શોધી શકો છો:
=IF(AND(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("blue",A2))),"Valid ","")
અથવા, તમે ટાઇપ કરી શકો છો અલગ કોષોમાંની સ્ટ્રીંગ્સ અને તે કોષોને તમારા સૂત્રમાં સંદર્ભિત કરો:
=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2))),"Valid ","")
એક વૈકલ્પિક ઉકેલ તરીકે, તમે દરેક સ્ટ્રીંગની ઘટનાઓની ગણતરી કરી શકો છો અને તપાસો જો દરેક ગણતરી શૂન્ય કરતા વધારે હોય તો:
=IF(AND(COUNTIF(A2,"*dress*")>0,COUNTIF(A2,"*blue*")>0),"Valid","")
પરિણામ ઉપરના સ્ક્રીનશૉટમાં બતાવ્યા પ્રમાણે બરાબર હશે.
સેલ મૂલ્યના આધારે વિવિધ પરિણામો કેવી રીતે પરત કરવા
જો તમે આઇટમ્સની અન્ય સૂચિ સાથે લક્ષ્ય કૉલમમાં દરેક કોષની તુલના કરવા માંગતા હો અને દરેક મેચ માટે અલગ મૂલ્ય પરત કરવા માંગતા હો, તો નીચેનામાંથી એક અભિગમનો ઉપયોગ કરો.
નેસ્ટેડ IFs
નેસ્ટેડ IF ફોર્મ્યુલાનો તર્ક આના જેટલો સરળ છે: તમે દરેક સ્થિતિને ચકાસવા માટે અલગ IF ફંક્શનનો ઉપયોગ કરો છો અને તે પરીક્ષણોના પરિણામોના આધારે અલગ-અલગ મૂલ્યો પરત કરો છો.
IF( સેલ=" lookup_text1", " return_ text1", IF( cell=" lookup_text2", " return_ text2", IF( cell=" lookup_text3", " return_ ટેક્સ્ટ3", "")))ધારો કે તમારી પાસે કૉલમ A માં વસ્તુઓની સૂચિ છે અને તમે કૉલમ B માં તેમના સંક્ષિપ્ત શબ્દો રાખવા માંગો છો. તે પૂર્ણ કરવા માટે, નીચેના સૂત્રનો ઉપયોગ કરો:
=IF(A2="apple", "Ap", IF(A2="avocado", "Av", IF(A2="banana", "B", IF(A2="lemon", "L", ""))))
નેસ્ટેડ IF ના વાક્યરચના અને તર્ક વિશે સંપૂર્ણ વિગતો માટે, કૃપા કરીને જુઓ એક્સેલ નેસ્ટેડ IF - એક ફોર્મ્યુલામાં બહુવિધ શરતો.
લુકઅપ ફોર્મ્યુલા
જો તમે વધુ શોધી રહ્યા છો કોમ્પેક્ટ અને વધુ સારી રીતે સમજી શકાય તેવું સૂત્ર, લુકઅપ ફંક્શનનો ઉપયોગ કરો અને વર્ટિકલ એરે સ્થિરાંકો તરીકે પૂરા પાડવામાં આવેલ મૂલ્યો પરત કરો:
LOOKUP( cell, {" lookup_text1";" lookup_text2";" lookup_text3";…}, {" return_ text1";" return_ text2";" રીટર્ન_ ટેક્સ્ટ3";…})સચોટ પરિણામો માટે, લુકઅપ મૂલ્યોને મૂળાક્ષરોના ક્રમ માં સૂચિબદ્ધ કરવાની ખાતરી કરો, A થી Z સુધી.
=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})
નેસ્ટેડ IFs ની સરખામણીમાં, લુકઅપ ફોર્મ્યુલાનો એક વધુ ફાયદો છે - તે વાઇલ્ડકાર્ડ અક્ષરોને સમજે છે અને તેથી આંશિક મેળ ઓળખી શકે છે.
ઉદાહરણ તરીકે, જો કૉલમ A માં અમુક પ્રકારના કેળામાંથી, તમે "*બનાના*" શોધી શકો છો અને આવા તમામ કોષો માટે સમાન સંક્ષેપ ("B") પરત કરી શકો છો:
=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})
વધુ માહિતી માટે, કૃપા કરીને નેસ્ટેડ IFs ના વિકલ્પ તરીકે લુકઅપ ફોર્મ્યુલા જુઓ.
Vlookup ફોર્મ્યુલા
જ્યારે વેરિયેબલ ડેટા સેટ સાથે કામ કરો, ત્યારે અલગમાં મેચોની સૂચિ ઇનપુટ કરવી વધુ અનુકૂળ હોઈ શકે છે. કોષો અને Vlookup ફોર્મ્યુલાનો ઉપયોગ કરીને તેમને પુનઃપ્રાપ્ત કરો,દા.ત.:
=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )
વધુ માહિતી માટે, કૃપા કરીને નવા નિશાળીયા માટે એક્સેલ VLOOKUP ટ્યુટોરીયલ જુઓ.
આ રીતે તમે તપાસો છો કે સેલ Excel માં કોઈપણ મૂલ્ય અથવા ચોક્કસ ટેક્સ્ટ ધરાવે છે. આવતા અઠવાડિયે, અમે એક્સેલના જો કોષમાં ફોર્મ્યુલા છે તે જોવાનું ચાલુ રાખીશું અને સંબંધિત કોષોને કેવી રીતે ગણવા અથવા સરવાળો કરવા, તે કોષો ધરાવતી સમગ્ર પંક્તિઓની નકલ કરવી અથવા દૂર કરવી વગેરે શીખીશું. કૃપા કરીને ટ્યુન રહો!
વર્કબુકની પ્રેક્ટિસ કરો
એક્સેલ જો સેલ સમાવે છે - ફોર્મ્યુલા ઉદાહરણો (.xlsx ફાઇલ)
