이 자습서는 대상 셀에 필수 값이 포함된 경우 다른 열에 무언가를 반환하는 방법, 부분 일치로 검색하는 방법 및 OR을 사용하여 여러 기준을 테스트하는 방법을 보여주는 여러 "포함하는 경우 Excel" 수식 예제를 제공합니다. AND 논리도 마찬가지입니다.

Excel에서 가장 일반적인 작업 중 하나는 셀에 원하는 값이 포함되어 있는지 확인하는 것입니다. 어떤 종류의 가치가 될 수 있습니까? 임의의 텍스트나 숫자, 특정 텍스트 또는 임의의 값(빈 셀이 아님).

찾고자 하는 값에 따라 Excel의 "셀에 다음이 포함된 경우" 수식의 여러 변형이 있습니다. 일반적으로 IF 함수를 사용하여 논리 테스트를 수행하고 조건이 충족되면(셀 포함) 하나의 값을 반환하고 조건이 충족되지 않으면(셀에 포함되지 않음) 다른 값을 반환합니다. 아래 예는 가장 자주 발생하는 시나리오를 다룹니다.

셀에 값이 있으면

먼저 무엇이든 포함하는 셀을 찾는 방법을 살펴보겠습니다. 텍스트, 숫자 또는 날짜. 이를 위해 비어 있지 않은 셀을 확인하는 간단한 IF 수식을 사용합니다.

For 예를 들어, 같은 행에 있는 A열의 셀에 값이 포함된 경우 B열에 "Not blank"를 반환하려면 B2에 다음 수식을 입력한 다음 오른쪽 하단 모서리에 있는 작은 녹색 사각형을 두 번 클릭하여 수식을 아래로 복사합니다. 그만큼column:

=IF(A2"", "Not blank", "")

결과는 다음과 유사합니다.

셀에 텍스트가 포함된 경우

숫자와 날짜를 무시하고 텍스트 값이 있는 셀만 찾으려면 ISTEXT 함수와 함께 IF를 사용하십시오. 다음은 대상 셀에 텍스트 가 포함된 경우 다른 셀에 일부 값을 반환하는 일반 공식입니다.

A 열의 셀에 텍스트가 포함된 경우 B 열에 "yes"라는 단어를 삽입한다고 가정합니다. 완료하려면 B2에 다음 수식을 입력합니다.

=IF(ISTEXT(A2), "Yes", "")

셀에 숫자가 포함된 경우

유사한 방식 , 숫자 값(숫자 및 날짜)이 있는 셀을 식별할 수 있습니다. 이를 위해 IF 함수를 ISNUMBER와 함께 사용합니다.

다음 수식은 열에 "yes"를 반환합니다. A 열의 해당 셀에 숫자가 포함된 경우 B:

=IF(ISNUMBER(A2), "Yes", "")

셀에 특정 텍스트가 포함된 경우

특정 텍스트가 포함된 셀 찾기 (또는 숫자 또는 날짜)는 쉽습니다. 대상 셀에 원하는 텍스트가 포함되어 있는지 확인하는 일반 IF 수식을 작성하고 value_if_true 인수에 반환할 텍스트를 입력합니다.

예를 들어 셀 A2에 "사과"가 포함되어 있는지 확인하려면 다음 수식을 사용하세요.

=IF(A2="apples", "Yes", "")

셀에 특정 정보가 포함되지 않은 경우text

반대 결과를 찾는 경우, 즉 대상 셀에 지정된 텍스트("사과")가 포함되지 않은 경우 다른 열에 일부 값을 반환하려면 다음 중 하나를 수행하십시오.

value_if_true 인수에 빈 문자열("")을 제공하고 value_if_false 인수에 반환할 텍스트를 제공합니다.

=IF(A2="apples", "", "Not apples")

또는 , logical_test 에 "같지 않음" 연산자를 입력하고 value_if_true:

=IF(A2"apples", "Not apples", "")

에 반환할 텍스트를 입력합니다. 이 결과는 다음과 같습니다.

셀에 텍스트가 포함된 경우: 대소문자 구분 수식

수식이 대문자와 소문자를 구분하도록 강제하려면 다음과 같은 EXACT 함수를 사용하십시오. 대소문자를 포함하여 두 텍스트 문자열이 정확히 동일한지 확인합니다.

=IF(EXACT(A2,"APPLES"), "Yes", "")

일부 셀에 모델 텍스트 문자열을 입력할 수도 있습니다(예: C1) 셀 참조를 $ 기호($C$1)로 고정하고 대상 셀을 해당 셀과 비교합니다.

=IF(EXACT(A2,$C$1), "Yes", "")

If 셀 특정 텍스트 문자열 포함 (부분 일치)

사소한 작업을 마치고 더 어렵고 흥미로운 작업으로 넘어갑니다 :) 이 예제에서는 주어진 문자 또는 하위 문자열이 셀의 일부인지 확인하기 위해 세 가지 다른 기능을 사용합니다. 내용:

내부에서 작업 , 수식이 수행하는 작업은 다음과 같습니다.

• TheSEARCH 함수는 텍스트 문자열을 검색하고 문자열이 발견되면 첫 번째 문자의 위치인 #VALUE! 그렇지 않으면 오류입니다.
• ISNUMBER 기능은 SEARCH가 성공했는지 실패했는지 확인합니다. SEARCH가 숫자를 반환하면 ISNUMBER는 TRUE를 반환합니다. SEARCH에서 오류가 발생하면 ISNUMBER는 FALSE를 반환합니다.
• 마지막으로 IF 함수는 논리 테스트에서 TRUE인 셀에 대해 지정된 값을 반환하고 그렇지 않으면 빈 문자열("")을 반환합니다.

이제 이 일반 공식이 실제 워크시트에서 어떻게 작동하는지 살펴보겠습니다.

셀에 특정 텍스트가 포함되어 있으면 다른 셀에 값을 입력합니다.

A열에 주문이 있고 특정 식별자(예: "A-")가 있는 주문을 찾으려고 합니다. 다음 수식을 사용하여 작업을 수행할 수 있습니다.

=IF(ISNUMBER(SEARCH("A-",A2)),"Valid","")

수식에 문자열을 하드코딩하는 대신 별도의 셀(E1)에 입력할 수 있습니다. :

=IF(ISNUMBER(SEARCH($E$1,A2)),"Valid","")

수식이 올바르게 작동하려면 문자열이 포함된 셀의 주소를 $ 기호(절대 셀 참조)로 잠가야 합니다.

셀에 특정 텍스트가 포함되어 있으면 다른 열에 복사하십시오.

유효한 셀의 내용을 다른 곳에 복사하려면 평가된 셀의 주소를 제공하십시오(A2). value_if_true 인수:

=IF(ISNUMBER(SEARCH($E$1,A2)),A2,"")

아래 스크린샷은 결과를 보여줍니다.

If셀에 특정 텍스트 포함: 대소문자 구분 수식

위의 두 예에서 수식은 대소문자를 구분하지 않습니다. 대소문자를 구분하는 데이터로 작업하는 경우에는 SEARCH 대신 FIND 함수를 사용하여 대소문자를 구별하십시오.

예를 들어 다음 수식은 소문자 "를 무시하고 대문자 "A-"가 있는 주문만 식별합니다. a-".

=IF(ISNUMBER(FIND("A-",A2)),"Valid","")

셀에 여러 텍스트 문자열(OR 논리) 중 하나가 포함된 경우

적어도 찾고 있는 많은 항목 중 하나를 찾으려면 다음 공식 중 하나를 사용하십시오.

IF OR ISNUMBER SEARCH 공식

가장 확실한 방법은 각 하위 문자열을 개별적으로 확인하고 OR 기능을 사용하는 것입니다. 하나 이상의 하위 문자열이 발견되면 IF 수식의 논리 테스트에서 TRUE를 반환합니다.

A열에 SKU 목록이 있고 "드레스" 또는 "스커트"를 포함하는 항목을 찾고 싶습니다. 다음 수식을 사용하여 수행할 수 있습니다.

=IF(OR(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("skirt",A2))),"Valid ","")

이 수식은 몇 가지 항목에 대해 꽤 잘 작동하지만 확실히 방법은 아닙니다. 많은 것을 확인하고 싶다면 가십시오. 이 경우 다음 예제와 같이 SUMPRODUCT 함수를 사용하는 것이 더 나은 접근 방식입니다.

SUMPRODUCT ISNUMBER SEARCH 수식

다음과 같은 경우여러 텍스트 문자열을 처리하는 경우 각 문자열을 개별적으로 검색하면 수식이 너무 길고 읽기 어려워집니다. 보다 우아한 솔루션은 ISNUMBER SEARCH 조합을 SUMPRODUCT 함수에 포함하고 결과가 0보다 큰지 확인하는 것입니다.

예를 들어 A2에 D2:D4 셀에 입력된 단어가 포함되어 있는지 확인하려면 다음 수식을 사용합니다.

=SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0

또는 검색할 문자열을 포함하는 명명된 범위를 만들거나 수식에 직접 단어를 제공할 수 있습니다.

=SUMPRODUCT(--ISNUMBER(SEARCH({"dress","skirt","jeans"},A2)))>0

어느 쪽이든 결과는 다음과 유사합니다.

보다 사용자 친화적인 출력을 만들려면 위 공식을 IF 함수에 중첩하고 TRUE/FALSE 값 대신 자신의 텍스트를 반환할 수 있습니다.

=IF(SUMPRODUCT(--ISNUMBER(SEARCH($D$2:$D$4,A2)))>0, "Valid", "")

이 수식이 작동하는 방식

핵심에서는 이전 예에서 설명한 대로 SEARCH와 함께 ISNUMBER를 사용합니다. 이때 검색 결과는 {TRUE;FALSE;FALSE}와 같은 배열 형태로 표현된다. 셀에 지정된 하위 문자열 중 하나 이상이 포함되어 있으면 배열에 TRUE가 있습니다. 이중 단항 연산자(--)는 TRUE/FALSE 값을 각각 1과 0으로 강제 변환하고 {1;0;0}과 같은 배열을 전달합니다. 마지막으로 SUMPRODUCT 함수는 숫자를 더하고 결과가 0보다 큰 셀을 선택합니다.

만약셀에 여러 문자열(AND 논리)이 포함됨

지정된 텍스트 문자열이 모두 포함된 셀을 찾으려면 IF AND:

예를 들어 다음 수식을 사용하여 "드레스"와 "파란색"을 모두 포함하는 SKU를 찾을 수 있습니다.

=IF(AND(ISNUMBER(SEARCH("dress",A2)),ISNUMBER(SEARCH("blue",A2))),"Valid ","")

또는 다음을 입력할 수 있습니다. 문자열을 별도의 셀에 넣고 수식에서 해당 셀을 참조합니다.

=IF(AND(ISNUMBER(SEARCH($D$2,A2)),ISNUMBER(SEARCH($E$2,A2))),"Valid ","")

대체 솔루션으로 각 문자열의 발생 횟수를 계산하고 확인할 수 있습니다. 각 개수가 0보다 큰 경우:

=IF(AND(COUNTIF(A2,"*dress*")>0,COUNTIF(A2,"*blue*")>0),"Valid","")

결과는 위의 스크린샷에 표시된 것과 똑같습니다.

셀 값에 따라 다른 결과를 반환하는 방법

대상 열의 각 셀을 다른 항목 목록과 비교하고 각 일치 항목에 대해 다른 값을 반환하려는 경우 다음 접근 방식 중 하나를 사용합니다.

중첩 IFs

중첩된 IF 수식의 논리는 다음과 같이 간단합니다. 별도의 IF 함수를 사용하여 각 조건을 테스트하고 이러한 테스트 결과에 따라 다른 값을 반환합니다.

A 열에 항목 목록이 있고 B 열에 해당 약어가 있다고 가정합니다. 이렇게 하려면 다음 수식을 사용하십시오.

=IF(A2="apple", "Ap", IF(A2="avocado", "Av", IF(A2="banana", "B", IF(A2="lemon", "L", ""))))

중첩된 IF의 구문 및 논리에 대한 자세한 내용은 Excel 중첩된 IF - 단일 수식의 여러 조건을 참조하세요.

조회 수식

자세히 알아보려면 간결하고 이해하기 쉬운 수식을 사용하려면 LOOKUP 함수를 수직 배열 상수로 제공되는 조회 및 반환 값과 함께 사용하세요.

정확한 결과를 얻으려면 조회 값을 알파벳순 으로 나열해야 합니다. A부터 Z까지.

=LOOKUP(A2,{"apple";"avocado";"banana";"lemon"},{"Ap";"Av";"B";"L"})

내포된 IF와 비교할 때 조회 수식에는 와일드카드 문자<10를 이해한다는 장점이 하나 더 있습니다> 따라서 부분 일치 항목을 식별할 수 있습니다.

예를 들어 A 열에 몇 가지 정렬이 포함된 경우 바나나의 경우 "*banana*"를 조회하고 이러한 모든 셀에 대해 동일한 약어("B")가 반환되도록 할 수 있습니다.

=LOOKUP(A2,{"apple";"avocado";"*banana*";"lemon"},{"Ap";"Av";"B";"L"})

자세한 내용은 중첩된 IF 대신 조회 수식을 참조하세요.

Vlookup 수식

가변 데이터 세트로 작업할 때 일치 목록을 별도로 입력하는 것이 더 편리할 수 있습니다. Vlookup 수식을 사용하여 셀을 검색하고,예:

=VLOOKUP(A2, $D$2:$E$5, 2,FALSE )

자세한 내용은 초보자를 위한 Excel VLOOKUP 자습서를 참조하세요.

셀이 있는지 확인하는 방법입니다. Excel의 모든 값 또는 특정 텍스트를 포함합니다. 다음 주에는 Excel의 셀에 수식이 포함된 경우를 계속 살펴보고 관련 셀을 계산하거나 합계하는 방법, 해당 셀이 포함된 전체 행을 복사하거나 제거하는 방법 등을 알아봅니다. 계속 지켜봐 주세요!

연습 워크북

셀에 Excel 포함 - 수식 예제(.xlsx 파일)